opac/opac-downloadshelf.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 BibLibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22
  23 use CGI qw ( -utf8 );
  24 use Encode qw(encode);
  25
  26 use C4::Auth;
  27 use C4::Biblio;
  28 use C4::Items;
  29 use C4::Output;
  30 use C4::VirtualShelves;
  31 use C4::Record;
  32 use C4::Ris;
  33 use C4::Csv;
  34 use utf8;
  35 my $query = new CGI;
  36
  37 # if virtualshelves is disabled, leave immediately
  38 if ( ! C4::Context->preference('virtualshelves') ) {
  39     print $query->redirect("/cgi-bin/koha/errors/404.pl");
  40     exit;
  41 }
  42
  43 my ( $template, $borrowernumber, $cookie ) = get_template_and_user (
  44     {
  45         template_name   => "opac-downloadshelf.tt",
  46         query           => $query,
  47         type            => "opac",
  48         authnotrequired => 1,
  49         flagsrequired   => { borrow => 1 },
  50     }
  51 );
  52
  53 my $shelfid = $query->param('shelfid');
  54 my $format  = $query->param('format');
  55 my $context = $query->param('context');
  56 my $showprivateshelves = $query->param('showprivateshelves');
  57 my $dbh     = C4::Context->dbh;
  58
  59 if ( ShelfPossibleAction( (defined($borrowernumber) ? $borrowernumber : -1), $shelfid, 'view' ) ) {
  60
  61     if ($shelfid && $format) {
  62
  63         my ($items, $totitems)  = GetShelfContents($shelfid);
  64         my $marcflavour         = C4::Context->preference('marcflavour');
  65         my $output;
  66         my $extension;
  67         my $type;
  68
  69        # CSV
  70         if ($format =~ /^\d+$/) {
  71             my @biblios;
  72             foreach (@$items) {
  73                 push @biblios, $_->{biblionumber};
  74             }
  75             $output = marc2csv(\@biblios, $format);
  76
  77         # Other formats
  78         } else {
  79             foreach my $biblio (@$items) {
  80                 my $biblionumber = $biblio->{biblionumber};
  81
  82                 my $record = GetMarcBiblio($biblionumber, 1);
  83                 next unless $record;
  84
  85                 if ($format eq 'iso2709') {
  86                     $output .= $record->as_usmarc();
  87                 }
  88                 elsif ($format eq 'ris' ) {
  89                     $output .= marc2ris($record);
  90                 }
  91                 elsif ($format eq 'bibtex') {
  92                     $output .= marc2bibtex($record, $biblionumber);
  93                 }
  94                 elsif ( $format eq 'isbd' ) {
  95                     $output   .= GetISBDView($biblionumber, "opac");
  96                     $extension = "txt";
  97                     $type      = "text/plain";
  98                 }
  99             }
 100         }
 101
 102         # If it was a CSV export we change the format after the export so the file extension is fine
 103         $format = "csv" if ($format =~ m/^\d+$/);
 104
 105         print $query->header(
 106                                    -type => ($type) ? $type : 'application/octet-stream',
 107             -'Content-Transfer-Encoding' => 'binary',
 108                              -attachment => ($extension) ? "shelf.$format.$extension" : "shelf.$format"
 109         );
 110         print $output;
 111
 112     } else {
 113
 114         # get details of the list
 115         my ($shelfnumber,$shelfname,$owner,$category,$sorton) = GetShelf($shelfid);
 116
 117         # if modal context is passed set a variable so that page markup can be different
 118         if($context eq "modal"){
 119             $template->param(modal => 1);
 120         } else {
 121             $template->param(fullpage => 1);
 122         }
 123         $template->param(csv_profiles => GetCsvProfilesLoop('marc'));
 124         $template->param(
 125             showprivateshelves  => $showprivateshelves,
 126             shelfid             => $shelfid,
 127             shelfname           => $shelfname,
 128             shelfnumber         => $shelfnumber,
 129             viewshelf           => $shelfnumber
 130         );
 131         output_html_with_http_headers $query, $cookie, $template->output;
 132     }
 133
 134 } else {
 135     $template->param(invalidlist => 1);
 136     output_html_with_http_headers $query, $cookie, $template->output;
 137 }