ksplice-obj.pl.in

   1 #!/usr/bin/perl
   2
   3 # Copyright (C) 2008  Anders Kaseorg <andersk@mit.edu>,
   4 #                     Jeffrey Brian Arnold <jbarnold@mit.edu>,
   5 #                     Tim Abbott <tabbott@mit.edu>
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License, version 2.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston, MA
  18 # 02110-1301, USA.
  19
  20 use strict;
  21 use warnings;
  22 use lib 'KSPLICE_DATA_DIR';
  23 use Ksplice;
  24
  25 $Verbose::level = $ENV{KSPLICE_VERBOSE} if (defined $ENV{KSPLICE_VERBOSE});
  26
  27 sub empty_diff {
  28         my ($out) = @_;
  29         my ($obj) = $out =~ /^(.*)\.KSPLICE$/ or die;
  30         unlink "$obj.KSPLICE_primary" if (-e "$obj.KSPLICE_primary");
  31         unlink "$obj.KSPLICE_helper" if (-e "$obj.KSPLICE_helper");
  32         open OUT, '>', "$out.tmp";
  33         close OUT;
  34         rename "$out.tmp", $out;
  35 }
  36
  37 sub do_snap {
  38         my ($out) = @_;
  39         my ($obj) = $out =~ /^(.*)\.KSPLICE$/ or die;
  40         die if (!-e $obj);
  41         unlink "$obj.KSPLICE_pre" if (-e "$obj.KSPLICE_pre");
  42         empty_diff($out);
  43 }
  44
  45 sub do_diff {
  46         my ($out) = @_;
  47         my ($obj) = $out =~ /^(.*)\.KSPLICE$/ or die;
  48         my $obj_old = "$obj.KSPLICE_pre";
  49         die if (!-e $obj);
  50         die "Patch creates new object $obj" if (!-e $obj_old);
  51         if (system('cmp', '-s', '--', $obj_old, $obj) == 0) {
  52                 unlink $obj_old;
  53                 return empty_diff($out);
  54         }
  55
  56         my $objdiff = runsuc("objdiff", $obj_old, $obj);
  57         return empty_diff($out) if($objdiff !~ m/\S/);
  58
  59         runsuc_in($objdiff, "objmanip", $obj, "$obj.KSPLICE_primary", "keep-primary", $ENV{KSPLICE_KID});
  60         runsuc_in($objdiff, "objmanip", $obj_old, "$obj.KSPLICE_helper", "keep-helper", $ENV{KSPLICE_KID});
  61
  62         open OUT, '>', "$out.tmp";
  63         print OUT "1\n";
  64         close OUT;
  65         rename "$out.tmp", $out;
  66 }
  67
  68 sub do_combine {
  69         my ($out, @ins) = @_;
  70         my @objs;
  71         foreach my $in (@ins) {
  72                 next if (!-s $in);
  73                 my ($obj) = $in =~ /^(.*)\.KSPLICE$/ or die;
  74                 push @objs, $obj;
  75         }
  76
  77         return empty_diff($out) unless (@objs);
  78
  79         my ($obj) = $out =~ /^(.*)\.KSPLICE$/ or die;
  80         if (@objs == 1) {
  81                 copy "$objs[0].KSPLICE_primary", "$obj.KSPLICE_primary";
  82                 copy "$objs[0].KSPLICE_helper", "$obj.KSPLICE_helper";
  83         } else {
  84                 system(shellwords($ENV{LD}), "-r", "-o",
  85                        map { "$_.KSPLICE_primary" } ($obj, @objs));
  86                 system(shellwords($ENV{LD}), "-r", "-o",
  87                        map { "$_.KSPLICE_helper" } ($obj, @objs));
  88         }
  89
  90         open OUT, '>', "$out.tmp";
  91         print OUT "1\n";
  92         close OUT;
  93         rename "$out.tmp", $out;
  94 }
  95
  96 sub do_finalize {
  97         my ($in, $out) = @_;
  98         runsuc("objmanip", $in, $out, "finalize");
  99 }
 100
 101 sub do_rmsyms {
 102         my ($in, $out, @rmsyms) = @_;
 103         my $relocs = runsuc("objmanip", $in, $out, "rmsyms", @rmsyms);
 104 }
 105
 106 sub do_system_map_lookup {
 107         my ($symarg) = @_;
 108         open(SYMS, "<", "$ENV{KSPLICE_CONFIG_DIR}/System.map") or die;
 109         my $line;
 110         while (defined($line = <SYMS>)) {
 111                 my ($addr, $type, $sym, $mod) = split(/\s+/, $line);
 112                 if ($sym eq $symarg) { print $addr; last; }
 113         }
 114         close(SYMS);
 115 }
 116
 117 my %handlers = (
 118         'snap' => \&do_snap,
 119         'diff' => \&do_diff,
 120         'combine' => \&do_combine,
 121         'finalize' => \&do_finalize,
 122         'rmsyms' => \&do_rmsyms,
 123         'system_map_lookup' => \&do_system_map_lookup,
 124 );
 125
 126 my ($cmd, @args) = @ARGV;
 127 if (exists $handlers{$cmd}) {
 128         my $handler = $handlers{$cmd};
 129         &$handler(@args);
 130 } else {
 131         print "Usage: ksplice-obj.pl ", join('|', keys %handlers), " ...\n";
 132 };