t/db_dependent/Holds/RevertWaitingStatus.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use t::lib::Mocks;
  21 use C4::Context;
  22
  23 use Test::More tests => 3;
  24 use MARC::Record;
  25 use C4::Biblio;
  26 use C4::Items;
  27 use C4::Members;
  28 use C4::Reserves;
  29
  30 use Koha::Libraries;
  31
  32 use t::lib::TestBuilder;
  33
  34 my $schema = Koha::Database->schema;
  35 $schema->storage->txn_begin;
  36 my $builder = t::lib::TestBuilder->new;
  37 my $dbh = C4::Context->dbh;
  38 $dbh->{RaiseError} = 1;
  39
  40 $dbh->do("DELETE FROM reserves");
  41 $dbh->do("DELETE FROM old_reserves");
  42
  43 my $branchcode = $builder->build( { source => 'Branch' } )->{branchcode};
  44 my $itemtype = $builder->build(
  45     { source => 'Itemtype', value => { notforloan => undef } } )->{itemtype};
  46
  47 local $SIG{__WARN__} = sub { warn $_[0] unless $_[0] =~ /redefined/ };
  48 *C4::Context::userenv = \&Mock_userenv;
  49
  50 sub Mock_userenv {
  51     my $userenv = { flags => 1, id => '1', branch => $branchcode };
  52     return $userenv;
  53 }
  54
  55 my $borrowers_count = 3;
  56
  57 # Create a biblio instance
  58 my ( $bibnum, $title, $bibitemnum ) = create_helper_biblio();
  59
  60 # Create an item
  61 my $item_barcode = 'my_barcode';
  62 my ( $item_bibnum, $item_bibitemnum, $itemnumber ) = AddItem(
  63     {   homebranch    => $branchcode,
  64         holdingbranch => $branchcode,
  65         barcode       => $item_barcode,
  66         itype         => $itemtype
  67     },
  68     $bibnum
  69 );
  70
  71 # Create some borrowers
  72 my @borrowernumbers;
  73 foreach my $i ( 1 .. $borrowers_count ) {
  74     my $borrowernumber = AddMember(
  75         firstname    => 'my firstname',
  76         surname      => 'my surname ' . $i,
  77         categorycode => 'S',
  78         branchcode   => $branchcode,
  79     );
  80     push @borrowernumbers, $borrowernumber;
  81 }
  82
  83 my $biblionumber = $bibnum;
  84
  85 # Create five item level holds
  86 foreach my $borrowernumber (@borrowernumbers) {
  87     AddReserve(
  88         $branchcode,
  89         $borrowernumber,
  90         $biblionumber,
  91         my $bibitems   = q{},
  92         my $priority,
  93         my $resdate,
  94         my $expdate,
  95         my $notes = q{},
  96         $title,
  97         my $checkitem,
  98         my $found,
  99     );
 100 }
 101
 102 ModReserveAffect( $itemnumber, $borrowernumbers[0] );
 103 C4::Circulation::AddIssue( GetMember( borrowernumber => $borrowernumbers[1] ),
 104     $item_barcode, my $datedue, my $cancelreserve = 'revert' );
 105
 106 my $priorities = $dbh->selectall_arrayref(
 107     "SELECT priority FROM reserves ORDER BY priority ASC");
 108 ok( scalar @$priorities == 2,   'Only 2 holds remain in the reserves table' );
 109 ok( $priorities->[0]->[0] == 1, 'First hold has a priority of 1' );
 110 ok( $priorities->[1]->[0] == 2, 'Second hold has a priority of 2' );
 111
 112 $schema->storage->txn_rollback;
 113
 114 # Helper method to set up a Biblio.
 115 sub create_helper_biblio {
 116     my $bib   = MARC::Record->new();
 117     my $title = 'Silence in the library';
 118     $bib->append_fields(
 119         MARC::Field->new( '100', ' ', ' ', a => 'Moffat, Steven' ),
 120         MARC::Field->new( '245', ' ', ' ', a => $title ),
 121     );
 122     return ( $bibnum, $title, $bibitemnum ) = AddBiblio( $bib, '' );
 123 }