configure.ac

   1 AC_INIT(libass, 0.9.12)
   2 AM_INIT_AUTOMAKE
   3 AC_CONFIG_MACRO_DIR([m4])
   4 # Disable C++/Fortran checks
   5 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])
   6 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])
   7 AC_PROG_LIBTOOL
   8 AC_CONFIG_SRCDIR([libass/ass.c])
   9 AC_CONFIG_HEADER([config.h])
  10
  11 # Checks for programs.
  12 AC_PROG_CC
  13 AC_PROG_CPP
  14 AM_PROG_CC_C_O
  15
  16 # Checks for header files.
  17 AC_HEADER_STDC
  18 AC_HEADER_STDBOOL
  19 AC_CHECK_HEADERS([inttypes.h stdint.h stdlib.h string.h sys/time.h unistd.h iconv.h])
  20
  21 # Checks for typedefs, structures, and compiler characteristics.
  22 AC_C_CONST
  23 AC_C_INLINE
  24 AC_TYPE_INT64_T
  25 AC_TYPE_SIZE_T
  26 AC_TYPE_UINT32_T
  27 AC_TYPE_UINT8_T
  28
  29 # Checks for library functions.
  30 AC_CHECK_FUNCS([mkdir strcasecmp strdup strtol])
  31
  32 # Checks for libraries.
  33 AC_SEARCH_LIBS([iconv_open], [iconv], AC_DEFINE(CONFIG_ICONV, 1, [use iconv]))
  34 AC_CHECK_LIB([m], [fabs])
  35
  36 # Check for libraries via pkg-config
  37 AC_ARG_ENABLE([test], AS_HELP_STRING([--enable-test],
  38     [enable test program (requires libpng) @<:@default=no@:>@]))
  39 AC_ARG_ENABLE([enca], AS_HELP_STRING([--disable-enca],
  40     [disable enca (charset autodetect) support @<:@default=check@:>@]))
  41 AC_ARG_ENABLE([fontconfig], AS_HELP_STRING([--disable-fontconfig],
  42     [disable fontconfig support @<:@default=enabled@:>@]))
  43 AC_ARG_ENABLE([fribidi], AS_HELP_STRING([--disable-fribidi],
  44     [disable bidi support @<:@default=enabled@:>@]))
  45
  46 PKG_CHECK_MODULES([FREETYPE], freetype2 >= 9.10.3, [
  47     CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
  48     LIBS="$LIBS $FREETYPE_LIBS"
  49     AC_DEFINE(CONFIG_FREETYPE, 1, [found freetype2 via pkg-config])
  50     ])
  51
  52 if test x$enable_fontconfig != xno; then
  53 PKG_CHECK_MODULES([FONTCONFIG], fontconfig >= 2.4.2, [
  54     CFLAGS="$CFLAGS $FONTCONFIG_CFLAGS"
  55     LIBS="$LIBS $FONTCONFIG_LIBS"
  56     AC_DEFINE(CONFIG_FONTCONFIG, 1, [found fontconfig via pkg-config])
  57         fontconfig=true
  58     ])
  59 fi
  60
  61 if test x$enable_fribidi != xno; then
  62 PKG_CHECK_MODULES([FRIBIDI], fribidi >= 0.19.0, [
  63     CFLAGS="$CFLAGS $FRIBIDI_CFLAGS"
  64     LIBS="$LIBS $FRIBIDI_LIBS"
  65     AC_DEFINE(CONFIG_FRIBIDI, 1, [found fribidi via pkg-config])
  66         fribidi=true
  67     ])
  68 fi
  69
  70 if test x$enable_enca != xno; then
  71 PKG_CHECK_MODULES([ENCA], enca, [
  72     CFLAGS="$CFLAGS $ENCA_CFLAGS"
  73     LIBS="$LIBS $ENCA_LIBS"
  74     AC_DEFINE(CONFIG_ENCA, 1, [found enca via pkg-config])
  75         enca=true
  76         ], [enca=false])
  77 fi
  78
  79 libpng=false
  80 if test x$enable_test = xyes; then
  81 PKG_CHECK_MODULES([LIBPNG], libpng >= 1.2.0, [
  82     CFLAGS="$CFLAGS $LIBPNG_CFLAGS"
  83     LIBS="$LIBS $LIBPNG_LIBS"
  84     AC_DEFINE(CONFIG_LIBPNG, 1, [found libpng via pkg-config])
  85     libpng=true])
  86 fi
  87
  88 AM_CONDITIONAL([HAVE_LIBPNG], [test x$libpng = xtrue])
  89
  90 # Add dependent libraries to pkg-config for static linking
  91 PKG_REQUIRES="freetype2 >= 9.6.3"
  92 if test x$enca = xtrue; then
  93     PKG_REQUIRES="enca, ${PKG_REQUIRES}"
  94 fi
  95 if test x$fontconfig = xtrue; then
  96     PKG_REQUIRES="fontconfig >= 2.2.0, ${PKG_REQUIRES}"
  97 fi
  98 if test x$fribidi = xtrue; then
  99     PKG_REQUIRES="fribidi >= 0.19.0, ${PKG_REQUIRES}"
 100 fi
 101 AC_SUBST([PKG_REQUIRES])
 102
 103 # Setup output beautifier.
 104 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
 105
 106 AC_CONFIG_FILES([Makefile libass/Makefile test/Makefile libass.pc])
 107 AC_OUTPUT