Koha/Hold.pm

   1 package Koha::Hold;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright 2017 Koha Development team
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 3 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21 use Modern::Perl;
  22
  23 use Carp;
  24 use Data::Dumper qw(Dumper);
  25
  26 use C4::Context qw(preference);
  27 use C4::Log;
  28
  29 use Koha::DateUtils qw(dt_from_string output_pref);
  30 use Koha::Patrons;
  31 use Koha::Biblios;
  32 use Koha::Items;
  33 use Koha::Libraries;
  34 use Koha::Old::Holds;
  35 use Koha::Calendar;
  36
  37 use base qw(Koha::Object);
  38
  39 =head1 NAME
  40
  41 Koha::Hold - Koha Hold object class
  42
  43 =head1 API
  44
  45 =head2 Class Methods
  46
  47 =cut
  48
  49 =head3 age
  50
  51 returns the number of days since a hold was placed, optionally
  52 using the calendar
  53
  54 my $age = $hold->age( $use_calendar );
  55
  56 =cut
  57
  58 sub age {
  59     my ( $self, $use_calendar ) = @_;
  60
  61     my $today = dt_from_string;
  62     my $age;
  63
  64     if ( $use_calendar ) {
  65         my $calendar = Koha::Calendar->new( branchcode => $self->branchcode );
  66         $age = $calendar->days_between( dt_from_string( $self->reservedate ), $today );
  67     }
  68     else {
  69         $age = $today->delta_days( dt_from_string( $self->reservedate ) );
  70     }
  71
  72     $age = $age->in_units( 'days' );
  73
  74     return $age;
  75 }
  76
  77 =head3 suspend_hold
  78
  79 my $hold = $hold->suspend_hold( $suspend_until_dt );
  80
  81 =cut
  82
  83 sub suspend_hold {
  84     my ( $self, $dt ) = @_;
  85
  86     $dt = $dt ? $dt->clone()->truncate( to => 'day' ) : undef;
  87
  88     if ( $self->is_waiting ) {    # We can't suspend waiting holds
  89         carp "Unable to suspend waiting hold!";
  90         return $self;
  91     }
  92
  93     $self->suspend(1);
  94     $self->suspend_until( $dt->datetime ) if ( defined $dt );
  95     $self->store();
  96
  97     logaction( 'HOLDS', 'SUSPEND', $self->reserve_id, Dumper($self->unblessed) )
  98         if C4::Context->preference('HoldsLog');
  99
 100     return $self;
 101 }
 102
 103 =head3 resume
 104
 105 my $hold = $hold->resume();
 106
 107 =cut
 108
 109 sub resume {
 110     my ( $self ) = @_;
 111
 112     $self->suspend(0);
 113     $self->suspend_until( undef );
 114
 115     $self->store();
 116
 117     logaction( 'HOLDS', 'RESUME', $self->reserve_id, Dumper($self->unblessed) )
 118         if C4::Context->preference('HoldsLog');
 119
 120     return $self;
 121 }
 122
 123 =head3 delete
 124
 125 $hold->delete();
 126
 127 =cut
 128
 129 sub delete {
 130     my ( $self ) = @_;
 131
 132     my $deleted = $self->SUPER::delete($self);
 133
 134     logaction( 'HOLDS', 'DELETE', $self->reserve_id, Dumper($self->unblessed) )
 135         if C4::Context->preference('HoldsLog');
 136
 137     return $deleted;
 138 }
 139
 140 =head3 set_waiting
 141
 142 =cut
 143
 144 sub set_waiting {
 145     my ( $self, $transferToDo ) = @_;
 146
 147     $self->priority(0);
 148
 149     if ($transferToDo) {
 150         $self->found('T')->store();
 151         return $self;
 152     }
 153
 154     my $today = dt_from_string();
 155     my $values = {
 156         found => 'W',
 157         waitingdate => $today->ymd,
 158     };
 159
 160     my $requested_expiration;
 161     if ($self->expirationdate) {
 162         $requested_expiration = dt_from_string($self->expirationdate);
 163     }
 164
 165     my $max_pickup_delay = C4::Context->preference("ReservesMaxPickUpDelay");
 166     my $cancel_on_holidays = C4::Context->preference('ExpireReservesOnHolidays');
 167     my $calendar = Koha::Calendar->new( branchcode => $self->branchcode );
 168
 169     my $expirationdate = $today->clone;
 170     $expirationdate->add(days => $max_pickup_delay);
 171
 172     if ( C4::Context->preference("ExcludeHolidaysFromMaxPickUpDelay") ) {
 173         $expirationdate = $calendar->days_forward( dt_from_string(), $max_pickup_delay );
 174     }
 175
 176     # If patron's requested expiration date is prior to the
 177     # calculated one, we keep the patron's one.
 178     my $cmp = $requested_expiration ? DateTime->compare($requested_expiration, $expirationdate) : 0;
 179     $values->{expirationdate} = $cmp == -1 ? $requested_expiration->ymd : $expirationdate->ymd;
 180
 181     $self->set($values)->store();
 182
 183     return $self;
 184 }
 185
 186 =head3 is_found
 187
 188 Returns true if hold is a waiting or in transit
 189
 190 =cut
 191
 192 sub is_found {
 193     my ($self) = @_;
 194
 195     return 0 unless $self->found();
 196     return 1 if $self->found() eq 'W';
 197     return 1 if $self->found() eq 'T';
 198 }
 199
 200 =head3 is_waiting
 201
 202 Returns true if hold is a waiting hold
 203
 204 =cut
 205
 206 sub is_waiting {
 207     my ($self) = @_;
 208
 209     my $found = $self->found;
 210     return $found && $found eq 'W';
 211 }
 212
 213 =head3 is_in_transit
 214
 215 Returns true if hold is a in_transit hold
 216
 217 =cut
 218
 219 sub is_in_transit {
 220     my ($self) = @_;
 221
 222     return 0 unless $self->found();
 223     return $self->found() eq 'T';
 224 }
 225
 226 =head3 is_cancelable
 227
 228 Returns true if hold is a cancelable hold
 229
 230 Holds may be canceled if they not found, or
 231 are found and waiting. A hold found but in
 232 transit cannot be canceled.
 233
 234 =cut
 235
 236 sub is_cancelable {
 237     my ($self) = @_;
 238
 239     return 1 unless $self->is_found();
 240     return 0 if $self->is_in_transit();
 241     return 1 if $self->is_waiting();
 242     return 0;
 243 }
 244
 245 =head3 is_at_destination
 246
 247 Returns true if hold is waiting
 248 and the hold's pickup branch matches
 249 the hold item's holding branch
 250
 251 =cut
 252
 253 sub is_at_destination {
 254     my ($self) = @_;
 255
 256     return $self->is_waiting() && ( $self->branchcode() eq $self->item()->holdingbranch() );
 257 }
 258
 259 =head3 biblio
 260
 261 Returns the related Koha::Biblio object for this hold
 262
 263 =cut
 264
 265 sub biblio {
 266     my ($self) = @_;
 267
 268     $self->{_biblio} ||= Koha::Biblios->find( $self->biblionumber() );
 269
 270     return $self->{_biblio};
 271 }
 272
 273 =head3 item
 274
 275 Returns the related Koha::Item object for this Hold
 276
 277 =cut
 278
 279 sub item {
 280     my ($self) = @_;
 281
 282     $self->{_item} ||= Koha::Items->find( $self->itemnumber() );
 283
 284     return $self->{_item};
 285 }
 286
 287 =head3 branch
 288
 289 Returns the related Koha::Library object for this Hold
 290
 291 =cut
 292
 293 sub branch {
 294     my ($self) = @_;
 295
 296     $self->{_branch} ||= Koha::Libraries->find( $self->branchcode() );
 297
 298     return $self->{_branch};
 299 }
 300
 301 =head3 borrower
 302
 303 Returns the related Koha::Patron object for this Hold
 304
 305 =cut
 306
 307 # FIXME Should be renamed with ->patron
 308 sub borrower {
 309     my ($self) = @_;
 310
 311     $self->{_borrower} ||= Koha::Patrons->find( $self->borrowernumber() );
 312
 313     return $self->{_borrower};
 314 }
 315
 316 =head3 is_suspended
 317
 318 my $bool = $hold->is_suspended();
 319
 320 =cut
 321
 322 sub is_suspended {
 323     my ( $self ) = @_;
 324
 325     return $self->suspend();
 326 }
 327
 328
 329 =head3 cancel
 330
 331 my $cancel_hold = $hold->cancel();
 332
 333 Cancel a hold:
 334 - The hold will be moved to the old_reserves table with a priority=0
 335 - The priority of other holds will be updated
 336 - The patron will be charge (see ExpireReservesMaxPickUpDelayCharge) if the charge_cancel_fee parameter is set
 337 - a CANCEL HOLDS log will be done if the pref HoldsLog is on
 338
 339 =cut
 340
 341 sub cancel {
 342     my ( $self, $params ) = @_;
 343     $self->_result->result_source->schema->txn_do(
 344         sub {
 345             $self->cancellationdate(dt_from_string);
 346             $self->priority(0);
 347             $self->_move_to_old;
 348             $self->SUPER::delete(); # Do not add a DELETE log
 349
 350             # now fix the priority on the others....
 351             C4::Reserves::_FixPriority({ biblionumber => $self->biblionumber });
 352
 353             # and, if desired, charge a cancel fee
 354             my $charge = C4::Context->preference("ExpireReservesMaxPickUpDelayCharge");
 355             if ( $charge && $params->{'charge_cancel_fee'} ) {
 356                 C4::Accounts::manualinvoice($self->borrowernumber, $self->itemnumber, '', 'HE', $charge);
 357             }
 358
 359             C4::Log::logaction( 'HOLDS', 'CANCEL', $self->reserve_id, Dumper($self->unblessed) )
 360                 if C4::Context->preference('HoldsLog');
 361         }
 362     );
 363     return $self;
 364 }
 365
 366 =head3 _move_to_old
 367
 368 my $is_moved = $hold->_move_to_old;
 369
 370 Move a hold to the old_reserve table following the same pattern as Koha::Patron->move_to_deleted
 371
 372 =cut
 373
 374 sub _move_to_old {
 375     my ($self) = @_;
 376     my $hold_infos = $self->unblessed;
 377     return Koha::Old::Hold->new( $hold_infos )->store;
 378 }
 379
 380 =head3 type
 381
 382 =cut
 383
 384 sub _type {
 385     return 'Reserve';
 386 }
 387
 388 =head1 AUTHORS
 389
 390 Kyle M Hall <kyle@bywatersolutions.com>
 391
 392 Jonathan Druart <jonathan.druart@bugs.koha-community.org>
 393
 394 =cut
 395
 396 1;