misc/cronjobs/delete_records_via_leader.pl

   1 #!/usr/bin/perl
   2
   3 #-----------------------------------
   4 # Copyright 2013 ByWater Solutions
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 3 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #-----------------------------------
  21
  22 use Modern::Perl;
  23
  24 binmode( STDOUT, ":encoding(UTF-8)" );
  25
  26 BEGIN {
  27
  28     # find Koha's Perl modules
  29     # test carefully before changing this
  30     use FindBin;
  31     eval { require "$FindBin::Bin/../kohalib.pl" };
  32 }
  33
  34 use Getopt::Long;
  35
  36 use C4::Biblio;
  37 use C4::Items;
  38 use Koha::Database;
  39
  40 my $delete_items;
  41 my $confirm;
  42 my $test;
  43 my $verbose;
  44 my $help;
  45
  46 GetOptions(
  47     'i|di|delete-items' => \$delete_items,
  48     'c|confirm'         => \$confirm,
  49     't|test'            => \$test,
  50     'v|verbose'         => \$verbose,
  51     'h|help'            => \$help,
  52 );
  53
  54 if ( $help || !$confirm ) {
  55     say qq{
  56 delete_records_via_leader.pl - Attempt to delete any MARC records where the leader character 5 equals 'd'
  57 usage: delete_records_via_leader.pl --confirm --verbose [--test]
  58 This script has the following parameters :
  59     -h --help: Prints this message
  60     -c --confirm: Script will do nothing without this parameter
  61     -v --verbose: Be verbose
  62     -t --test: Test mode, does not delete records.
  63                Test mode cannot determine if a record/item will be deleted successfully,
  64                it will only tell you what records and items the script will attempt to delete.
  65     -i --delete-items: Try deleting items before deleting record.
  66                        Records with items cannot be deleted.
  67 };
  68     exit();
  69 }
  70
  71 my $schema = Koha::Database->new()->schema();
  72 my @biblioitems =
  73   $schema->resultset('Biblioitem')->search( { marc => { LIKE => '_____d%' } } );
  74
  75 my $total_records_count   = @biblioitems;
  76 my $deleted_records_count = 0;
  77 my $total_items_count     = 0;
  78 my $deleted_items_count   = 0;
  79
  80 foreach my $biblioitem (@biblioitems) {
  81     my $biblionumber = $biblioitem->get_column('biblionumber');
  82
  83     say "RECORD: $biblionumber" if $verbose;
  84
  85     if ($delete_items) {
  86         my $deleted_count = 0;
  87         foreach my $item ( $biblioitem->items() ) {
  88             my $itemnumber = $item->itemnumber();
  89
  90             my $error = $test ? "Test mode enabled" : DelItemCheck( undef, $biblionumber, $itemnumber );
  91             $error = undef if $error eq '1';
  92
  93             if ($error) {
  94                 say "ERROR DELETING ITEM $itemnumber: $error";
  95             }
  96             else {
  97                 say "DELETED ITEM $itemnumber" if $verbose;
  98                 $deleted_items_count++;
  99             }
 100
 101             $total_items_count++;
 102         }
 103
 104     }
 105
 106     my $error = $test ? q{Test mode enabled} : DelBiblio($biblionumber);
 107     if ( $error ) {
 108         say "ERROR DELETING BIBLIO $biblionumber: $error";
 109     } else {
 110         say "DELETED BIBLIO $biblionumber" if $verbose;
 111         $deleted_records_count++;
 112     }
 113
 114     say q{};
 115 }
 116
 117 if ( $verbose ) {
 118     say "DELETED $deleted_records_count OF $total_records_count RECORDS";
 119     say "DELETED $deleted_items_count OF $total_items_count ITEMS" if $delete_items;
 120 }