ksplice-obj.pl.in

   1 #!/usr/bin/perl
   2
   3 # Copyright (C) 2008  Anders Kaseorg <andersk@mit.edu>,
   4 #                     Jeffrey Brian Arnold <jbarnold@mit.edu>,
   5 #                     Tim Abbott <tabbott@mit.edu>
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License, version 2.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston, MA
  18 # 02110-1301, USA.
  19
  20 use strict;
  21 use warnings;
  22 use lib 'KSPLICE_DATA_DIR';
  23 use Ksplice;
  24
  25 $Verbose::level = $ENV{KSPLICE_VERBOSE} if (defined $ENV{KSPLICE_VERBOSE});
  26
  27 sub empty_diff {
  28         my ($out) = @_;
  29         my ($obj) = $out =~ /^(.*)\.KSPLICE$/ or die;
  30         unlink "$obj.KSPLICE_primary" if (-e "$obj.KSPLICE_primary");
  31         unlink "$obj.KSPLICE_helper" if (-e "$obj.KSPLICE_helper");
  32         open OUT, '>', "$out.tmp";
  33         close OUT;
  34         rename "$out.tmp", $out;
  35 }
  36
  37 sub do_snap {
  38         my ($out) = @_;
  39         my ($obj) = $out =~ /^(.*)\.KSPLICE$/ or die;
  40         die if (!-e $obj);
  41         unlink "$obj.KSPLICE_pre" if (-e "$obj.KSPLICE_pre");
  42         empty_diff($out);
  43 }
  44
  45 sub do_diff {
  46         my ($out) = @_;
  47         my ($obj) = $out =~ /^(.*)\.KSPLICE$/ or die;
  48         my $obj_old = "$obj.KSPLICE_pre";
  49         die if (!-e $obj);
  50         die "Patch creates new object $obj" if (!-e $obj_old);
  51         if (system('cmp', '-s', '--', $obj_old, $obj) == 0) {
  52                 unlink $obj_old;
  53                 return empty_diff($out);
  54         }
  55
  56         runval("$libexecdir/ksplice-objmanip", $obj, "$obj.KSPLICE_primary", "keep-primary", "$obj.KSPLICE_pre", $ENV{KSPLICE_KID});
  57
  58         open OUT, '>', "$out.tmp";
  59         print OUT "1\n";
  60         close OUT;
  61         rename "$out.tmp", $out;
  62
  63         runval("$libexecdir/ksplice-objmanip", $obj_old, "$obj.KSPLICE_helper", "keep-helper");
  64 }
  65
  66 sub do_helper {
  67         my ($out) = @_;
  68         my ($obj) = $out =~ /^(.*)\.KSPLICE_helper$/ or die;
  69         my $obj_old = "$obj.KSPLICE_pre";
  70         -e $obj_old or $obj_old = $obj;
  71         runval("$libexecdir/ksplice-objmanip", $obj_old, "$obj.KSPLICE_helper", "keep-helper");
  72 }
  73
  74 sub link_objs {
  75         my ($out, @ins) = @_;
  76         if (@ins == 0) {
  77                 runval(shellwords($ENV{AR}), "rcs", $out);
  78         } elsif (@ins == 1) {
  79                 copy @ins, $out;
  80         } else {
  81                 runval(shellwords($ENV{LD}), "-r", "-o", $out, @ins);
  82         }
  83 }
  84
  85 sub do_combine {
  86         my ($out, @ins) = @_;
  87         my @primaries;
  88         my @helpers;
  89         foreach my $in (@ins) {
  90                 if (my ($obj) = $in =~ /^(.*)\.KSPLICE$/) {
  91                         next if (!-s $in);
  92                         push @primaries, "$obj.KSPLICE_primary";
  93                         push @helpers, "$obj.KSPLICE_helper";
  94                 } elsif (($obj) = $in =~ /^(.*)\.KSPLICE_helper$/) {
  95                         push @helpers, "$obj.KSPLICE_helper"
  96                             unless (@helpers && $helpers[$#helpers] eq "$obj.KSPLICE_helper");
  97                 } else {
  98                         die;
  99                 }
 100         }
 101
 102         return empty_diff($out) unless (@helpers);
 103
 104         my ($obj) = $out =~ /^(.*)\.KSPLICE$/ or die;
 105         link_objs("$obj.KSPLICE_primary", @primaries);
 106         link_objs("$obj.KSPLICE_helper", @helpers);
 107
 108         open OUT, '>', "$out.tmp";
 109         print OUT "1\n";
 110         close OUT;
 111         rename "$out.tmp", $out;
 112 }
 113
 114 sub do_finalize {
 115         my ($in, $out) = @_;
 116         runval("$libexecdir/ksplice-objmanip", $in, $out, "finalize");
 117 }
 118
 119 sub do_rmsyms {
 120         my ($in, $out, @rmsyms) = @_;
 121         runval_in("@rmsyms\n", "$libexecdir/ksplice-objmanip", $in, $out, "rmsyms");
 122 }
 123
 124 sub do_system_map_lookup {
 125         my ($symarg) = @_;
 126         open(SYMS, "<", "$ENV{KSPLICE_CONFIG_DIR}/System.map") or die;
 127         my $line;
 128         while (defined($line = <SYMS>)) {
 129                 my ($addr, $type, $sym, $mod) = split(/\s+/, $line);
 130                 if ($sym eq $symarg) { print $addr; last; }
 131         }
 132         close(SYMS);
 133 }
 134
 135 my %handlers = (
 136         'snap' => \&do_snap,
 137         'diff' => \&do_diff,
 138         'helper' => \&do_helper,
 139         'combine' => \&do_combine,
 140         'finalize' => \&do_finalize,
 141         'rmsyms' => \&do_rmsyms,
 142         'system_map_lookup' => \&do_system_map_lookup,
 143 );
 144
 145 my ($cmd, @args) = @ARGV;
 146 if (exists $handlers{$cmd}) {
 147         my $handler = $handlers{$cmd};
 148         &$handler(@args);
 149 } else {
 150         print "Usage: ksplice-obj.pl ", join('|', keys %handlers), " ...\n";
 151         exit(1);
 152 };