C4/Heading.pm

   1 package C4::Heading;
   2
   3 # Copyright (C) 2008 LibLime
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use strict;
  21 #use warnings; FIXME - Bug 2505
  22 use MARC::Record;
  23 use MARC::Field;
  24 use C4::Context;
  25 use C4::Heading::MARC21;
  26 use C4::Search;
  27
  28 our $VERSION = 3.00;
  29
  30 =head1 NAME
  31
  32 C4::Heading
  33
  34 =head1 SYNOPSIS
  35
  36  use C4::Heading;
  37  my $heading = C4::Heading->new_from_bib_field($field);
  38  my $thesaurus = $heading->thesaurus();
  39  my $type = $heading->type();
  40  my $display_heading = $heading->display();
  41  my $search_string = $heading->search_string();
  42
  43 =head1 DESCRIPTION
  44
  45 C<C4::Heading> implements a simple class to representing
  46 headings found in bibliographic and authority records.
  47
  48 =head1 METHODS
  49
  50 =head2 new_from_bib_field
  51
  52   my $heading = C4::Heading->new_from_bib_field($field[, $marc_flavour]);
  53
  54 Given a C<MARC::Field> object containing a heading from a
  55 bib record, create a C<C4::Heading> object.
  56
  57 The optional second parameter is the MARC flavour (i.e., MARC21
  58 or UNIMARC); if this parameter is not supplied, it is
  59 taken from the Koha application context.
  60
  61 If the MARC field supplied is not a valid heading, undef
  62 is returned.
  63
  64 =cut
  65
  66 sub new_from_bib_field {
  67     my $class = shift;
  68     my $field = shift;
  69     my $marcflavour = @_ ? shift : C4::Context->preference('marcflavour');
  70
  71     my $marc_handler = _marc_format_handler($marcflavour);
  72
  73     my $tag = $field->tag();
  74     return unless $marc_handler->valid_bib_heading_tag($tag);
  75     my $self = {};
  76
  77     ($self->{'auth_type'}, $self->{'subject_added_entry'}, $self->{'series_added_entry'}, $self->{'main_entry'},
  78      $self->{'thesaurus'}, $self->{'search_form'}, $self->{'display_form'}) =
  79         $marc_handler->parse_heading($field);
  80
  81     bless $self, $class;
  82     return $self;
  83 }
  84
  85 =head2 display_form
  86
  87   my $display = $heading->display_form();
  88
  89 Return the "canonical" display form of the heading.
  90
  91 =cut
  92
  93 sub display_form {
  94     my $self = shift;
  95     return $self->{'display_form'};
  96 }
  97
  98 =head2 authorities
  99
 100   my $authorities = $heading->authorities;
 101
 102 Return a list of authority records for this
 103 heading.
 104
 105 =cut
 106
 107 sub authorities {
 108     my $self = shift;
 109     my $query = qq(Match-heading,ext="$self->{'search_form'}");
 110     $query .= $self->_query_limiters();
 111     my ($error, $results, $total_hits) = SimpleSearch( $query, undef, undef, [ "authorityserver" ] );
 112     return $results;
 113 }
 114
 115 =head2 preferred_authorities
 116
 117   my $preferred_authorities = $heading->preferred_authorities;
 118
 119 Return a list of authority records for headings
 120 that are a preferred form of the heading.
 121
 122 =cut
 123
 124 sub preferred_authorities {
 125     my $self = shift;
 126     my $query = "Match-heading-see-from,ext='$self->{'search_form'}'";
 127     $query .= $self->_query_limiters();
 128     my ($error, $results, $total_hits) = SimpleSearch( $query, undef, undef, [ "authorityserver" ] );
 129     return $results;
 130 }
 131
 132 =head1 INTERNAL METHODS
 133
 134 =head2 _query_limiters
 135
 136 =cut
 137
 138 sub _query_limiters {
 139     my $self = shift;
 140
 141     my $limiters = " AND at='$self->{'auth_type'}'";
 142     if ($self->{'subject_added_entry'}) {
 143         $limiters .= " AND Heading-use-subject-added-entry=a"; # FIXME -- is this properly in C4::Heading::MARC21?
 144         $limiters .= " AND Subject-heading-thesaurus=$self->{'thesaurus'}";
 145     }
 146     if ($self->{'series_added_entry'}) {
 147         $limiters .= " AND Heading-use-series-added-entry=a"; # FIXME -- is this properly in C4::Heading::MARC21?
 148     }
 149     if (not $self->{'subject_added_entry'} and not $self->{'series_added_entry'}) {
 150         $limiters .= " AND Heading-use-main-or-added-entry=a" # FIXME -- is this properly in C4::Heading::MARC21?
 151     }
 152     return $limiters;
 153 }
 154
 155 =head1 INTERNAL FUNCTIONS
 156
 157 =head2 _marc_format_handler
 158
 159 Returns a C4::Heading::MARC21 or C4::Heading::UNIMARC object
 160 depending on the selected MARC flavour.
 161
 162 =cut
 163
 164 sub _marc_format_handler {
 165     my $marcflavour = shift;
 166
 167     if ($marcflavour eq 'UNIMARC') {
 168         return C4::Heading::UNIMARC->new();
 169     } else {
 170         return C4::Heading::MARC21->new();
 171     }
 172
 173 }
 174
 175 =head1 AUTHOR
 176
 177 Koha Development Team <http://koha-community.org/>
 178
 179 Galen Charlton <galen.charlton@liblime.com>
 180
 181 =cut
 182
 183 1;