configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Copyright (C) 2002, 2003, 2004 Simon Josefsson.
   4 dnl
   5 dnl This file is part of GNU Libidn.
   6 dnl
   7 dnl GNU Libidn is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU Lesser General Public License as
   9 dnl published by the Free Software Foundation; either version 2.1 of
  10 dnl the License, or (at your option) any later version.
  11 dnl
  12 dnl GNU Libidn is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU Lesser General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU Lesser General Public
  18 dnl License along with GNU Libidn; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
  20
  21 AC_INIT([libidn], [0.4.5], [bug-libidn@gnu.org])
  22
  23 # Library code modified:                              REVISION++
  24 # Interfaces changed/added/removed:   CURRENT++       REVISION=0
  25 # Interfaces added:                             AGE++
  26 # Interfaces removed:                           AGE=0
  27 LT_CURRENT=14
  28 LT_REVISION=0
  29 LT_AGE=3
  30 AC_SUBST(LT_CURRENT)
  31 AC_SUBST(LT_REVISION)
  32 AC_SUBST(LT_AGE)
  33
  34 AC_PREREQ(2.59)
  35 AM_INIT_AUTOMAKE([1.8 gnits])
  36 AC_CONFIG_HEADERS(config.h)
  37
  38 # Checks for programs.
  39 AM_GNU_GETTEXT(external)
  40 AM_GNU_GETTEXT_VERSION(0.14.1)
  41 AC_PROG_LIBTOOL
  42 AC_PROG_CC
  43 AM_MISSING_PROG(PERL, perl, $missing_dir)
  44 AM_MISSING_PROG(HELP2MAN, help2man, $missing_dir)
  45 AM_ICONV
  46 AM_PATH_LISPDIR
  47
  48 # Checks for header files.
  49 AC_HEADER_STDC
  50 AC_CHECK_HEADERS(unistd.h errno.h)
  51
  52 # Checks for typedefs, structures, and compiler characteristics.
  53 AX_CREATE_STDINT_H(lib/idn-int.h, sys/types.h)
  54
  55 # Need getopt.
  56 AC_CHECK_FUNCS(getopt_long,, [AC_LIBOBJ(getopt) AC_LIBOBJ(getopt1)])
  57
  58 # Check if locale stuff works
  59 AC_CACHE_CHECK([if setlocale() and nl_langinfo() works],
  60         ac_cv_locale_works, [
  61         AC_RUN_IFELSE([AC_LANG_SOURCE([[
  62 #include <locale.h>
  63 #include <langinfo.h>
  64 int main ()
  65 {
  66   char* cs;
  67   setlocale(LC_CTYPE, "");
  68   cs = nl_langinfo(CODESET);
  69   return !cs;
  70 }
  71 ]])],[ac_cv_locale_works=yes],[ac_cv_locale_works=no],[ac_cv_locale_works=no])
  72         ])
  73 if test "$ac_cv_locale_works" = "yes"; then
  74   AC_DEFINE(LOCALE_WORKS, 1, [Define if setlocale() and nl_langinfo() works.])
  75 fi
  76
  77 # Make it possible to disable TLD code.
  78 AC_ARG_ENABLE(tld, AC_HELP_STRING([--disable-tld], [disable TLD code]),
  79                 enable_tld=$enableval, enable_tld=yes)
  80 AM_CONDITIONAL(TLD, test "$enable_tld" != "no")
  81 if test "$enable_tld" != "no"; then
  82         AC_DEFINE(WITH_TLD, 1, [Define to 1 if you want TLD code.])
  83 fi
  84 AC_MSG_CHECKING([if TLD API for specific TLD rules should be built])
  85 AC_MSG_RESULT($enable_tld)
  86
  87 # Check for gtk-doc.
  88 GTK_DOC_CHECK(1.1)
  89
  90 # Check for java
  91 AC_ARG_ENABLE(java, AC_HELP_STRING([--enable-java], [enable Java API]),,
  92                 enable_java=no)
  93 if test "$enable_java" != "no"; then
  94         AC_PROG_JAVAC
  95         AC_PROG_JAR
  96 fi
  97 AM_CONDITIONAL(JAVA, test "$enable_java" != "no")
  98 AC_MSG_CHECKING([if implementation in Java should be built])
  99 AC_MSG_RESULT($enable_java)
 100
 101 AC_CONFIG_FILES([Makefile libidn.pc doc/reference/Makefile \
 102                 lib/stringprep.h contrib/doxygen/Doxyfile \
 103                 doc/Makefile doc/specifications/Makefile doc/tld/Makefile \
 104                 lib/Makefile src/Makefile tests/Makefile examples/Makefile \
 105                 java/Makefile java/gnu/Makefile java/gnu/inet/Makefile \
 106                 java/gnu/inet/encoding/Makefile po/Makefile.in])
 107 AC_OUTPUT