circ/waitingreserves.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # parts copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use CGI qw ( -utf8 );
  23 use C4::Context;
  24 use C4::Output;
  25 use C4::Auth;
  26 use C4::Circulation;
  27 use C4::Members;
  28 use C4::Biblio;
  29 use C4::Items;
  30 use Date::Calc qw(
  31   Today
  32   Add_Delta_Days
  33   Date_to_Days
  34 );
  35 use C4::Reserves;
  36 use C4::Koha;
  37 use Koha::DateUtils;
  38 use Koha::BiblioFrameworks;
  39 use Koha::Items;
  40 use Koha::ItemTypes;
  41 use Koha::Patrons;
  42
  43 my $input = new CGI;
  44
  45 my $item           = $input->param('itemnumber');
  46 my $borrowernumber = $input->param('borrowernumber');
  47 my $fbr            = $input->param('fbr') || '';
  48 my $tbr            = $input->param('tbr') || '';
  49 my $all_branches   = $input->param('allbranches') || '';
  50 my $cancelall      = $input->param('cancelall');
  51 my $tab            = $input->param('tab');
  52
  53 my ( $template, $loggedinuser, $cookie, $flags ) = get_template_and_user(
  54     {
  55         template_name   => "circ/waitingreserves.tt",
  56         query           => $input,
  57         type            => "intranet",
  58         authnotrequired => 0,
  59         flagsrequired   => { circulate => "circulate_remaining_permissions" },
  60         debug           => 1,
  61     }
  62 );
  63
  64 my $default = C4::Context->userenv->{'branch'};
  65
  66 my $transfer_when_cancel_all = C4::Context->preference('TransferWhenCancelAllWaitingHolds');
  67 $template->param( TransferWhenCancelAllWaitingHolds => 1 ) if $transfer_when_cancel_all;
  68
  69 my @cancel_result;
  70 # if we have a return from the form we cancel the holds
  71 if ($item) {
  72     my $res = cancel( $item, $borrowernumber, $fbr, $tbr );
  73     push @cancel_result, $res if $res;
  74 }
  75
  76 if ( C4::Context->preference('IndependentBranches') ) {
  77     undef $all_branches;
  78 } else {
  79     $template->param( all_branches_link => '/cgi-bin/koha/circ/waitingreserves.pl' . '?allbranches=1' )
  80       unless $all_branches;
  81 }
  82 $template->param( all_branches => 1 ) if $all_branches;
  83
  84 my (@reserve_loop, @over_loop);
  85 # FIXME - Is priority => 0 useful? If yes it must be moved to waiting, otherwise we need to remove it from here.
  86 my $holds = Koha::Holds->waiting->search({ priority => 0, ( $all_branches ? () : ( branchcode => $default ) ) }, { order_by => ['waitingdate'] });
  87
  88 # get reserves for the branch we are logged into, or for all branches
  89
  90 my $today = Date_to_Days(&Today);
  91
  92 while ( my $hold = $holds->next ) {
  93     next unless ($hold->waitingdate && $hold->waitingdate ne '0000-00-00');
  94
  95     my ( $expire_year, $expire_month, $expire_day ) = split (/-/, $hold->expirationdate);
  96     my $calcDate = Date_to_Days( $expire_year, $expire_month, $expire_day );
  97
  98     if ($today > $calcDate) {
  99         if ($cancelall) {
 100             my $res = cancel( $hold->item->itemnumber, $hold->borrowernumber, $hold->item->holdingbranch, $hold->item->homebranch, !$transfer_when_cancel_all );
 101             push @cancel_result, $res if $res;
 102             next;
 103         } else {
 104             push @over_loop, $hold;
 105         }
 106     }else{
 107         push @reserve_loop, $hold;
 108     }
 109
 110 }
 111
 112 $template->param(cancel_result => \@cancel_result) if @cancel_result;
 113
 114 $template->param(
 115     reserveloop => \@reserve_loop,
 116     reservecount => scalar @reserve_loop,
 117     overloop    => \@over_loop,
 118     overcount   => scalar @over_loop,
 119     show_date   => output_pref({ dt => dt_from_string, dateformat => 'iso', dateonly => 1 }),
 120     tab => $tab,
 121 );
 122
 123 # Checking if there is a Fast Cataloging Framework
 124 $template->param( fast_cataloging => 1 ) if Koha::BiblioFrameworks->find( 'FA' );
 125
 126 if ($item && $tab eq 'holdsover' && !@cancel_result) {
 127     print $input->redirect("/cgi-bin/koha/circ/waitingreserves.pl#holdsover");
 128 } elsif ($cancelall) {
 129     print $input->redirect("/cgi-bin/koha/circ/waitingreserves.pl");
 130 } else {
 131     output_html_with_http_headers $input, $cookie, $template->output;
 132 }
 133
 134 exit;
 135
 136 sub cancel {
 137     my ($item, $borrowernumber, $fbr, $tbr, $skip_transfers ) = @_;
 138
 139     my $transfer = $fbr ne $tbr; # XXX && !$nextreservinfo;
 140
 141     return if $transfer && $skip_transfers;
 142
 143     my ( $messages, $nextreservinfo ) = ModReserveCancelAll( $item, $borrowernumber );
 144
 145 #       if the document is not in his homebranch location and there is not reservation after, we transfer it
 146     if ($transfer && !$nextreservinfo) {
 147         ModItemTransfer( $item, $fbr, $tbr, 'CancelReserve' );
 148     }
 149     # if we have a result
 150     if ($nextreservinfo) {
 151         my %res;
 152         my $patron = Koha::Patrons->find( $nextreservinfo );
 153         my $title = Koha::Items->find( $item )->biblio->title;
 154         if ( $messages->{'transfert'} ) {
 155             $res{messagetransfert} = $messages->{'transfert'};
 156             $res{branchcode}       = $messages->{'transfert'};
 157         }
 158
 159         $res{message}             = 1;
 160         $res{nextreservnumber}    = $nextreservinfo;
 161         $res{nextreservsurname}   = $patron->surname;
 162         $res{nextreservfirstname} = $patron->firstname;
 163         $res{nextreservitem}      = $item;
 164         $res{nextreservtitle}     = $title;
 165         $res{waiting}             = $messages->{'waiting'} ? 1 : 0;
 166
 167         return \%res;
 168     }
 169
 170     return;
 171 }