configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Copyright (C) 2002, 2003, 2004, 2005, 2006 Simon Josefsson.
   4 dnl
   5 dnl This file is part of GNU Libidn.
   6 dnl
   7 dnl GNU Libidn is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU Lesser General Public License as
   9 dnl published by the Free Software Foundation; either version 2, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl GNU Libidn is distributed in the hope that it will be useful, but
  13 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 dnl General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with GNU Libidn; see the file COPYING.LIB.  If not, write to
  19 dnl the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  20 dnl Floor, Boston, MA 02110-1301, USA.
  21
  22 AC_INIT([libidn], [0.6.8], [bug-libidn@gnu.org])
  23
  24 # Library code modified:                              REVISION++
  25 # Interfaces changed/added/removed:   CURRENT++       REVISION=0
  26 # Interfaces added:                             AGE++
  27 # Interfaces removed:                           AGE=0
  28 AC_SUBST(LT_CURRENT, 16)
  29 AC_SUBST(LT_REVISION, 22)
  30 AC_SUBST(LT_AGE, 5)
  31
  32 AC_PREREQ(2.60)
  33 AM_INIT_AUTOMAKE([1.9 gnits])
  34 AB_INIT
  35 AC_CONFIG_HEADERS(config.h)
  36
  37 # Checks for programs.
  38 AM_GNU_GETTEXT(external)
  39 AM_GNU_GETTEXT_VERSION(0.14.1)
  40 AC_LIBTOOL_WIN32_DLL
  41 AC_PROG_LIBTOOL
  42 AC_PROG_CC
  43 gl_EARLY
  44 lgl_EARLY
  45 AM_MISSING_PROG(PERL, perl, $missing_dir)
  46 AM_MISSING_PROG(HELP2MAN, help2man, $missing_dir)
  47 AM_ICONV
  48 AM_PATH_LISPDIR
  49
  50 if test "$am_cv_func_iconv" != "yes"; then
  51   AC_MSG_NOTICE([
  52 ***
  53
  54 Your system does not have iconv().  The iconv() function is not
  55 strictly required by the source code.  However, that may change in
  56 the future, unless you report that this may be a problem for you.
  57
  58 Please report this to $PACKAGE_BUGREPORT.
  59
  60 ***])
  61 fi
  62
  63 # Checks for header files.
  64 AC_HEADER_STDC
  65 AC_CHECK_HEADERS([locale.h])
  66
  67 # Checks for library functions.
  68 AC_CHECK_FUNCS([setlocale])
  69
  70 # For gnulib stuff in gl/.
  71 gl_INIT
  72 lgl_INIT
  73
  74 # Check if locale stuff works
  75 AM_LANGINFO_CODESET
  76
  77 # Run self-tests under valgrind?
  78 if test "$cross_compiling" = no; then
  79   AC_CHECK_PROGS(VALGRIND, valgrind)
  80 fi
  81 if test -n "$VALGRIND" && $VALGRIND true > /dev/null 2>&1; then
  82   opt_valgrind_tests=yes
  83 else
  84   opt_valgrind_tests=no
  85   VALGRIND=
  86 fi
  87 AC_MSG_CHECKING([whether self tests are run under valgrind])
  88 AC_ARG_ENABLE(valgrind-tests,
  89         AS_HELP_STRING([--enable-valgrind-tests],
  90                        [run self tests under valgrind]),
  91   opt_valgrind_tests=$enableval)
  92 AC_MSG_RESULT($opt_valgrind_tests)
  93
  94 # Make it possible to disable TLD code.
  95 AC_ARG_ENABLE(tld, AC_HELP_STRING([--disable-tld], [disable TLD code]),
  96                 enable_tld=$enableval, enable_tld=yes)
  97 AM_CONDITIONAL(TLD, test "$enable_tld" != "no")
  98 if test "$enable_tld" != "no"; then
  99         AC_DEFINE(WITH_TLD, 1, [Define to 1 if you want TLD code.])
 100 fi
 101 AC_MSG_CHECKING([if TLD API for specific TLD rules should be built])
 102 AC_MSG_RESULT($enable_tld)
 103
 104 # Check for gtk-doc.
 105 GTK_DOC_CHECK(1.1)
 106
 107 # Check for java
 108 AC_ARG_ENABLE(java, AC_HELP_STRING([--enable-java], [enable Java API]),,
 109                 enable_java=no)
 110 if test "$enable_java" != "no"; then
 111         AC_PROG_JAVAC
 112         AC_PROG_JAR
 113         AM_MISSING_PROG(GJDOC, gjdoc, $missing_dir)
 114 fi
 115 AM_CONDITIONAL(JAVA, test "$enable_java" != "no")
 116 AC_MSG_CHECKING([if implementation in Java should be built])
 117 AC_MSG_RESULT($enable_java)
 118
 119 # Check for C#
 120 AM_CONDITIONAL(CSHARP, test -n "$HAVE_CSHARPCOMP")
 121 AC_MSG_CHECKING([[if implementation in C# should be built]])
 122 if test -n "$HAVE_CSHARPCOMP"; then
 123   ac_result=yes
 124 else
 125   ac_result=no
 126 fi
 127 AC_MSG_RESULT($ac_result)
 128
 129 AC_CONFIG_FILES([Makefile libidn.pc doc/reference/Makefile doc/java/Makefile \
 130                 gl/Makefile lib/gl/Makefile lib/stringprep.h contrib/doxygen/Doxyfile \
 131                 doc/Makefile doc/specifications/Makefile doc/tld/Makefile \
 132                 lib/Makefile src/Makefile tests/Makefile examples/Makefile \
 133                 java/Makefile java/gnu/Makefile java/gnu/inet/Makefile \
 134                 java/gnu/inet/encoding/Makefile java/misc/Makefile \
 135                 csharp/Makefile \
 136                 po/Makefile.in])
 137 AC_OUTPUT