virtualshelves/sendshelf.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 BibLibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23 use Encode qw( encode );
  24 use Carp;
  25
  26 use Mail::Sendmail;
  27 use MIME::QuotedPrint;
  28 use MIME::Base64;
  29 use C4::Auth;
  30 use C4::Biblio;
  31 use C4::Items;
  32 use C4::Output;
  33 use Koha::Email;
  34 use Koha::Virtualshelves;
  35
  36 my $query = new CGI;
  37
  38 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  39     {
  40         template_name   => "virtualshelves/sendshelfform.tt",
  41         query           => $query,
  42         type            => "intranet",
  43         authnotrequired => 0,
  44         flagsrequired   => { catalogue => 1 },
  45     }
  46 );
  47
  48 my $shelfid = $query->param('shelfid');
  49 my $email   = $query->param('email');
  50
  51 my $dbh = C4::Context->dbh;
  52
  53 if ($email) {
  54     my $comment = $query->param('comment');
  55     my $message = Koha::Email->new();
  56     my %mail    = $message->create_message_headers(
  57         {
  58             to => $email
  59         }
  60     );
  61
  62     my ( $template2, $borrowernumber, $cookie ) = get_template_and_user(
  63         {
  64         template_name   => "virtualshelves/sendshelf.tt",
  65         query           => $query,
  66         type            => "intranet",
  67         authnotrequired => 0,
  68         flagsrequired   => { catalogue => 1 },
  69         }
  70     );
  71
  72     my $shelf = Koha::Virtualshelves->find( $shelfid );
  73     my $contents = $shelf->get_contents;
  74     my $marcflavour = C4::Context->preference('marcflavour');
  75     my $iso2709;
  76     my @results;
  77
  78     while ( my $content = $contents->next ) {
  79         my $biblionumber     = $content->biblionumber;
  80         my $fw               = GetFrameworkCode($biblionumber);
  81         my $dat              = GetBiblioData($biblionumber);
  82         my $record           = GetMarcBiblio({
  83             biblionumber => $biblionumber,
  84             embed_items  => 1 });
  85         my $marcauthorsarray = GetMarcAuthors( $record, $marcflavour );
  86         my $marcsubjctsarray = GetMarcSubjects( $record, $marcflavour );
  87         my $subtitle         = GetRecordValue( 'subtitle', $record, $fw );
  88
  89         my @items = GetItemsInfo($biblionumber);
  90
  91         $dat->{ISBN}           = GetMarcISBN($record, $marcflavour);
  92         $dat->{MARCSUBJCTS}    = $marcsubjctsarray;
  93         $dat->{MARCAUTHORS}    = $marcauthorsarray;
  94         $dat->{'biblionumber'} = $biblionumber;
  95         $dat->{ITEM_RESULTS}   = \@items;
  96         $dat->{subtitle}       = $subtitle;
  97         $dat->{HASAUTHORS}     = $dat->{'author'} || @$marcauthorsarray;
  98
  99         $iso2709 .= $record->as_usmarc();
 100
 101         push( @results, $dat );
 102     }
 103
 104     $template2->param(
 105         BIBLIO_RESULTS => \@results,
 106         comment        => $comment,
 107         shelfname      => $shelf->shelfname,
 108     );
 109
 110     # Getting template result
 111     my $template_res = $template2->output();
 112     my $body;
 113
 114     # Analysing information and getting mail properties
 115     if ( $template_res =~ /<SUBJECT>(.*)<END_SUBJECT>/s ) {
 116         $mail{'subject'} = Encode::encode("UTF-8", $1);
 117         $mail{subject} =~ s|\n?(.*)\n?|$1|;
 118     }
 119     else { $mail{'subject'} = "no subject"; }
 120
 121     my $email_header = "";
 122     if ( $template_res =~ /<HEADER>(.*)<END_HEADER>/s ) {
 123         $email_header = $1;
 124         $email_header =~ s|\n?(.*)\n?|$1|;
 125         $email_header = encode_qp(Encode::encode("UTF-8", $email_header));
 126     }
 127
 128     my $email_file = "list.txt";
 129     if ( $template_res =~ /<FILENAME>(.*)<END_FILENAME>/s ) {
 130         $email_file = $1;
 131         $email_file =~ s|\n?(.*)\n?|$1|;
 132     }
 133
 134     if ( $template_res =~ /<MESSAGE>(.*)<END_MESSAGE>/s ) {
 135         $body = $1;
 136         $body =~ s|\n?(.*)\n?|$1|;
 137         $body = encode_qp(Encode::encode("UTF-8", $body));
 138     }
 139
 140     my $boundary = "====" . time() . "====";
 141
 142     # We set and put the multipart content
 143     $mail{'content-type'} = "multipart/mixed; boundary=\"$boundary\"";
 144
 145     my $isofile = encode_base64( encode( "UTF-8", $iso2709 ) );
 146     $boundary = '--' . $boundary;
 147
 148     $mail{body} = <<END_OF_BODY;
 149 $boundary
 150 Content-Type: text/plain; charset="utf-8"
 151 Content-Transfer-Encoding: quoted-printable
 152
 153 $email_header
 154 $body
 155 $boundary
 156 Content-Type: application/octet-stream; name="shelf.iso2709"
 157 Content-Transfer-Encoding: base64
 158 Content-Disposition: attachment; filename="shelf.iso2709"
 159
 160 $isofile
 161 $boundary--
 162 END_OF_BODY
 163
 164     # Sending mail
 165     if ( sendmail %mail ) {
 166
 167         # do something if it works....
 168         $template->param( SENT => "1" );
 169     }
 170     else {
 171         # do something if it doesn't work....
 172         carp "Error sending mail: $Mail::Sendmail::error \n";
 173         $template->param( error => 1 );
 174     }
 175
 176     $template->param( email => $email );
 177     output_html_with_http_headers $query, $cookie, $template->output;
 178
 179 }
 180 else {
 181     $template->param(
 182         shelfid => $shelfid,
 183         url     => "/cgi-bin/koha/virtualshelves/sendshelf.pl",
 184     );
 185     output_html_with_http_headers $query, $cookie, $template->output;
 186 }