configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Copyright (C) 2002, 2003, 2004 Simon Josefsson.
   4 dnl
   5 dnl This file is part of GNU Libidn.
   6 dnl
   7 dnl GNU Libidn is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU Lesser General Public License as
   9 dnl published by the Free Software Foundation; either version 2.1 of
  10 dnl the License, or (at your option) any later version.
  11 dnl
  12 dnl GNU Libidn is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU Lesser General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU Lesser General Public
  18 dnl License along with GNU Libidn; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
  20
  21 AC_INIT([libidn], [0.5.10], [bug-libidn@gnu.org])
  22
  23 # Library code modified:                              REVISION++
  24 # Interfaces changed/added/removed:   CURRENT++       REVISION=0
  25 # Interfaces added:                             AGE++
  26 # Interfaces removed:                           AGE=0
  27 LT_CURRENT=16
  28 LT_REVISION=3
  29 LT_AGE=5
  30 AC_SUBST(LT_CURRENT)
  31 AC_SUBST(LT_REVISION)
  32 AC_SUBST(LT_AGE)
  33
  34 AC_PREREQ(2.59)
  35 AM_INIT_AUTOMAKE([1.9 gnits])
  36 AB_INIT
  37 AC_CONFIG_HEADERS(config.h)
  38
  39 # Checks for programs.
  40 AM_GNU_GETTEXT(external)
  41 AM_GNU_GETTEXT_VERSION(0.14.1)
  42 AC_PROG_LIBTOOL
  43 AC_PROG_CC
  44 gl_EARLY
  45 AM_MISSING_PROG(PERL, perl, $missing_dir)
  46 AM_MISSING_PROG(HELP2MAN, help2man, $missing_dir)
  47 AM_ICONV
  48 AM_PATH_LISPDIR
  49
  50 # Checks for header files.
  51 AC_HEADER_STDC
  52 AC_CHECK_HEADERS(unistd.h errno.h)
  53
  54 # Checks for typedefs, structures, and compiler characteristics.
  55 AX_CREATE_STDINT_H(lib/idn-int.h, sys/types.h)
  56
  57 # For gnulib stuff in gl/.
  58 gl_SOURCE_BASE(gl)
  59 gl_M4_BASE(gl/m4)
  60 gl_MODULES(strdup dummy getopt error)
  61 gl_LGPL
  62 gl_INIT
  63
  64 # Check if locale stuff works
  65 AC_CACHE_CHECK([if setlocale() and nl_langinfo() works],
  66         ac_cv_locale_works, [
  67         AC_RUN_IFELSE([AC_LANG_SOURCE([[
  68 #include <locale.h>
  69 #include <langinfo.h>
  70 int main ()
  71 {
  72   char* cs;
  73   setlocale(LC_CTYPE, "");
  74   cs = nl_langinfo(CODESET);
  75   return !cs;
  76 }
  77 ]])],[ac_cv_locale_works=yes],[ac_cv_locale_works=no],[ac_cv_locale_works=no])
  78         ])
  79 if test "$ac_cv_locale_works" = "yes"; then
  80   AC_DEFINE(LOCALE_WORKS, 1, [Define if setlocale() and nl_langinfo() works.])
  81 fi
  82
  83 # Make it possible to disable TLD code.
  84 AC_ARG_ENABLE(tld, AC_HELP_STRING([--disable-tld], [disable TLD code]),
  85                 enable_tld=$enableval, enable_tld=yes)
  86 AM_CONDITIONAL(TLD, test "$enable_tld" != "no")
  87 if test "$enable_tld" != "no"; then
  88         AC_DEFINE(WITH_TLD, 1, [Define to 1 if you want TLD code.])
  89 fi
  90 AC_MSG_CHECKING([if TLD API for specific TLD rules should be built])
  91 AC_MSG_RESULT($enable_tld)
  92
  93 # Check for gtk-doc.
  94 GTK_DOC_CHECK(1.1)
  95
  96 # Check for java
  97 AC_ARG_ENABLE(java, AC_HELP_STRING([--enable-java], [enable Java API]),,
  98                 enable_java=no)
  99 if test "$enable_java" != "no"; then
 100         AC_PROG_JAVAC
 101         AC_PROG_JAR
 102         AC_PROG_JAVADOC
 103 fi
 104 AM_CONDITIONAL(JAVA, test "$enable_java" != "no")
 105 AC_MSG_CHECKING([if implementation in Java should be built])
 106 AC_MSG_RESULT($enable_java)
 107
 108 AC_CONFIG_FILES([Makefile libidn.pc doc/reference/Makefile doc/java/Makefile \
 109                 gl/Makefile lib/stringprep.h contrib/doxygen/Doxyfile \
 110                 doc/Makefile doc/specifications/Makefile doc/tld/Makefile \
 111                 lib/Makefile src/Makefile tests/Makefile examples/Makefile \
 112                 java/Makefile java/gnu/Makefile java/gnu/inet/Makefile \
 113                 java/gnu/inet/encoding/Makefile java/misc/Makefile \
 114                 po/Makefile.in])
 115 AC_OUTPUT