ksplice-undo.in

   1 #!/usr/bin/perl
   2
   3 # Copyright (C) 2007-2009  Ksplice, Inc.
   4 # Authors: Jeff Arnold, Anders Kaseorg, Tim Abbott
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License, version 2.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston, MA
  17 # 02110-1301, USA.
  18
  19 use strict;
  20 use warnings;
  21 use lib 'KSPLICE_DATA_DIR';
  22 use Ksplice;
  23 use Time::HiRes qw(usleep);
  24
  25 my $debug;
  26 my $debugon = 0;
  27 GetOptions(@common_options,
  28         "debug" => \$debugon,
  29         "debugfile=s" => \$debug) or pod2usage(1);
  30
  31 pod2usage(1) if($help || scalar(@ARGV) != 1);
  32 $debugon = 1 if (defined($debug));
  33 $debug = abs_path($debug) if (defined $debug);
  34
  35 my $kid = $ARGV[0];
  36 $kid =~ s/^ksplice[-_]//;
  37 $kid =~ s/[-_].*$//;
  38 my $update = "ksplice_$kid";
  39 my $nounload = runstr("lsmod") =~ m/- $/m;
  40
  41 if (!update_loaded($kid)) {
  42         print "Ksplice id $kid is not present in the kernel\n";
  43         exit(1);
  44 }
  45
  46 chdir("/sys/module/");
  47 set_debug_level($kid, $debugon);
  48 my $stage = get_stage($kid);
  49 if ($stage ne 'applied') {
  50         print "Ksplice id $kid is not applied\n";
  51 }
  52 else {
  53         set_stage($kid, "reversed");
  54 }
  55
  56 $stage = get_stage($kid);
  57 my $failed = 0;
  58 $failed = 1 if ($stage ne 'reversed');
  59 foreach my $module (glob("${update}_*")) {
  60         if (!$nounload && runval_raw('rmmod', $module) != 0) {
  61                 child_error();
  62                 $failed = 1;
  63         }
  64 }
  65 if ($failed == 0) {
  66         set_stage($kid, "cleanup");
  67         my $count = 0;
  68         while (update_loaded($kid) && $count < 5) {
  69                 usleep(100000);
  70                 $count++;
  71         }
  72 }
  73 if ($failed == 0 && -e "/sys/module/$update") {
  74         if (!$nounload && runval_raw('rmmod', $update) != 0) {
  75                 child_error();
  76                 $failed = 1;
  77         }
  78 }
  79 unless($failed == 0) {
  80         my $debugfile = get_debug_output($kid, $debug);
  81         print STDERR "Error undoing Ksplice update $kid:\n";
  82         my $abort_cause = get_abort_cause($kid);
  83         my $conflicts = get_conflicts($kid);
  84         print_error($abort_cause);
  85         if ($abort_cause eq 'code_busy') {
  86                 print $conflicts;
  87         }
  88         if($debugon && defined $debugfile) {
  89                 print("Debugging output saved to $debugfile\n");
  90         }
  91         die;
  92 }
  93 rmtree("/var/run/ksplice/updates/$kid");
  94 exit(0);
  95
  96 sub print_error {
  97         my ($error) = @_;
  98         my %errors = (
  99                 "code_busy" => <<'END',
 100 Ksplice has aborted the undo operation because it appears that the code that
 101 you are trying to change is continuously in use by the system.  More
 102 specifically, Ksplice has been unable to find a moment when one or more of the
 103 to-be-changed functions is not on a thread's kernel stack.
 104 END
 105                 "module_busy" => <<'END',
 106 Ksplice has aborted the undo operation because it appears that the Ksplice
 107 update that you are trying to unload is in use by another module.  You can find
 108 out what module is using the Ksplice update using the lsmod command.
 109 END
 110                 "unexpected_running_task" => <<'END',
 111 Ksplice has aborted the undo operation because of an unexpected failure during
 112 the kernel stack check.  Please consider reporting a bug to PACKAGE_BUGREPORT.
 113 END
 114                 "out_of_memory" => <<'END',
 115 Ksplice has aborted the undo operation because the kernel ran out of memory.
 116 END
 117                 "call_failed" => <<'END',
 118 Ksplice has aborted the undo operation at the request of a one of the
 119 pre-application hooks that were included as part of this Ksplice
 120 update.  This is likely the result of a bug in the patch used to
 121 generate this update.
 122 END
 123                 "cold_update_loaded" => <<'END',
 124 Ksplice has aborted the undo operation because the update was applied using the
 125 --partial option, and one of the modules that was changed by the update was loaded
 126 since the update was applied.  You must first unload that (cold patched) module
 127 before you can undo this update.
 128 END
 129                 "unexpected" => <<'END',
 130 Ksplice has aborted because of an unexpected error.
 131 Please consider reporting a bug to PACKAGE_BUGREPORT.
 132 END
 133                 "UNKNOWN" => <<'END',
 134 The Ksplice kernel component has returned an error code that this version of
 135 ksplice-undo does not understand.
 136 END
 137                 "ok" => <<'END',
 138 Ksplice has aborted the undo operation for unknown reasons.
 139 Please consider reporting a bug to PACKAGE_BUGREPORT.
 140 END
 141 );
 142         $error = "UNKNOWN" if (!exists $errors{$error});
 143         print STDERR "\n$errors{$error}\n";
 144 }
 145
 146 =head1 NAME
 147
 148 ksplice-undo - Undo a Ksplice update that has been applied to the running kernel
 149
 150 =head1 SYNOPSIS
 151
 152 B<ksplice-undo> [I<OPTIONS>] I<KSPLICE_ID>
 153
 154 =head1 DESCRIPTION
 155
 156 B<ksplice-undo> takes as input a Ksplice identification tag, as reported by
 157 L<ksplice-view(8)>, and it reverses that update within the running binary kernel.
 158
 159 =head1 OPTIONS
 160
 161 =over 8
 162
 163 =item B<--debug>
 164
 165 Reverses the update with debugging output enabled.  Recommended only for
 166 debugging.
 167
 168 =item B<--debugfile=>I<filename>
 169
 170 Sets the location where debugging output should be saved.  Implies --debug.
 171
 172 =back
 173
 174 =head1 SEE ALSO
 175
 176 L<ksplice-create(8)>, L<ksplice-apply(8)>, L<ksplice-view(8)>
 177
 178 =head1 BUGS
 179
 180 Please report bugs to <PACKAGE_BUGREPORT>.
 181
 182 =head1 AUTHORS
 183
 184 Jeff Arnold, Anders Kaseorg, and Tim Abbott
 185
 186 =head1 COPYRIGHT
 187
 188 Copyright (C) 2007-2009  Ksplice, Inc.
 189
 190 This is free software and documentation.  You can redistribute and/or modify it
 191 under the terms of the GNU General Public License, version 2.
 192
 193 =cut