configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.60)
   3 AC_INIT(libpwmd, 7.0.0, [Ben Kibbey bjk@luxsci.net])
   4 AC_CONFIG_MACRO_DIR([m4])
   5 AC_CONFIG_AUX_DIR(build)
   6 AC_CANONICAL_TARGET
   7 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   8 AC_PROG_MAKE_SET
   9 #AC_DISABLE_SHARED
  10 AC_USE_SYSTEM_EXTENSIONS
  11 AC_PROG_LIBTOOL
  12 AC_CONFIG_SRCDIR([src/libpwmd.c])
  13 AM_CONFIG_HEADER([config.h])
  14 AM_GNU_GETTEXT([external])
  15 AM_GNU_GETTEXT_VERSION([0.16.1])
  16
  17 VER_MAJOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`"
  18 VER_MINOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`"
  19 VER_PATCH="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`"
  20 AC_SUBST(VER_MAJOR)
  21 AC_SUBST(VER_MINOR)
  22 AC_SUBST(VER_PATCH)
  23 VER_MAJOR_HEX=`printf "%02X" $VER_MAJOR`
  24 VER_MINOR_HEX=`printf "%02X" $VER_MINOR`
  25 VER_PATCH_HEX=`printf "%02X" $VER_PATCH`
  26 AC_SUBST(VER_MAJOR_HEX)
  27 AC_SUBST(VER_MINOR_HEX)
  28 AC_SUBST(VER_PATCH_HEX)
  29 VER_STRING="\"$VERSION\""
  30 AC_SUBST(VER_STRING)
  31
  32 case "$target_os" in
  33     darwin*)
  34         LDFLAGS="$LDFLAGS -flat_namespace -L/sw/lib"
  35         CPPFLAGS="$CPPFLAGS -I/sw/include -L/sw/lib"
  36         ;;
  37     linux*)
  38         case "$target_cpu" in
  39             x86_64*)
  40                 LDFLAGS="$LDFLAGS -lrt"
  41                 ;;
  42             *)
  43                 ;;
  44         esac
  45         ;;
  46     *)
  47         ;;
  48 esac
  49
  50 dnl Checks for programs.
  51 AC_PROG_CC_C99
  52
  53 if test "$ac_cv_prog_cc_c99" = "no"; then
  54     AC_MSG_ERROR("Unable to find a C99 compatible compiler.")
  55 fi
  56
  57 dnl Borrowed from libssh2!
  58 dnl ************************************************************
  59 dnl Enable hiding of internal symbols in library to reduce its size and
  60 dnl speed dynamic linking of applications.  This currently is only supported
  61 dnl on gcc >= 4.0 and SunPro C.
  62 dnl
  63 AC_MSG_CHECKING([whether to enable hidden symbols in the library])
  64 AC_ARG_ENABLE(hidden-symbols,
  65 AC_HELP_STRING([--enable-hidden-symbols],[Hide internal symbols in library])
  66 AC_HELP_STRING([--disable-hidden-symbols],[Leave all symbols with default visibility in library]),
  67 [ case "$enableval" in
  68   no)
  69        AC_MSG_RESULT(no)
  70        ;;
  71   *)
  72        AC_MSG_CHECKING([whether $CC supports it])
  73        if test "$GCC" = yes ; then
  74          if $CC --help --verbose 2>&1 | grep fvisibility= > /dev/null ; then
  75            AC_MSG_RESULT(yes)
  76            AC_DEFINE(LIBPWMD_API, [__attribute__ ((visibility ("default")))], [to make a symbol visible])
  77            CFLAGS="$CFLAGS -fvisibility=hidden"
  78          else
  79             AC_MSG_RESULT(no)
  80           fi
  81
  82        else
  83          dnl Test for SunPro cc
  84          if $CC 2>&1 | grep flags >/dev/null && $CC -flags | grep xldscope= >/dev/null ; then
  85            AC_MSG_RESULT(yes)
  86            AC_DEFINE(LIBPWMD_API, [__global], [to make a symbol visible])
  87            CFLAGS="$CFLAGS -xldscope=hidden"
  88          else
  89            AC_MSG_RESULT(no)
  90          fi
  91        fi
  92        ;;
  93   esac ],
  94        AC_MSG_RESULT(no)
  95 )
  96
  97 dnl Checks for header files.
  98 AC_HEADER_STDC
  99 AC_HEADER_SYS_WAIT
 100 AC_CHECK_HEADERS([fcntl.h limits.h stdlib.h string.h unistd.h sys/socket.h \
 101                   getopt.h])
 102
 103 dnl Checks for typedefs, structures, and compiler characteristics.
 104 AC_C_CONST
 105 AC_TYPE_SIZE_T
 106 AC_STRUCT_TM
 107 AC_TYPE_SSIZE_T
 108 AC_TYPE_PID_T
 109
 110 ACX_PTHREAD(, AC_MSG_ERROR([Missing or incomplete pthread installation]))
 111 PKG_PROG_PKG_CONFIG
 112
 113 AC_ARG_ENABLE(interactive, AC_HELP_STRING([--disable-interactive], [Disable interactive mode in pwmc.]),
 114                 WITH_INTERACTIVE=no, WITH_INTERACTIVE=yes)
 115 AC_MSG_CHECKING([if interactive mode is wanted])
 116 AC_MSG_RESULT($WITH_INTERACTIVE)
 117 if test "x$WITH_INTERACTIVE" = "xyes"; then
 118     VL_LIB_READLINE
 119
 120     if test "x$vl_cv_lib_readline" != "xno"; then
 121         READLINE_LIBS="$vl_cv_lib_readline"
 122         AC_SUBST(READLINE_LIBS)
 123     else
 124         AC_MSG_ERROR([Missing or incomplete readline installation.])
 125         WITH_INTERACTIVE="no"
 126     fi
 127 fi
 128 AM_CONDITIONAL([WITH_READLINE], [test x"$vl_cv_lib_readline" != "x"])
 129
 130 AM_PATH_LIBASSUAN([2.1.0], have_libassuan_2_1_0=yes)
 131 if test x"$have_libassuan_2_1_0" != x"yes";then
 132    AM_PATH_LIBASSUAN([2.0.3],, AC_MSG_ERROR([libassuan 2.0.3 or later required.]))
 133 else
 134    AC_DEFINE(LIBASSUAN_2_1_0, 1, [Define if you have libassuan 2.1.0 or later.])
 135 fi
 136
 137 AM_PATH_GPG_ERROR(,, AC_MSG_ERROR([Missing or incomplete libgpg-error installation.]))
 138
 139 AC_ARG_ENABLE(ssh, AC_HELP_STRING([--enable-ssh], [Enable SSH support.]),
 140                 WITH_SSH=$enableval, WITH_SSH=no)
 141 AC_MSG_CHECKING([if ssh support is wanted])
 142 AC_MSG_RESULT($WITH_SSH)
 143 if test "x$WITH_SSH" = "xyes"; then
 144     AC_MSG_CHECKING([for libssh2 availability])
 145     PKG_CHECK_EXISTS([libssh2], have_libssh2=1)
 146     WITH_SSH=no
 147
 148     if test $have_libssh2; then
 149         PKG_CHECK_MODULES([libssh2], [libssh2 >= 1.2.9])
 150         AC_DEFINE(WITH_SSH, 1, [Define if you want SSH support.])
 151         WITH_SSH=yes
 152     else
 153         AC_MSG_ERROR([Missing or incomplete libssh2 installation.])
 154     fi
 155 fi
 156 AM_CONDITIONAL([WITH_SSH], [test "x$WITH_SSH" = "xyes"])
 157
 158 AC_ARG_ENABLE(gnutls, AC_HELP_STRING([--enable-gnutls],
 159               [Enable GnuTLS client support.]), WITH_GNUTLS=$enableval,
 160               WITH_GNUTLS=no)
 161 AC_MSG_CHECKING([if gnutls support is wanted])
 162 AC_MSG_RESULT($WITH_GNUTLS)
 163 if test "x$WITH_GNUTLS" = "xyes"; then
 164     AC_MSG_CHECKING([for libgnutls availability])
 165     PKG_CHECK_EXISTS(gnutls, have_libgnutls=1, AC_MSG_ERROR([gnutls pkg-config module not found]))
 166     WITH_GNUTLS=no
 167
 168     if test $have_libgnutls; then
 169         PKG_CHECK_MODULES([GNUTLS], [gnutls])
 170         AC_DEFINE(WITH_GNUTLS, 1, [Define if you want GnuTLS support.])
 171         WITH_GNUTLS=yes
 172     else
 173         AC_MSG_ERROR([Missing or incomplete gnutls installation.])
 174     fi
 175 fi
 176 AM_CONDITIONAL(WITH_GNUTLS, [test "x$WITH_GNUTLS" = "xyes"])
 177
 178 dnl Checks for library functions.
 179 AC_FUNC_MALLOC
 180 AC_FUNC_REALLOC
 181 AC_FUNC_STRFTIME
 182 AC_FUNC_SELECT_ARGTYPES
 183 AC_CHECK_FUNCS([memmove select socket strdup strerror setlocale getcwd \
 184                 memset stpcpy strchr strrchr strtok_r getopt_long getpwuid_r])
 185 AM_CONDITIONAL([NEED_GETOPT_LONG], [test "$ac_cv_func_getopt_long" != "yes"])
 186
 187 AC_DEFUN([AC_MEM_DEBUG],
 188 [
 189     if test "$1"; then
 190         ac_cv_sys_mem_debug=$1
 191     fi
 192
 193     AC_CACHE_CHECK([if memory debugging is wanted], [ac_cv_sys_mem_debug],
 194         [ac_cv_sys_mem_debug=no])
 195     AM_CONDITIONAL([WITH_MEM_DEBUG], [test "$ac_cv_sys_mem_debug" = "yes"])
 196 ])
 197
 198 AC_ARG_ENABLE(mem_debug, AC_HELP_STRING([--enable-mem-debug],
 199               [Enable memory debugging.]), AC_MEM_DEBUG([$enableval]),
 200               AC_MEM_DEBUG)
 201
 202 AM_CONDITIONAL(MEM_DEBUG, test "x${ac_cv_sys_mem_debug}" != "xno")
 203
 204 AC_ARG_ENABLE(pinentry, AC_HELP_STRING([--disable-pinentry],
 205               [Disable pinentry(1) support (not pwmd).]), WITH_PINENTRY=no,
 206               WITH_PINENTRY=yes)
 207
 208 if test "x$WITH_PINENTRY" != "xno"; then
 209     AC_CHECK_HEADERS([locale.h])
 210     AC_DEFINE(WITH_PINENTRY, 1, [Define if you want local pinentry(1) support.])
 211 fi
 212
 213 AM_CONDITIONAL([WITH_PINENTRY], [test "x$WITH_PINENTRY" = "xyes"])
 214 pinentry="/usr/bin/pinentry"
 215
 216 AC_ARG_WITH(pinentry, AC_HELP_STRING([--with-pinentry=PATH],
 217               [Default location of the pinentry binary (/usr/bin/pinentry)]),
 218               pinentry="$withval")
 219
 220 AC_SUBST(pinentry)
 221 AC_DEFINE_UNQUOTED(PINENTRY_PATH, ["$pinentry"],
 222                    [Default location of the pinentry binary.])
 223
 224 # Cracklib support (requires pinentry support).
 225 AC_ARG_ENABLE(quality, AC_HELP_STRING([--enable-quality],
 226               [Enable password quality checking with cracklib.]),
 227               WITH_QUALITY=$enableval, WITH_QUALITY=no)
 228 if test "x$WITH_QUALITY" = "xyes"; then
 229     if test "x$WITH_PINENTRY" != "xyes"; then
 230         AC_MSG_ERROR([--enable-quality needs --enable-pinentry])
 231     fi
 232
 233     AC_CHECK_HEADER([crack.h],, AC_MSG_ERROR([Missing or invalid cracklib installation.]))
 234     AC_CHECK_LIB([crack], FascistCheck,, AC_MSG_ERROR([Missing or invalid cracklib installation.]))
 235     AC_DEFINE(WITH_QUALITY, 1, [Define if you want password quality checking.])
 236 fi
 237 AM_CONDITIONAL(WITH_QUALITY, [test "x$WITH_QUALITY" = "xyes"])
 238
 239 crackdict="/var/cache/cracklib/cracklib_dict"
 240 AC_ARG_WITH(crackdict, AC_HELP_STRING([--with-crack-dict=PATH],
 241               [Location of the cracklib dictionary (/var/cache/cracklib/cracklib_dict).]),
 242               crackdict="$withval")
 243 AC_SUBST(crackdict)
 244 AC_DEFINE_UNQUOTED(CRACKLIB_DICT, ["$crackdict"], [The location of the cracklib dictionary.])
 245
 246 dnl Disable optimizing of memset(). GCC and CLang (and others?) accept
 247 dnl multiple optimization flags and use the last one specified. The
 248 dnl non-optimized memset() may still use any CPU features found in the
 249 dnl user specified CFLAGS (-mtune) and libc.
 250 CFLAGS_ORIG="$CFLAGS"
 251 CFLAGS_MEMZERO="$CFLAGS -O0"
 252 CFLAGS=
 253 AC_SUBST(CFLAGS_ORIG)
 254 AC_SUBST(CFLAGS_MEMZERO)
 255
 256 AC_CONFIG_FILES([Makefile libpwmd-7.0.pc doc/Makefile doc/doxygen.conf.in \
 257                  doc/pwmc.1 src/Makefile src/libpwmd.h po/Makefile.in])
 258 AC_OUTPUT
 259 echo
 260 echo "Features:"
 261 echo "    Interactive pwmc: $WITH_INTERACTIVE"
 262 echo "    Ssh: $WITH_SSH"
 263 echo "    GnuTLS: $WITH_GNUTLS"
 264 echo "    Local pinentry: $WITH_PINENTRY"
 265 echo "    Pinentry location: $pinentry"
 266 echo "    Local passphrase quality checking: $WITH_QUALITY"
 267 echo "    Crack dictionary: $crackdict"
 268 echo "    Memory debug: ${ac_cv_sys_mem_debug}"