reserve/request.pl

   1 #!/usr/bin/perl
   2
   3
   4 #written 2/1/00 by chris@katipo.oc.nz
   5 # Copyright 2000-2002 Katipo Communications
   6 # Parts Copyright 2011 Catalyst IT
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 request.pl
  24
  25 script to place reserves/requests
  26
  27 =cut
  28
  29 use Modern::Perl;
  30
  31 use CGI qw ( -utf8 );
  32 use List::MoreUtils qw/uniq/;
  33 use Date::Calc qw/Date_to_Days/;
  34 use C4::Output;
  35 use C4::Auth;
  36 use C4::Reserves;
  37 use C4::Biblio;
  38 use C4::Items;
  39 use C4::Koha;
  40 use C4::Serials;
  41 use C4::Circulation;
  42 use Koha::DateUtils;
  43 use C4::Utils::DataTables::Members;
  44 use C4::Members;
  45 use C4::Search;         # enabled_staff_search_views
  46
  47 use Koha::Biblios;
  48 use Koha::DateUtils;
  49 use Koha::Checkouts;
  50 use Koha::Holds;
  51 use Koha::IssuingRules;
  52 use Koha::Items;
  53 use Koha::ItemTypes;
  54 use Koha::Libraries;
  55 use Koha::Patrons;
  56
  57 my $dbh = C4::Context->dbh;
  58 my $input = new CGI;
  59 my ( $template, $borrowernumber, $cookie, $flags ) = get_template_and_user(
  60     {
  61         template_name   => "reserve/request.tt",
  62         query           => $input,
  63         type            => "intranet",
  64         authnotrequired => 0,
  65         flagsrequired   => { reserveforothers => 'place_holds' },
  66     }
  67 );
  68
  69 my $showallitems = $input->param('showallitems');
  70 my $pickup = $input->param('pickup') || C4::Context->userenv->{'branch'};
  71
  72 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
  73
  74 # Select borrowers infos
  75 my $findborrower = $input->param('findborrower');
  76 $findborrower = '' unless defined $findborrower;
  77 $findborrower =~ s|,| |g;
  78 my $borrowernumber_hold = $input->param('borrowernumber') || '';
  79 my $messageborrower;
  80 my $warnings;
  81 my $messages;
  82 my $exceeded_maxreserves;
  83 my $exceeded_holds_per_record;
  84
  85 my $date = output_pref({ dt => dt_from_string, dateformat => 'iso', dateonly => 1 });
  86 my $action = $input->param('action');
  87 $action ||= q{};
  88
  89 if ( $action eq 'move' ) {
  90   my $where           = $input->param('where');
  91   my $reserve_id      = $input->param('reserve_id');
  92   my $prev_priority   = $input->param('prev_priority');
  93   my $next_priority   = $input->param('next_priority');
  94   my $first_priority  = $input->param('first_priority');
  95   my $last_priority   = $input->param('last_priority');
  96   my $hold_itemnumber = $input->param('itemnumber');
  97   if ( $prev_priority == 0 && $next_priority == 1 ){
  98       C4::Reserves::RevertWaitingStatus({ itemnumber => $hold_itemnumber });
  99   } else {
 100       AlterPriority( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority );
 101   }
 102 } elsif ( $action eq 'cancel' ) {
 103   my $reserve_id = $input->param('reserve_id');
 104   my $hold = Koha::Holds->find( $reserve_id );
 105   $hold->cancel if $hold;
 106 } elsif ( $action eq 'setLowestPriority' ) {
 107   my $reserve_id = $input->param('reserve_id');
 108   ToggleLowestPriority( $reserve_id );
 109 } elsif ( $action eq 'toggleSuspend' ) {
 110   my $reserve_id = $input->param('reserve_id');
 111   my $suspend_until  = $input->param('suspend_until');
 112   ToggleSuspend( $reserve_id, $suspend_until );
 113 }
 114
 115 if ($findborrower) {
 116     my $patron = Koha::Patrons->find( { cardnumber => $findborrower } );
 117     if ( $patron ) {
 118         $borrowernumber_hold = $patron->borrowernumber;
 119     } else {
 120         my $dt_params = { iDisplayLength => -1 };
 121         my $results = C4::Utils::DataTables::Members::search(
 122             {
 123                 searchmember => $findborrower,
 124                 dt_params => $dt_params,
 125             }
 126         );
 127         my $borrowers = $results->{patrons};
 128         if ( scalar @$borrowers == 1 ) {
 129             $borrowernumber_hold = $borrowers->[0]->{borrowernumber};
 130         } elsif ( @$borrowers ) {
 131             $template->param( borrowers => $borrowers );
 132         } else {
 133             $messageborrower = "'$findborrower'";
 134         }
 135     }
 136 }
 137
 138 my @biblionumbers = ();
 139 my $biblionumber = $input->param('biblionumber');
 140 my $biblionumbers = $input->param('biblionumbers');
 141 if ( $biblionumbers ) {
 142     @biblionumbers = split '/', $biblionumbers;
 143 } else {
 144     push @biblionumbers, $input->multi_param('biblionumber');
 145 }
 146
 147 my $multihold = scalar $input->param('multi_hold');
 148 # FIXME multi_hold should not be a variable but depends on the number of elements in @biblionumbers
 149 $template->param(multi_hold => scalar $input->param('multi_hold'));
 150
 151 # If we have the borrowernumber because we've performed an action, then we
 152 # don't want to try to place another reserve.
 153 if ($borrowernumber_hold && !$action) {
 154     my $patron = Koha::Patrons->find( $borrowernumber_hold );
 155     my $diffbranch;
 156
 157     # we check the reserves of the user, and if they can reserve a document
 158     # FIXME At this time we have a simple count of reservs, but, later, we could improve the infos "title" ...
 159
 160     my $reserves_count = $patron->holds->count;
 161
 162     my $new_reserves_count = scalar( @biblionumbers );
 163
 164     my $maxreserves = C4::Context->preference('maxreserves');
 165     if ( $maxreserves
 166         && ( $reserves_count + $new_reserves_count > $maxreserves ) )
 167     {
 168         my $new_reserves_allowed =
 169             $maxreserves - $reserves_count > 0
 170           ? $maxreserves - $reserves_count
 171           : 0;
 172         $warnings             = 1;
 173         $exceeded_maxreserves = 1;
 174         $template->param(
 175             new_reserves_allowed => $new_reserves_allowed,
 176             new_reserves_count   => $new_reserves_count,
 177             reserves_count       => $reserves_count,
 178             maxreserves          => $maxreserves,
 179         );
 180     }
 181
 182     # we check the date expiry of the borrower (only if there is an expiry date, otherwise, set to 1 (warn)
 183     my $expiry_date = $patron->dateexpiry;
 184     my $expiry = 0; # flag set if patron account has expired
 185     if ($expiry_date and $expiry_date ne '0000-00-00' and
 186         Date_to_Days(split /-/,$date) > Date_to_Days(split /-/,$expiry_date)) {
 187         $expiry = 1;
 188     }
 189
 190     # check if the borrower make the reserv in a different branch
 191     if ( $patron->branchcode ne C4::Context->userenv->{'branch'} ) {
 192         $diffbranch = 1;
 193     }
 194
 195     my $amount_outstanding = $patron->account->balance;
 196     $template->param(
 197                 patron              => $patron,
 198                 expiry              => $expiry,
 199                 diffbranch          => $diffbranch,
 200                 messages            => $messages,
 201                 warnings            => $warnings,
 202                 amount_outstanding  => $amount_outstanding,
 203     );
 204 }
 205
 206 $template->param( messageborrower => $messageborrower );
 207
 208 # FIXME launch another time GetMember perhaps until (Joubu: Why?)
 209 my $patron = Koha::Patrons->find( $borrowernumber_hold );
 210
 211 my $logged_in_patron = Koha::Patrons->find( $borrowernumber );
 212
 213 my $wants_check;
 214 if ($patron) {
 215     $wants_check = $patron->wants_check_for_previous_checkout;
 216 }
 217 my $itemdata_enumchron = 0;
 218 my $itemdata_ccode = 0;
 219 my @biblioloop = ();
 220 foreach my $biblionumber (@biblionumbers) {
 221     next unless $biblionumber =~ m|^\d+$|;
 222
 223     my %biblioloopiter = ();
 224
 225     my $biblio = Koha::Biblios->find( $biblionumber );
 226
 227     my $force_hold_level;
 228     if ( $patron ) {
 229         { # CanBookBeReserved
 230             my $canReserve = CanBookBeReserved( $patron->borrowernumber, $biblionumber, $pickup );
 231             if ( $canReserve->{status} eq 'OK' ) {
 232
 233                 #All is OK and we can continue
 234             }
 235             elsif ( $canReserve->{status} eq 'tooManyReserves' ) {
 236                 $exceeded_maxreserves = 1;
 237                 $template->param( maxreserves => $canReserve->{limit} );
 238             }
 239             elsif ( $canReserve->{status} eq 'tooManyHoldsForThisRecord' ) {
 240                 $exceeded_holds_per_record = 1;
 241                 $biblioloopiter{ $canReserve->{status} } = 1;
 242             }
 243             elsif ( $canReserve->{status} eq 'ageRestricted' ) {
 244                 $template->param( $canReserve->{status} => 1 );
 245                 $biblioloopiter{ $canReserve->{status} } = 1;
 246             }
 247             else {
 248                 $biblioloopiter{ $canReserve->{status} } = 1;
 249             }
 250         }
 251
 252         # For multiple holds per record, if a patron has previously placed a hold,
 253         # the patron can only place more holds of the same type. That is, if the
 254         # patron placed a record level hold, all the holds the patron places must
 255         # be record level. If the patron placed an item level hold, all holds
 256         # the patron places must be item level
 257         my $holds = Koha::Holds->search(
 258             {
 259                 borrowernumber => $patron->borrowernumber,
 260                 biblionumber   => $biblionumber,
 261                 found          => undef,
 262             }
 263         );
 264         $force_hold_level = $holds->forced_hold_level();
 265         $biblioloopiter{force_hold_level} = $force_hold_level;
 266         $template->param( force_hold_level => $force_hold_level );
 267
 268         # For a librarian to be able to place multiple record holds for a patron for a record,
 269         # we must find out what the maximum number of holds they can place for the patron is
 270         my $max_holds_for_record = GetMaxPatronHoldsForRecord( $patron->borrowernumber, $biblionumber );
 271         my $remaining_holds_for_record = $max_holds_for_record - $holds->count();
 272         $biblioloopiter{remaining_holds_for_record} = $max_holds_for_record;
 273         $template->param( max_holds_for_record => $max_holds_for_record );
 274         $template->param( remaining_holds_for_record => $remaining_holds_for_record );
 275
 276         { # alreadypossession
 277             # Check to see if patron is allowed to place holds on records where the
 278             # patron already has an item from that record checked out
 279             if ( !C4::Context->preference('AllowHoldsOnPatronsPossessions')
 280                 && CheckIfIssuedToPatron( $patron->borrowernumber, $biblionumber ) )
 281             {
 282                 $template->param( alreadypossession => 1, );
 283             }
 284         }
 285     }
 286
 287
 288     my $count = Koha::Holds->search( { biblionumber => $biblionumber } )->count();
 289     my $totalcount = $count;
 290
 291     # FIXME think @optionloop, is maybe obsolete, or  must be switchable by a systeme preference fixed rank or not
 292     # make priorities options
 293
 294     my @optionloop;
 295     for ( 1 .. $count + 1 ) {
 296         push(
 297              @optionloop,
 298              {
 299               num      => $_,
 300               selected => ( $_ == $count + 1 ),
 301              }
 302             );
 303     }
 304     # adding a fixed value for priority options
 305     my $fixedRank = $count+1;
 306
 307     my %itemnumbers_of_biblioitem;
 308
 309     my @hostitems = get_hostitemnumbers_of($biblionumber);
 310     my @itemnumbers;
 311     if (@hostitems){
 312         $template->param('hostitemsflag' => 1);
 313         push(@itemnumbers, @hostitems);
 314     }
 315
 316     my $items = Koha::Items->search({ -or => { biblionumber => $biblionumber, itemnumber => { in => \@itemnumbers } } });
 317
 318     unless ( $items->count ) {
 319         # FIXME Then why do we continue?
 320         $template->param('noitems' => 1);
 321         $biblioloopiter{noitems} = 1;
 322     }
 323
 324     ## Here we go backwards again to create hash of biblioitemnumber to itemnumbers,
 325     ## when by definition all of the itemnumber have the same biblioitemnumber
 326     my ( $iteminfos_of );
 327     while ( my $item = $items->next ) {
 328         $item = $item->unblessed;
 329         my $biblioitemnumber = $item->{biblioitemnumber};
 330         my $itemnumber = $item->{itemnumber};
 331         push( @{ $itemnumbers_of_biblioitem{$biblioitemnumber} }, $itemnumber );
 332         $iteminfos_of->{$itemnumber} = $item;
 333     }
 334
 335     ## Should be same as biblionumber
 336     my @biblioitemnumbers = keys %itemnumbers_of_biblioitem;
 337
 338     my $biblioiteminfos_of = {
 339         map {
 340             my $biblioitem = $_;
 341             ( $biblioitem->{biblioitemnumber} => $biblioitem )
 342           } @{ Koha::Biblioitems->search(
 343                 { biblioitemnumber => { -in => \@biblioitemnumbers } },
 344                 { select => ['biblioitemnumber', 'publicationyear', 'itemtype']}
 345             )->unblessed
 346           }
 347     };
 348
 349     my $frameworkcode = GetFrameworkCode( $biblionumber );
 350     my @notforloan_avs = Koha::AuthorisedValues->search_by_koha_field({ kohafield => 'items.notforloan', frameworkcode => $frameworkcode });
 351     my $notforloan_label_of = { map { $_->authorised_value => $_->lib } @notforloan_avs };
 352
 353     my @bibitemloop;
 354
 355     my @available_itemtypes;
 356     foreach my $biblioitemnumber (@biblioitemnumbers) {
 357         my $biblioitem = $biblioiteminfos_of->{$biblioitemnumber};
 358         my $num_available = 0;
 359         my $num_override  = 0;
 360         my $hiddencount   = 0;
 361
 362         $biblioitem->{force_hold_level} = $force_hold_level;
 363
 364         if ( $biblioitem->{biblioitemnumber} ne $biblionumber ) {
 365             $biblioitem->{hostitemsflag} = 1;
 366         }
 367
 368         $biblioloopiter{description} = $biblioitem->{description};
 369         $biblioloopiter{itypename}   = $biblioitem->{description};
 370         if ( $biblioitem->{itemtype} ) {
 371
 372             $biblioitem->{description} =
 373               $itemtypes->{ $biblioitem->{itemtype} }{description};
 374
 375             $biblioloopiter{imageurl} =
 376               getitemtypeimagelocation( 'intranet',
 377                 $itemtypes->{ $biblioitem->{itemtype} }{imageurl} );
 378         }
 379
 380         foreach my $itemnumber ( @{ $itemnumbers_of_biblioitem{$biblioitemnumber} } )    {
 381             my $item = $iteminfos_of->{$itemnumber};
 382             my $do_check;
 383             if ( $patron ) {
 384                 $do_check = $patron->do_check_for_previous_checkout($item) if $wants_check;
 385                 if ( $do_check && $wants_check ) {
 386                     $item->{checked_previously} = $do_check;
 387                     if ( $multihold ) {
 388                         $biblioloopiter{checked_previously} = $do_check;
 389                     } else {
 390                         $template->param( checked_previously => $do_check );
 391                     }
 392                 }
 393             }
 394             $item->{force_hold_level} = $force_hold_level;
 395
 396             unless (C4::Context->preference('item-level_itypes')) {
 397                 $item->{itype} = $biblioitem->{itemtype};
 398             }
 399
 400             $item->{itypename} = $itemtypes->{ $item->{itype} }{description};
 401             $item->{imageurl} = getitemtypeimagelocation( 'intranet', $itemtypes->{ $item->{itype} }{imageurl} );
 402             $item->{homebranch} = $item->{homebranch};
 403
 404             # if the holdingbranch is different than the homebranch, we show the
 405             # holdingbranch of the document too
 406             if ( $item->{homebranch} ne $item->{holdingbranch} ) {
 407                 $item->{holdingbranch} = $item->{holdingbranch};
 408             }
 409
 410             if($item->{biblionumber} ne $biblionumber){
 411                 $item->{hostitemsflag} = 1;
 412                 $item->{hosttitle} = Koha::Biblios->find( $item->{biblionumber} )->title;
 413             }
 414
 415             # if the item is currently on loan, we display its return date and
 416             # change the background color
 417             my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } );
 418             if ( $issue ) {
 419                 $item->{date_due} = $issue->date_due;
 420                 $item->{backgroundcolor} = 'onloan';
 421             }
 422
 423             # checking reserve
 424             my $item_object = Koha::Items->find( $itemnumber );
 425             my $holds = $item_object->current_holds;
 426             if ( my $first_hold = $holds->next ) {
 427                 my $p = Koha::Patrons->find( $first_hold->borrowernumber );
 428
 429                 $item->{backgroundcolor} = 'reserved';
 430                 $item->{reservedate}     = output_pref({ dt => dt_from_string( $first_hold->reservedate ), dateonly => 1 }); # FIXME Should be formatted in the template
 431                 $item->{ReservedFor}     = $p;
 432                 $item->{ExpectedAtLibrary}     = $first_hold->branchcode;
 433                 $item->{waitingdate} = $first_hold->waitingdate;
 434             }
 435
 436             # Management of the notforloan document
 437             if ( $item->{notforloan} ) {
 438                 $item->{backgroundcolor} = 'other';
 439                 $item->{notforloanvalue} =
 440                   $notforloan_label_of->{ $item->{notforloan} };
 441             }
 442
 443             # Management of lost or long overdue items
 444             if ( $item->{itemlost} ) {
 445
 446                 # FIXME localized strings should never be in Perl code
 447                 $item->{message} =
 448                   $item->{itemlost} == 1 ? "(lost)"
 449                     : $item->{itemlost} == 2 ? "(long overdue)"
 450                       : "";
 451                 $item->{backgroundcolor} = 'other';
 452                 if ($logged_in_patron->category->hidelostitems && !$showallitems) {
 453                     $item->{hide} = 1;
 454                     $hiddencount++;
 455                 }
 456             }
 457
 458             # Check the transit status
 459             my ( $transfertwhen, $transfertfrom, $transfertto ) =
 460               GetTransfers($itemnumber);
 461
 462             if ( defined $transfertwhen && $transfertwhen ne '' ) {
 463                 $item->{transfertwhen} = output_pref({ dt => dt_from_string( $transfertwhen ), dateonly => 1 });
 464                 $item->{transfertfrom} = $transfertfrom;
 465                 $item->{transfertto} = $transfertto;
 466                 $item->{nocancel} = 1;
 467             }
 468
 469             # If there is no loan, return and transfer, we show a checkbox.
 470             $item->{notforloan} ||= 0;
 471
 472             # if independent branches is on we need to check if the person can reserve
 473             # for branches they arent logged in to
 474             if ( C4::Context->preference("IndependentBranches") ) {
 475                 if (! C4::Context->preference("canreservefromotherbranches")){
 476                     # can't reserve items so need to check if item homebranch and userenv branch match if not we can't reserve
 477                     my $userenv = C4::Context->userenv;
 478                     unless ( C4::Context->IsSuperLibrarian ) {
 479                         $item->{cantreserve} = 1 if ( $item->{homebranch} ne $userenv->{branch} );
 480                     }
 481                 }
 482             }
 483
 484             if ( $patron ) {
 485                 my $patron_unblessed = $patron->unblessed;
 486                 my $branch = C4::Circulation::_GetCircControlBranch($item, $patron_unblessed);
 487
 488                 my $branchitemrule = GetBranchItemRule( $branch, $item->{'itype'} );
 489
 490                 $item->{'holdallowed'} = $branchitemrule->{'holdallowed'};
 491
 492                 my $can_item_be_reserved = CanItemBeReserved( $patron->borrowernumber, $itemnumber, $pickup );
 493                 $item->{not_holdable} = $can_item_be_reserved->{status} unless ( $can_item_be_reserved->{status} eq 'OK' );
 494
 495                 $item->{item_level_holds} = Koha::IssuingRules->get_opacitemholds_policy( { item => $item_object, patron => $patron } );
 496
 497                 if (
 498                        !$item->{cantreserve}
 499                     && !$exceeded_maxreserves
 500                     && IsAvailableForItemLevelRequest($item, $patron_unblessed)
 501                     && $can_item_be_reserved->{status} eq 'OK'
 502                   )
 503                 {
 504                     $item->{available} = 1;
 505                     $num_available++;
 506
 507                     push( @available_itemtypes, $item->{itype} );
 508                 }
 509                 elsif ( C4::Context->preference('AllowHoldPolicyOverride') ) {
 510                     # If AllowHoldPolicyOverride is set, it should override EVERY restriction, not just branch item rules
 511                     $item->{override} = 1;
 512                     $num_override++;
 513
 514                     push( @available_itemtypes, $item->{itype} );
 515                 }
 516
 517                 # If none of the conditions hold true, then neither override nor available is set and the item cannot be checked
 518
 519                 # Show serial enumeration when needed
 520                 if ($item->{enumchron}) {
 521                     $itemdata_enumchron = 1;
 522                 }
 523                 # Show collection when needed
 524                 if ($item->{ccode}) {
 525                     $itemdata_ccode = 1;
 526                 }
 527             }
 528
 529             push @{ $biblioitem->{itemloop} }, $item;
 530         }
 531
 532         if ( $num_override == scalar( @{ $biblioitem->{itemloop} } ) ) { # That is, if all items require an override
 533             $template->param( override_required => 1 );
 534         } elsif ( $num_available == 0 ) {
 535             $template->param( none_available => 1 );
 536             $biblioloopiter{warn} = 1;
 537             $biblioloopiter{none_avail} = 1;
 538         }
 539         $template->param( hiddencount => $hiddencount);
 540
 541         push @bibitemloop, $biblioitem;
 542     }
 543
 544     @available_itemtypes = uniq( @available_itemtypes );
 545     $template->param( available_itemtypes => \@available_itemtypes );
 546
 547     # existingreserves building
 548     my @reserveloop;
 549     my @reserves = Koha::Holds->search( { biblionumber => $biblionumber }, { order_by => 'priority' } );
 550     foreach my $res (
 551         sort {
 552             my $a_found = $a->found() || '';
 553             my $b_found = $a->found() || '';
 554             $a_found cmp $b_found;
 555         } @reserves
 556       )
 557     {
 558         my $priority = $res->priority();
 559         my %reserve;
 560         my @optionloop;
 561         for ( my $i = 1 ; $i <= $totalcount ; $i++ ) {
 562             push(
 563                 @optionloop,
 564                 {
 565                     num      => $i,
 566                     selected => ( $i == $priority ),
 567                 }
 568             );
 569         }
 570
 571         if ( $res->is_found() ) {
 572             $reserve{'holdingbranch'} = $res->item()->holdingbranch();
 573             $reserve{'biblionumber'}  = $res->item()->biblionumber();
 574             $reserve{'barcodenumber'} = $res->item()->barcode();
 575             $reserve{'wbrcode'}       = $res->branchcode();
 576             $reserve{'itemnumber'}    = $res->itemnumber();
 577             $reserve{'wbrname'}       = $res->branch()->branchname();
 578
 579             if ( $reserve{'holdingbranch'} eq $reserve{'wbrcode'} ) {
 580
 581                 # Just because the holdingbranch matches the reserve branch doesn't mean the item
 582                 # has arrived at the destination, check for an open transfer for the item as well
 583                 my ( $transfertwhen, $transfertfrom, $transferto ) =
 584                   C4::Circulation::GetTransfers( $res->itemnumber() );
 585                 if ( not $transferto or $transferto ne $res->branchcode() ) {
 586                     $reserve{'atdestination'} = 1;
 587                 }
 588             }
 589
 590             # set found to 1 if reserve is waiting for patron pickup
 591             $reserve{'found'}     = $res->is_found();
 592             $reserve{'intransit'} = $res->is_in_transit();
 593         }
 594         elsif ( $res->priority() > 0 ) {
 595             if ( my $item = $res->item() )  {
 596                 $reserve{'itemnumber'}      = $item->id();
 597                 $reserve{'barcodenumber'}   = $item->barcode();
 598                 $reserve{'item_level_hold'} = 1;
 599             }
 600         }
 601
 602         $reserve{'expirationdate'} = output_pref( { dt => dt_from_string( $res->expirationdate ), dateonly => 1 } )
 603           unless ( !defined( $res->expirationdate ) || $res->expirationdate eq '0000-00-00' );
 604         $reserve{'date'}           = output_pref( { dt => dt_from_string( $res->reservedate ), dateonly => 1 } );
 605         $reserve{'borrowernumber'} = $res->borrowernumber();
 606         $reserve{'biblionumber'}   = $res->biblionumber();
 607         $reserve{'patron'}         = $res->borrower;
 608         $reserve{'notes'}          = $res->reservenotes();
 609         $reserve{'waiting_date'}   = $res->waitingdate();
 610         $reserve{'ccode'}          = $res->item() ? $res->item()->ccode() : undef;
 611         $reserve{'barcode'}        = $res->item() ? $res->item()->barcode() : undef;
 612         $reserve{'priority'}       = $res->priority();
 613         $reserve{'lowestPriority'} = $res->lowestPriority();
 614         $reserve{'optionloop'}     = \@optionloop;
 615         $reserve{'suspend'}        = $res->suspend();
 616         $reserve{'suspend_until'}  = $res->suspend_until();
 617         $reserve{'reserve_id'}     = $res->reserve_id();
 618         $reserve{itemtype}         = $res->itemtype();
 619         $reserve{branchcode}       = $res->branchcode();
 620         $reserve{object}           = $res;
 621
 622         push( @reserveloop, \%reserve );
 623     }
 624
 625     # get the time for the form name...
 626     my $time = time();
 627
 628     $template->param(
 629                      time        => $time,
 630                      fixedRank   => $fixedRank,
 631                     );
 632
 633     # display infos
 634     $template->param(
 635                      optionloop        => \@optionloop,
 636                      bibitemloop       => \@bibitemloop,
 637                      itemdata_enumchron => $itemdata_enumchron,
 638                      itemdata_ccode    => $itemdata_ccode,
 639                      date              => $date,
 640                      biblionumber      => $biblionumber,
 641                      findborrower      => $findborrower,
 642                      title             => $biblio->title,
 643                      author            => $biblio->author,
 644                      holdsview => 1,
 645                      C4::Search::enabled_staff_search_views,
 646                     );
 647
 648     $biblioloopiter{biblionumber} = $biblionumber;
 649     $biblioloopiter{title} = $biblio->title;
 650     $biblioloopiter{rank} = $fixedRank;
 651     $biblioloopiter{reserveloop} = \@reserveloop;
 652
 653     if (@reserveloop) {
 654         $template->param( reserveloop => \@reserveloop );
 655     }
 656
 657     push @biblioloop, \%biblioloopiter;
 658 }
 659
 660 $template->param( biblioloop => \@biblioloop );
 661 $template->param( biblionumbers => $biblionumbers );
 662 $template->param( exceeded_maxreserves => $exceeded_maxreserves );
 663 $template->param( exceeded_holds_per_record => $exceeded_holds_per_record );
 664 $template->param( subscriptionsnumber => CountSubscriptionFromBiblionumber($biblionumber));
 665 $template->param( pickup => $pickup );
 666
 667 if ( C4::Context->preference( 'AllowHoldDateInFuture' ) ) {
 668     $template->param( reserve_in_future => 1 );
 669 }
 670
 671 $template->param(
 672     SuspendHoldsIntranet => C4::Context->preference('SuspendHoldsIntranet'),
 673     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 674 );
 675
 676 # printout the page
 677 output_html_with_http_headers $input, $cookie, $template->output;
 678
 679 sub sort_borrowerlist {
 680     my $borrowerslist = shift;
 681     my $ref           = [];
 682     push @{$ref}, sort {
 683         uc( $a->{surname} . $a->{firstname} ) cmp
 684           uc( $b->{surname} . $b->{firstname} )
 685     } @{$borrowerslist};
 686     return $ref;
 687 }