ksplice-undo.in

   1 #!/usr/bin/perl
   2
   3 # Copyright (C) 2007-2008  Jeffrey Brian Arnold <jbarnold@mit.edu>
   4 # Copyright (C) 2008  Anders Kaseorg <andersk@mit.edu>,
   5 #                     Tim Abbott <tabbott@mit.edu>
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License, version 2.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston, MA
  18 # 02110-1301, USA.
  19
  20 use strict;
  21 use warnings;
  22 use lib 'KSPLICE_DATA_DIR';
  23 use Ksplice;
  24
  25 my ($help, $wantversion, $debug) = (0, 0, 0);
  26 GetOptions("help|?" => \$help,
  27         "version" => \$wantversion,
  28         "verbose|v:+" => \$Verbose::level,
  29         "debug" => \$debug) or pod2usage(1);
  30
  31 if($wantversion) {
  32         print $version_str;
  33         exit(0);
  34 }
  35 pod2usage(1) if($help || scalar(@ARGV) != 1);
  36
  37 my $kid = $ARGV[0];
  38 $kid =~ s/^ksplice[-_]//;
  39 $kid =~ s/[-_].*$//;
  40 my $update = "ksplice_$kid";
  41 my $nounload = runstr("lsmod") =~ m/- $/m;
  42
  43 if (!update_loaded($kid)) {
  44         print "Ksplice id $kid is not present in the kernel\n";
  45         exit(1);
  46 }
  47
  48 chdir("/sys/module/");
  49 set_debug_level($kid, $debug) if(defined($debug));
  50 my $stage = get_stage($kid);
  51 if ($stage ne 'applied') {
  52         print "Ksplice id $kid is not applied\n";
  53 }
  54 else {
  55         set_stage($kid, "reversed");
  56 }
  57
  58 my $failed = 0;
  59 foreach my $module (glob("${update}_*")) {
  60         if (!$nounload && runval_raw('rmmod', $module) != 0) {
  61                 child_error();
  62                 $failed = 1;
  63         }
  64 }
  65 if ($failed == 0 && -e "/sys/module/$update") {
  66         if (!$nounload && runval_raw('rmmod', $update) != 0) {
  67                 child_error();
  68                 $failed = 1;
  69         }
  70 }
  71 unless($failed == 0) {
  72         my ($debugfile, $debugout) = get_debug_output($kid);
  73         print STDERR "Error undoing Ksplice update $kid:\n";
  74         print $debugout;
  75         my $abort_cause = get_abort_cause($kid);
  76         my $conflicts = get_conflicts($kid);
  77         print_error($abort_cause);
  78         if ($abort_cause eq 'code_busy') {
  79                 print $conflicts;
  80         }
  81         if(defined $debugfile) {
  82                 print $debugout;
  83                 print("Debugging output saved to $debugfile\n");
  84         }
  85         die;
  86 }
  87 exit(0);
  88
  89 sub print_error {
  90         my ($error) = @_;
  91         my %errors = (
  92                 "code_busy" => <<'END',
  93 Ksplice has aborted the undo operation because it appears that the code that
  94 you are trying to change is continuously in use by the system.  More
  95 specifically, Ksplice has been unable to find a moment when one or more of the
  96 to-be-changed functions is not on a thread's kernel stack.
  97 END
  98                 "module_busy" => <<'END',
  99 Ksplice has aborted the undo operation because it appears that the Ksplice
 100 update that you are trying to unload is in use by another module.  You can find
 101 out what module is using the Ksplice update using the lsmod command.
 102 END
 103                 "unexpected_running_task" => <<'END',
 104 Ksplice has aborted the undo operation because of an unexpected failure during
 105 the kernel stack check.  Please consider reporting a bug to PACKAGE_BUGREPORT.
 106 END
 107                 "out_of_memory" => <<'END',
 108 Ksplice has aborted the undo operation because the kernel ran out of memory.
 109 END
 110                 "unexpected" => <<'END',
 111 Ksplice has aborted because of an unexpected error.
 112 Please consider reporting a bug to PACKAGE_BUGREPORT.
 113 END
 114                 "UNKNOWN" => <<'END',
 115 The Ksplice kernel component has returned an error code that this version of
 116 ksplice-undo does not understand.
 117 END
 118                 "ok" => <<'END',
 119 Ksplice has aborted the undo operation for unknown reasons.
 120 Please consider reporting a bug to PACKAGE_BUGREPORT.
 121 END
 122 );
 123         $error = "UNKNOWN" if (!exists $errors{$error});
 124         print STDERR "\n$errors{$error}\n";
 125 }
 126
 127 =head1 NAME
 128
 129 ksplice-undo - Undo a Ksplice update that has been applied to the running kernel
 130
 131 =head1 SYNOPSIS
 132
 133 B<ksplice-undo> I<KSPLICE_ID>
 134
 135 =head1 DESCRIPTION
 136
 137 B<ksplice-undo> takes as input a Ksplice identification tag, as reported by
 138 L<ksplice-view(8)>, and it reverses that update within the running binary kernel.
 139
 140 =head1 OPTIONS
 141
 142 =over 8
 143
 144 =item B<--debug>
 145
 146 Reverses the update with debugging output enabled.  Recommended only for
 147 debugging.
 148
 149 =back
 150
 151 =head1 SEE ALSO
 152
 153 L<ksplice-create(8)>, L<ksplice-apply(8)>, L<ksplice-view(8)>
 154
 155 =head1 COPYRIGHT
 156
 157 Copyright (C) 2007-2008  Jeffrey Brian Arnold <jbarnold@mit.edu>
 158 Copyright (C) 2008  Anders Kaseorg <andersk@mit.edu>,
 159                     Tim Abbott <tabbott@mit.edu>
 160
 161 This is free software and documentation.  You can redistribute and/or modify it
 162 under the terms of the GNU General Public License, version 2.
 163
 164 =cut