prolooks/VuMeter.vala

   1 /*
   2     Copyright 2009 by Hans Baier, Krzysztof Foltman
   3     License: LGPLv2+
   4 */
   5
   6 using Gtk;
   7
   8 namespace Prolooks {
   9
  10 public class VuMeter : DrawingArea {
  11
  12     public enum Mode {
  13         STANDARD,
  14         MONOCHROME,
  15         MONOCHROME_REVERSE
  16     }
  17
  18     private Cairo.Surface? cache_surface = null;
  19     private Mode _mode = Mode.STANDARD; private double _value = 0.5;
  20
  21
  22     [Description(blurb="the displayed value, ranging from 0.0 to 1.0")]
  23     public double value {
  24         set {
  25             if (Math.fabs(_value - value) >= 0.0001)
  26                 queue_draw();
  27             _value = value;
  28         }
  29         get {
  30             return _value;
  31         }
  32     }
  33
  34     private double r = 1;
  35     private double g = 1;
  36     private double b = 0;
  37
  38     [Description(nick="monochrome color", blurb="sets the meter color in monochrome color mode, can contain a string as accepted by gdk_color_parse (), eg: #a0b1c2")]
  39     public string color {
  40         set {
  41             if (value != null & value != "") {
  42                 gdk_color_to_cairo_color (color_from_string (value), ref r, ref g, ref b);
  43                 cache_surface = null;
  44                 queue_draw ();
  45             } else {
  46                 r = 1; g = 1; b = 0;
  47             }
  48         }
  49     }
  50
  51     [Description(nick="mode", blurb="whether the vu meter should be red/yellow/green (standard), or one color (monochrome) or one color but flipped left to right (monochrome reversed)")]
  52     public Mode mode {
  53         set {
  54             if (value != _mode) {
  55                 _mode = value;
  56                 cache_surface = null;
  57                 queue_draw();
  58             }
  59         }
  60         get {
  61             return _mode;
  62         }
  63     }
  64
  65     construct {
  66         // Set favored widget size
  67         set_size_request (100, 14);
  68     }
  69
  70     public override void size_allocate (Gdk.Rectangle allocation) {
  71         base.size_allocate (allocation);
  72         cache_surface = null;
  73     }
  74
  75     /* Widget is asked to draw itself */
  76     public override bool expose_event (Gdk.EventExpose event) {
  77         int ox = 1, oy = 1;
  78         int sx = allocation.width - 2, sy = allocation.height - 2;
  79
  80         // Create a Cairo context
  81         var cr = Gdk.cairo_create (this.window);
  82
  83         if (cache_surface == null)
  84         {
  85             int x;
  86             // looks like its either first call or the widget has been resized.
  87             // create the cache_surface.
  88             cache_surface = new Cairo.Surface.similar (cr.get_target(),
  89                                                        Cairo.Content.COLOR,
  90                                                        allocation.width,
  91                                                        allocation.height );
  92
  93             // And render the meterstuff again.
  94
  95             Cairo.Context cache_cr = new Cairo.Context ( cache_surface );
  96             cache_cr.set_source_rgba (0, 0, 0, 0);
  97             cache_cr.rectangle (ox, oy, sx, sy);
  98             cache_cr.fill ();
  99             cache_cr.set_line_width (1);
 100
 101             for (x = ox; x <= ox + sx; x += 3)
 102             {
 103                 double ts = (x - ox) * 1.0 / sx;
 104                 switch(mode)
 105                 {
 106                     case Mode.STANDARD:
 107                     default:
 108                         if (ts < 0.75) {
 109                             r = ts / 0.75;
 110                             g = 1;
 111                             b = 0;
 112                         }
 113                         else {
 114                             r = 1;
 115                             g = 1 - (ts - 0.75) / 0.25;
 116                             b = 0;
 117                         }
 118                         break;
 119                     case Mode.MONOCHROME_REVERSE:
 120                         break;
 121                     case Mode.MONOCHROME:
 122                         break;
 123                 }
 124                 cache_cr.set_source_rgb(r, g, b);
 125                 cache_cr.move_to (x, oy);
 126                 cache_cr.line_to (x, oy + sy + 1);
 127                 cache_cr.move_to (x, oy + sy);
 128                 cache_cr.line_to (x, oy );
 129                 cache_cr.stroke  ();
 130             }
 131         }
 132
 133         // Set clipping area in order to avoid unnecessary drawing
 134         cr.rectangle (event.area.x, event.area.y,
 135                       event.area.width, event.area.height);
 136         cr.clip ();
 137
 138         cr.set_source_surface (cache_surface, 0, 0);
 139         cr.paint ();
 140         cr.set_source_rgba (0, 0, 0, 0.5);
 141
 142         if( mode == Mode.MONOCHROME_REVERSE )
 143             cr.rectangle (ox, oy, _value * (sx - ox) + 1, sy - oy + 1);
 144         else
 145             cr.rectangle (ox + _value * (sx - ox), oy, sx - ox + 1, sy - oy + 1);
 146
 147         cr.fill ();
 148
 149         return false;
 150     }
 151 }
 152
 153 } // namespace Prolooks