C4/Budgets.pm

   1 package C4::Budgets;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 #use warnings; FIXME - Bug 2505
  22 use C4::Context;
  23 use Koha::Database;
  24 use C4::Debug;
  25 use vars qw(@ISA @EXPORT);
  26
  27 BEGIN {
  28         require Exporter;
  29         @ISA    = qw(Exporter);
  30         @EXPORT = qw(
  31
  32         &GetBudget
  33         &GetBudgetByOrderNumber
  34         &GetBudgetByCode
  35         &GetBudgets
  36         &BudgetsByActivity
  37         &GetBudgetsReport
  38         &GetBudgetReport
  39         &GetBudgetHierarchy
  40             &AddBudget
  41         &ModBudget
  42         &DelBudget
  43         &GetBudgetSpent
  44         &GetBudgetOrdered
  45         &GetBudgetName
  46         &GetPeriodsCount
  47         GetBudgetHierarchySpent
  48         GetBudgetHierarchyOrdered
  49
  50         &GetBudgetUsers
  51         &ModBudgetUsers
  52         &CanUserUseBudget
  53         &CanUserModifyBudget
  54
  55             &GetBudgetPeriod
  56         &GetBudgetPeriods
  57         &ModBudgetPeriod
  58         &AddBudgetPeriod
  59             &DelBudgetPeriod
  60
  61         &ModBudgetPlan
  62
  63                 &GetBudgetsPlanCell
  64         &AddBudgetPlanValue
  65         &GetBudgetAuthCats
  66         &BudgetHasChildren
  67         &CheckBudgetParent
  68         &CheckBudgetParentPerm
  69
  70         &HideCols
  71         &GetCols
  72         );
  73 }
  74
  75 # ----------------------------BUDGETS.PM-----------------------------";
  76
  77 =head1 FUNCTIONS ABOUT BUDGETS
  78
  79 =cut
  80
  81 sub HideCols {
  82     my ( $authcat, @hide_cols ) = @_;
  83     my $dbh = C4::Context->dbh;
  84
  85     my $sth1 = $dbh->prepare(
  86         qq|
  87         UPDATE aqbudgets_planning SET display = 0
  88         WHERE authcat = ?
  89         AND  authvalue = ? |
  90     );
  91     foreach my $authvalue (@hide_cols) {
  92 #        $sth1->{TraceLevel} = 3;
  93         $sth1->execute(  $authcat, $authvalue );
  94     }
  95 }
  96
  97 sub GetCols {
  98     my ( $authcat, $authvalue ) = @_;
  99
 100     my $dbh = C4::Context->dbh;
 101     my $sth = $dbh->prepare(
 102         qq|
 103         SELECT count(display) as cnt from aqbudgets_planning
 104         WHERE  authcat = ?
 105         AND authvalue = ? and display  = 0   |
 106     );
 107
 108 #    $sth->{TraceLevel} = 3;
 109     $sth->execute( $authcat, $authvalue );
 110     my $res  = $sth->fetchrow_hashref;
 111
 112     return  $res->{cnt} > 0 ? 0: 1
 113
 114 }
 115
 116 sub CheckBudgetParentPerm {
 117     my ( $budget, $borrower_id ) = @_;
 118     my $depth = $budget->{depth};
 119     my $parent_id = $budget->{budget_parent_id};
 120     while ($depth) {
 121         my $parent = GetBudget($parent_id);
 122         $parent_id = $parent->{budget_parent_id};
 123         if ( $parent->{budget_owner_id} == $borrower_id ) {
 124             return 1;
 125         }
 126         $depth--
 127     }
 128     return 0;
 129 }
 130
 131 sub AddBudgetPeriod {
 132     my ($budgetperiod) = @_;
 133     return unless($budgetperiod->{budget_period_startdate} && $budgetperiod->{budget_period_enddate});
 134
 135     my $resultset = Koha::Database->new()->schema->resultset('Aqbudgetperiod');
 136     return $resultset->create($budgetperiod)->id;
 137 }
 138 # -------------------------------------------------------------------
 139 sub GetPeriodsCount {
 140     my $dbh = C4::Context->dbh;
 141     my $sth = $dbh->prepare("
 142         SELECT COUNT(*) AS sum FROM aqbudgetperiods ");
 143     $sth->execute();
 144     my $res = $sth->fetchrow_hashref;
 145     return $res->{'sum'};
 146 }
 147
 148 # -------------------------------------------------------------------
 149 sub CheckBudgetParent {
 150     my ( $new_parent, $budget ) = @_;
 151     my $new_parent_id = $new_parent->{'budget_id'};
 152     my $budget_id     = $budget->{'budget_id'};
 153     my $dbh           = C4::Context->dbh;
 154     my $parent_id_tmp = $new_parent_id;
 155
 156     # check new-parent is not a child (or a child's child ;)
 157     my $sth = $dbh->prepare(qq|
 158         SELECT budget_parent_id FROM
 159             aqbudgets where budget_id = ? | );
 160     while (1) {
 161         $sth->execute($parent_id_tmp);
 162         my $res = $sth->fetchrow_hashref;
 163         if ( $res->{'budget_parent_id'} == $budget_id ) {
 164             return 1;
 165         }
 166         if ( not defined $res->{'budget_parent_id'} ) {
 167             return 0;
 168         }
 169         $parent_id_tmp = $res->{'budget_parent_id'};
 170     }
 171 }
 172
 173 # -------------------------------------------------------------------
 174 sub BudgetHasChildren {
 175     my ( $budget_id  ) = @_;
 176     my $dbh = C4::Context->dbh;
 177     my $sth = $dbh->prepare(qq|
 178        SELECT count(*) as sum FROM  aqbudgets
 179         WHERE budget_parent_id = ?   | );
 180     $sth->execute( $budget_id );
 181     my $sum = $sth->fetchrow_hashref;
 182     return $sum->{'sum'};
 183 }
 184
 185 sub GetBudgetChildren {
 186     my ( $budget_id ) = @_;
 187     my $dbh = C4::Context->dbh;
 188     return $dbh->selectall_arrayref(q|
 189        SELECT  * FROM  aqbudgets
 190         WHERE budget_parent_id = ?
 191     |, { Slice => {} }, $budget_id );
 192 }
 193
 194 sub SetOwnerToFundHierarchy {
 195     my ( $budget_id, $borrowernumber ) = @_;
 196
 197     my $budget = GetBudget( $budget_id );
 198     $budget->{budget_owner_id} = $borrowernumber;
 199     ModBudget( $budget );
 200     my $children = GetBudgetChildren( $budget_id );
 201     for my $child ( @$children ) {
 202         SetOwnerToFundHierarchy( $child->{budget_id}, $borrowernumber );
 203     }
 204 }
 205
 206 # -------------------------------------------------------------------
 207 sub GetBudgetsPlanCell {
 208     my ( $cell, $period, $budget ) = @_;
 209     my ($actual, $sth);
 210     my $dbh = C4::Context->dbh;
 211     if ( $cell->{'authcat'} eq 'MONTHS' ) {
 212         # get the actual amount
 213         $sth = $dbh->prepare( qq|
 214
 215             SELECT SUM(ecost_tax_included) AS actual FROM aqorders
 216                 WHERE    budget_id = ? AND
 217                 entrydate like "$cell->{'authvalue'}%"  |
 218         );
 219         $sth->execute( $cell->{'budget_id'} );
 220     } elsif ( $cell->{'authcat'} eq 'BRANCHES' ) {
 221         # get the actual amount
 222         $sth = $dbh->prepare( qq|
 223
 224             SELECT SUM(ecost_tax_included) FROM aqorders
 225                 LEFT JOIN aqorders_items
 226                 ON (aqorders.ordernumber = aqorders_items.ordernumber)
 227                 LEFT JOIN items
 228                 ON (aqorders_items.itemnumber = items.itemnumber)
 229                 WHERE budget_id = ? AND homebranch = ? |          );
 230
 231         $sth->execute( $cell->{'budget_id'}, $cell->{'authvalue'} );
 232     } elsif ( $cell->{'authcat'} eq 'ITEMTYPES' ) {
 233         # get the actual amount
 234         $sth = $dbh->prepare(  qq|
 235
 236             SELECT SUM( ecost_tax_included *  quantity) AS actual
 237                 FROM aqorders JOIN biblioitems
 238                 ON (biblioitems.biblionumber = aqorders.biblionumber )
 239                 WHERE aqorders.budget_id = ? and itemtype  = ? |
 240         );
 241         $sth->execute(  $cell->{'budget_id'},
 242                         $cell->{'authvalue'} );
 243     }
 244     # ELSE GENERIC ORDERS SORT1/SORT2 STAT COUNT.
 245     else {
 246         # get the actual amount
 247         $sth = $dbh->prepare( qq|
 248
 249         SELECT  SUM(ecost_tax_included * quantity) AS actual
 250             FROM aqorders
 251             JOIN aqbudgets ON (aqbudgets.budget_id = aqorders.budget_id )
 252             WHERE  aqorders.budget_id = ? AND
 253                 ((aqbudgets.sort1_authcat = ? AND sort1 =?) OR
 254                 (aqbudgets.sort2_authcat = ? AND sort2 =?))    |
 255         );
 256         $sth->execute(  $cell->{'budget_id'},
 257                         $budget->{'sort1_authcat'},
 258                         $cell->{'authvalue'},
 259                         $budget->{'sort2_authcat'},
 260                         $cell->{'authvalue'}
 261         );
 262     }
 263     $actual = $sth->fetchrow_array;
 264
 265     # get the estimated amount
 266     $sth = $dbh->prepare( qq|
 267
 268         SELECT estimated_amount AS estimated, display FROM aqbudgets_planning
 269             WHERE budget_period_id = ? AND
 270                 budget_id = ? AND
 271                 authvalue = ? AND
 272                 authcat = ?         |
 273     );
 274     $sth->execute(  $cell->{'budget_period_id'},
 275                     $cell->{'budget_id'},
 276                     $cell->{'authvalue'},
 277                     $cell->{'authcat'},
 278     );
 279
 280
 281     my $res  = $sth->fetchrow_hashref;
 282   #  my $display = $res->{'display'};
 283     my $estimated = $res->{'estimated'};
 284
 285
 286     return $actual, $estimated;
 287 }
 288
 289 # -------------------------------------------------------------------
 290 sub ModBudgetPlan {
 291     my ( $budget_plan, $budget_period_id, $authcat ) = @_;
 292     my $dbh = C4::Context->dbh;
 293     foreach my $buds (@$budget_plan) {
 294         my $lines = $buds->{lines};
 295         my $sth = $dbh->prepare( qq|
 296                 DELETE FROM aqbudgets_planning
 297                     WHERE   budget_period_id   = ? AND
 298                             budget_id   = ? AND
 299                             authcat            = ? |
 300         );
 301     #delete a aqplan line of cells, then insert new cells,
 302     # these could be UPDATES rather than DEL/INSERTS...
 303         $sth->execute( $budget_period_id,  $lines->[0]{budget_id}   , $authcat );
 304
 305         foreach my $cell (@$lines) {
 306             my $sth = $dbh->prepare( qq|
 307
 308                 INSERT INTO aqbudgets_planning
 309                      SET   budget_id     = ?,
 310                      budget_period_id  = ?,
 311                      authcat          = ?,
 312                      estimated_amount  = ?,
 313                      authvalue       = ?  |
 314             );
 315             $sth->execute(
 316                             $cell->{'budget_id'},
 317                             $cell->{'budget_period_id'},
 318                             $cell->{'authcat'},
 319                             $cell->{'estimated_amount'},
 320                             $cell->{'authvalue'},
 321             );
 322         }
 323     }
 324 }
 325
 326 # -------------------------------------------------------------------
 327 sub GetBudgetSpent {
 328     my ($budget_id) = @_;
 329     my $dbh = C4::Context->dbh;
 330     # unitprice_tax_included should always been set here
 331     # we should not need to retrieve ecost_tax_included
 332     my $sth = $dbh->prepare(qq|
 333         SELECT SUM( COALESCE(unitprice_tax_included, ecost_tax_included) * quantity ) AS sum FROM aqorders
 334             WHERE budget_id = ? AND
 335             quantityreceived > 0 AND
 336             datecancellationprinted IS NULL
 337     |);
 338         $sth->execute($budget_id);
 339         my $sum =  $sth->fetchrow_array;
 340
 341     $sth = $dbh->prepare(qq|
 342         SELECT SUM(shipmentcost) AS sum
 343         FROM aqinvoices
 344         WHERE shipmentcost_budgetid = ?
 345           AND closedate IS NOT NULL
 346     |);
 347     $sth->execute($budget_id);
 348     my ($shipmentcost_sum) = $sth->fetchrow_array;
 349     $sum += $shipmentcost_sum;
 350
 351         return $sum;
 352 }
 353
 354 # -------------------------------------------------------------------
 355 sub GetBudgetOrdered {
 356         my ($budget_id) = @_;
 357         my $dbh = C4::Context->dbh;
 358         my $sth = $dbh->prepare(qq|
 359         SELECT SUM(ecost_tax_included *  quantity) AS sum FROM aqorders
 360             WHERE budget_id = ? AND
 361             quantityreceived = 0 AND
 362             datecancellationprinted IS NULL
 363     |);
 364         $sth->execute($budget_id);
 365         my $sum =  $sth->fetchrow_array;
 366
 367     $sth = $dbh->prepare(qq|
 368         SELECT SUM(shipmentcost) AS sum
 369         FROM aqinvoices
 370         WHERE shipmentcost_budgetid = ?
 371           AND closedate IS NULL
 372     |);
 373     $sth->execute($budget_id);
 374     my ($shipmentcost_sum) = $sth->fetchrow_array;
 375     $sum += $shipmentcost_sum;
 376
 377         return $sum;
 378 }
 379
 380 =head2 GetBudgetName
 381
 382   my $budget_name = &GetBudgetName($budget_id);
 383
 384 get the budget_name for a given budget_id
 385
 386 =cut
 387
 388 sub GetBudgetName {
 389     my ( $budget_id ) = @_;
 390     my $dbh         = C4::Context->dbh;
 391     my $sth         = $dbh->prepare(
 392         qq|
 393         SELECT budget_name
 394         FROM aqbudgets
 395         WHERE budget_id = ?
 396     |);
 397
 398     $sth->execute($budget_id);
 399     return $sth->fetchrow_array;
 400 }
 401
 402 =head2 GetBudgetAuthCats
 403
 404   my $auth_cats = &GetBudgetAuthCats($budget_period_id);
 405
 406 Return the list of authcat for a given budget_period_id
 407
 408 =cut
 409
 410 sub GetBudgetAuthCats  {
 411     my ($budget_period_id) = shift;
 412     # now, populate the auth_cats_loop used in the budget planning button
 413     # we must retrieve all auth values used by at least one budget
 414     my $dbh = C4::Context->dbh;
 415     my $sth=$dbh->prepare("SELECT sort1_authcat,sort2_authcat FROM aqbudgets WHERE budget_period_id=?");
 416     $sth->execute($budget_period_id);
 417     my %authcats;
 418     while (my ($sort1_authcat,$sort2_authcat) = $sth->fetchrow) {
 419         $authcats{$sort1_authcat}=1 if $sort1_authcat;
 420         $authcats{$sort2_authcat}=1 if $sort2_authcat;
 421     }
 422     return [ sort keys %authcats ];
 423 }
 424
 425 # -------------------------------------------------------------------
 426 sub GetBudgetPeriods {
 427         my ($filters,$orderby) = @_;
 428
 429     my $rs = Koha::Database->new()->schema->resultset('Aqbudgetperiod');
 430     $rs = $rs->search( $filters, { order_by => $orderby } );
 431     $rs->result_class('DBIx::Class::ResultClass::HashRefInflator');
 432     return [ $rs->all ];
 433 }
 434 # -------------------------------------------------------------------
 435 sub GetBudgetPeriod {
 436         my ($budget_period_id) = @_;
 437         my $dbh = C4::Context->dbh;
 438         ## $total = number of records linked to the record that must be deleted
 439         my $total = 0;
 440         ## get information about the record that will be deleted
 441         my $sth;
 442         if ($budget_period_id) {
 443                 $sth = $dbh->prepare( qq|
 444               SELECT      *
 445                 FROM aqbudgetperiods
 446                 WHERE budget_period_id=? |
 447                 );
 448                 $sth->execute($budget_period_id);
 449         } else {         # ACTIVE BUDGET
 450                 $sth = $dbh->prepare(qq|
 451                           SELECT      *
 452                 FROM aqbudgetperiods
 453                 WHERE budget_period_active=1 |
 454                 );
 455                 $sth->execute();
 456         }
 457         my $data = $sth->fetchrow_hashref;
 458         return $data;
 459 }
 460
 461 sub DelBudgetPeriod{
 462         my ($budget_period_id) = @_;
 463         my $dbh = C4::Context->dbh;
 464           ; ## $total = number of records linked to the record that must be deleted
 465     my $total = 0;
 466
 467         ## get information about the record that will be deleted
 468         my $sth = $dbh->prepare(qq|
 469                 DELETE
 470          FROM aqbudgetperiods
 471          WHERE budget_period_id=? |
 472         );
 473         return $sth->execute($budget_period_id);
 474 }
 475
 476 # -------------------------------------------------------------------
 477 sub ModBudgetPeriod {
 478     my ($budget_period) = @_;
 479     my $result = Koha::Database->new()->schema->resultset('Aqbudgetperiod')->find($budget_period);
 480     return unless($result);
 481
 482     $result = $result->update($budget_period);
 483     return $result->in_storage;
 484 }
 485
 486 # -------------------------------------------------------------------
 487 sub GetBudgetHierarchy {
 488     my ( $budget_period_id, $branchcode, $owner ) = @_;
 489     my @bind_params;
 490     my $dbh   = C4::Context->dbh;
 491     my $query = qq|
 492                     SELECT aqbudgets.*, aqbudgetperiods.budget_period_active, aqbudgetperiods.budget_period_description
 493                     FROM aqbudgets
 494                     JOIN aqbudgetperiods USING (budget_period_id)|;
 495
 496         my @where_strings;
 497     # show only period X if requested
 498     if ($budget_period_id) {
 499         push @where_strings," aqbudgets.budget_period_id = ?";
 500         push @bind_params, $budget_period_id;
 501     }
 502         # show only budgets owned by me, my branch or everyone
 503     if ($owner) {
 504         if ($branchcode) {
 505             push @where_strings,
 506             qq{ (budget_owner_id = ? OR budget_branchcode = ? OR ((budget_branchcode IS NULL or budget_branchcode="") AND (budget_owner_id IS NULL OR budget_owner_id="")))};
 507             push @bind_params, ( $owner, $branchcode );
 508         } else {
 509             push @where_strings, ' (budget_owner_id = ? OR budget_owner_id IS NULL or budget_owner_id ="") ';
 510             push @bind_params, $owner;
 511         }
 512     } else {
 513         if ($branchcode) {
 514             push @where_strings," (budget_branchcode =? or budget_branchcode is NULL OR budget_branchcode='')";
 515             push @bind_params, $branchcode;
 516         }
 517     }
 518         $query.=" WHERE ".join(' AND ', @where_strings) if @where_strings;
 519         $debug && warn $query,join(",",@bind_params);
 520         my $sth = $dbh->prepare($query);
 521         $sth->execute(@bind_params);
 522
 523     my %links;
 524     # create hash with budget_id has key
 525     while ( my $data = $sth->fetchrow_hashref ) {
 526         $links{ $data->{'budget_id'} } = $data;
 527     }
 528
 529     # link child to parent
 530     my @first_parents;
 531     foreach my $budget ( sort { $a->{budget_code} cmp $b->{budget_code} } values %links ) {
 532         my $child = $links{$budget->{budget_id}};
 533         if ( $child->{'budget_parent_id'} ) {
 534             my $parent = $links{ $child->{'budget_parent_id'} };
 535             if ($parent) {
 536                 unless ( $parent->{'children'} ) {
 537                     # init child arrayref
 538                     $parent->{'children'} = [];
 539                 }
 540                 # add as child
 541                 push @{ $parent->{'children'} }, $child;
 542             }
 543         } else {
 544             push @first_parents, $child;
 545         }
 546     }
 547
 548     my @sort = ();
 549     foreach my $first_parent (@first_parents) {
 550         _add_budget_children(\@sort, $first_parent, 0);
 551     }
 552
 553     foreach my $budget (@sort) {
 554         $budget->{budget_spent}   = GetBudgetSpent( $budget->{budget_id} );
 555         $budget->{budget_ordered} = GetBudgetOrdered( $budget->{budget_id} );
 556         $budget->{total_spent} = GetBudgetHierarchySpent( $budget->{budget_id} );
 557         $budget->{total_ordered} = GetBudgetHierarchyOrdered( $budget->{budget_id} );
 558     }
 559     return \@sort;
 560 }
 561
 562 # Recursive method to add a budget and its chidren to an array
 563 sub _add_budget_children {
 564     my $res = shift;
 565     my $budget = shift;
 566     $budget->{budget_level} = shift;
 567     push @$res, $budget;
 568     my $children = $budget->{'children'} || [];
 569     return unless @$children; # break recursivity
 570     foreach my $child (@$children) {
 571         _add_budget_children($res, $child, $budget->{budget_level} + 1);
 572     }
 573 }
 574
 575 # -------------------------------------------------------------------
 576
 577 sub AddBudget {
 578     my ($budget) = @_;
 579     return unless ($budget);
 580
 581     my $resultset = Koha::Database->new()->schema->resultset('Aqbudget');
 582     return $resultset->create($budget)->id;
 583 }
 584
 585 # -------------------------------------------------------------------
 586 sub ModBudget {
 587     my ($budget) = @_;
 588     my $result = Koha::Database->new()->schema->resultset('Aqbudget')->find($budget);
 589     return unless($result);
 590
 591     $result = $result->update($budget);
 592     return $result->in_storage;
 593 }
 594
 595 # -------------------------------------------------------------------
 596 sub DelBudget {
 597         my ($budget_id) = @_;
 598         my $dbh         = C4::Context->dbh;
 599         my $sth         = $dbh->prepare("delete from aqbudgets where budget_id=?");
 600         my $rc          = $sth->execute($budget_id);
 601         return $rc;
 602 }
 603
 604
 605 # -------------------------------------------------------------------
 606
 607 =head2 GetBudget
 608
 609   &GetBudget($budget_id);
 610
 611 get a specific budget
 612
 613 =cut
 614
 615 sub GetBudget {
 616     my ( $budget_id ) = @_;
 617     my $dbh = C4::Context->dbh;
 618     my $query = "
 619         SELECT *
 620         FROM   aqbudgets
 621         WHERE  budget_id=?
 622         ";
 623     my $sth = $dbh->prepare($query);
 624     $sth->execute( $budget_id );
 625     my $result = $sth->fetchrow_hashref;
 626     return $result;
 627 }
 628
 629 # -------------------------------------------------------------------
 630
 631 =head2 GetBudgetByOrderNumber
 632
 633   &GetBudgetByOrderNumber($ordernumber);
 634
 635 get a specific budget by order number
 636
 637 =cut
 638
 639 sub GetBudgetByOrderNumber {
 640     my ( $ordernumber ) = @_;
 641     my $dbh = C4::Context->dbh;
 642     my $query = "
 643         SELECT aqbudgets.*
 644         FROM   aqbudgets, aqorders
 645         WHERE  ordernumber=?
 646         AND    aqorders.budget_id = aqbudgets.budget_id
 647         ";
 648     my $sth = $dbh->prepare($query);
 649     $sth->execute( $ordernumber );
 650     my $result = $sth->fetchrow_hashref;
 651     return $result;
 652 }
 653
 654 =head2 GetBudgetReport
 655
 656   &GetBudgetReport( [$budget_id] );
 657
 658 Get all orders for a specific budget, without cancelled orders.
 659
 660 Returns an array of hashrefs.
 661
 662 =cut
 663
 664 # --------------------------------------------------------------------
 665 sub GetBudgetReport {
 666     my ( $budget_id ) = @_;
 667     my $dbh = C4::Context->dbh;
 668     my $query = '
 669         SELECT o.*, b.budget_name
 670         FROM   aqbudgets b
 671         INNER JOIN aqorders o
 672         ON b.budget_id = o.budget_id
 673         WHERE  b.budget_id=?
 674         AND (o.orderstatus != "cancelled")
 675         ORDER BY b.budget_name';
 676
 677     my $sth = $dbh->prepare($query);
 678     $sth->execute( $budget_id );
 679
 680     my @results = ();
 681     while ( my $data = $sth->fetchrow_hashref ) {
 682         push( @results, $data );
 683     }
 684     return @results;
 685 }
 686
 687 =head2 GetBudgetsByActivity
 688
 689   &GetBudgetsByActivity( $budget_period_active );
 690
 691 Get all active or inactive budgets, depending of the value
 692 of the parameter.
 693
 694 1 = active
 695 0 = inactive
 696
 697 =cut
 698
 699 # --------------------------------------------------------------------
 700 sub GetBudgetsByActivity {
 701     my ( $budget_period_active ) = @_;
 702     my $dbh = C4::Context->dbh;
 703     my $query = "
 704         SELECT DISTINCT b.*
 705         FROM   aqbudgetperiods bp
 706         INNER JOIN aqbudgets b
 707         ON bp.budget_period_id = b.budget_period_id
 708         WHERE  bp.budget_period_active=?
 709         ";
 710     my $sth = $dbh->prepare($query);
 711     $sth->execute( $budget_period_active );
 712     my @results = ();
 713     while ( my $data = $sth->fetchrow_hashref ) {
 714         push( @results, $data );
 715     }
 716     return @results;
 717 }
 718 # --------------------------------------------------------------------
 719
 720 =head2 GetBudgetsReport
 721
 722   &GetBudgetsReport( [$activity] );
 723
 724 Get all but cancelled orders for all funds.
 725
 726 If the optionnal activity parameter is passed, returns orders for active/inactive budgets only.
 727
 728 active = 1
 729 inactive = 0
 730
 731 Returns an array of hashrefs.
 732
 733 =cut
 734
 735 sub GetBudgetsReport {
 736     my ($activity) = @_;
 737     my $dbh = C4::Context->dbh;
 738     my $query = '
 739         SELECT o.*, b.budget_name
 740         FROM   aqbudgetperiods bp
 741         INNER JOIN aqbudgets b
 742         ON bp.budget_period_id = b.budget_period_id
 743         INNER JOIN aqorders o
 744         ON b.budget_id = o.budget_id ';
 745     if($activity ne ''){
 746         $query .= 'WHERE  bp.budget_period_active=? ';
 747     }
 748     $query .= 'AND (o.orderstatus != "cancelled")
 749                ORDER BY b.budget_name';
 750
 751     my $sth = $dbh->prepare($query);
 752     if($activity ne ''){
 753         $sth->execute($activity);
 754     }
 755     else{
 756         $sth->execute;
 757     }
 758     my @results = ();
 759     while ( my $data = $sth->fetchrow_hashref ) {
 760         push( @results, $data );
 761     }
 762     return @results;
 763 }
 764
 765 =head2 GetBudgetByCode
 766
 767     my $budget = &GetBudgetByCode($budget_code);
 768
 769 Retrieve all aqbudgets fields as a hashref for the budget that has
 770 given budget_code
 771
 772 =cut
 773
 774 sub GetBudgetByCode {
 775     my ( $budget_code ) = @_;
 776
 777     my $dbh = C4::Context->dbh;
 778     my $query = qq{
 779         SELECT aqbudgets.*
 780         FROM aqbudgets
 781         JOIN aqbudgetperiods USING (budget_period_id)
 782         WHERE budget_code = ?
 783         ORDER BY budget_period_active DESC, budget_id DESC
 784         LIMIT 1
 785     };
 786     my $sth = $dbh->prepare( $query );
 787     $sth->execute( $budget_code );
 788     return $sth->fetchrow_hashref;
 789 }
 790
 791 =head2 GetBudgetHierarchySpent
 792
 793   my $spent = GetBudgetHierarchySpent( $budget_id );
 794
 795 Gets the total spent of the level and sublevels of $budget_id
 796
 797 =cut
 798
 799 sub GetBudgetHierarchySpent {
 800     my ( $budget_id ) = @_;
 801     my $dbh = C4::Context->dbh;
 802     my $children_ids = $dbh->selectcol_arrayref(q|
 803         SELECT budget_id
 804         FROM   aqbudgets
 805         WHERE  budget_parent_id = ?
 806     |, {}, $budget_id );
 807
 808     my $total_spent = GetBudgetSpent( $budget_id );
 809     for my $child_id ( @$children_ids ) {
 810         $total_spent += GetBudgetHierarchySpent( $child_id );
 811     }
 812     return $total_spent;
 813 }
 814
 815 =head2 GetBudgetHierarchyOrdered
 816
 817   my $ordered = GetBudgetHierarchyOrdered( $budget_id );
 818
 819 Gets the total ordered of the level and sublevels of $budget_id
 820
 821 =cut
 822
 823 sub GetBudgetHierarchyOrdered {
 824     my ( $budget_id ) = @_;
 825     my $dbh = C4::Context->dbh;
 826     my $children_ids = $dbh->selectcol_arrayref(q|
 827         SELECT budget_id
 828         FROM   aqbudgets
 829         WHERE  budget_parent_id = ?
 830     |, {}, $budget_id );
 831
 832     my $total_ordered = GetBudgetOrdered( $budget_id );
 833     for my $child_id ( @$children_ids ) {
 834         $total_ordered += GetBudgetHierarchyOrdered( $child_id );
 835     }
 836     return $total_ordered;
 837 }
 838
 839 =head2 GetBudgets
 840
 841   &GetBudgets($filter, $order_by);
 842
 843 gets all budgets
 844
 845 =cut
 846
 847 # -------------------------------------------------------------------
 848 sub GetBudgets {
 849     my ($filters, $orderby) = @_;
 850     $orderby = 'budget_name' unless($orderby);
 851
 852     my $rs = Koha::Database->new()->schema->resultset('Aqbudget');
 853     $rs = $rs->search( $filters, { order_by => $orderby } );
 854     $rs->result_class('DBIx::Class::ResultClass::HashRefInflator');
 855     return [ $rs->all  ];
 856 }
 857
 858 =head2 GetBudgetUsers
 859
 860     my @borrowernumbers = &GetBudgetUsers($budget_id);
 861
 862 Return the list of borrowernumbers linked to a budget
 863
 864 =cut
 865
 866 sub GetBudgetUsers {
 867     my ($budget_id) = @_;
 868
 869     my $dbh = C4::Context->dbh;
 870     my $query = qq{
 871         SELECT borrowernumber
 872         FROM aqbudgetborrowers
 873         WHERE budget_id = ?
 874     };
 875     my $sth = $dbh->prepare($query);
 876     $sth->execute($budget_id);
 877
 878     my @borrowernumbers;
 879     while (my ($borrowernumber) = $sth->fetchrow_array) {
 880         push @borrowernumbers, $borrowernumber
 881     }
 882
 883     return @borrowernumbers;
 884 }
 885
 886 =head2 ModBudgetUsers
 887
 888     &ModBudgetUsers($budget_id, @borrowernumbers);
 889
 890 Modify the list of borrowernumbers linked to a budget
 891
 892 =cut
 893
 894 sub ModBudgetUsers {
 895     my ($budget_id, @budget_users_id) = @_;
 896
 897     return unless $budget_id;
 898
 899     my $dbh = C4::Context->dbh;
 900     my $query = "DELETE FROM aqbudgetborrowers WHERE budget_id = ?";
 901     my $sth = $dbh->prepare($query);
 902     $sth->execute($budget_id);
 903
 904     $query = qq{
 905         INSERT INTO aqbudgetborrowers (budget_id, borrowernumber)
 906         VALUES (?,?)
 907     };
 908     $sth = $dbh->prepare($query);
 909     foreach my $borrowernumber (@budget_users_id) {
 910         next unless $borrowernumber;
 911         $sth->execute($budget_id, $borrowernumber);
 912     }
 913 }
 914
 915 sub CanUserUseBudget {
 916     my ($borrower, $budget, $userflags) = @_;
 917
 918     if (not ref $borrower) {
 919         $borrower = C4::Members::GetMember(borrowernumber => $borrower);
 920     }
 921     if (not ref $budget) {
 922         $budget = GetBudget($budget);
 923     }
 924
 925     return 0 unless ($borrower and $budget);
 926
 927     if (not defined $userflags) {
 928         $userflags = C4::Auth::getuserflags($borrower->{flags},
 929             $borrower->{userid});
 930     }
 931
 932     unless ($userflags->{superlibrarian}
 933     || (ref $userflags->{acquisition}
 934         && $userflags->{acquisition}->{budget_manage_all})
 935     || (!ref $userflags->{acquisition} && $userflags->{acquisition}))
 936     {
 937         if (not exists $userflags->{acquisition}) {
 938             return 0;
 939         }
 940
 941         if (!ref $userflags->{acquisition} && !$userflags->{acquisition}) {
 942             return 0;
 943         }
 944
 945         # Budget restricted to owner
 946         if ( $budget->{budget_permission} == 1 ) {
 947             if (    $budget->{budget_owner_id}
 948                 and $budget->{budget_owner_id} != $borrower->{borrowernumber} )
 949             {
 950                 return 0;
 951             }
 952         }
 953
 954         # Budget restricted to owner, users and library
 955         elsif ( $budget->{budget_permission} == 2 ) {
 956             my @budget_users = GetBudgetUsers( $budget->{budget_id} );
 957
 958             if (
 959                 (
 960                         $budget->{budget_owner_id}
 961                     and $budget->{budget_owner_id} !=
 962                     $borrower->{borrowernumber}
 963                     or not $budget->{budget_owner_id}
 964                 )
 965                 and ( 0 == grep { $borrower->{borrowernumber} == $_ }
 966                     @budget_users )
 967                 and defined $budget->{budget_branchcode}
 968                 and $budget->{budget_branchcode} ne
 969                 C4::Context->userenv->{branch}
 970               )
 971             {
 972                 return 0;
 973             }
 974         }
 975
 976         # Budget restricted to owner and users
 977         elsif ( $budget->{budget_permission} == 3 ) {
 978             my @budget_users = GetBudgetUsers( $budget->{budget_id} );
 979             if (
 980                 (
 981                         $budget->{budget_owner_id}
 982                     and $budget->{budget_owner_id} !=
 983                     $borrower->{borrowernumber}
 984                     or not $budget->{budget_owner_id}
 985                 )
 986                 and ( 0 == grep { $borrower->{borrowernumber} == $_ }
 987                     @budget_users )
 988               )
 989             {
 990                 return 0;
 991             }
 992         }
 993     }
 994
 995     return 1;
 996 }
 997
 998 sub CanUserModifyBudget {
 999     my ($borrower, $budget, $userflags) = @_;
1000
1001     if (not ref $borrower) {
1002         $borrower = C4::Members::GetMember(borrowernumber => $borrower);
1003     }
1004     if (not ref $budget) {
1005         $budget = GetBudget($budget);
1006     }
1007
1008     return 0 unless ($borrower and $budget);
1009
1010     if (not defined $userflags) {
1011         $userflags = C4::Auth::getuserflags($borrower->{flags},
1012             $borrower->{userid});
1013     }
1014
1015     unless ($userflags->{superlibrarian}
1016     || (ref $userflags->{acquisition}
1017         && $userflags->{acquisition}->{budget_manage_all})
1018     || (!ref $userflags->{acquisition} && $userflags->{acquisition}))
1019     {
1020         if (!CanUserUseBudget($borrower, $budget, $userflags)) {
1021             return 0;
1022         }
1023
1024         if (ref $userflags->{acquisition}
1025         && !$userflags->{acquisition}->{budget_modify}) {
1026             return 0;
1027         }
1028     }
1029
1030     return 1;
1031 }
1032
1033 sub _round {
1034     my ($value, $increment) = @_;
1035
1036     if ($increment && $increment != 0) {
1037         $value = int($value / $increment) * $increment;
1038     }
1039
1040     return $value;
1041 }
1042
1043 =head2 CloneBudgetPeriod
1044
1045   my $new_budget_period_id = CloneBudgetPeriod({
1046     budget_period_id => $budget_period_id,
1047     budget_period_startdate => $budget_period_startdate,
1048     budget_period_enddate   => $budget_period_enddate,
1049     mark_original_budget_as_inactive => 1n
1050     reset_all_budgets => 1,
1051   });
1052
1053 Clone a budget period with all budgets.
1054 If the mark_origin_budget_as_inactive is set (0 by default),
1055 the original budget will be marked as inactive.
1056
1057 If the reset_all_budgets is set (0 by default), all budget (fund)
1058 amounts will be reset.
1059
1060 =cut
1061
1062 sub CloneBudgetPeriod {
1063     my ($params)                  = @_;
1064     my $budget_period_id          = $params->{budget_period_id};
1065     my $budget_period_startdate   = $params->{budget_period_startdate};
1066     my $budget_period_enddate     = $params->{budget_period_enddate};
1067     my $budget_period_description = $params->{budget_period_description};
1068     my $amount_change_percentage  = $params->{amount_change_percentage};
1069     my $amount_change_round_increment = $params->{amount_change_round_increment};
1070     my $mark_original_budget_as_inactive =
1071       $params->{mark_original_budget_as_inactive} || 0;
1072     my $reset_all_budgets = $params->{reset_all_budgets} || 0;
1073
1074     my $budget_period = GetBudgetPeriod($budget_period_id);
1075
1076     $budget_period->{budget_period_startdate}   = $budget_period_startdate;
1077     $budget_period->{budget_period_enddate}     = $budget_period_enddate;
1078     $budget_period->{budget_period_description} = $budget_period_description;
1079     # The new budget (budget_period) should be active by default
1080     $budget_period->{budget_period_active}    = 1;
1081
1082     if ($amount_change_percentage) {
1083         my $total = $budget_period->{budget_period_total};
1084         $total += $total * $amount_change_percentage / 100;
1085         $total = _round($total, $amount_change_round_increment);
1086         $budget_period->{budget_period_total} = $total;
1087     }
1088
1089     my $original_budget_period_id = $budget_period->{budget_period_id};
1090     delete $budget_period->{budget_period_id};
1091     my $new_budget_period_id = AddBudgetPeriod( $budget_period );
1092
1093     my $budgets = GetBudgetHierarchy($budget_period_id);
1094     CloneBudgetHierarchy(
1095         {
1096             budgets              => $budgets,
1097             new_budget_period_id => $new_budget_period_id
1098         }
1099     );
1100
1101     if ($mark_original_budget_as_inactive) {
1102         ModBudgetPeriod(
1103             {
1104                 budget_period_id     => $budget_period_id,
1105                 budget_period_active => 0,
1106             }
1107         );
1108     }
1109
1110     if ( $reset_all_budgets ) {
1111         my $budgets = GetBudgets({ budget_period_id => $new_budget_period_id });
1112         for my $budget ( @$budgets ) {
1113             $budget->{budget_amount} = 0;
1114             ModBudget( $budget );
1115         }
1116     } elsif ($amount_change_percentage) {
1117         my $budgets = GetBudgets({ budget_period_id => $new_budget_period_id });
1118         for my $budget ( @$budgets ) {
1119             my $amount = $budget->{budget_amount};
1120             $amount += $amount * $amount_change_percentage / 100;
1121             $amount = _round($amount, $amount_change_round_increment);
1122             $budget->{budget_amount} = $amount;
1123             ModBudget( $budget );
1124         }
1125     }
1126
1127     return $new_budget_period_id;
1128 }
1129
1130 =head2 CloneBudgetHierarchy
1131
1132   CloneBudgetHierarchy({
1133     budgets => $budgets,
1134     new_budget_period_id => $new_budget_period_id;
1135   });
1136
1137 Clone a budget hierarchy.
1138
1139 =cut
1140
1141 sub CloneBudgetHierarchy {
1142     my ($params)             = @_;
1143     my $budgets              = $params->{budgets};
1144     my $new_budget_period_id = $params->{new_budget_period_id};
1145     next unless @$budgets or $new_budget_period_id;
1146
1147     my $children_of   = $params->{children_of};
1148     my $new_parent_id = $params->{new_parent_id};
1149
1150     my @first_level_budgets =
1151       ( not defined $children_of )
1152       ? map { ( not $_->{budget_parent_id} )             ? $_ : () } @$budgets
1153       : map { ( $_->{budget_parent_id} == $children_of ) ? $_ : () } @$budgets;
1154
1155     # get only the columns of aqbudgets
1156     my @columns = Koha::Database->new()->schema->source('Aqbudget')->columns;
1157
1158     for my $budget ( sort { $a->{budget_id} <=> $b->{budget_id} }
1159         @first_level_budgets )
1160     {
1161
1162         my $tidy_budget =
1163           { map { join( ' ', @columns ) =~ /$_/ ? ( $_ => $budget->{$_} ) : () }
1164               keys %$budget };
1165         my $new_budget_id = AddBudget(
1166             {
1167                 %$tidy_budget,
1168                 budget_id        => undef,
1169                 budget_parent_id => $new_parent_id,
1170                 budget_period_id => $new_budget_period_id
1171             }
1172         );
1173         CloneBudgetHierarchy(
1174             {
1175                 budgets              => $budgets,
1176                 new_budget_period_id => $new_budget_period_id,
1177                 children_of          => $budget->{budget_id},
1178                 new_parent_id        => $new_budget_id
1179             }
1180         );
1181     }
1182 }
1183
1184 =head2 MoveOrders
1185
1186   my $report = MoveOrders({
1187     from_budget_period_id => $from_budget_period_id,
1188     to_budget_period_id   => $to_budget_period_id,
1189   });
1190
1191 Move orders from one budget period to another.
1192
1193 =cut
1194
1195 sub MoveOrders {
1196     my ($params)              = @_;
1197     my $from_budget_period_id = $params->{from_budget_period_id};
1198     my $to_budget_period_id   = $params->{to_budget_period_id};
1199     my $move_remaining_unspent = $params->{move_remaining_unspent};
1200     return
1201       if not $from_budget_period_id
1202           or not $to_budget_period_id
1203           or $from_budget_period_id == $to_budget_period_id;
1204
1205     # Can't move orders to an inactive budget (budgetperiod)
1206     my $budget_period = GetBudgetPeriod($to_budget_period_id);
1207     return unless $budget_period->{budget_period_active};
1208
1209     my @report;
1210     my $dbh     = C4::Context->dbh;
1211     my $sth_update_aqorders = $dbh->prepare(
1212         q|
1213             UPDATE aqorders
1214             SET budget_id = ?
1215             WHERE ordernumber = ?
1216         |
1217     );
1218     my $sth_update_budget_amount = $dbh->prepare(
1219         q|
1220             UPDATE aqbudgets
1221             SET budget_amount = ?
1222             WHERE budget_id = ?
1223         |
1224     );
1225     my $from_budgets = GetBudgetHierarchy($from_budget_period_id);
1226     for my $from_budget (@$from_budgets) {
1227         my $new_budget_id = $dbh->selectcol_arrayref(
1228             q|
1229                 SELECT budget_id
1230                 FROM aqbudgets
1231                 WHERE budget_period_id = ?
1232                     AND budget_code = ?
1233             |, {}, $to_budget_period_id, $from_budget->{budget_code}
1234         );
1235         $new_budget_id = $new_budget_id->[0];
1236         my $new_budget = GetBudget( $new_budget_id );
1237         unless ( $new_budget ) {
1238             push @report,
1239               {
1240                 moved       => 0,
1241                 budget      => $from_budget,
1242                 error       => 'budget_code_not_exists',
1243               };
1244             next;
1245         }
1246         my $orders_to_move = C4::Acquisition::SearchOrders(
1247             {
1248                 budget_id => $from_budget->{budget_id},
1249                 pending   => 1,
1250             }
1251         );
1252
1253         my @orders_moved;
1254         for my $order (@$orders_to_move) {
1255             $sth_update_aqorders->execute( $new_budget->{budget_id}, $order->{ordernumber} );
1256             push @orders_moved, $order;
1257         }
1258
1259         my $unspent_moved = 0;
1260         if ($move_remaining_unspent) {
1261             my $spent   = GetBudgetHierarchySpent( $from_budget->{budget_id} );
1262             my $unspent = $from_budget->{budget_amount} - $spent;
1263             my $new_budget_amount = $new_budget->{budget_amount};
1264             if ( $unspent > 0 ) {
1265                 $new_budget_amount += $unspent;
1266                 $unspent_moved = $unspent;
1267             }
1268             $new_budget->{budget_amount} = $new_budget_amount;
1269             $sth_update_budget_amount->execute( $new_budget_amount,
1270                 $new_budget->{budget_id} );
1271         }
1272
1273         push @report,
1274           {
1275             budget        => $new_budget,
1276             orders_moved  => \@orders_moved,
1277             moved         => 1,
1278             unspent_moved => $unspent_moved,
1279           };
1280     }
1281     return \@report;
1282 }
1283
1284 END { }    # module clean-up code here (global destructor)
1285
1286 1;
1287 __END__
1288
1289 =head1 AUTHOR
1290
1291 Koha Development Team <http://koha-community.org/>
1292
1293 =cut