authorities/auth_finder.pl

   1 #!/usr/bin/perl
   2 # WARNING: 4-character tab stops here
   3
   4 # Copyright 2000-2002 Katipo Communications
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 2 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21 use strict;
  22 use warnings;
  23
  24 use CGI qw ( -utf8 );
  25 use C4::Output;
  26 use C4::Auth;
  27 use C4::Context;
  28 use C4::AuthoritiesMarc;
  29 use C4::Acquisition;
  30 use C4::Koha;
  31
  32 my $query        = new CGI;
  33 my $op           = $query->param('op') || '';
  34 my $authtypecode = $query->param('authtypecode') || '';
  35 my $index        = $query->param('index') || '';
  36 my $tagid        = $query->param('tagid') || '';
  37 my $source       = $query->param('source') || '';
  38 my $relationship = $query->param('relationship') || '';
  39
  40 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  41     {
  42         template_name => ( $op eq 'do_search' )
  43         ? 'authorities/searchresultlist-auth.tt'
  44         : 'authorities/auth_finder.tt',
  45         query           => $query,
  46         type            => 'intranet',
  47         authnotrequired => 0,
  48         flagsrequired   => { catalogue => 1 },
  49     }
  50 );
  51
  52 # Authority types loop
  53 my $authtypes = C4::Koha::getauthtypes();
  54 my @authtypesloop;
  55 foreach my $thisauthtype ( keys %$authtypes ) {
  56     my %row = (
  57         value        => $thisauthtype,
  58         selected     => ( $thisauthtype eq $authtypecode ),
  59         authtypetext => $authtypes->{$thisauthtype}{'authtypetext'},
  60         index        => $index,
  61     );
  62     push @authtypesloop, \%row;
  63 }
  64
  65 # If search form posted
  66 if ( $op eq "do_search" ) {
  67     my @marclist  = $query->param('marclist');
  68     my @and_or    = $query->param('and_or');
  69     my @excluding = $query->param('excluding');
  70     my @operator  = $query->param('operator');
  71     my @value     = (
  72         $query->param('value_mainstr') || undef,
  73         $query->param('value_main')    || undef,
  74         $query->param('value_any')     || undef,
  75         $query->param('value_match')   || undef
  76     );
  77     my $orderby        = $query->param('orderby')        || '';
  78     my $startfrom      = $query->param('startfrom')      || 0;
  79     my $resultsperpage = $query->param('resultsperpage') || 20;
  80
  81     my ( $results, $total ) =
  82       SearchAuthorities( \@marclist, \@and_or, \@excluding, \@operator, \@value,
  83         $startfrom * $resultsperpage,
  84         $resultsperpage, $authtypecode, $orderby );
  85
  86     # multi page display gestion
  87     my $displaynext = 0;
  88     my $displayprev = $startfrom;
  89     if ( ( $total - ( ( $startfrom + 1 ) * ($resultsperpage) ) ) > 0 ) {
  90         $displaynext = 1;
  91     }
  92
  93     my @field_data = ();
  94
  95 # get marclist again, as the previous one has been modified by catalogsearch (mainentry replaced by field name)
  96     my @marclist_ini = $query->param('marclist');
  97     for ( my $i = 0 ; $i <= $#marclist ; $i++ ) {
  98         push @field_data, { term => "marclist",  val => $marclist_ini[$i] };
  99         push @field_data, { term => "and_or",    val => $and_or[$i] };
 100         push @field_data, { term => "excluding", val => $excluding[$i] };
 101         push @field_data, { term => "operator",  val => $operator[$i] };
 102     }
 103
 104     push @field_data,
 105       { term => "value_mainstr", val => $query->param('value_mainstr') || "" };
 106     push @field_data,
 107       { term => "value_main", val => $query->param('value_main') || "" };
 108     push @field_data,
 109       { term => "value_any", val => $query->param('value_any') || "" };
 110     push @field_data,
 111       { term => "value_match", val => $query->param('value_match') || "" };
 112
 113     my @numbers = ();
 114     if ( $total > $resultsperpage ) {
 115         for ( my $i = 1 ; $i < $total / $resultsperpage + 1 ; $i++ ) {
 116             if ( $i < 16 ) {
 117                 my $highlight = 0;
 118                 ( $startfrom == ( $i - 1 ) ) && ( $highlight = 1 );
 119                 push @numbers,
 120                   {
 121                     number     => $i,
 122                     highlight  => $highlight,
 123                     searchdata => \@field_data,
 124                     startfrom  => ( $i - 1 )
 125                   };
 126             }
 127         }
 128     }
 129
 130     my $from = $startfrom * $resultsperpage + 1;
 131     my $to;
 132     if ( $total < ( ( $startfrom + 1 ) * $resultsperpage ) ) {
 133         $to = $total;
 134     }
 135     else {
 136         $to = ( ( $startfrom + 1 ) * $resultsperpage );
 137     }
 138
 139     $template->param( result => $results ) if $results;
 140     $template->param(
 141         orderby          => $orderby,
 142         startfrom        => $startfrom,
 143         displaynext      => $displaynext,
 144         displayprev      => $displayprev,
 145         resultsperpage   => $resultsperpage,
 146         startfromnext    => $startfrom + 1,
 147         startfromprev    => $startfrom - 1,
 148         searchdata       => \@field_data,
 149         total            => $total,
 150         from             => $from,
 151         to               => $to,
 152         numbers          => \@numbers,
 153         operator_mainstr => ( @operator > 0 && $operator[0] )
 154         ? $operator[0]
 155         : '',
 156         operator_main  => ( @operator > 1 && $operator[1] ) ? $operator[1] : '',
 157         operator_any   => ( @operator > 2 && $operator[2] ) ? $operator[2] : '',
 158         operator_match => ( @operator > 3 && $operator[3] ) ? $operator[3] : '',
 159     );
 160 }
 161 else {
 162
 163     # special case for UNIMARC field 210c builder
 164     my $resultstring = $query->param('result') || '';
 165     $template->param( resultstring => $resultstring, );
 166 }
 167
 168 $template->param(
 169     op            => $op,
 170     value_mainstr => $query->param('value_mainstr') || '',
 171     value_main    => $query->param('value_main') || '',
 172     value_any     => $query->param('value_any') || '',
 173     value_match   => $query->param('value_match') || '',
 174     tagid         => $tagid,
 175     index         => $index,
 176     authtypesloop => \@authtypesloop,
 177     authtypecode  => $authtypecode,
 178     source        => $source,
 179     relationship  => $relationship,
 180 );
 181
 182 # Print the page
 183 output_html_with_http_headers $query, $cookie, $template->output;
 184
 185 # Local Variables:
 186 # tab-width: 4
 187 # End: