C4/Reserves.pm

   1 package C4::Reserves;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #           2006 SAN Ouest Provence
   5 #           2007-2010 BibLibre Paul POULAIN
   6 #           2011 Catalyst IT
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23
  24 use Modern::Perl;
  25
  26 use C4::Accounts;
  27 use C4::Biblio;
  28 use C4::Circulation;
  29 use C4::Context;
  30 use C4::Items;
  31 use C4::Letters;
  32 use C4::Log;
  33 use C4::Members::Messaging;
  34 use C4::Members;
  35 use Koha::Account::Lines;
  36 use Koha::Biblios;
  37 use Koha::Calendar;
  38 use Koha::CirculationRules;
  39 use Koha::Database;
  40 use Koha::DateUtils;
  41 use Koha::Hold;
  42 use Koha::Holds;
  43 use Koha::ItemTypes;
  44 use Koha::Items;
  45 use Koha::Libraries;
  46 use Koha::Old::Hold;
  47 use Koha::Patrons;
  48
  49 use Carp;
  50 use Data::Dumper;
  51 use List::MoreUtils qw( firstidx any );
  52
  53 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  54
  55 =head1 NAME
  56
  57 C4::Reserves - Koha functions for dealing with reservation.
  58
  59 =head1 SYNOPSIS
  60
  61   use C4::Reserves;
  62
  63 =head1 DESCRIPTION
  64
  65 This modules provides somes functions to deal with reservations.
  66
  67   Reserves are stored in reserves table.
  68   The following columns contains important values :
  69   - priority >0      : then the reserve is at 1st stage, and not yet affected to any item.
  70              =0      : then the reserve is being dealed
  71   - found : NULL       : means the patron requested the 1st available, and we haven't chosen the item
  72             T(ransit)  : the reserve is linked to an item but is in transit to the pickup branch
  73             W(aiting)  : the reserve is linked to an item, is at the pickup branch, and is waiting on the hold shelf
  74             F(inished) : the reserve has been completed, and is done
  75   - itemnumber : empty : the reserve is still unaffected to an item
  76                  filled: the reserve is attached to an item
  77   The complete workflow is :
  78   ==== 1st use case ====
  79   patron request a document, 1st available :                      P >0, F=NULL, I=NULL
  80   a library having it run "transfertodo", and clic on the list
  81          if there is no transfer to do, the reserve waiting
  82          patron can pick it up                                    P =0, F=W,    I=filled
  83          if there is a transfer to do, write in branchtransfer    P =0, F=T,    I=filled
  84            The pickup library receive the book, it check in       P =0, F=W,    I=filled
  85   The patron borrow the book                                      P =0, F=F,    I=filled
  86
  87   ==== 2nd use case ====
  88   patron requests a document, a given item,
  89     If pickup is holding branch                                   P =0, F=W,   I=filled
  90     If transfer needed, write in branchtransfer                   P =0, F=T,    I=filled
  91         The pickup library receive the book, it checks it in      P =0, F=W,    I=filled
  92   The patron borrow the book                                      P =0, F=F,    I=filled
  93
  94 =head1 FUNCTIONS
  95
  96 =cut
  97
  98 BEGIN {
  99     require Exporter;
 100     @ISA = qw(Exporter);
 101     @EXPORT = qw(
 102         &AddReserve
 103
 104         &GetReserveStatus
 105
 106         &GetOtherReserves
 107
 108         &ModReserveFill
 109         &ModReserveAffect
 110         &ModReserve
 111         &ModReserveStatus
 112         &ModReserveCancelAll
 113         &ModReserveMinusPriority
 114         &MoveReserve
 115
 116         &CheckReserves
 117         &CanBookBeReserved
 118         &CanItemBeReserved
 119         &CanReserveBeCanceledFromOpac
 120         &CancelExpiredReserves
 121
 122         &AutoUnsuspendReserves
 123
 124         &IsAvailableForItemLevelRequest
 125         ItemsAnyAvailableForHold
 126
 127         &AlterPriority
 128         &ToggleLowestPriority
 129
 130         &ReserveSlip
 131         &ToggleSuspend
 132         &SuspendAll
 133
 134         &GetReservesControlBranch
 135
 136         IsItemOnHoldAndFound
 137
 138         GetMaxPatronHoldsForRecord
 139     );
 140     @EXPORT_OK = qw( MergeHolds );
 141 }
 142
 143 =head2 AddReserve
 144
 145     AddReserve(
 146         {
 147             branch           => $branchcode,
 148             borrowernumber   => $borrowernumber,
 149             biblionumber     => $biblionumber,
 150             priority         => $priority,
 151             reservation_date => $reservation_date,
 152             expiration_date  => $expiration_date,
 153             notes            => $notes,
 154             title            => $title,
 155             itemnumber       => $itemnumber,
 156             found            => $found,
 157             itemtype         => $itemtype,
 158         }
 159     );
 160
 161 Adds reserve and generates HOLDPLACED message.
 162
 163 The following tables are available witin the HOLDPLACED message:
 164
 165     branches
 166     borrowers
 167     biblio
 168     biblioitems
 169     items
 170     reserves
 171
 172 =cut
 173
 174 sub AddReserve {
 175     my ($params)       = @_;
 176     my $branch         = $params->{branchcode};
 177     my $borrowernumber = $params->{borrowernumber};
 178     my $biblionumber   = $params->{biblionumber};
 179     my $priority       = $params->{priority};
 180     my $resdate        = $params->{reservation_date};
 181     my $expdate        = $params->{expiration_date};
 182     my $notes          = $params->{notes};
 183     my $title          = $params->{title};
 184     my $checkitem      = $params->{itemnumber};
 185     my $found          = $params->{found};
 186     my $itemtype       = $params->{itemtype};
 187
 188     $resdate = output_pref( { str => dt_from_string( $resdate ), dateonly => 1, dateformat => 'iso' })
 189         or output_pref({ dt => dt_from_string, dateonly => 1, dateformat => 'iso' });
 190
 191     $expdate = output_pref({ str => $expdate, dateonly => 1, dateformat => 'iso' });
 192
 193     # if we have an item selectionned, and the pickup branch is the same as the holdingbranch
 194     # of the document, we force the value $priority and $found .
 195     if ( $checkitem and not C4::Context->preference('ReservesNeedReturns') ) {
 196         my $item = Koha::Items->find( $checkitem ); # FIXME Prevent bad calls
 197
 198         if (
 199             # If item is already checked out, it cannot be set waiting
 200             !$item->onloan
 201
 202             # The item can't be waiting if it needs a transfer
 203             && $item->holdingbranch eq $branch
 204
 205             # Similarly, if in transit it can't be waiting
 206             && !$item->get_transfer
 207
 208             # If we can't hold damaged items, and it is damaged, it can't be waiting
 209             && ( $item->damaged && C4::Context->preference('AllowHoldsOnDamagedItems') || !$item->damaged )
 210
 211             # Lastly, if this already has holds, we shouldn't make it waiting for the new hold
 212             && !$item->current_holds->count )
 213         {
 214             $priority = 0;
 215             $found = 'W';
 216         }
 217     }
 218
 219     if ( C4::Context->preference('AllowHoldDateInFuture') ) {
 220
 221         # Make room in reserves for this before those of a later reserve date
 222         $priority = _ShiftPriorityByDateAndPriority( $biblionumber, $resdate, $priority );
 223     }
 224
 225     my $waitingdate;
 226
 227     # If the reserv had the waiting status, we had the value of the resdate
 228     if ( $found && $found eq 'W' ) {
 229         $waitingdate = $resdate;
 230     }
 231
 232     # Don't add itemtype limit if specific item is selected
 233     $itemtype = undef if $checkitem;
 234
 235     # updates take place here
 236     my $hold = Koha::Hold->new(
 237         {
 238             borrowernumber => $borrowernumber,
 239             biblionumber   => $biblionumber,
 240             reservedate    => $resdate,
 241             branchcode     => $branch,
 242             priority       => $priority,
 243             reservenotes   => $notes,
 244             itemnumber     => $checkitem,
 245             found          => $found,
 246             waitingdate    => $waitingdate,
 247             expirationdate => $expdate,
 248             itemtype       => $itemtype,
 249             item_level_hold => $checkitem ? 1 : 0,
 250         }
 251     )->store();
 252     $hold->set_waiting() if $found && $found eq 'W';
 253
 254     logaction( 'HOLDS', 'CREATE', $hold->id, Dumper($hold->unblessed) )
 255         if C4::Context->preference('HoldsLog');
 256
 257     my $reserve_id = $hold->id();
 258
 259     # add a reserve fee if needed
 260     if ( C4::Context->preference('HoldFeeMode') ne 'any_time_is_collected' ) {
 261         my $reserve_fee = GetReserveFee( $borrowernumber, $biblionumber );
 262         ChargeReserveFee( $borrowernumber, $reserve_fee, $title );
 263     }
 264
 265     _FixPriority({ biblionumber => $biblionumber});
 266
 267     # Send e-mail to librarian if syspref is active
 268     if(C4::Context->preference("emailLibrarianWhenHoldIsPlaced")){
 269         my $patron = Koha::Patrons->find( $borrowernumber );
 270         my $library = $patron->library;
 271         if ( my $letter =  C4::Letters::GetPreparedLetter (
 272             module => 'reserves',
 273             letter_code => 'HOLDPLACED',
 274             branchcode => $branch,
 275             lang => $patron->lang,
 276             tables => {
 277                 'branches'    => $library->unblessed,
 278                 'borrowers'   => $patron->unblessed,
 279                 'biblio'      => $biblionumber,
 280                 'biblioitems' => $biblionumber,
 281                 'items'       => $checkitem,
 282                 'reserves'    => $hold->unblessed,
 283             },
 284         ) ) {
 285
 286             my $branch_email_address = $library->inbound_email_address;
 287
 288             C4::Letters::EnqueueLetter(
 289                 {
 290                     letter                 => $letter,
 291                     borrowernumber         => $borrowernumber,
 292                     message_transport_type => 'email',
 293                     to_address             => $branch_email_address,
 294                 }
 295             );
 296         }
 297     }
 298
 299     return $reserve_id;
 300 }
 301
 302 =head2 CanBookBeReserved
 303
 304   $canReserve = &CanBookBeReserved($borrowernumber, $biblionumber, $branchcode)
 305   if ($canReserve eq 'OK') { #We can reserve this Item! }
 306
 307 See CanItemBeReserved() for possible return values.
 308
 309 =cut
 310
 311 sub CanBookBeReserved{
 312     my ($borrowernumber, $biblionumber, $pickup_branchcode) = @_;
 313
 314     my @itemnumbers = Koha::Items->search({ biblionumber => $biblionumber})->get_column("itemnumber");
 315     #get items linked via host records
 316     my @hostitems = get_hostitemnumbers_of($biblionumber);
 317     if (@hostitems){
 318         push (@itemnumbers, @hostitems);
 319     }
 320
 321     my $canReserve = { status => '' };
 322     foreach my $itemnumber (@itemnumbers) {
 323         $canReserve = CanItemBeReserved( $borrowernumber, $itemnumber, $pickup_branchcode );
 324         return { status => 'OK' } if $canReserve->{status} eq 'OK';
 325     }
 326     return $canReserve;
 327 }
 328
 329 =head2 CanItemBeReserved
 330
 331   $canReserve = &CanItemBeReserved($borrowernumber, $itemnumber, $branchcode)
 332   if ($canReserve->{status} eq 'OK') { #We can reserve this Item! }
 333
 334 @RETURNS { status => OK },              if the Item can be reserved.
 335          { status => ageRestricted },   if the Item is age restricted for this borrower.
 336          { status => damaged },         if the Item is damaged.
 337          { status => cannotReserveFromOtherBranches }, if syspref 'canreservefromotherbranches' is OK.
 338          { status => branchNotInHoldGroup }, if borrower home library is not in hold group, and holds are only allowed from hold groups.
 339          { status => tooManyReserves, limit => $limit }, if the borrower has exceeded their maximum reserve amount.
 340          { status => notReservable },   if holds on this item are not allowed
 341          { status => libraryNotFound },   if given branchcode is not an existing library
 342          { status => libraryNotPickupLocation },   if given branchcode is not configured to be a pickup location
 343          { status => cannotBeTransferred }, if branch transfer limit applies on given item and branchcode
 344          { status => pickupNotInHoldGroup }, pickup location is not in hold group, and pickup locations are only allowed from hold groups.
 345
 346 =cut
 347
 348 sub CanItemBeReserved {
 349     my ( $borrowernumber, $itemnumber, $pickup_branchcode ) = @_;
 350
 351     my $dbh = C4::Context->dbh;
 352     my $ruleitemtype;    # itemtype of the matching issuing rule
 353     my $allowedreserves  = 0; # Total number of holds allowed across all records
 354     my $holds_per_record = 1; # Total number of holds allowed for this one given record
 355     my $holds_per_day;        # Default to unlimited
 356
 357     # we retrieve borrowers and items informations #
 358     # item->{itype} will come for biblioitems if necessery
 359     my $item       = Koha::Items->find($itemnumber);
 360     my $biblio     = $item->biblio;
 361     my $patron = Koha::Patrons->find( $borrowernumber );
 362     my $borrower = $patron->unblessed;
 363
 364     # If an item is damaged and we don't allow holds on damaged items, we can stop right here
 365     return { status =>'damaged' }
 366       if ( $item->damaged
 367         && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 368
 369     # Check for the age restriction
 370     my ( $ageRestriction, $daysToAgeRestriction ) =
 371       C4::Circulation::GetAgeRestriction( $biblio->biblioitem->agerestriction, $borrower );
 372     return { status => 'ageRestricted' } if $daysToAgeRestriction && $daysToAgeRestriction > 0;
 373
 374     # Check that the patron doesn't have an item level hold on this item already
 375     return { status =>'itemAlreadyOnHold' }
 376       if Koha::Holds->search( { borrowernumber => $borrowernumber, itemnumber => $itemnumber } )->count();
 377
 378     my $controlbranch = C4::Context->preference('ReservesControlBranch');
 379
 380     my $querycount = q{
 381         SELECT count(*) AS count
 382           FROM reserves
 383      LEFT JOIN items USING (itemnumber)
 384      LEFT JOIN biblioitems ON (reserves.biblionumber=biblioitems.biblionumber)
 385      LEFT JOIN borrowers USING (borrowernumber)
 386          WHERE borrowernumber = ?
 387     };
 388
 389     my $branchcode  = "";
 390     my $branchfield = "reserves.branchcode";
 391
 392     if ( $controlbranch eq "ItemHomeLibrary" ) {
 393         $branchfield = "items.homebranch";
 394         $branchcode  = $item->homebranch;
 395     }
 396     elsif ( $controlbranch eq "PatronLibrary" ) {
 397         $branchfield = "borrowers.branchcode";
 398         $branchcode  = $borrower->{branchcode};
 399     }
 400
 401     # we retrieve rights
 402     if ( my $rights = GetHoldRule( $borrower->{'categorycode'}, $item->effective_itemtype, $branchcode ) ) {
 403         $ruleitemtype     = $rights->{itemtype};
 404         $allowedreserves  = $rights->{reservesallowed} // $allowedreserves;
 405         $holds_per_record = $rights->{holds_per_record} // $holds_per_record;
 406         $holds_per_day    = $rights->{holds_per_day};
 407     }
 408     else {
 409         $ruleitemtype = undef;
 410     }
 411
 412     my $holds = Koha::Holds->search(
 413         {
 414             borrowernumber => $borrowernumber,
 415             biblionumber   => $item->biblionumber,
 416         }
 417     );
 418     if (   defined $holds_per_record && $holds_per_record ne ''
 419         && $holds->count() >= $holds_per_record ) {
 420         return { status => "tooManyHoldsForThisRecord", limit => $holds_per_record };
 421     }
 422
 423     my $today_holds = Koha::Holds->search({
 424         borrowernumber => $borrowernumber,
 425         reservedate    => dt_from_string->date
 426     });
 427
 428     if (   defined $holds_per_day && $holds_per_day ne ''
 429         && $today_holds->count() >= $holds_per_day )
 430     {
 431         return { status => 'tooManyReservesToday', limit => $holds_per_day };
 432     }
 433
 434     # we retrieve count
 435
 436     $querycount .= "AND ( $branchfield = ? OR $branchfield IS NULL )";
 437
 438     # If using item-level itypes, fall back to the record
 439     # level itemtype if the hold has no associated item
 440     $querycount .=
 441       C4::Context->preference('item-level_itypes')
 442       ? " AND COALESCE( items.itype, biblioitems.itemtype ) = ?"
 443       : " AND biblioitems.itemtype = ?"
 444       if defined $ruleitemtype;
 445
 446     my $sthcount = $dbh->prepare($querycount);
 447
 448     if ( defined $ruleitemtype ) {
 449         $sthcount->execute( $borrowernumber, $branchcode, $ruleitemtype );
 450     }
 451     else {
 452         $sthcount->execute( $borrowernumber, $branchcode );
 453     }
 454
 455     my $reservecount = "0";
 456     if ( my $rowcount = $sthcount->fetchrow_hashref() ) {
 457         $reservecount = $rowcount->{count};
 458     }
 459
 460     # we check if it's ok or not
 461     if (   defined  $allowedreserves && $allowedreserves ne ''
 462         && $reservecount >= $allowedreserves ) {
 463         return { status => 'tooManyReserves', limit => $allowedreserves };
 464     }
 465
 466     # Now we need to check hold limits by patron category
 467     my $rule = Koha::CirculationRules->get_effective_rule(
 468         {
 469             categorycode => $borrower->{categorycode},
 470             branchcode   => $branchcode,
 471             rule_name    => 'max_holds',
 472         }
 473     );
 474     if ( $rule && defined( $rule->rule_value ) && $rule->rule_value ne '' ) {
 475         my $total_holds_count = Koha::Holds->search(
 476             {
 477                 borrowernumber => $borrower->{borrowernumber}
 478             }
 479         )->count();
 480
 481         return { status => 'tooManyReserves', limit => $rule->rule_value} if $total_holds_count >= $rule->rule_value;
 482     }
 483
 484     my $reserves_control_branch =
 485       GetReservesControlBranch( $item->unblessed(), $borrower );
 486     my $branchitemrule =
 487       C4::Circulation::GetBranchItemRule( $reserves_control_branch, $item->itype ); # FIXME Should not be item->effective_itemtype?
 488
 489     if ( $branchitemrule->{holdallowed} == 0 ) {
 490         return { status => 'notReservable' };
 491     }
 492
 493     if (   $branchitemrule->{holdallowed} == 1
 494         && $borrower->{branchcode} ne $item->homebranch )
 495     {
 496         return { status => 'cannotReserveFromOtherBranches' };
 497     }
 498
 499     my $item_library = Koha::Libraries->find( {branchcode => $item->homebranch} );
 500     if ( $branchitemrule->{holdallowed} == 3) {
 501         if($borrower->{branchcode} ne $item->homebranch && !$item_library->validate_hold_sibling( {branchcode => $borrower->{branchcode}} )) {
 502             return { status => 'branchNotInHoldGroup' };
 503         }
 504     }
 505
 506     # If reservecount is ok, we check item branch if IndependentBranches is ON
 507     # and canreservefromotherbranches is OFF
 508     if ( C4::Context->preference('IndependentBranches')
 509         and !C4::Context->preference('canreservefromotherbranches') )
 510     {
 511         if ( $item->homebranch ne $borrower->{branchcode} ) {
 512             return { status => 'cannotReserveFromOtherBranches' };
 513         }
 514     }
 515
 516     if ($pickup_branchcode) {
 517         my $destination = Koha::Libraries->find({
 518             branchcode => $pickup_branchcode,
 519         });
 520
 521         unless ($destination) {
 522             return { status => 'libraryNotFound' };
 523         }
 524         unless ($destination->pickup_location) {
 525             return { status => 'libraryNotPickupLocation' };
 526         }
 527         unless ($item->can_be_transferred({ to => $destination })) {
 528             return { status => 'cannotBeTransferred' };
 529         }
 530         unless ($branchitemrule->{hold_fulfillment_policy} ne 'holdgroup' || $item_library->validate_hold_sibling( {branchcode => $pickup_branchcode} )) {
 531             return { status => 'pickupNotInHoldGroup' };
 532         }
 533         unless ($branchitemrule->{hold_fulfillment_policy} ne 'patrongroup' || Koha::Libraries->find({branchcode => $borrower->{branchcode}})->validate_hold_sibling({branchcode => $pickup_branchcode})) {
 534             return { status => 'pickupNotInHoldGroup' };
 535         }
 536     }
 537
 538     return { status => 'OK' };
 539 }
 540
 541 =head2 CanReserveBeCanceledFromOpac
 542
 543     $number = CanReserveBeCanceledFromOpac($reserve_id, $borrowernumber);
 544
 545     returns 1 if reserve can be cancelled by user from OPAC.
 546     First check if reserve belongs to user, next checks if reserve is not in
 547     transfer or waiting status
 548
 549 =cut
 550
 551 sub CanReserveBeCanceledFromOpac {
 552     my ($reserve_id, $borrowernumber) = @_;
 553
 554     return unless $reserve_id and $borrowernumber;
 555     my $reserve = Koha::Holds->find($reserve_id);
 556
 557     return 0 unless $reserve->borrowernumber == $borrowernumber;
 558     return 0 if ( $reserve->found eq 'W' ) or ( $reserve->found eq 'T' );
 559
 560     return 1;
 561
 562 }
 563
 564 =head2 GetOtherReserves
 565
 566   ($messages,$nextreservinfo)=$GetOtherReserves(itemnumber);
 567
 568 Check queued list of this document and check if this document must be transferred
 569
 570 =cut
 571
 572 sub GetOtherReserves {
 573     my ($itemnumber) = @_;
 574     my $messages;
 575     my $nextreservinfo;
 576     my ( undef, $checkreserves, undef ) = CheckReserves($itemnumber);
 577     if ($checkreserves) {
 578         my $item = Koha::Items->find($itemnumber);
 579         if ( $item->holdingbranch ne $checkreserves->{'branchcode'} ) {
 580             $messages->{'transfert'} = $checkreserves->{'branchcode'};
 581             #minus priorities of others reservs
 582             ModReserveMinusPriority(
 583                 $itemnumber,
 584                 $checkreserves->{'reserve_id'},
 585             );
 586
 587             #launch the subroutine dotransfer
 588             C4::Items::ModItemTransfer(
 589                 $itemnumber,
 590                 $item->holdingbranch,
 591                 $checkreserves->{'branchcode'},
 592                 'Reserve'
 593               ),
 594               ;
 595         }
 596
 597      #step 2b : case of a reservation on the same branch, set the waiting status
 598         else {
 599             $messages->{'waiting'} = 1;
 600             ModReserveMinusPriority(
 601                 $itemnumber,
 602                 $checkreserves->{'reserve_id'},
 603             );
 604             ModReserveStatus($itemnumber,'W');
 605         }
 606
 607         $nextreservinfo = $checkreserves->{'borrowernumber'};
 608     }
 609
 610     return ( $messages, $nextreservinfo );
 611 }
 612
 613 =head2 ChargeReserveFee
 614
 615     $fee = ChargeReserveFee( $borrowernumber, $fee, $title );
 616
 617     Charge the fee for a reserve (if $fee > 0)
 618
 619 =cut
 620
 621 sub ChargeReserveFee {
 622     my ( $borrowernumber, $fee, $title ) = @_;
 623     return if !$fee || $fee == 0;    # the last test is needed to include 0.00
 624     Koha::Account->new( { patron_id => $borrowernumber } )->add_debit(
 625         {
 626             amount       => $fee,
 627             description  => $title,
 628             note         => undef,
 629             user_id      => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
 630             library_id   => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
 631             interface    => C4::Context->interface,
 632             invoice_type => undef,
 633             type         => 'RESERVE',
 634             item_id      => undef
 635         }
 636     );
 637 }
 638
 639 =head2 GetReserveFee
 640
 641     $fee = GetReserveFee( $borrowernumber, $biblionumber );
 642
 643     Calculate the fee for a reserve (if applicable).
 644
 645 =cut
 646
 647 sub GetReserveFee {
 648     my ( $borrowernumber, $biblionumber ) = @_;
 649     my $borquery = qq{
 650 SELECT reservefee FROM borrowers LEFT JOIN categories ON borrowers.categorycode = categories.categorycode WHERE borrowernumber = ?
 651     };
 652     my $issue_qry = qq{
 653 SELECT COUNT(*) FROM items
 654 LEFT JOIN issues USING (itemnumber)
 655 WHERE items.biblionumber=? AND issues.issue_id IS NULL
 656     };
 657     my $holds_qry = qq{
 658 SELECT COUNT(*) FROM reserves WHERE biblionumber=? AND borrowernumber<>?
 659     };
 660
 661     my $dbh = C4::Context->dbh;
 662     my ( $fee ) = $dbh->selectrow_array( $borquery, undef, ($borrowernumber) );
 663     my $hold_fee_mode = C4::Context->preference('HoldFeeMode') || 'not_always';
 664     if( $fee and $fee > 0 and $hold_fee_mode eq 'not_always' ) {
 665         # This is a reconstruction of the old code:
 666         # Compare number of items with items issued, and optionally check holds
 667         # If not all items are issued and there are no holds: charge no fee
 668         # NOTE: Lost, damaged, not-for-loan, etc. are just ignored here
 669         my ( $notissued, $reserved );
 670         ( $notissued ) = $dbh->selectrow_array( $issue_qry, undef,
 671             ( $biblionumber ) );
 672         if( $notissued ) {
 673             ( $reserved ) = $dbh->selectrow_array( $holds_qry, undef,
 674                 ( $biblionumber, $borrowernumber ) );
 675             $fee = 0 if $reserved == 0;
 676         }
 677     }
 678     return $fee;
 679 }
 680
 681 =head2 GetReserveStatus
 682
 683   $reservestatus = GetReserveStatus($itemnumber);
 684
 685 Takes an itemnumber and returns the status of the reserve placed on it.
 686 If several reserves exist, the reserve with the lower priority is given.
 687
 688 =cut
 689
 690 ## FIXME: I don't think this does what it thinks it does.
 691 ## It only ever checks the first reserve result, even though
 692 ## multiple reserves for that bib can have the itemnumber set
 693 ## the sub is only used once in the codebase.
 694 sub GetReserveStatus {
 695     my ($itemnumber) = @_;
 696
 697     my $dbh = C4::Context->dbh;
 698
 699     my ($sth, $found, $priority);
 700     if ( $itemnumber ) {
 701         $sth = $dbh->prepare("SELECT found, priority FROM reserves WHERE itemnumber = ? order by priority LIMIT 1");
 702         $sth->execute($itemnumber);
 703         ($found, $priority) = $sth->fetchrow_array;
 704     }
 705
 706     if(defined $found) {
 707         return 'Waiting'  if $found eq 'W' and $priority == 0;
 708         return 'Finished' if $found eq 'F';
 709     }
 710
 711     return 'Reserved' if defined $priority && $priority > 0;
 712
 713     return ''; # empty string here will remove need for checking undef, or less log lines
 714 }
 715
 716 =head2 CheckReserves
 717
 718   ($status, $matched_reserve, $possible_reserves) = &CheckReserves($itemnumber);
 719   ($status, $matched_reserve, $possible_reserves) = &CheckReserves(undef, $barcode);
 720   ($status, $matched_reserve, $possible_reserves) = &CheckReserves($itemnumber,undef,$lookahead);
 721
 722 Find a book in the reserves.
 723
 724 C<$itemnumber> is the book's item number.
 725 C<$lookahead> is the number of days to look in advance for future reserves.
 726
 727 As I understand it, C<&CheckReserves> looks for the given item in the
 728 reserves. If it is found, that's a match, and C<$status> is set to
 729 C<Waiting>.
 730
 731 Otherwise, it finds the most important item in the reserves with the
 732 same biblio number as this book (I'm not clear on this) and returns it
 733 with C<$status> set to C<Reserved>.
 734
 735 C<&CheckReserves> returns a two-element list:
 736
 737 C<$status> is either C<Waiting>, C<Reserved> (see above), or 0.
 738
 739 C<$reserve> is the reserve item that matched. It is a
 740 reference-to-hash whose keys are mostly the fields of the reserves
 741 table in the Koha database.
 742
 743 =cut
 744
 745 sub CheckReserves {
 746     my ( $item, $barcode, $lookahead_days, $ignore_borrowers) = @_;
 747     my $dbh = C4::Context->dbh;
 748     my $sth;
 749     my $select;
 750     if (C4::Context->preference('item-level_itypes')){
 751         $select = "
 752            SELECT items.biblionumber,
 753            items.biblioitemnumber,
 754            itemtypes.notforloan,
 755            items.notforloan AS itemnotforloan,
 756            items.itemnumber,
 757            items.damaged,
 758            items.homebranch,
 759            items.holdingbranch
 760            FROM   items
 761            LEFT JOIN biblioitems ON items.biblioitemnumber = biblioitems.biblioitemnumber
 762            LEFT JOIN itemtypes   ON items.itype   = itemtypes.itemtype
 763         ";
 764     }
 765     else {
 766         $select = "
 767            SELECT items.biblionumber,
 768            items.biblioitemnumber,
 769            itemtypes.notforloan,
 770            items.notforloan AS itemnotforloan,
 771            items.itemnumber,
 772            items.damaged,
 773            items.homebranch,
 774            items.holdingbranch
 775            FROM   items
 776            LEFT JOIN biblioitems ON items.biblioitemnumber = biblioitems.biblioitemnumber
 777            LEFT JOIN itemtypes   ON biblioitems.itemtype   = itemtypes.itemtype
 778         ";
 779     }
 780
 781     if ($item) {
 782         $sth = $dbh->prepare("$select WHERE itemnumber = ?");
 783         $sth->execute($item);
 784     }
 785     else {
 786         $sth = $dbh->prepare("$select WHERE barcode = ?");
 787         $sth->execute($barcode);
 788     }
 789     # note: we get the itemnumber because we might have started w/ just the barcode.  Now we know for sure we have it.
 790     my ( $biblio, $bibitem, $notforloan_per_itemtype, $notforloan_per_item, $itemnumber, $damaged, $item_homebranch, $item_holdingbranch ) = $sth->fetchrow_array;
 791     return if ( $damaged && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 792
 793     return unless $itemnumber; # bail if we got nothing.
 794     # if item is not for loan it cannot be reserved either.....
 795     # except where items.notforloan < 0 :  This indicates the item is holdable.
 796     return if  ( $notforloan_per_item > 0 ) or $notforloan_per_itemtype;
 797
 798     # Find this item in the reserves
 799     my @reserves = _Findgroupreserve( $bibitem, $biblio, $itemnumber, $lookahead_days, $ignore_borrowers);
 800
 801     # $priority and $highest are used to find the most important item
 802     # in the list returned by &_Findgroupreserve. (The lower $priority,
 803     # the more important the item.)
 804     # $highest is the most important item we've seen so far.
 805     my $highest;
 806     if (scalar @reserves) {
 807         my $LocalHoldsPriority = C4::Context->preference('LocalHoldsPriority');
 808         my $LocalHoldsPriorityPatronControl = C4::Context->preference('LocalHoldsPriorityPatronControl');
 809         my $LocalHoldsPriorityItemControl = C4::Context->preference('LocalHoldsPriorityItemControl');
 810
 811         my $priority = 10000000;
 812         foreach my $res (@reserves) {
 813             if ( $res->{'itemnumber'} && $res->{'itemnumber'} == $itemnumber && $res->{'priority'} == 0) {
 814                 if ($res->{'found'} eq 'W') {
 815                     return ( "Waiting", $res, \@reserves ); # Found it, it is waiting
 816                 } else {
 817                     return ( "Reserved", $res, \@reserves ); # Found determinated hold, e. g. the tranferred one
 818                 }
 819             } else {
 820                 my $patron;
 821                 my $item;
 822                 my $local_hold_match;
 823
 824                 if ($LocalHoldsPriority) {
 825                     $patron = Koha::Patrons->find( $res->{borrowernumber} );
 826                     $item = Koha::Items->find($itemnumber);
 827
 828                     my $local_holds_priority_item_branchcode =
 829                       $item->$LocalHoldsPriorityItemControl;
 830                     my $local_holds_priority_patron_branchcode =
 831                       ( $LocalHoldsPriorityPatronControl eq 'PickupLibrary' )
 832                       ? $res->{branchcode}
 833                       : ( $LocalHoldsPriorityPatronControl eq 'HomeLibrary' )
 834                       ? $patron->branchcode
 835                       : undef;
 836                     $local_hold_match =
 837                       $local_holds_priority_item_branchcode eq
 838                       $local_holds_priority_patron_branchcode;
 839                 }
 840
 841                 # See if this item is more important than what we've got so far
 842                 if ( ( $res->{'priority'} && $res->{'priority'} < $priority ) || $local_hold_match ) {
 843                     $item ||= Koha::Items->find($itemnumber);
 844                     next if $res->{itemtype} && $res->{itemtype} ne $item->effective_itemtype;
 845                     $patron ||= Koha::Patrons->find( $res->{borrowernumber} );
 846                     my $branch = GetReservesControlBranch( $item->unblessed, $patron->unblessed );
 847                     my $branchitemrule = C4::Circulation::GetBranchItemRule($branch,$item->effective_itemtype);
 848                     next if ($branchitemrule->{'holdallowed'} == 0);
 849                     next if (($branchitemrule->{'holdallowed'} == 1) && ($branch ne $patron->branchcode));
 850                     my $library = Koha::Libraries->find({branchcode=>$item->homebranch});
 851                     next if (($branchitemrule->{'holdallowed'} == 3) && (!$library->validate_hold_sibling({branchcode => $patron->branchcode}) ));
 852                     my $hold_fulfillment_policy = $branchitemrule->{hold_fulfillment_policy};
 853                     next if ( ($hold_fulfillment_policy eq 'holdgroup') && (!$library->validate_hold_sibling({branchcode => $res->{branchcode}})) );
 854                     next if ( ($hold_fulfillment_policy eq 'homebranch') && ($res->{branchcode} ne $item->$hold_fulfillment_policy) );
 855                     next if ( ($hold_fulfillment_policy eq 'holdingbranch') && ($res->{branchcode} ne $item->$hold_fulfillment_policy) );
 856                     next unless $item->can_be_transferred( { to => Koha::Libraries->find( $res->{branchcode} ) } );
 857                     $priority = $res->{'priority'};
 858                     $highest  = $res;
 859                     last if $local_hold_match;
 860                 }
 861             }
 862         }
 863     }
 864
 865     # If we get this far, then no exact match was found.
 866     # We return the most important (i.e. next) reservation.
 867     if ($highest) {
 868         $highest->{'itemnumber'} = $item;
 869         return ( "Reserved", $highest, \@reserves );
 870     }
 871
 872     return ( '' );
 873 }
 874
 875 =head2 CancelExpiredReserves
 876
 877   CancelExpiredReserves();
 878
 879 Cancels all reserves with an expiration date from before today.
 880
 881 =cut
 882
 883 sub CancelExpiredReserves {
 884     my $today = dt_from_string();
 885     my $cancel_on_holidays = C4::Context->preference('ExpireReservesOnHolidays');
 886     my $expireWaiting = C4::Context->preference('ExpireReservesMaxPickUpDelay');
 887
 888     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 889     my $params = { expirationdate => { '<', $dtf->format_date($today) } };
 890     $params->{found} = [ { '!=', 'W' }, undef ]  unless $expireWaiting;
 891
 892     # FIXME To move to Koha::Holds->search_expired (?)
 893     my $holds = Koha::Holds->search( $params );
 894
 895     while ( my $hold = $holds->next ) {
 896         my $calendar = Koha::Calendar->new( branchcode => $hold->branchcode );
 897
 898         next if !$cancel_on_holidays && $calendar->is_holiday( $today );
 899
 900         my $cancel_params = {};
 901         if ( $hold->found eq 'W' ) {
 902             $cancel_params->{charge_cancel_fee} = 1;
 903         }
 904         $hold->cancel( $cancel_params );
 905     }
 906 }
 907
 908 =head2 AutoUnsuspendReserves
 909
 910   AutoUnsuspendReserves();
 911
 912 Unsuspends all suspended reserves with a suspend_until date from before today.
 913
 914 =cut
 915
 916 sub AutoUnsuspendReserves {
 917     my $today = dt_from_string();
 918
 919     my @holds = Koha::Holds->search( { suspend_until => { '<=' => $today->ymd() } } );
 920
 921     map { $_->resume() } @holds;
 922 }
 923
 924 =head2 ModReserve
 925
 926   ModReserve({ rank => $rank,
 927                reserve_id => $reserve_id,
 928                branchcode => $branchcode
 929                [, itemnumber => $itemnumber ]
 930                [, biblionumber => $biblionumber, $borrowernumber => $borrowernumber ]
 931               });
 932
 933 Change a hold request's priority or cancel it.
 934
 935 C<$rank> specifies the effect of the change.  If C<$rank>
 936 is 'W' or 'n', nothing happens.  This corresponds to leaving a
 937 request alone when changing its priority in the holds queue
 938 for a bib.
 939
 940 If C<$rank> is 'del', the hold request is cancelled.
 941
 942 If C<$rank> is an integer greater than zero, the priority of
 943 the request is set to that value.  Since priority != 0 means
 944 that the item is not waiting on the hold shelf, setting the
 945 priority to a non-zero value also sets the request's found
 946 status and waiting date to NULL.
 947
 948 The optional C<$itemnumber> parameter is used only when
 949 C<$rank> is a non-zero integer; if supplied, the itemnumber
 950 of the hold request is set accordingly; if omitted, the itemnumber
 951 is cleared.
 952
 953 B<FIXME:> Note that the forgoing can have the effect of causing
 954 item-level hold requests to turn into title-level requests.  This
 955 will be fixed once reserves has separate columns for requested
 956 itemnumber and supplying itemnumber.
 957
 958 =cut
 959
 960 sub ModReserve {
 961     my ( $params ) = @_;
 962
 963     my $rank = $params->{'rank'};
 964     my $reserve_id = $params->{'reserve_id'};
 965     my $branchcode = $params->{'branchcode'};
 966     my $itemnumber = $params->{'itemnumber'};
 967     my $suspend_until = $params->{'suspend_until'};
 968     my $borrowernumber = $params->{'borrowernumber'};
 969     my $biblionumber = $params->{'biblionumber'};
 970
 971     return if $rank eq "W";
 972     return if $rank eq "n";
 973
 974     return unless ( $reserve_id || ( $borrowernumber && ( $biblionumber || $itemnumber ) ) );
 975
 976     my $hold;
 977     unless ( $reserve_id ) {
 978         my $holds = Koha::Holds->search({ biblionumber => $biblionumber, borrowernumber => $borrowernumber, itemnumber => $itemnumber });
 979         return unless $holds->count; # FIXME Should raise an exception
 980         $hold = $holds->next;
 981         $reserve_id = $hold->reserve_id;
 982     }
 983
 984     $hold ||= Koha::Holds->find($reserve_id);
 985
 986     if ( $rank eq "del" ) {
 987         $hold->cancel;
 988     }
 989     elsif ($rank =~ /^\d+/ and $rank > 0) {
 990         logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, Dumper($hold->unblessed) )
 991             if C4::Context->preference('HoldsLog');
 992
 993         my $properties = {
 994             priority    => $rank,
 995             branchcode  => $branchcode,
 996             itemnumber  => $itemnumber,
 997             found       => undef,
 998             waitingdate => undef
 999         };
1000         if (exists $params->{reservedate}) {
1001             $properties->{reservedate} = $params->{reservedate} || undef;
1002         }
1003         if (exists $params->{expirationdate}) {
1004             $properties->{expirationdate} = $params->{expirationdate} || undef;
1005         }
1006
1007         $hold->set($properties)->store();
1008
1009         if ( defined( $suspend_until ) ) {
1010             if ( $suspend_until ) {
1011                 $suspend_until = eval { dt_from_string( $suspend_until ) };
1012                 $hold->suspend_hold( $suspend_until );
1013             } else {
1014                 # If the hold is suspended leave the hold suspended, but convert it to an indefinite hold.
1015                 # If the hold is not suspended, this does nothing.
1016                 $hold->set( { suspend_until => undef } )->store();
1017             }
1018         }
1019
1020         _FixPriority({ reserve_id => $reserve_id, rank =>$rank });
1021     }
1022 }
1023
1024 =head2 ModReserveFill
1025
1026   &ModReserveFill($reserve);
1027
1028 Fill a reserve. If I understand this correctly, this means that the
1029 reserved book has been found and given to the patron who reserved it.
1030
1031 C<$reserve> specifies the reserve to fill. It is a reference-to-hash
1032 whose keys are fields from the reserves table in the Koha database.
1033
1034 =cut
1035
1036 sub ModReserveFill {
1037     my ($res) = @_;
1038     my $reserve_id = $res->{'reserve_id'};
1039
1040     my $hold = Koha::Holds->find($reserve_id);
1041     # get the priority on this record....
1042     my $priority = $hold->priority;
1043
1044     # update the hold statuses, no need to store it though, we will be deleting it anyway
1045     $hold->set(
1046         {
1047             found    => 'F',
1048             priority => 0,
1049         }
1050     );
1051
1052     logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, Dumper($hold->unblessed) )
1053         if C4::Context->preference('HoldsLog');
1054
1055     # FIXME Must call Koha::Hold->cancel ? => No, should call ->filled and add the correct log
1056     Koha::Old::Hold->new( $hold->unblessed() )->store();
1057
1058     $hold->delete();
1059
1060     if ( C4::Context->preference('HoldFeeMode') eq 'any_time_is_collected' ) {
1061         my $reserve_fee = GetReserveFee( $hold->borrowernumber, $hold->biblionumber );
1062         ChargeReserveFee( $hold->borrowernumber, $reserve_fee, $hold->biblio->title );
1063     }
1064
1065     # now fix the priority on the others (if the priority wasn't
1066     # already sorted!)....
1067     unless ( $priority == 0 ) {
1068         _FixPriority( { reserve_id => $reserve_id, biblionumber => $hold->biblionumber } );
1069     }
1070 }
1071
1072 =head2 ModReserveStatus
1073
1074   &ModReserveStatus($itemnumber, $newstatus);
1075
1076 Update the reserve status for the active (priority=0) reserve.
1077
1078 $itemnumber is the itemnumber the reserve is on
1079
1080 $newstatus is the new status.
1081
1082 =cut
1083
1084 sub ModReserveStatus {
1085
1086     #first : check if we have a reservation for this item .
1087     my ($itemnumber, $newstatus) = @_;
1088     my $dbh = C4::Context->dbh;
1089
1090     my $query = "UPDATE reserves SET found = ?, waitingdate = NOW() WHERE itemnumber = ? AND found IS NULL AND priority = 0";
1091     my $sth_set = $dbh->prepare($query);
1092     $sth_set->execute( $newstatus, $itemnumber );
1093
1094     my $item = Koha::Items->find($itemnumber);
1095     if ( $item->location && $item->location eq 'CART'
1096         && ( !$item->permanent_location || $item->permanent_location ne 'CART' )
1097         && $newstatus ) {
1098       CartToShelf( $itemnumber );
1099     }
1100 }
1101
1102 =head2 ModReserveAffect
1103
1104   &ModReserveAffect($itemnumber,$borrowernumber,$diffBranchSend,$reserve_id);
1105
1106 This function affect an item and a status for a given reserve, either fetched directly
1107 by record_id, or by borrowernumber and itemnumber or biblionumber. If only biblionumber
1108 is given, only first reserve returned is affected, which is ok for anything but
1109 multi-item holds.
1110
1111 if $transferToDo is not set, then the status is set to "Waiting" as well.
1112 otherwise, a transfer is on the way, and the end of the transfer will
1113 take care of the waiting status
1114
1115 =cut
1116
1117 sub ModReserveAffect {
1118     my ( $itemnumber, $borrowernumber, $transferToDo, $reserve_id ) = @_;
1119     my $dbh = C4::Context->dbh;
1120
1121     # we want to attach $itemnumber to $borrowernumber, find the biblionumber
1122     # attached to $itemnumber
1123     my $sth = $dbh->prepare("SELECT biblionumber FROM items WHERE itemnumber=?");
1124     $sth->execute($itemnumber);
1125     my ($biblionumber) = $sth->fetchrow;
1126
1127     # get request - need to find out if item is already
1128     # waiting in order to not send duplicate hold filled notifications
1129
1130     my $hold;
1131     # Find hold by id if we have it
1132     $hold = Koha::Holds->find( $reserve_id ) if $reserve_id;
1133     # Find item level hold for this item if there is one
1134     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, itemnumber => $itemnumber } )->next();
1135     # Find record level hold if there is no item level hold
1136     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, biblionumber => $biblionumber } )->next();
1137
1138     return unless $hold;
1139
1140     my $already_on_shelf = $hold->found && $hold->found eq 'W';
1141
1142     $hold->itemnumber($itemnumber);
1143     $hold->set_waiting($transferToDo);
1144
1145     if( !$transferToDo ){
1146         _koha_notify_reserve( $hold->reserve_id ) unless $already_on_shelf;
1147         my $transfers = Koha::Item::Transfers->search({
1148             itemnumber => $itemnumber,
1149             datearrived => undef
1150         });
1151         while( my $transfer = $transfers->next ){
1152             $transfer->datearrived( dt_from_string() )->store;
1153         };
1154     }
1155
1156
1157     _FixPriority( { biblionumber => $biblionumber } );
1158     my $item = Koha::Items->find($itemnumber);
1159     if ( $item->location && $item->location eq 'CART'
1160         && ( !$item->permanent_location || $item->permanent_location ne 'CART' ) ) {
1161       CartToShelf( $itemnumber );
1162     }
1163
1164     logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, Dumper($hold->unblessed) )
1165         if C4::Context->preference('HoldsLog');
1166
1167     return;
1168 }
1169
1170 =head2 ModReserveCancelAll
1171
1172   ($messages,$nextreservinfo) = &ModReserveCancelAll($itemnumber,$borrowernumber);
1173
1174 function to cancel reserv,check other reserves, and transfer document if it's necessary
1175
1176 =cut
1177
1178 sub ModReserveCancelAll {
1179     my $messages;
1180     my $nextreservinfo;
1181     my ( $itemnumber, $borrowernumber ) = @_;
1182
1183     #step 1 : cancel the reservation
1184     my $holds = Koha::Holds->search({ itemnumber => $itemnumber, borrowernumber => $borrowernumber });
1185     return unless $holds->count;
1186     $holds->next->cancel;
1187
1188     #step 2 launch the subroutine of the others reserves
1189     ( $messages, $nextreservinfo ) = GetOtherReserves($itemnumber);
1190
1191     return ( $messages, $nextreservinfo );
1192 }
1193
1194 =head2 ModReserveMinusPriority
1195
1196   &ModReserveMinusPriority($itemnumber,$borrowernumber,$biblionumber)
1197
1198 Reduce the values of queued list
1199
1200 =cut
1201
1202 sub ModReserveMinusPriority {
1203     my ( $itemnumber, $reserve_id ) = @_;
1204
1205     #first step update the value of the first person on reserv
1206     my $dbh   = C4::Context->dbh;
1207     my $query = "
1208         UPDATE reserves
1209         SET    priority = 0 , itemnumber = ?
1210         WHERE  reserve_id = ?
1211     ";
1212     my $sth_upd = $dbh->prepare($query);
1213     $sth_upd->execute( $itemnumber, $reserve_id );
1214     # second step update all others reserves
1215     _FixPriority({ reserve_id => $reserve_id, rank => '0' });
1216 }
1217
1218 =head2 IsAvailableForItemLevelRequest
1219
1220   my $is_available = IsAvailableForItemLevelRequest( $item_record, $borrower_record, $pickup_branchcode );
1221
1222 Checks whether a given item record is available for an
1223 item-level hold request.  An item is available if
1224
1225 * it is not lost AND
1226 * it is not damaged AND
1227 * it is not withdrawn AND
1228 * a waiting or in transit reserve is placed on
1229 * does not have a not for loan value > 0
1230
1231 Need to check the issuingrules onshelfholds column,
1232 if this is set items on the shelf can be placed on hold
1233
1234 Note that IsAvailableForItemLevelRequest() does not
1235 check if the staff operator is authorized to place
1236 a request on the item - in particular,
1237 this routine does not check IndependentBranches
1238 and canreservefromotherbranches.
1239
1240 =cut
1241
1242 sub IsAvailableForItemLevelRequest {
1243     my $item                = shift;
1244     my $patron              = shift;
1245     my $pickup_branchcode   = shift;
1246     # items_any_available is precalculated status passed from request.pl when set of items
1247     # looped outside of IsAvailableForItemLevelRequest to avoid nested loops:
1248     my $items_any_available = shift;
1249
1250     my $dbh = C4::Context->dbh;
1251     # must check the notforloan setting of the itemtype
1252     # FIXME - a lot of places in the code do this
1253     #         or something similar - need to be
1254     #         consolidated
1255     my $itemtype = $item->effective_itemtype;
1256     my $notforloan_per_itemtype = Koha::ItemTypes->find($itemtype)->notforloan;
1257
1258     return 0 if
1259         $notforloan_per_itemtype ||
1260         $item->itemlost        ||
1261         $item->notforloan > 0  ||
1262         $item->withdrawn        ||
1263         ($item->damaged && !C4::Context->preference('AllowHoldsOnDamagedItems'));
1264
1265     if ($pickup_branchcode) {
1266         my $destination = Koha::Libraries->find($pickup_branchcode);
1267         return 0 unless $destination;
1268         return 0 unless $destination->pickup_location;
1269         return 0 unless $item->can_be_transferred( { to => $destination } );
1270         my $reserves_control_branch =
1271             GetReservesControlBranch( $item->unblessed(), $patron->unblessed() );
1272         my $branchitemrule =
1273             C4::Circulation::GetBranchItemRule( $reserves_control_branch, $item->itype );
1274         my $home_library = Koka::Libraries->find( {branchcode => $item->homebranch} );
1275         return 0 unless $branchitemrule->{hold_fulfillment_policy} ne 'holdgroup' || $home_library->validate_hold_sibling( {branchcode => $pickup_branchcode} );
1276     }
1277
1278     my $on_shelf_holds = Koha::CirculationRules->get_onshelfholds_policy( { item => $item, patron => $patron } );
1279
1280     if ( $on_shelf_holds == 1 ) {
1281         return 1;
1282     } elsif ( $on_shelf_holds == 2 ) {
1283
1284         # if we have this param predefined from outer caller sub, we just need
1285         # to return it, so we saving from having loop inside other loop:
1286         return  $items_any_available ? 0 : 1
1287             if defined $items_any_available;
1288
1289         my $any_available = ItemsAnyAvailableForHold( { biblionumber => $item->biblionumber, patron => $patron });
1290         return $any_available ? 0 : 1;
1291     } else { # on_shelf_holds == 0 "If any unavailable" (the description is rather cryptic and could still be improved)
1292         return $item->onloan || IsItemOnHoldAndFound( $item->itemnumber );
1293     }
1294 }
1295
1296 =head2 ItemsAnyAvailableForHold
1297
1298   ItemsAnyAvailableForHold( { biblionumber => $biblionumber, patron => $patron });
1299
1300 This function checks all items for specified biblionumber (num) / patron (object)
1301 and returns true (1) or false (0) depending if any of rules allows at least of
1302 one item to be available for hold including lots of parameters/logic
1303
1304 =cut
1305
1306 sub ItemsAnyAvailableForHold {
1307     my $param = shift;
1308
1309     my @items = Koha::Items->search( { biblionumber => $param->{biblionumber} } );
1310
1311     my $any_available = 0;
1312
1313     foreach my $i (@items) {
1314         my $reserves_control_branch =
1315             GetReservesControlBranch( $i->unblessed(), $param->{patron}->unblessed );
1316         my $branchitemrule =
1317             C4::Circulation::GetBranchItemRule( $reserves_control_branch, $i->itype );
1318         my $item_library = Koha::Libraries->find( { branchcode => $i->homebranch } );
1319
1320         $any_available = 1
1321             unless $i->itemlost
1322             || $i->notforloan > 0
1323             || $i->withdrawn
1324             || $i->onloan
1325             || IsItemOnHoldAndFound( $i->id )
1326             || ( $i->damaged
1327             && ! C4::Context->preference('AllowHoldsOnDamagedItems') )
1328             || Koha::ItemTypes->find( $i->effective_itemtype() )->notforloan
1329             || $branchitemrule->{holdallowed} == 1 && $param->{patron}->branchcode ne $i->homebranch
1330             || $branchitemrule->{holdallowed} == 3 && ! $item_library->validate_hold_sibling( { branchcode => $param->{patron}->branchcode } );
1331     }
1332
1333     return $any_available;
1334 }
1335
1336 =head2 AlterPriority
1337
1338   AlterPriority( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority );
1339
1340 This function changes a reserve's priority up, down, to the top, or to the bottom.
1341 Input: $where is 'up', 'down', 'top' or 'bottom'. Biblionumber, Date reserve was placed
1342
1343 =cut
1344
1345 sub AlterPriority {
1346     my ( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority ) = @_;
1347
1348     my $hold = Koha::Holds->find( $reserve_id );
1349     return unless $hold;
1350
1351     if ( $hold->cancellationdate ) {
1352         warn "I cannot alter the priority for reserve_id $reserve_id, the reserve has been cancelled (" . $hold->cancellationdate . ')';
1353         return;
1354     }
1355
1356     if ( $where eq 'up' ) {
1357       return unless $prev_priority;
1358       _FixPriority({ reserve_id => $reserve_id, rank => $prev_priority })
1359     } elsif ( $where eq 'down' ) {
1360       return unless $next_priority;
1361       _FixPriority({ reserve_id => $reserve_id, rank => $next_priority })
1362     } elsif ( $where eq 'top' ) {
1363       _FixPriority({ reserve_id => $reserve_id, rank => $first_priority })
1364     } elsif ( $where eq 'bottom' ) {
1365       _FixPriority({ reserve_id => $reserve_id, rank => $last_priority });
1366     }
1367
1368     # FIXME Should return the new priority
1369 }
1370
1371 =head2 ToggleLowestPriority
1372
1373   ToggleLowestPriority( $borrowernumber, $biblionumber );
1374
1375 This function sets the lowestPriority field to true if is false, and false if it is true.
1376
1377 =cut
1378
1379 sub ToggleLowestPriority {
1380     my ( $reserve_id ) = @_;
1381
1382     my $dbh = C4::Context->dbh;
1383
1384     my $sth = $dbh->prepare( "UPDATE reserves SET lowestPriority = NOT lowestPriority WHERE reserve_id = ?");
1385     $sth->execute( $reserve_id );
1386
1387     _FixPriority({ reserve_id => $reserve_id, rank => '999999' });
1388 }
1389
1390 =head2 ToggleSuspend
1391
1392   ToggleSuspend( $reserve_id );
1393
1394 This function sets the suspend field to true if is false, and false if it is true.
1395 If the reserve is currently suspended with a suspend_until date, that date will
1396 be cleared when it is unsuspended.
1397
1398 =cut
1399
1400 sub ToggleSuspend {
1401     my ( $reserve_id, $suspend_until ) = @_;
1402
1403     $suspend_until = dt_from_string($suspend_until) if ($suspend_until);
1404
1405     my $hold = Koha::Holds->find( $reserve_id );
1406
1407     if ( $hold->is_suspended ) {
1408         $hold->resume()
1409     } else {
1410         $hold->suspend_hold( $suspend_until );
1411     }
1412 }
1413
1414 =head2 SuspendAll
1415
1416   SuspendAll(
1417       borrowernumber   => $borrowernumber,
1418       [ biblionumber   => $biblionumber, ]
1419       [ suspend_until  => $suspend_until, ]
1420       [ suspend        => $suspend ]
1421   );
1422
1423   This function accepts a set of hash keys as its parameters.
1424   It requires either borrowernumber or biblionumber, or both.
1425
1426   suspend_until is wholly optional.
1427
1428 =cut
1429
1430 sub SuspendAll {
1431     my %params = @_;
1432
1433     my $borrowernumber = $params{'borrowernumber'} || undef;
1434     my $biblionumber   = $params{'biblionumber'}   || undef;
1435     my $suspend_until  = $params{'suspend_until'}  || undef;
1436     my $suspend = defined( $params{'suspend'} ) ? $params{'suspend'} : 1;
1437
1438     $suspend_until = eval { dt_from_string($suspend_until) }
1439       if ( defined($suspend_until) );
1440
1441     return unless ( $borrowernumber || $biblionumber );
1442
1443     my $params;
1444     $params->{found}          = undef;
1445     $params->{borrowernumber} = $borrowernumber if $borrowernumber;
1446     $params->{biblionumber}   = $biblionumber if $biblionumber;
1447
1448     my @holds = Koha::Holds->search($params);
1449
1450     if ($suspend) {
1451         map { $_->suspend_hold($suspend_until) } @holds;
1452     }
1453     else {
1454         map { $_->resume() } @holds;
1455     }
1456 }
1457
1458
1459 =head2 _FixPriority
1460
1461   _FixPriority({
1462     reserve_id => $reserve_id,
1463     [rank => $rank,]
1464     [ignoreSetLowestRank => $ignoreSetLowestRank]
1465   });
1466
1467   or
1468
1469   _FixPriority({ biblionumber => $biblionumber});
1470
1471 This routine adjusts the priority of a hold request and holds
1472 on the same bib.
1473
1474 In the first form, where a reserve_id is passed, the priority of the
1475 hold is set to supplied rank, and other holds for that bib are adjusted
1476 accordingly.  If the rank is "del", the hold is cancelled.  If no rank
1477 is supplied, all of the holds on that bib have their priority adjusted
1478 as if the second form had been used.
1479
1480 In the second form, where a biblionumber is passed, the holds on that
1481 bib (that are not captured) are sorted in order of increasing priority,
1482 then have reserves.priority set so that the first non-captured hold
1483 has its priority set to 1, the second non-captured hold has its priority
1484 set to 2, and so forth.
1485
1486 In both cases, holds that have the lowestPriority flag on are have their
1487 priority adjusted to ensure that they remain at the end of the line.
1488
1489 Note that the ignoreSetLowestRank parameter is meant to be used only
1490 when _FixPriority calls itself.
1491
1492 =cut
1493
1494 sub _FixPriority {
1495     my ( $params ) = @_;
1496     my $reserve_id = $params->{reserve_id};
1497     my $rank = $params->{rank} // '';
1498     my $ignoreSetLowestRank = $params->{ignoreSetLowestRank};
1499     my $biblionumber = $params->{biblionumber};
1500
1501     my $dbh = C4::Context->dbh;
1502
1503     my $hold;
1504     if ( $reserve_id ) {
1505         $hold = Koha::Holds->find( $reserve_id );
1506         if (!defined $hold){
1507             # may have already been checked out and hold fulfilled
1508             $hold = Koha::Old::Holds->find( $reserve_id );
1509         }
1510         return unless $hold;
1511     }
1512
1513     unless ( $biblionumber ) { # FIXME This is a very weird API
1514         $biblionumber = $hold->biblionumber;
1515     }
1516
1517     if ( $rank eq "del" ) { # FIXME will crash if called without $hold
1518         $hold->cancel;
1519     }
1520     elsif ( $reserve_id && ( $rank eq "W" || $rank eq "0" ) ) {
1521
1522         # make sure priority for waiting or in-transit items is 0
1523         my $query = "
1524             UPDATE reserves
1525             SET    priority = 0
1526             WHERE reserve_id = ?
1527             AND found IN ('W', 'T')
1528         ";
1529         my $sth = $dbh->prepare($query);
1530         $sth->execute( $reserve_id );
1531     }
1532     my @priority;
1533
1534     # get whats left
1535     my $query = "
1536         SELECT reserve_id, borrowernumber, reservedate
1537         FROM   reserves
1538         WHERE  biblionumber   = ?
1539           AND  ((found <> 'W' AND found <> 'T') OR found IS NULL)
1540         ORDER BY priority ASC
1541     ";
1542     my $sth = $dbh->prepare($query);
1543     $sth->execute( $biblionumber );
1544     while ( my $line = $sth->fetchrow_hashref ) {
1545         push( @priority,     $line );
1546     }
1547
1548     # FIXME This whole sub must be rewritten, especially to highlight what is done when reserve_id is not given
1549     # To find the matching index
1550     my $i;
1551     my $key = -1;    # to allow for 0 to be a valid result
1552     for ( $i = 0 ; $i < @priority ; $i++ ) {
1553         if ( $reserve_id && $reserve_id == $priority[$i]->{'reserve_id'} ) {
1554             $key = $i;    # save the index
1555             last;
1556         }
1557     }
1558
1559     # if index exists in array then move it to new position
1560     if ( $key > -1 && $rank ne 'del' && $rank > 0 ) {
1561         my $new_rank = $rank -
1562           1;    # $new_rank is what you want the new index to be in the array
1563         my $moving_item = splice( @priority, $key, 1 );
1564         splice( @priority, $new_rank, 0, $moving_item );
1565     }
1566
1567     # now fix the priority on those that are left....
1568     $query = "
1569         UPDATE reserves
1570         SET    priority = ?
1571         WHERE  reserve_id = ?
1572     ";
1573     $sth = $dbh->prepare($query);
1574     for ( my $j = 0 ; $j < @priority ; $j++ ) {
1575         $sth->execute(
1576             $j + 1,
1577             $priority[$j]->{'reserve_id'}
1578         );
1579     }
1580
1581     $sth = $dbh->prepare( "SELECT reserve_id FROM reserves WHERE lowestPriority = 1 ORDER BY priority" );
1582     $sth->execute();
1583
1584     unless ( $ignoreSetLowestRank ) {
1585       while ( my $res = $sth->fetchrow_hashref() ) {
1586         _FixPriority({
1587             reserve_id => $res->{'reserve_id'},
1588             rank => '999999',
1589             ignoreSetLowestRank => 1
1590         });
1591       }
1592     }
1593 }
1594
1595 =head2 _Findgroupreserve
1596
1597   @results = &_Findgroupreserve($biblioitemnumber, $biblionumber, $itemnumber, $lookahead, $ignore_borrowers);
1598
1599 Looks for a holds-queue based item-specific match first, then for a holds-queue title-level match, returning the
1600 first match found.  If neither, then we look for non-holds-queue based holds.
1601 Lookahead is the number of days to look in advance.
1602
1603 C<&_Findgroupreserve> returns :
1604 C<@results> is an array of references-to-hash whose keys are mostly
1605 fields from the reserves table of the Koha database, plus
1606 C<biblioitemnumber>.
1607
1608 This routine with either return:
1609 1 - Item specific holds from the holds queue
1610 2 - Title level holds from the holds queue
1611 3 - All holds for this biblionumber
1612
1613 All return values will respect any borrowernumbers passed as arrayref in $ignore_borrowers
1614
1615 =cut
1616
1617 sub _Findgroupreserve {
1618     my ( $bibitem, $biblio, $itemnumber, $lookahead, $ignore_borrowers) = @_;
1619     my $dbh   = C4::Context->dbh;
1620
1621     # TODO: consolidate at least the SELECT portion of the first 2 queries to a common $select var.
1622     # check for exact targeted match
1623     my $item_level_target_query = qq{
1624         SELECT reserves.biblionumber        AS biblionumber,
1625                reserves.borrowernumber      AS borrowernumber,
1626                reserves.reservedate         AS reservedate,
1627                reserves.branchcode          AS branchcode,
1628                reserves.cancellationdate    AS cancellationdate,
1629                reserves.found               AS found,
1630                reserves.reservenotes        AS reservenotes,
1631                reserves.priority            AS priority,
1632                reserves.timestamp           AS timestamp,
1633                biblioitems.biblioitemnumber AS biblioitemnumber,
1634                reserves.itemnumber          AS itemnumber,
1635                reserves.reserve_id          AS reserve_id,
1636                reserves.itemtype            AS itemtype
1637         FROM reserves
1638         JOIN biblioitems USING (biblionumber)
1639         JOIN hold_fill_targets USING (biblionumber, borrowernumber, itemnumber)
1640         WHERE found IS NULL
1641         AND priority > 0
1642         AND item_level_request = 1
1643         AND itemnumber = ?
1644         AND reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1645         AND suspend = 0
1646         ORDER BY priority
1647     };
1648     my $sth = $dbh->prepare($item_level_target_query);
1649     $sth->execute($itemnumber, $lookahead||0);
1650     my @results;
1651     if ( my $data = $sth->fetchrow_hashref ) {
1652         push( @results, $data )
1653           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1654     }
1655     return @results if @results;
1656
1657     # check for title-level targeted match
1658     my $title_level_target_query = qq{
1659         SELECT reserves.biblionumber        AS biblionumber,
1660                reserves.borrowernumber      AS borrowernumber,
1661                reserves.reservedate         AS reservedate,
1662                reserves.branchcode          AS branchcode,
1663                reserves.cancellationdate    AS cancellationdate,
1664                reserves.found               AS found,
1665                reserves.reservenotes        AS reservenotes,
1666                reserves.priority            AS priority,
1667                reserves.timestamp           AS timestamp,
1668                biblioitems.biblioitemnumber AS biblioitemnumber,
1669                reserves.itemnumber          AS itemnumber,
1670                reserves.reserve_id          AS reserve_id,
1671                reserves.itemtype            AS itemtype
1672         FROM reserves
1673         JOIN biblioitems USING (biblionumber)
1674         JOIN hold_fill_targets USING (biblionumber, borrowernumber)
1675         WHERE found IS NULL
1676         AND priority > 0
1677         AND item_level_request = 0
1678         AND hold_fill_targets.itemnumber = ?
1679         AND reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1680         AND suspend = 0
1681         ORDER BY priority
1682     };
1683     $sth = $dbh->prepare($title_level_target_query);
1684     $sth->execute($itemnumber, $lookahead||0);
1685     @results = ();
1686     if ( my $data = $sth->fetchrow_hashref ) {
1687         push( @results, $data )
1688           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1689     }
1690     return @results if @results;
1691
1692     my $query = qq{
1693         SELECT reserves.biblionumber               AS biblionumber,
1694                reserves.borrowernumber             AS borrowernumber,
1695                reserves.reservedate                AS reservedate,
1696                reserves.waitingdate                AS waitingdate,
1697                reserves.branchcode                 AS branchcode,
1698                reserves.cancellationdate           AS cancellationdate,
1699                reserves.found                      AS found,
1700                reserves.reservenotes               AS reservenotes,
1701                reserves.priority                   AS priority,
1702                reserves.timestamp                  AS timestamp,
1703                reserves.itemnumber                 AS itemnumber,
1704                reserves.reserve_id                 AS reserve_id,
1705                reserves.itemtype                   AS itemtype
1706         FROM reserves
1707         WHERE reserves.biblionumber = ?
1708           AND (reserves.itemnumber IS NULL OR reserves.itemnumber = ?)
1709           AND reserves.reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1710           AND suspend = 0
1711           ORDER BY priority
1712     };
1713     $sth = $dbh->prepare($query);
1714     $sth->execute( $biblio, $itemnumber, $lookahead||0);
1715     @results = ();
1716     while ( my $data = $sth->fetchrow_hashref ) {
1717         push( @results, $data )
1718           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1719     }
1720     return @results;
1721 }
1722
1723 =head2 _koha_notify_reserve
1724
1725   _koha_notify_reserve( $hold->reserve_id );
1726
1727 Sends a notification to the patron that their hold has been filled (through
1728 ModReserveAffect, _not_ ModReserveFill)
1729
1730 The letter code for this notice may be found using the following query:
1731
1732     select distinct letter_code
1733     from message_transports
1734     inner join message_attributes using (message_attribute_id)
1735     where message_name = 'Hold_Filled'
1736
1737 This will probably sipmly be 'HOLD', but because it is defined in the database,
1738 it is subject to addition or change.
1739
1740 The following tables are availalbe witin the notice:
1741
1742     branches
1743     borrowers
1744     biblio
1745     biblioitems
1746     reserves
1747     items
1748
1749 =cut
1750
1751 sub _koha_notify_reserve {
1752     my $reserve_id = shift;
1753     my $hold = Koha::Holds->find($reserve_id);
1754     my $borrowernumber = $hold->borrowernumber;
1755
1756     my $patron = Koha::Patrons->find( $borrowernumber );
1757
1758     # Try to get the borrower's email address
1759     my $to_address = $patron->notice_email_address;
1760
1761     my $messagingprefs = C4::Members::Messaging::GetMessagingPreferences( {
1762             borrowernumber => $borrowernumber,
1763             message_name => 'Hold_Filled'
1764     } );
1765
1766     my $library = Koha::Libraries->find( $hold->branchcode )->unblessed;
1767
1768     my $admin_email_address = $library->{branchemail} || C4::Context->preference('KohaAdminEmailAddress');
1769
1770     my %letter_params = (
1771         module => 'reserves',
1772         branchcode => $hold->branchcode,
1773         lang => $patron->lang,
1774         tables => {
1775             'branches'       => $library,
1776             'borrowers'      => $patron->unblessed,
1777             'biblio'         => $hold->biblionumber,
1778             'biblioitems'    => $hold->biblionumber,
1779             'reserves'       => $hold->unblessed,
1780             'items'          => $hold->itemnumber,
1781         },
1782     );
1783
1784     my $notification_sent = 0; #Keeping track if a Hold_filled message is sent. If no message can be sent, then default to a print message.
1785     my $send_notification = sub {
1786         my ( $mtt, $letter_code ) = (@_);
1787         return unless defined $letter_code;
1788         $letter_params{letter_code} = $letter_code;
1789         $letter_params{message_transport_type} = $mtt;
1790         my $letter =  C4::Letters::GetPreparedLetter ( %letter_params );
1791         unless ($letter) {
1792             warn "Could not find a letter called '$letter_params{'letter_code'}' for $mtt in the 'reserves' module";
1793             return;
1794         }
1795
1796         C4::Letters::EnqueueLetter( {
1797             letter => $letter,
1798             borrowernumber => $borrowernumber,
1799             from_address => $admin_email_address,
1800             message_transport_type => $mtt,
1801         } );
1802     };
1803
1804     while ( my ( $mtt, $letter_code ) = each %{ $messagingprefs->{transports} } ) {
1805         next if (
1806                ( $mtt eq 'email' and not $to_address ) # No email address
1807             or ( $mtt eq 'sms'   and not $patron->smsalertnumber ) # No SMS number
1808             or ( $mtt eq 'phone' and C4::Context->preference('TalkingTechItivaPhoneNotification') ) # Notice is handled by TalkingTech_itiva_outbound.pl
1809         );
1810
1811         &$send_notification($mtt, $letter_code);
1812         $notification_sent++;
1813     }
1814     #Making sure that a print notification is sent if no other transport types can be utilized.
1815     if (! $notification_sent) {
1816         &$send_notification('print', 'HOLD');
1817     }
1818
1819 }
1820
1821 =head2 _ShiftPriorityByDateAndPriority
1822
1823   $new_priority = _ShiftPriorityByDateAndPriority( $biblionumber, $reservedate, $priority );
1824
1825 This increments the priority of all reserves after the one
1826 with either the lowest date after C<$reservedate>
1827 or the lowest priority after C<$priority>.
1828
1829 It effectively makes room for a new reserve to be inserted with a certain
1830 priority, which is returned.
1831
1832 This is most useful when the reservedate can be set by the user.  It allows
1833 the new reserve to be placed before other reserves that have a later
1834 reservedate.  Since priority also is set by the form in reserves/request.pl
1835 the sub accounts for that too.
1836
1837 =cut
1838
1839 sub _ShiftPriorityByDateAndPriority {
1840     my ( $biblio, $resdate, $new_priority ) = @_;
1841
1842     my $dbh = C4::Context->dbh;
1843     my $query = "SELECT priority FROM reserves WHERE biblionumber = ? AND ( reservedate > ? OR priority > ? ) ORDER BY priority ASC LIMIT 1";
1844     my $sth = $dbh->prepare( $query );
1845     $sth->execute( $biblio, $resdate, $new_priority );
1846     my $min_priority = $sth->fetchrow;
1847     # if no such matches are found, $new_priority remains as original value
1848     $new_priority = $min_priority if ( $min_priority );
1849
1850     # Shift the priority up by one; works in conjunction with the next SQL statement
1851     $query = "UPDATE reserves
1852               SET priority = priority+1
1853               WHERE biblionumber = ?
1854               AND borrowernumber = ?
1855               AND reservedate = ?
1856               AND found IS NULL";
1857     my $sth_update = $dbh->prepare( $query );
1858
1859     # Select all reserves for the biblio with priority greater than $new_priority, and order greatest to least
1860     $query = "SELECT borrowernumber, reservedate FROM reserves WHERE priority >= ? AND biblionumber = ? ORDER BY priority DESC";
1861     $sth = $dbh->prepare( $query );
1862     $sth->execute( $new_priority, $biblio );
1863     while ( my $row = $sth->fetchrow_hashref ) {
1864         $sth_update->execute( $biblio, $row->{borrowernumber}, $row->{reservedate} );
1865     }
1866
1867     return $new_priority;  # so the caller knows what priority they wind up receiving
1868 }
1869
1870 =head2 MoveReserve
1871
1872   MoveReserve( $itemnumber, $borrowernumber, $cancelreserve )
1873
1874 Use when checking out an item to handle reserves
1875 If $cancelreserve boolean is set to true, it will remove existing reserve
1876
1877 =cut
1878
1879 sub MoveReserve {
1880     my ( $itemnumber, $borrowernumber, $cancelreserve ) = @_;
1881
1882     $cancelreserve //= 0;
1883
1884     my $lookahead = C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
1885     my ( $restype, $res, undef ) = CheckReserves( $itemnumber, undef, $lookahead );
1886     return unless $res;
1887
1888     my $biblionumber     =  $res->{biblionumber};
1889
1890     if ($res->{borrowernumber} == $borrowernumber) {
1891         ModReserveFill($res);
1892     }
1893     else {
1894         # warn "Reserved";
1895         # The item is reserved by someone else.
1896         # Find this item in the reserves
1897
1898         my $borr_res  = Koha::Holds->search({
1899             borrowernumber => $borrowernumber,
1900             biblionumber   => $biblionumber,
1901         },{
1902             order_by       => 'priority'
1903         })->next();
1904
1905         if ( $borr_res ) {
1906             # The item is reserved by the current patron
1907             ModReserveFill($borr_res->unblessed);
1908         }
1909
1910         if ( $cancelreserve eq 'revert' ) { ## Revert waiting reserve to priority 1
1911             RevertWaitingStatus({ itemnumber => $itemnumber });
1912         }
1913         elsif ( $cancelreserve eq 'cancel' || $cancelreserve ) { # cancel reserves on this item
1914             my $hold = Koha::Holds->find( $res->{reserve_id} );
1915             $hold->cancel;
1916         }
1917     }
1918 }
1919
1920 =head2 MergeHolds
1921
1922   MergeHolds($dbh,$to_biblio, $from_biblio);
1923
1924 This shifts the holds from C<$from_biblio> to C<$to_biblio> and reorders them by the date they were placed
1925
1926 =cut
1927
1928 sub MergeHolds {
1929     my ( $dbh, $to_biblio, $from_biblio ) = @_;
1930     my $sth = $dbh->prepare(
1931         "SELECT count(*) as reserve_count FROM reserves WHERE biblionumber = ?"
1932     );
1933     $sth->execute($from_biblio);
1934     if ( my $data = $sth->fetchrow_hashref() ) {
1935
1936         # holds exist on old record, if not we don't need to do anything
1937         $sth = $dbh->prepare(
1938             "UPDATE reserves SET biblionumber = ? WHERE biblionumber = ?");
1939         $sth->execute( $to_biblio, $from_biblio );
1940
1941         # Reorder by date
1942         # don't reorder those already waiting
1943
1944         $sth = $dbh->prepare(
1945 "SELECT * FROM reserves WHERE biblionumber = ? AND (found <> ? AND found <> ? OR found is NULL) ORDER BY reservedate ASC"
1946         );
1947         my $upd_sth = $dbh->prepare(
1948 "UPDATE reserves SET priority = ? WHERE biblionumber = ? AND borrowernumber = ?
1949         AND reservedate = ? AND (itemnumber = ? or itemnumber is NULL) "
1950         );
1951         $sth->execute( $to_biblio, 'W', 'T' );
1952         my $priority = 1;
1953         while ( my $reserve = $sth->fetchrow_hashref() ) {
1954             $upd_sth->execute(
1955                 $priority,                    $to_biblio,
1956                 $reserve->{'borrowernumber'}, $reserve->{'reservedate'},
1957                 $reserve->{'itemnumber'}
1958             );
1959             $priority++;
1960         }
1961     }
1962 }
1963
1964 =head2 RevertWaitingStatus
1965
1966   RevertWaitingStatus({ itemnumber => $itemnumber });
1967
1968   Reverts a 'waiting' hold back to a regular hold with a priority of 1.
1969
1970   Caveat: Any waiting hold fixed with RevertWaitingStatus will be an
1971           item level hold, even if it was only a bibliolevel hold to
1972           begin with. This is because we can no longer know if a hold
1973           was item-level or bib-level after a hold has been set to
1974           waiting status.
1975
1976 =cut
1977
1978 sub RevertWaitingStatus {
1979     my ( $params ) = @_;
1980     my $itemnumber = $params->{'itemnumber'};
1981
1982     return unless ( $itemnumber );
1983
1984     my $dbh = C4::Context->dbh;
1985
1986     ## Get the waiting reserve we want to revert
1987     my $query = "
1988         SELECT * FROM reserves
1989         WHERE itemnumber = ?
1990         AND found IS NOT NULL
1991     ";
1992     my $sth = $dbh->prepare( $query );
1993     $sth->execute( $itemnumber );
1994     my $reserve = $sth->fetchrow_hashref();
1995
1996     my $hold = Koha::Holds->find( $reserve->{reserve_id} ); # TODO Remove the next raw SQL statements and use this instead
1997
1998     ## Increment the priority of all other non-waiting
1999     ## reserves for this bib record
2000     $query = "
2001         UPDATE reserves
2002         SET
2003           priority = priority + 1
2004         WHERE
2005           biblionumber =  ?
2006         AND
2007           priority > 0
2008     ";
2009     $sth = $dbh->prepare( $query );
2010     $sth->execute( $reserve->{'biblionumber'} );
2011
2012     $hold->set(
2013         {
2014             priority    => 1,
2015             found       => undef,
2016             waitingdate => undef,
2017             itemnumber  => $hold->item_level_hold ? $hold->itemnumber : undef,
2018         }
2019     )->store();
2020
2021     _FixPriority( { biblionumber => $reserve->{biblionumber} } );
2022
2023     return $hold;
2024 }
2025
2026 =head2 ReserveSlip
2027
2028 ReserveSlip(
2029     {
2030         branchcode     => $branchcode,
2031         borrowernumber => $borrowernumber,
2032         biblionumber   => $biblionumber,
2033         [ itemnumber   => $itemnumber, ]
2034         [ barcode      => $barcode, ]
2035     }
2036   )
2037
2038 Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
2039
2040 The letter code will be HOLD_SLIP, and the following tables are
2041 available within the slip:
2042
2043     reserves
2044     branches
2045     borrowers
2046     biblio
2047     biblioitems
2048     items
2049
2050 =cut
2051
2052 sub ReserveSlip {
2053     my ($args) = @_;
2054     my $branchcode     = $args->{branchcode};
2055     my $borrowernumber = $args->{borrowernumber};
2056     my $biblionumber   = $args->{biblionumber};
2057     my $itemnumber     = $args->{itemnumber};
2058     my $barcode        = $args->{barcode};
2059
2060
2061     my $patron = Koha::Patrons->find($borrowernumber);
2062
2063     my $hold;
2064     if ($itemnumber || $barcode ) {
2065         $itemnumber ||= Koha::Items->find( { barcode => $barcode } )->itemnumber;
2066
2067         $hold = Koha::Holds->search(
2068             {
2069                 biblionumber   => $biblionumber,
2070                 borrowernumber => $borrowernumber,
2071                 itemnumber     => $itemnumber
2072             }
2073         )->next;
2074     }
2075     else {
2076         $hold = Koha::Holds->search(
2077             {
2078                 biblionumber   => $biblionumber,
2079                 borrowernumber => $borrowernumber
2080             }
2081         )->next;
2082     }
2083
2084     return unless $hold;
2085     my $reserve = $hold->unblessed;
2086
2087     return  C4::Letters::GetPreparedLetter (
2088         module => 'circulation',
2089         letter_code => 'HOLD_SLIP',
2090         branchcode => $branchcode,
2091         lang => $patron->lang,
2092         tables => {
2093             'reserves'    => $reserve,
2094             'branches'    => $reserve->{branchcode},
2095             'borrowers'   => $reserve->{borrowernumber},
2096             'biblio'      => $reserve->{biblionumber},
2097             'biblioitems' => $reserve->{biblionumber},
2098             'items'       => $reserve->{itemnumber},
2099         },
2100     );
2101 }
2102
2103 =head2 GetReservesControlBranch
2104
2105   my $reserves_control_branch = GetReservesControlBranch($item, $borrower);
2106
2107   Return the branchcode to be used to determine which reserves
2108   policy applies to a transaction.
2109
2110   C<$item> is a hashref for an item. Only 'homebranch' is used.
2111
2112   C<$borrower> is a hashref to borrower. Only 'branchcode' is used.
2113
2114 =cut
2115
2116 sub GetReservesControlBranch {
2117     my ( $item, $borrower ) = @_;
2118
2119     my $reserves_control = C4::Context->preference('ReservesControlBranch');
2120
2121     my $branchcode =
2122         ( $reserves_control eq 'ItemHomeLibrary' ) ? $item->{'homebranch'}
2123       : ( $reserves_control eq 'PatronLibrary' )   ? $borrower->{'branchcode'}
2124       :                                              undef;
2125
2126     return $branchcode;
2127 }
2128
2129 =head2 CalculatePriority
2130
2131     my $p = CalculatePriority($biblionumber, $resdate);
2132
2133 Calculate priority for a new reserve on biblionumber, placing it at
2134 the end of the line of all holds whose start date falls before
2135 the current system time and that are neither on the hold shelf
2136 or in transit.
2137
2138 The reserve date parameter is optional; if it is supplied, the
2139 priority is based on the set of holds whose start date falls before
2140 the parameter value.
2141
2142 After calculation of this priority, it is recommended to call
2143 _ShiftPriorityByDateAndPriority. Note that this is currently done in
2144 AddReserves.
2145
2146 =cut
2147
2148 sub CalculatePriority {
2149     my ( $biblionumber, $resdate ) = @_;
2150
2151     my $sql = q{
2152         SELECT COUNT(*) FROM reserves
2153         WHERE biblionumber = ?
2154         AND   priority > 0
2155         AND   (found IS NULL OR found = '')
2156     };
2157     #skip found==W or found==T (waiting or transit holds)
2158     if( $resdate ) {
2159         $sql.= ' AND ( reservedate <= ? )';
2160     }
2161     else {
2162         $sql.= ' AND ( reservedate < NOW() )';
2163     }
2164     my $dbh = C4::Context->dbh();
2165     my @row = $dbh->selectrow_array(
2166         $sql,
2167         undef,
2168         $resdate ? ($biblionumber, $resdate) : ($biblionumber)
2169     );
2170
2171     return @row ? $row[0]+1 : 1;
2172 }
2173
2174 =head2 IsItemOnHoldAndFound
2175
2176     my $bool = IsItemFoundHold( $itemnumber );
2177
2178     Returns true if the item is currently on hold
2179     and that hold has a non-null found status ( W, T, etc. )
2180
2181 =cut
2182
2183 sub IsItemOnHoldAndFound {
2184     my ($itemnumber) = @_;
2185
2186     my $rs = Koha::Database->new()->schema()->resultset('Reserve');
2187
2188     my $found = $rs->count(
2189         {
2190             itemnumber => $itemnumber,
2191             found      => { '!=' => undef }
2192         }
2193     );
2194
2195     return $found;
2196 }
2197
2198 =head2 GetMaxPatronHoldsForRecord
2199
2200 my $holds_per_record = ReservesControlBranch( $borrowernumber, $biblionumber );
2201
2202 For multiple holds on a given record for a given patron, the max
2203 number of record level holds that a patron can be placed is the highest
2204 value of the holds_per_record rule for each item if the record for that
2205 patron. This subroutine finds and returns the highest holds_per_record
2206 rule value for a given patron id and record id.
2207
2208 =cut
2209
2210 sub GetMaxPatronHoldsForRecord {
2211     my ( $borrowernumber, $biblionumber ) = @_;
2212
2213     my $patron = Koha::Patrons->find($borrowernumber);
2214     my @items = Koha::Items->search( { biblionumber => $biblionumber } );
2215
2216     my $controlbranch = C4::Context->preference('ReservesControlBranch');
2217
2218     my $categorycode = $patron->categorycode;
2219     my $branchcode;
2220     $branchcode = $patron->branchcode if ( $controlbranch eq "PatronLibrary" );
2221
2222     my $max = 0;
2223     foreach my $item (@items) {
2224         my $itemtype = $item->effective_itemtype();
2225
2226         $branchcode = $item->homebranch if ( $controlbranch eq "ItemHomeLibrary" );
2227
2228         my $rule = GetHoldRule( $categorycode, $itemtype, $branchcode );
2229         my $holds_per_record = $rule ? $rule->{holds_per_record} : 0;
2230         $max = $holds_per_record if $holds_per_record > $max;
2231     }
2232
2233     return $max;
2234 }
2235
2236 =head2 GetHoldRule
2237
2238 my $rule = GetHoldRule( $categorycode, $itemtype, $branchcode );
2239
2240 Returns the matching hold related issuingrule fields for a given
2241 patron category, itemtype, and library.
2242
2243 =cut
2244
2245 sub GetHoldRule {
2246     my ( $categorycode, $itemtype, $branchcode ) = @_;
2247
2248     my $reservesallowed = Koha::CirculationRules->get_effective_rule(
2249         {
2250             itemtype     => $itemtype,
2251             categorycode => $categorycode,
2252             branchcode   => $branchcode,
2253             rule_name    => 'reservesallowed',
2254             order_by     => {
2255                 -desc => [ 'categorycode', 'itemtype', 'branchcode' ]
2256             }
2257         }
2258     );
2259
2260     my $rules;
2261     if ( $reservesallowed ) {
2262         $rules->{reservesallowed} = $reservesallowed->rule_value;
2263         $rules->{itemtype}        = $reservesallowed->itemtype;
2264         $rules->{categorycode}    = $reservesallowed->categorycode;
2265         $rules->{branchcode}      = $reservesallowed->branchcode;
2266     }
2267
2268     my $holds_per_x_rules = Koha::CirculationRules->get_effective_rules(
2269         {
2270             itemtype     => $itemtype,
2271             categorycode => $categorycode,
2272             branchcode   => $branchcode,
2273             rules        => ['holds_per_record', 'holds_per_day'],
2274             order_by     => {
2275                 -desc => [ 'categorycode', 'itemtype', 'branchcode' ]
2276             }
2277         }
2278     );
2279     $rules->{holds_per_record} = $holds_per_x_rules->{holds_per_record};
2280     $rules->{holds_per_day} = $holds_per_x_rules->{holds_per_day};
2281
2282     return $rules;
2283 }
2284
2285 =head1 AUTHOR
2286
2287 Koha Development Team <http://koha-community.org/>
2288
2289 =cut
2290
2291 1;