misc/devel/populate_db.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Copyright 2016 Koha Development Team
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Getopt::Long;
  23 use Pod::Usage;
  24
  25 use Koha::Script;
  26 use C4::Installer;
  27 use C4::Context;
  28
  29 use Koha::SearchEngine::Elasticsearch;
  30
  31 =head1 NAME
  32
  33 populate_db.pl - Load included sample data into the DB
  34
  35 =head1 SYNOPSIS
  36
  37 populate_db.pl [--marcflavour MARCFLAVOUR]
  38
  39  Options:
  40    --help            Brief help message
  41    --marcflavour m   Specify the MARC flavour to use (MARC21|UNIMARC). Defaults
  42                                 to MARC21.
  43    -v                Be verbose.
  44
  45 =head1 OPTIONS
  46
  47 =over 8
  48
  49 =item B<--help>
  50
  51 Prints a brief help message and exits.
  52
  53 =item B<--marcflavour>
  54
  55 Lets you choose the desired MARC flavour for the sample data. Valid options are MARC21 and UNIMARC.
  56 It defaults to MARC21.
  57
  58 =item B<--verbose>
  59
  60 Make the output more verbose.
  61
  62 =back
  63
  64 =cut
  65
  66 my $help;
  67 my $verbose;
  68 my $marcflavour = 'MARC21';
  69
  70 GetOptions(
  71     'help|?'        => \$help,
  72     'verbose'       => \$verbose,
  73     'marcflavour=s' => \$marcflavour
  74 ) or pod2usage;
  75
  76 if ( $help ) {
  77     pod2usage;
  78 }
  79
  80 $marcflavour = uc($marcflavour);
  81
  82 if (     $marcflavour ne 'MARC21'
  83      and $marcflavour ne 'UNIMARC' ) {
  84     say "Invalid MARC flavour '$marcflavour' passed.";
  85     pod2usage;
  86 }
  87
  88 $ENV{KOHA_DB_DO_NOT_RAISE_OR_PRINT_ERROR} = 1;
  89 my $dbh = C4::Context->dbh; # At the beginning to die if DB does not exist.
  90
  91 my ( $prefs_count ) = $dbh->selectrow_array(q|SELECT COUNT(*) FROM systempreferences|);
  92 my ( $patrons_count ) = $dbh->selectrow_array(q|SELECT COUNT(*) FROM borrowers|);
  93 if ( $prefs_count or $patrons_count ) {
  94     die "Database is not empty!";
  95 }
  96 $dbh->disconnect;
  97 $ENV{KOHA_DB_DO_NOT_RAISE_OR_PRINT_ERROR} = 0;
  98
  99 our $root      = C4::Context->config('intranetdir');
 100 our $data_dir  = "$root/installer/data/mysql";
 101 our $installer = C4::Installer->new;
 102 my $lang                = 'en';
 103 my $koha_structure_file = "$data_dir/kohastructure.sql";
 104 my @sample_files_mandatory = (
 105     glob("$data_dir/mandatory/*.sql"),
 106     "$data_dir/audio_alerts.sql",
 107     "$data_dir/sysprefs.sql",
 108     "$data_dir/userflags.sql",
 109     "$data_dir/userpermissions.sql",
 110     "$data_dir/account_offset_types.sql",
 111 );
 112 my @sample_lang_files_mandatory    = ( glob $root . "/installer/data/mysql/$lang/mandatory/*.sql" );
 113 my @sample_lang_files_optional     = ( glob $root . "/installer/data/mysql/$lang/optional/*.sql" );
 114 my @marc21_sample_files_mandatory  = ( glob $root . "/installer/data/mysql/$lang/marcflavour/marc21/*/*.sql" );
 115 my @unimarc_sample_files_mandatory = ( glob $root . "/installer/data/mysql/$lang/marcflavour/unimarc/*/*.sql" );
 116
 117 my $version = get_version();
 118
 119 initialize_data();
 120 update_database();
 121
 122 sub initialize_data {
 123     say "Inserting koha db structure..."
 124         if $verbose;
 125     my $error = $installer->load_db_schema;
 126     die $error if $error;
 127
 128     for my $f (@sample_files_mandatory) {
 129         execute_sqlfile($f);
 130     }
 131
 132     for my $f (@sample_lang_files_mandatory) {
 133         execute_sqlfile($f);
 134     }
 135
 136     for my $f (@sample_lang_files_optional) {
 137         execute_sqlfile($f);
 138     }
 139
 140     if ( $marcflavour eq 'UNIMARC' ) {
 141         for my $f (@unimarc_sample_files_mandatory) {
 142             execute_sqlfile($f);
 143         }
 144     } else {
 145         for my $f (@marc21_sample_files_mandatory) {
 146             execute_sqlfile($f);
 147         }
 148     }
 149
 150     # set marcflavour (MARC21)
 151     my $dbh = C4::Context->dbh;
 152
 153     say "Setting the MARC flavour on the sysprefs..."
 154         if $verbose;
 155     $dbh->do(qq{
 156         INSERT INTO `systempreferences` (variable,value,explanation,options,type)
 157         VALUES ('marcflavour',?,'Define global MARC flavor (MARC21 or UNIMARC) used for character encoding','MARC21|UNIMARC','Choice')
 158     },undef,$marcflavour);
 159
 160     # set version
 161     say "Setting Koha version to $version..."
 162         if $verbose;
 163     $dbh->do(qq{
 164         INSERT INTO systempreferences(variable, value, options, explanation, type)
 165         VALUES ('Version', '$version', NULL, 'The Koha database version. WARNING: Do not change this value manually, it is maintained by the webinstaller', NULL)
 166     });
 167
 168     # Initialize ES mappings
 169     Koha::SearchEngine::Elasticsearch->reset_elasticsearch_mappings;
 170 }
 171
 172 sub execute_sqlfile {
 173     my ($filepath) = @_;
 174     say "Inserting $filepath..."
 175         if $verbose;
 176     my $error = $installer->load_sql($filepath);
 177     die $error if $error;
 178 }
 179
 180 sub get_version {
 181     do $root . '/kohaversion.pl';
 182     my $version = kohaversion();
 183     $version =~ s/(\d)\.(\d{2})\.(\d{2})\.(\d{3})/$1.$2$3$4/;
 184     return $version;
 185 }
 186
 187 sub update_database {
 188     my $update_db_path = $root . '/installer/data/mysql/updatedatabase.pl';
 189     say "Updating database..."
 190         if $verbose;
 191     my $file = `cat $update_db_path`;
 192     $file =~ s/exit;//;
 193     eval $file;
 194     if ($@) {
 195         die "updatedatabase.pl process failed: $@";
 196     } else {
 197         say "updatedatabase.pl process succeeded.";
 198     }
 199 }