Koha/DateUtils.pm

   1 package Koha::DateUtils;
   2
   3 # Copyright (c) 2011 PTFS-Europe Ltd.
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along with
  16 # Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 use strict;
  20 use warnings;
  21 use 5.010;
  22 use DateTime;
  23 use DateTime::Format::DateParse;
  24 use C4::Context;
  25
  26 use base 'Exporter';
  27 use version; our $VERSION = qv('1.0.0');
  28
  29 our @EXPORT = (
  30     qw( dt_from_string output_pref format_sqldatetime )
  31 );
  32
  33 =head1 DateUtils
  34
  35 Koha::DateUtils - Transitional wrappers to ease use of DateTime
  36
  37 =head1 DESCRIPTION
  38
  39 Koha has historically only used dates not datetimes and been content to
  40 handle these as strings. It also has confused formatting with actual dates
  41 this is a temporary module for wrappers to hide the complexity of switch to DateTime
  42
  43 =cut
  44
  45 =head2 dt_ftom_string
  46
  47 $dt = dt_from_string($date_string, [$format, $timezone ]);
  48
  49 Passed a date string returns a DateTime object format and timezone default
  50 to the system preferences. If the date string is empty DateTime->now is returned
  51
  52 =cut
  53
  54 sub dt_from_string {
  55     my ( $date_string, $date_format, $tz ) = @_;
  56
  57     # FIXME: see bug 13242 => no TZ for dates 'infinite'
  58     return DateTime::Format::DateParse->parse_datetime($date_string)
  59         if $date_string and $date_string =~ /^9999-/;
  60
  61     if ( !$tz ) {
  62         $tz = C4::Context->tz;
  63     }
  64     if ( !$date_format ) {
  65         $date_format = C4::Context->preference('dateformat');
  66     }
  67     if ($date_string) {
  68         if ( ref($date_string) eq 'DateTime' ) {    # already a dt return it
  69             return $date_string;
  70         }
  71
  72         if ( $date_format eq 'metric' ) {
  73             $date_string =~ s#-#/#g;
  74             $date_string =~ s/^00/01/;    # system allows the 0th of the month
  75             $date_string =~ s#^(\d{1,2})/(\d{1,2})#$2/$1#;
  76         } else {
  77             if ( $date_format eq 'iso' ) {
  78                 $date_string =~ s/-00/-01/;
  79                 if ( $date_string =~ m/^0000-0/ ) {
  80                     return;               # invalid date in db
  81                 }
  82             } elsif ( $date_format eq 'us' ) {
  83                 $date_string =~ s#-#/#g;
  84                 $date_string =~ s[/00/][/01/];
  85             } elsif ( $date_format eq 'sql' ) {
  86                 $date_string =~
  87 s/(\d{4})(\d{2})(\d{2})\s+(\d{2})(\d{2})(\d{2})/$1-$2-$3T$4:$5:$6/;
  88                 return if ($date_string =~ /^0000-00-00/);
  89                 $date_string =~ s/00T/01T/;
  90             }
  91         }
  92         return DateTime::Format::DateParse->parse_datetime( $date_string,
  93             $tz->name() );
  94     }
  95     return DateTime->now( time_zone => $tz );
  96
  97 }
  98
  99 =head2 output_pref
 100
 101 $date_string = output_pref({ dt => $dt [, dateformat => $date_format, timeformat => $time_format, dateonly => 0|1, as_due_date => 0|1 ] });
 102 $date_string = output_pref( $dt );
 103
 104 Returns a string containing the time & date formatted as per the C4::Context setting,
 105 or C<undef> if C<undef> was provided.
 106
 107 This routine can either be passed a DateTime object or or a hashref.  If it is
 108 passed a hashref, the expected keys are a mandatory 'dt' for the DateTime,
 109 an optional 'dateformat' to override the dateformat system preference, an
 110 optional 'timeformat' to override the TimeFormat system preference value,
 111 and an optional 'dateonly' to specify that only the formatted date string
 112 should be returned without the time.
 113
 114 =cut
 115
 116 sub output_pref {
 117     my $params = shift;
 118     my ( $dt, $force_pref, $force_time, $dateonly, $as_due_date );
 119     if ( ref $params eq 'HASH' ) {
 120         $dt         = $params->{dt};
 121         $force_pref = $params->{dateformat};         # if testing we want to override Context
 122         $force_time = $params->{timeformat};
 123         $dateonly   = $params->{dateonly} || 0;    # if you don't want the hours and minutes
 124         $as_due_date = $params->{as_due_date} || 0; # don't display the hours and minutes if eq to 23:59 or 11:59 (depending the TimeFormat value)
 125     } else {
 126         $dt = $params;
 127     }
 128
 129     return unless defined $dt;
 130
 131     # FIXME: see bug 13242 => no TZ for dates 'infinite'
 132     $dt->set_time_zone( C4::Context->tz ) if $dt->ymd !~ /^9999/;
 133
 134     my $pref =
 135       defined $force_pref ? $force_pref : C4::Context->preference('dateformat');
 136
 137     my $time_format = $force_time || C4::Context->preference('TimeFormat') || q{};
 138     my $time = ( $time_format eq '12hr' ) ? '%I:%M %p' : '%H:%M';
 139     my $date;
 140     if ( $pref =~ m/^iso/ ) {
 141         $date = $dateonly
 142           ? $dt->strftime("%Y-%m-%d")
 143           : $dt->strftime("%Y-%m-%d $time");
 144     }
 145     elsif ( $pref =~ m/^metric/ ) {
 146         $date = $dateonly
 147           ? $dt->strftime("%d/%m/%Y")
 148           : $dt->strftime("%d/%m/%Y $time");
 149     }
 150     elsif ( $pref =~ m/^us/ ) {
 151         $date = $dateonly
 152           ? $dt->strftime("%m/%d/%Y")
 153           : $dt->strftime("%m/%d/%Y $time");
 154     }
 155     else {
 156         $date = $dateonly
 157           ? $dt->strftime("%Y-%m-%d")
 158           : $dt->strftime("%Y-%m-%d $time");
 159     }
 160
 161     if ( $as_due_date ) {
 162         $time_format eq '12hr'
 163             ? $date =~ s| 11:59 PM$||
 164             : $date =~ s| 23:59$||;
 165     }
 166
 167     return $date;
 168 }
 169
 170 =head2 format_sqldatetime
 171
 172 $string = format_sqldatetime( $string_as_returned_from_db );
 173
 174 a convenience routine for calling dt_from_string and formatting the result
 175 with output_pref as it is a frequent activity in scripts
 176
 177 =cut
 178
 179 sub format_sqldatetime {
 180     my $str        = shift;
 181     my $force_pref = shift;    # if testing we want to override Context
 182     my $force_time = shift;
 183     my $dateonly   = shift;
 184
 185     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 186         my $dt = dt_from_string( $str, 'sql' );
 187         return q{} unless $dt;
 188         $dt->truncate( to => 'minute' );
 189         return output_pref({
 190             dt => $dt,
 191             dateformat => $force_pref,
 192             timeformat => $force_time,
 193             dateonly => $dateonly
 194         });
 195     }
 196     return q{};
 197 }
 198
 199 1;