kProfiler2/kPrf2WinApi-dumpbin.sed

   1 # $Id$
   2 ## @file
   3 # Strip down dumpbin /export output.
   4 #
   5
   6 #
   7 # Copyright (c) 2008 Knut St. Osmundsen <bird-kStuff-spamix@anduin.net>
   8 #
   9 # Permission is hereby granted, free of charge, to any person
  10 # obtaining a copy of this software and associated documentation
  11 # files (the "Software"), to deal in the Software without
  12 # restriction, including without limitation the rights to use,
  13 # copy, modify, merge, publish, distribute, sublicense, and/or sell
  14 # copies of the Software, and to permit persons to whom the
  15 # Software is furnished to do so, subject to the following
  16 # conditions:
  17 #
  18 # The above copyright notice and this permission notice shall be
  19 # included in all copies or substantial portions of the Software.
  20 #
  21 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  22 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
  23 # OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  24 # NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
  25 # HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
  26 # WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  27 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
  28 # OTHER DEALINGS IN THE SOFTWARE.
  29 #
  30
  31 #
  32 # State switch
  33 #
  34 x
  35 /^exports$/b exports
  36 /^summary$/b summary
  37 b header
  38
  39 #
  40 # Header
  41 #
  42 :header
  43 x
  44 /^[[:space:]][[:space:]]*ordinal[[:space:]]*name[[:space:]]*$/b switch_to_exports
  45 b drop_line
  46
  47 #
  48 # Exports
  49 #
  50 :switch_to_exports
  51 s/^.*$/exports/
  52 h
  53 b drop_line
  54
  55 :exports
  56 x
  57 /^[[:space:]][[:space:]]*Summary[[:space:]]*$/b switch_to_summary
  58 s/^[[:space:]]*//
  59 s/[[:space:]]*$//
  60 s/[[:space:]][[:space:]]*/ /g
  61 /^$/b drop_line
  62
  63 # Filter out APIs that hasn't been implemented.
  64 /AddLocalAlternateComputerNameA/b drop_line
  65 /AddLocalAlternateComputerNameW/b drop_line
  66 /EnumerateLocalComputerNamesA/b drop_line
  67 /EnumerateLocalComputerNamesW/b drop_line
  68 /RemoveLocalAlternateComputerNameA/b drop_line
  69 /RemoveLocalAlternateComputerNameW/b drop_line
  70 /SetLocalPrimaryComputerNameA/b drop_line
  71 /SetLocalPrimaryComputerNameW/b drop_line
  72 /__C_specific_handler/b drop_line
  73 /__misaligned_access/b drop_line
  74 /_local_unwind/b drop_line
  75
  76 b end
  77
  78 #
  79 # Summary
  80 #
  81 :switch_to_summary
  82 s/^.*$/summary/
  83 h
  84 b drop_line
  85
  86 :summary
  87 x
  88 b drop_line
  89
  90 #
  91 # Tail
  92 #
  93 :drop_line
  94 d
  95 :end
  96