Koha/DateUtils.pm

   1 package Koha::DateUtils;
   2
   3 # Copyright (c) 2011 PTFS-Europe Ltd.
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along with
  16 # Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 use strict;
  20 use warnings;
  21 use 5.010;
  22 use DateTime;
  23 use DateTime::Format::DateParse;
  24 use C4::Context;
  25
  26 use base 'Exporter';
  27 use version; our $VERSION = qv('1.0.0');
  28
  29 our @EXPORT = (
  30     qw( dt_from_string output_pref format_sqldatetime )
  31 );
  32
  33 =head1 DateUtils
  34
  35 Koha::DateUtils - Transitional wrappers to ease use of DateTime
  36
  37 =head1 DESCRIPTION
  38
  39 Koha has historically only used dates not datetimes and been content to
  40 handle these as strings. It also has confused formatting with actual dates
  41 this is a temporary module for wrappers to hide the complexity of switch to DateTime
  42
  43 =cut
  44
  45 =head2 dt_ftom_string
  46
  47 $dt = dt_from_string($date_string, [$format, $timezone ]);
  48
  49 Passed a date string returns a DateTime object format and timezone default
  50 to the system preferences. If the date string is empty DateTime->now is returned
  51
  52 =cut
  53
  54 sub dt_from_string {
  55     my ( $date_string, $date_format, $tz ) = @_;
  56
  57     # FIXME: see bug 13242 => no TZ for dates 'infinite'
  58     return DateTime::Format::DateParse->parse_datetime($date_string)
  59         if $date_string and $date_string =~ /^9999-/;
  60
  61     my $dt;
  62     $tz ||= C4::Context->tz;
  63     if ( !$date_format ) {
  64         $date_format = C4::Context->preference('dateformat');
  65     }
  66     if ($date_string) {
  67         if ( ref($date_string) eq 'DateTime' ) {    # already a dt return it
  68             return $date_string;
  69         }
  70
  71         if ( $date_format eq 'metric' ) {
  72             $date_string =~ s#-#/#g;
  73             $date_string =~ s/^00/01/;    # system allows the 0th of the month
  74             $date_string =~ s#^(\d{1,2})/(\d{1,2})#$2/$1#;
  75         } else {
  76             if ( $date_format eq 'iso' ) {
  77                 $date_string =~ s/-00/-01/;
  78                 if ( $date_string =~ m/^0000-0/ ) {
  79                     return;               # invalid date in db
  80                 }
  81             } elsif ( $date_format eq 'us' ) {
  82                 $date_string =~ s#-#/#g;
  83                 $date_string =~ s[/00/][/01/];
  84             } elsif ( $date_format eq 'sql' ) {
  85                 $date_string =~
  86 s/(\d{4})(\d{2})(\d{2})\s+(\d{2})(\d{2})(\d{2})/$1-$2-$3T$4:$5:$6/;
  87                 return if ($date_string =~ /^0000-00-00/);
  88                 $date_string =~ s/00T/01T/;
  89             }
  90         }
  91
  92         $dt = eval {
  93             DateTime::Format::DateParse->parse_datetime( $date_string,
  94                 $tz->name() );
  95         };
  96         if ($@) {
  97             $tz = DateTime::TimeZone->new( name => 'floating' );
  98             $dt = DateTime::Format::DateParse->parse_datetime( $date_string,
  99                 $tz->name() );
 100         }
 101     } else {
 102         $dt = DateTime->now( time_zone => $tz );
 103     }
 104
 105     return $dt;
 106
 107 }
 108
 109 =head2 output_pref
 110
 111 $date_string = output_pref({ dt => $dt [, dateformat => $date_format, timeformat => $time_format, dateonly => 0|1, as_due_date => 0|1 ] });
 112 $date_string = output_pref( $dt );
 113
 114 Returns a string containing the time & date formatted as per the C4::Context setting,
 115 or C<undef> if C<undef> was provided.
 116
 117 This routine can either be passed a DateTime object or or a hashref.  If it is
 118 passed a hashref, the expected keys are a mandatory 'dt' for the DateTime,
 119 an optional 'dateformat' to override the dateformat system preference, an
 120 optional 'timeformat' to override the TimeFormat system preference value,
 121 and an optional 'dateonly' to specify that only the formatted date string
 122 should be returned without the time.
 123
 124 =cut
 125
 126 sub output_pref {
 127     my $params = shift;
 128     my ( $dt, $force_pref, $force_time, $dateonly, $as_due_date );
 129     if ( ref $params eq 'HASH' ) {
 130         $dt         = $params->{dt};
 131         $force_pref = $params->{dateformat};         # if testing we want to override Context
 132         $force_time = $params->{timeformat};
 133         $dateonly   = $params->{dateonly} || 0;    # if you don't want the hours and minutes
 134         $as_due_date = $params->{as_due_date} || 0; # don't display the hours and minutes if eq to 23:59 or 11:59 (depending the TimeFormat value)
 135     } else {
 136         $dt = $params;
 137     }
 138
 139     return unless defined $dt;
 140
 141     # FIXME: see bug 13242 => no TZ for dates 'infinite'
 142     if ( $dt->ymd !~ /^9999/ ) {
 143         my $tz = $dateonly ? DateTime::TimeZone->new(name => 'floating') : C4::Context->tz;
 144         $dt->set_time_zone( $tz );
 145     }
 146
 147     my $pref =
 148       defined $force_pref ? $force_pref : C4::Context->preference('dateformat');
 149
 150     my $time_format = $force_time || C4::Context->preference('TimeFormat') || q{};
 151     my $time = ( $time_format eq '12hr' ) ? '%I:%M %p' : '%H:%M';
 152     my $date;
 153     if ( $pref =~ m/^iso/ ) {
 154         $date = $dateonly
 155           ? $dt->strftime("%Y-%m-%d")
 156           : $dt->strftime("%Y-%m-%d $time");
 157     }
 158     elsif ( $pref =~ m/^metric/ ) {
 159         $date = $dateonly
 160           ? $dt->strftime("%d/%m/%Y")
 161           : $dt->strftime("%d/%m/%Y $time");
 162     }
 163     elsif ( $pref =~ m/^us/ ) {
 164         $date = $dateonly
 165           ? $dt->strftime("%m/%d/%Y")
 166           : $dt->strftime("%m/%d/%Y $time");
 167     }
 168     else {
 169         $date = $dateonly
 170           ? $dt->strftime("%Y-%m-%d")
 171           : $dt->strftime("%Y-%m-%d $time");
 172     }
 173
 174     if ( $as_due_date ) {
 175         $time_format eq '12hr'
 176             ? $date =~ s| 11:59 PM$||
 177             : $date =~ s| 23:59$||;
 178     }
 179
 180     return $date;
 181 }
 182
 183 =head2 format_sqldatetime
 184
 185 $string = format_sqldatetime( $string_as_returned_from_db );
 186
 187 a convenience routine for calling dt_from_string and formatting the result
 188 with output_pref as it is a frequent activity in scripts
 189
 190 =cut
 191
 192 sub format_sqldatetime {
 193     my $str        = shift;
 194     my $force_pref = shift;    # if testing we want to override Context
 195     my $force_time = shift;
 196     my $dateonly   = shift;
 197
 198     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 199         my $dt = dt_from_string( $str, 'sql' );
 200         return q{} unless $dt;
 201         $dt->truncate( to => 'minute' );
 202         return output_pref({
 203             dt => $dt,
 204             dateformat => $force_pref,
 205             timeformat => $force_time,
 206             dateonly => $dateonly
 207         });
 208     }
 209     return q{};
 210 }
 211
 212 1;