configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Copyright (C) 2002, 2003, 2004, 2005, 2006 Simon Josefsson.
   4 dnl
   5 dnl This file is part of GNU Libidn.
   6 dnl
   7 dnl GNU Libidn is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU Lesser General Public License as
   9 dnl published by the Free Software Foundation; either version 2, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl GNU Libidn is distributed in the hope that it will be useful, but
  13 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 dnl General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with GNU Libidn; see the file COPYING.LIB.  If not, write to
  19 dnl the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  20 dnl Floor, Boston, MA 02110-1301, USA.
  21
  22 AC_INIT([libidn], [0.6.6], [bug-libidn@gnu.org])
  23
  24 # Library code modified:                              REVISION++
  25 # Interfaces changed/added/removed:   CURRENT++       REVISION=0
  26 # Interfaces added:                             AGE++
  27 # Interfaces removed:                           AGE=0
  28 AC_SUBST(LT_CURRENT, 16)
  29 AC_SUBST(LT_REVISION, 20)
  30 AC_SUBST(LT_AGE, 5)
  31
  32 AC_PREREQ(2.59)
  33 AM_INIT_AUTOMAKE([1.9 gnits])
  34 AB_INIT
  35 AC_CONFIG_HEADERS(config.h)
  36
  37 # Checks for programs.
  38 AM_GNU_GETTEXT(external)
  39 AM_GNU_GETTEXT_VERSION(0.14.1)
  40 AC_LIBTOOL_WIN32_DLL
  41 AC_PROG_LIBTOOL
  42 AC_PROG_CC
  43 gl_EARLY
  44 AM_MISSING_PROG(PERL, perl, $missing_dir)
  45 AM_MISSING_PROG(HELP2MAN, help2man, $missing_dir)
  46 AM_ICONV
  47 AM_PATH_LISPDIR
  48
  49 if test "$am_cv_func_iconv" != "yes"; then
  50   AC_MSG_NOTICE([
  51 ***
  52
  53 Your system does not have iconv().  The iconv() function is not
  54 strictly required by the source code.  However, that may change in
  55 the future, unless you report that this may be a problem for you.
  56
  57 Please report this to $PACKAGE_BUGREPORT.
  58
  59 ***])
  60 fi
  61
  62 # Checks for header files.
  63 AC_HEADER_STDC
  64 AC_CHECK_HEADERS([locale.h])
  65
  66 # Checks for library functions.
  67 AC_CHECK_FUNCS([setlocale])
  68
  69 # For gnulib stuff in gl/.
  70 gl_INIT
  71
  72 # Check if locale stuff works
  73 AM_LANGINFO_CODESET
  74
  75 # Run self-tests under valgrind?
  76 if test "$cross_compiling" = no; then
  77   AC_CHECK_PROGS(VALGRIND, valgrind)
  78 fi
  79 if test -n "$VALGRIND" && $VALGRIND true > /dev/null 2>&1; then
  80   opt_valgrind_tests=yes
  81 else
  82   opt_valgrind_tests=no
  83   VALGRIND=
  84 fi
  85 AC_MSG_CHECKING([whether self tests are run under valgrind])
  86 AC_ARG_ENABLE(valgrind-tests,
  87         AS_HELP_STRING([--enable-valgrind-tests],
  88                        [run self tests under valgrind]),
  89   opt_valgrind_tests=$enableval)
  90 AC_MSG_RESULT($opt_valgrind_tests)
  91
  92 # Make it possible to disable TLD code.
  93 AC_ARG_ENABLE(tld, AC_HELP_STRING([--disable-tld], [disable TLD code]),
  94                 enable_tld=$enableval, enable_tld=yes)
  95 AM_CONDITIONAL(TLD, test "$enable_tld" != "no")
  96 if test "$enable_tld" != "no"; then
  97         AC_DEFINE(WITH_TLD, 1, [Define to 1 if you want TLD code.])
  98 fi
  99 AC_MSG_CHECKING([if TLD API for specific TLD rules should be built])
 100 AC_MSG_RESULT($enable_tld)
 101
 102 # Check for gtk-doc.
 103 GTK_DOC_CHECK(1.1)
 104
 105 # Check for java
 106 AC_ARG_ENABLE(java, AC_HELP_STRING([--enable-java], [enable Java API]),,
 107                 enable_java=no)
 108 if test "$enable_java" != "no"; then
 109         AC_PROG_JAVAC
 110         AC_PROG_JAR
 111         AM_MISSING_PROG(GJDOC, gjdoc, $missing_dir)
 112 fi
 113 AM_CONDITIONAL(JAVA, test "$enable_java" != "no")
 114 AC_MSG_CHECKING([if implementation in Java should be built])
 115 AC_MSG_RESULT($enable_java)
 116
 117 # Check for C#
 118 AM_CONDITIONAL(CSHARP, test -n "$HAVE_CSHARPCOMP")
 119 AC_MSG_CHECKING([[if implementation in C# should be built]])
 120 if test -n "$HAVE_CSHARPCOMP"; then
 121   ac_result=yes
 122 else
 123   ac_result=no
 124 fi
 125 AC_MSG_RESULT($ac_result)
 126
 127 AC_CONFIG_FILES([Makefile libidn.pc doc/reference/Makefile doc/java/Makefile \
 128                 gl/Makefile lib/stringprep.h contrib/doxygen/Doxyfile \
 129                 doc/Makefile doc/specifications/Makefile doc/tld/Makefile \
 130                 lib/Makefile src/Makefile tests/Makefile examples/Makefile \
 131                 java/Makefile java/gnu/Makefile java/gnu/inet/Makefile \
 132                 java/gnu/inet/encoding/Makefile java/misc/Makefile \
 133                 csharp/Makefile \
 134                 po/Makefile.in])
 135 AC_OUTPUT