C4/Reports/Guided.pm

   1 package C4::Reports::Guided;
   2
   3 # Copyright 2007 Liblime Ltd
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use CGI qw ( -utf8 );
  22 use Carp;
  23 use JSON qw( from_json );
  24
  25 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  26 use C4::Context;
  27 use C4::Templates qw/themelanguage/;
  28 use C4::Koha;
  29 use Koha::DateUtils;
  30 use Koha::Patrons;
  31 use Koha::Reports;
  32 use C4::Output;
  33 use C4::Debug;
  34 use C4::Log;
  35 use Koha::Notice::Templates;
  36 use C4::Letters;
  37
  38 use Koha::AuthorisedValues;
  39 use Koha::Patron::Categories;
  40 use Koha::SharedContent;
  41
  42 BEGIN {
  43     require Exporter;
  44     @ISA    = qw(Exporter);
  45     @EXPORT = qw(
  46       get_report_types get_report_areas get_report_groups get_columns build_query get_criteria
  47       save_report get_saved_reports execute_query
  48       get_column_type get_distinct_values save_dictionary get_from_dictionary
  49       delete_definition delete_report format_results get_sql
  50       nb_rows update_sql
  51       GetReservedAuthorisedValues
  52       GetParametersFromSQL
  53       IsAuthorisedValueValid
  54       ValidateSQLParameters
  55       nb_rows update_sql
  56     );
  57 }
  58
  59 =head1 NAME
  60
  61 C4::Reports::Guided - Module for generating guided reports
  62
  63 =head1 SYNOPSIS
  64
  65   use C4::Reports::Guided;
  66
  67 =head1 DESCRIPTION
  68
  69 =cut
  70
  71 =head1 METHODS
  72
  73 =head2 get_report_areas
  74
  75 This will return a list of all the available report areas
  76
  77 =cut
  78
  79 sub get_area_name_sql_snippet {
  80     my @REPORT_AREA = (
  81         [CIRC => "Circulation"],
  82         [CAT  => "Catalogue"],
  83         [PAT  => "Patrons"],
  84         [ACQ  => "Acquisition"],
  85         [ACC  => "Accounts"],
  86         [SER  => "Serials"],
  87     );
  88
  89     return "CASE report_area " .
  90     join (" ", map "WHEN '$_->[0]' THEN '$_->[1]'", @REPORT_AREA) .
  91     " END AS areaname";
  92 }
  93
  94 sub get_report_areas {
  95
  96     my $report_areas = [ 'CIRC', 'CAT', 'PAT', 'ACQ', 'ACC', 'SER' ];
  97
  98     return $report_areas;
  99 }
 100
 101 sub get_table_areas {
 102     return (
 103     CIRC => [ 'borrowers', 'statistics', 'items', 'biblioitems' ],
 104     CAT  => [ 'items', 'biblioitems', 'biblio' ],
 105     PAT  => ['borrowers'],
 106     ACQ  => [ 'aqorders', 'biblio', 'items' ],
 107     ACC  => [ 'borrowers', 'accountlines' ],
 108     SER  => [ 'serial', 'serialitems', 'subscription', 'subscriptionhistory', 'subscriptionroutinglist', 'biblioitems', 'biblio', 'aqbooksellers' ],
 109     );
 110 }
 111
 112 =head2 get_report_types
 113
 114 This will return a list of all the available report types
 115
 116 =cut
 117
 118 sub get_report_types {
 119     my $dbh = C4::Context->dbh();
 120
 121     # FIXME these should be in the database perhaps
 122     my @reports = ( 'Tabular', 'Summary', 'Matrix' );
 123     my @reports2;
 124     for ( my $i = 0 ; $i < 3 ; $i++ ) {
 125         my %hashrep;
 126         $hashrep{id}   = $i + 1;
 127         $hashrep{name} = $reports[$i];
 128         push @reports2, \%hashrep;
 129     }
 130     return ( \@reports2 );
 131
 132 }
 133
 134 =head2 get_report_groups
 135
 136 This will return a list of all the available report areas with groups
 137
 138 =cut
 139
 140 sub get_report_groups {
 141     my $dbh = C4::Context->dbh();
 142
 143     my $groups = GetAuthorisedValues('REPORT_GROUP');
 144     my $subgroups = GetAuthorisedValues('REPORT_SUBGROUP');
 145
 146     my %groups_with_subgroups = map { $_->{authorised_value} => {
 147                         name => $_->{lib},
 148                         groups => {}
 149                     } } @$groups;
 150     foreach (@$subgroups) {
 151         my $sg = $_->{authorised_value};
 152         my $g = $_->{lib_opac}
 153           or warn( qq{REPORT_SUBGROUP "$sg" without REPORT_GROUP (lib_opac)} ),
 154              next;
 155         my $g_sg = $groups_with_subgroups{$g}
 156           or warn( qq{REPORT_SUBGROUP "$sg" with invalid REPORT_GROUP "$g"} ),
 157              next;
 158         $g_sg->{subgroups}{$sg} = $_->{lib};
 159     }
 160     return \%groups_with_subgroups
 161 }
 162
 163 =head2 get_all_tables
 164
 165 This will return a list of all tables in the database
 166
 167 =cut
 168
 169 sub get_all_tables {
 170     my $dbh   = C4::Context->dbh();
 171     my $query = "SHOW TABLES";
 172     my $sth   = $dbh->prepare($query);
 173     $sth->execute();
 174     my @tables;
 175     while ( my $data = $sth->fetchrow_arrayref() ) {
 176         push @tables, $data->[0];
 177     }
 178     $sth->finish();
 179     return ( \@tables );
 180
 181 }
 182
 183 =head2 get_columns($area)
 184
 185 This will return a list of all columns for a report area
 186
 187 =cut
 188
 189 sub get_columns {
 190
 191     # this calls the internal function _get_columns
 192     my ( $area, $cgi ) = @_;
 193     my %table_areas = get_table_areas;
 194     my $tables = $table_areas{$area}
 195       or die qq{Unsuported report area "$area"};
 196
 197     my @allcolumns;
 198     my $first = 1;
 199     foreach my $table (@$tables) {
 200         my @columns = _get_columns($table,$cgi, $first);
 201         $first = 0;
 202         push @allcolumns, @columns;
 203     }
 204     return ( \@allcolumns );
 205 }
 206
 207 sub _get_columns {
 208     my ($tablename,$cgi, $first) = @_;
 209     my $dbh         = C4::Context->dbh();
 210     my $sth         = $dbh->prepare("show columns from $tablename");
 211     $sth->execute();
 212     my @columns;
 213         my $column_defs = _get_column_defs($cgi);
 214         my %tablehash;
 215         $tablehash{'table'}=$tablename;
 216     $tablehash{'__first__'} = $first;
 217         push @columns, \%tablehash;
 218     while ( my $data = $sth->fetchrow_arrayref() ) {
 219         my %temphash;
 220         $temphash{'name'}        = "$tablename.$data->[0]";
 221         $temphash{'description'} = $column_defs->{"$tablename.$data->[0]"};
 222         push @columns, \%temphash;
 223     }
 224     $sth->finish();
 225     return (@columns);
 226 }
 227
 228 =head2 build_query($columns,$criteria,$orderby,$area)
 229
 230 This will build the sql needed to return the results asked for,
 231 $columns is expected to be of the format tablename.columnname.
 232 This is what get_columns returns.
 233
 234 =cut
 235
 236 sub build_query {
 237     my ( $columns, $criteria, $orderby, $area, $totals, $definition ) = @_;
 238
 239     my %keys = (
 240         CIRC => [ 'statistics.borrowernumber=borrowers.borrowernumber',
 241                   'items.itemnumber = statistics.itemnumber',
 242                   'biblioitems.biblioitemnumber = items.biblioitemnumber' ],
 243         CAT  => [ 'items.biblioitemnumber=biblioitems.biblioitemnumber',
 244                   'biblioitems.biblionumber=biblio.biblionumber' ],
 245         PAT  => [],
 246         ACQ  => [ 'aqorders.biblionumber=biblio.biblionumber',
 247                   'biblio.biblionumber=items.biblionumber' ],
 248         ACC  => ['borrowers.borrowernumber=accountlines.borrowernumber'],
 249         SER  => [ 'serial.serialid=serialitems.serialid', 'serial.subscriptionid=subscription.subscriptionid', 'serial.subscriptionid=subscriptionhistory.subscriptionid', 'serial.subscriptionid=subscriptionroutinglist.subscriptionid', 'biblioitems.biblionumber=serial.biblionumber', 'biblio.biblionumber=biblioitems.biblionumber', 'subscription.aqbooksellerid=aqbooksellers.id'],
 250     );
 251
 252
 253 ### $orderby
 254     my $keys   = $keys{$area};
 255     my %table_areas = get_table_areas;
 256     my $tables = $table_areas{$area};
 257
 258     my $sql =
 259       _build_query( $tables, $columns, $criteria, $keys, $orderby, $totals, $definition );
 260     return ($sql);
 261 }
 262
 263 sub _build_query {
 264     my ( $tables, $columns, $criteria, $keys, $orderby, $totals, $definition) = @_;
 265 ### $orderby
 266     # $keys is an array of joining constraints
 267     my $dbh           = C4::Context->dbh();
 268     my $joinedtables  = join( ',', @$tables );
 269     my $joinedcolumns = join( ',', @$columns );
 270     my $query =
 271       "SELECT $totals $joinedcolumns FROM $tables->[0] ";
 272         for (my $i=1;$i<@$tables;$i++){
 273                 $query .= "LEFT JOIN $tables->[$i] on ($keys->[$i-1]) ";
 274         }
 275
 276     if ($criteria) {
 277                 $criteria =~ s/AND/WHERE/;
 278         $query .= " $criteria";
 279     }
 280         if ($definition){
 281                 my @definitions = split(',',$definition);
 282                 my $deftext;
 283                 foreach my $def (@definitions){
 284                         my $defin=get_from_dictionary('',$def);
 285                         $deftext .=" ".$defin->[0]->{'saved_sql'};
 286                 }
 287                 if ($query =~ /WHERE/i){
 288                         $query .= $deftext;
 289                 }
 290                 else {
 291                         $deftext  =~ s/AND/WHERE/;
 292                         $query .= $deftext;
 293                 }
 294         }
 295     if ($totals) {
 296         my $groupby;
 297         my @totcolumns = split( ',', $totals );
 298         foreach my $total (@totcolumns) {
 299             if ( $total =~ /\((.*)\)/ ) {
 300                 if ( $groupby eq '' ) {
 301                     $groupby = " GROUP BY $1";
 302                 }
 303                 else {
 304                     $groupby .= ",$1";
 305                 }
 306             }
 307         }
 308         $query .= $groupby;
 309     }
 310     if ($orderby) {
 311         $query .= $orderby;
 312     }
 313     return ($query);
 314 }
 315
 316 =head2 get_criteria($area,$cgi);
 317
 318 Returns an arraref to hashrefs suitable for using in a tmpl_loop. With the criteria and available values.
 319
 320 =cut
 321
 322 sub get_criteria {
 323     my ($area,$cgi) = @_;
 324     my $dbh    = C4::Context->dbh();
 325
 326     # have to do someting here to know if its dropdown, free text, date etc
 327     my %criteria = (
 328         CIRC => [ 'statistics.type', 'borrowers.categorycode', 'statistics.branch',
 329                   'biblioitems.publicationyear|date', 'items.dateaccessioned|date' ],
 330         CAT  => [ 'items.itemnumber|textrange', 'items.biblionumber|textrange',
 331                   'items.barcode|textrange', 'biblio.frameworkcode',
 332                   'items.holdingbranch', 'items.homebranch',
 333                   'biblio.datecreated|daterange', 'biblio.timestamp|daterange',
 334                   'items.onloan|daterange', 'items.ccode',
 335                   'items.itemcallnumber|textrange', 'items.itype', 'items.itemlost',
 336                   'items.location' ],
 337         PAT  => [ 'borrowers.branchcode', 'borrowers.categorycode' ],
 338         ACQ  => ['aqorders.datereceived|date'],
 339         ACC  => [ 'borrowers.branchcode', 'borrowers.categorycode' ],
 340         SER  => ['subscription.startdate|date', 'subscription.enddate|date', 'subscription.periodicity', 'subscription.callnumber', 'subscription.location', 'subscription.branchcode'],
 341     );
 342
 343     # Adds itemtypes to criteria, according to the syspref
 344     if ( C4::Context->preference('item-level_itypes') ) {
 345         unshift @{ $criteria{'CIRC'} }, 'items.itype';
 346         unshift @{ $criteria{'CAT'} }, 'items.itype';
 347     } else {
 348         unshift @{ $criteria{'CIRC'} }, 'biblioitems.itemtype';
 349         unshift @{ $criteria{'CAT'} }, 'biblioitems.itemtype';
 350     }
 351
 352
 353     my $crit   = $criteria{$area};
 354     my $column_defs = _get_column_defs($cgi);
 355     my @criteria_array;
 356     foreach my $localcrit (@$crit) {
 357         my ( $value, $type )   = split( /\|/, $localcrit );
 358         my ( $table, $column ) = split( /\./, $value );
 359         if ($type eq 'textrange') {
 360             my %temp;
 361             $temp{'name'}        = $value;
 362             $temp{'from'}        = "from_" . $value;
 363             $temp{'to'}          = "to_" . $value;
 364             $temp{'textrange'}   = 1;
 365             $temp{'description'} = $column_defs->{$value};
 366             push @criteria_array, \%temp;
 367         }
 368         elsif ($type eq 'date') {
 369             my %temp;
 370             $temp{'name'}        = $value;
 371             $temp{'date'}        = 1;
 372             $temp{'description'} = $column_defs->{$value};
 373             push @criteria_array, \%temp;
 374         }
 375         elsif ($type eq 'daterange') {
 376             my %temp;
 377             $temp{'name'}        = $value;
 378             $temp{'from'}        = "from_" . $value;
 379             $temp{'to'}          = "to_" . $value;
 380             $temp{'daterange'}   = 1;
 381             $temp{'description'} = $column_defs->{$value};
 382             push @criteria_array, \%temp;
 383         }
 384         else {
 385             my $query =
 386             "SELECT distinct($column) as availablevalues FROM $table";
 387             my $sth = $dbh->prepare($query);
 388             $sth->execute();
 389             my @values;
 390             # push the runtime choosing option
 391             my $list;
 392             $list='branches' if $column eq 'branchcode' or $column eq 'holdingbranch' or $column eq 'homebranch';
 393             $list='categorycode' if $column eq 'categorycode';
 394             $list='itemtypes' if $column eq 'itype';
 395             $list='ccode' if $column eq 'ccode';
 396             # TODO : improve to let the librarian choose the description at runtime
 397             push @values, {
 398                 availablevalues => "<<$column" . ( $list ? "|$list" : '' ) . ">>",
 399                 display_value   => "<<$column" . ( $list ? "|$list" : '' ) . ">>",
 400             };
 401             while ( my $row = $sth->fetchrow_hashref() ) {
 402                 if ($row->{'availablevalues'} eq '') { $row->{'default'} = 1 }
 403                 else { $row->{display_value} = _get_display_value( $row->{'availablevalues'}, $column ); }
 404                 push @values, $row;
 405             }
 406             $sth->finish();
 407
 408             my %temp;
 409             $temp{'name'}        = $value;
 410             $temp{'description'} = $column_defs->{$value};
 411             $temp{'values'}      = \@values;
 412
 413             push @criteria_array, \%temp;
 414         }
 415     }
 416     return ( \@criteria_array );
 417 }
 418
 419 sub nb_rows {
 420     my $sql = shift or return;
 421
 422     my $derived_name = 'xxx';
 423     # make sure the derived table name is not already used
 424     while ( $sql =~ m/$derived_name/ ) {
 425         $derived_name .= 'x';
 426     }
 427
 428
 429     my $dbh = C4::Context->dbh;
 430     my $sth;
 431     my $n = 0;
 432
 433     my $RaiseError = $dbh->{RaiseError};
 434     my $PrintError = $dbh->{PrintError};
 435     $dbh->{RaiseError} = 1;
 436     $dbh->{PrintError} = 0;
 437     eval {
 438         $sth = $dbh->prepare(qq{
 439             SELECT COUNT(*) FROM
 440             ( $sql ) $derived_name
 441         });
 442
 443         $sth->execute();
 444     };
 445     $dbh->{RaiseError} = $RaiseError;
 446     $dbh->{PrintError} = $PrintError;
 447     if ($@) { # To catch "Duplicate column name" caused by the derived table, or any other syntax error
 448         $sth = $dbh->prepare($sql);
 449         $sth->execute;
 450         # Loop through the complete results, fetching 1,000 rows at a time.  This
 451         # lowers memory requirements but increases execution time.
 452         while (my $rows = $sth->fetchall_arrayref(undef, 1000)) {
 453             $n += @$rows;
 454         }
 455         return $n;
 456     }
 457
 458     my $results = $sth->fetch;
 459     return $results ? $results->[0] : 0;
 460 }
 461
 462 =head2 execute_query
 463
 464   ($sth, $error) = execute_query($sql, $offset, $limit[, \@sql_params])
 465
 466
 467 This function returns a DBI statement handler from which the caller can
 468 fetch the results of the SQL passed via C<$sql>.
 469
 470 If passed any query other than a SELECT, or if there is a DB error,
 471 C<$errors> is returned, and is a hashref containing the error after this
 472 manner:
 473
 474 C<$error->{'sqlerr'}> contains the offending SQL keyword.
 475 C<$error->{'queryerr'}> contains the native db engine error returned
 476 for the query.
 477
 478 C<$offset>, and C<$limit> are required parameters.
 479
 480 C<\@sql_params> is an optional list of parameter values to paste in.
 481 The caller is responsible for making sure that C<$sql> has placeholders
 482 and that the number placeholders matches the number of parameters.
 483
 484 =cut
 485
 486 # returns $sql, $offset, $limit
 487 # $sql returned will be transformed to:
 488 #  ~ remove any LIMIT clause
 489 #  ~ repace SELECT clause w/ SELECT count(*)
 490
 491 sub select_2_select_count {
 492     # Modify the query passed in to create a count query... (I think this covers all cases -crn)
 493     my ($sql) = strip_limit(shift) or return;
 494     $sql =~ s/\bSELECT\W+(?:\w+\W+){1,}?FROM\b|\bSELECT\W\*\WFROM\b/SELECT count(*) FROM /ig;
 495     return $sql;
 496 }
 497
 498 # This removes the LIMIT from the query so that a custom one can be specified.
 499 # Usage:
 500 #   ($new_sql, $offset, $limit) = strip_limit($sql);
 501 #
 502 # Where:
 503 #   $sql is the query to modify
 504 #   $new_sql is the resulting query
 505 #   $offset is the offset value, if the LIMIT was the two-argument form,
 506 #       0 if it wasn't otherwise given.
 507 #   $limit is the limit value
 508 #
 509 # Notes:
 510 #   * This makes an effort to not break subqueries that have their own
 511 #     LIMIT specified. It does that by only removing a LIMIT if it comes after
 512 #     a WHERE clause (which isn't perfect, but at least should make more cases
 513 #     work - subqueries with a limit in the WHERE will still break.)
 514 #   * If your query doesn't have a WHERE clause then all LIMITs will be
 515 #     removed. This may break some subqueries, but is hopefully rare enough
 516 #     to not be a big issue.
 517 sub strip_limit {
 518     my ($sql) = @_;
 519
 520     return unless $sql;
 521     return ($sql, 0, undef) unless $sql =~ /\bLIMIT\b/i;
 522
 523     # Two options: if there's no WHERE clause in the SQL, we simply capture
 524     # any LIMIT that's there. If there is a WHERE, we make sure that we only
 525     # capture a LIMIT after the last one. This prevents stomping on subqueries.
 526     if ($sql !~ /\bWHERE\b/i) {
 527         (my $res = $sql) =~ s/\bLIMIT\b\s*(\d+)(\s*\,\s*(\d+))?\s*/ /ig;
 528         return ($res, (defined $2 ? $1 : 0), (defined $3 ? $3 : $1));
 529     } else {
 530         my $res = $sql;
 531         $res =~ m/.*\bWHERE\b/gsi;
 532         $res =~ s/\G(.*)\bLIMIT\b\s*(\d+)(\s*\,\s*(\d+))?\s*/$1 /is;
 533         return ($res, (defined $3 ? $2 : 0), (defined $4 ? $4 : $2));
 534     }
 535 }
 536
 537 sub execute_query {
 538
 539     my ( $sql, $offset, $limit, $sql_params, $report_id ) = @_;
 540
 541     $sql_params = [] unless defined $sql_params;
 542
 543     # check parameters
 544     unless ($sql) {
 545         carp "execute_query() called without SQL argument";
 546         return;
 547     }
 548     $offset = 0    unless $offset;
 549     $limit  = 999999 unless $limit;
 550     $debug and print STDERR "execute_query($sql, $offset, $limit)\n";
 551     if ($sql =~ /;?\W?(UPDATE|DELETE|DROP|INSERT|SHOW|CREATE)\W/i) {
 552         return (undef, {  sqlerr => $1} );
 553     } elsif ($sql !~ /^\s*SELECT\b\s*/i) {
 554         return (undef, { queryerr => 'Missing SELECT'} );
 555     }
 556
 557     my ($useroffset, $userlimit);
 558
 559     # Grab offset/limit from user supplied LIMIT and drop the LIMIT so we can control pagination
 560     ($sql, $useroffset, $userlimit) = strip_limit($sql);
 561     $debug and warn sprintf "User has supplied (OFFSET,) LIMIT = %s, %s",
 562         $useroffset,
 563         (defined($userlimit ) ? $userlimit  : 'UNDEF');
 564     $offset += $useroffset;
 565     if (defined($userlimit)) {
 566         if ($offset + $limit > $userlimit ) {
 567             $limit = $userlimit - $offset;
 568         } elsif ( ! $offset && $limit < $userlimit ) {
 569             $limit = $userlimit;
 570         }
 571     }
 572     $sql .= " LIMIT ?, ?";
 573
 574     my $dbh = C4::Context->dbh;
 575
 576     $dbh->do( 'UPDATE saved_sql SET last_run = NOW() WHERE id = ?', undef, $report_id ) if $report_id;
 577
 578     my $sth = $dbh->prepare($sql);
 579     $sth->execute(@$sql_params, $offset, $limit);
 580
 581     return ( $sth, { queryerr => $sth->errstr } ) if ($sth->err);
 582     return ( $sth );
 583 }
 584
 585 =head2 save_report($sql,$name,$type,$notes)
 586
 587 Given some sql and a name this will saved it so that it can reused
 588 Returns id of the newly created report
 589
 590 =cut
 591
 592 sub save_report {
 593     my ($fields) = @_;
 594     my $borrowernumber = $fields->{borrowernumber};
 595     my $sql = $fields->{sql};
 596     my $name = $fields->{name};
 597     my $type = $fields->{type};
 598     my $notes = $fields->{notes};
 599     my $area = $fields->{area};
 600     my $group = $fields->{group};
 601     my $subgroup = $fields->{subgroup};
 602     my $cache_expiry = $fields->{cache_expiry} || 300;
 603     my $public = $fields->{public};
 604
 605     my $dbh = C4::Context->dbh();
 606     $sql =~ s/(\s*\;\s*)$//;    # removes trailing whitespace and /;/
 607     my $query = "INSERT INTO saved_sql (borrowernumber,date_created,last_modified,savedsql,report_name,report_area,report_group,report_subgroup,type,notes,cache_expiry,public)  VALUES (?,now(),now(),?,?,?,?,?,?,?,?,?)";
 608     $dbh->do($query, undef, $borrowernumber, $sql, $name, $area, $group, $subgroup, $type, $notes, $cache_expiry, $public);
 609
 610     my $id = $dbh->selectrow_array("SELECT max(id) FROM saved_sql WHERE borrowernumber=? AND report_name=?", undef,
 611                                    $borrowernumber, $name);
 612     return $id;
 613 }
 614
 615 sub update_sql {
 616     my $id         = shift || croak "No Id given";
 617     my $fields     = shift;
 618     my $sql = $fields->{sql};
 619     my $name = $fields->{name};
 620     my $notes = $fields->{notes};
 621     my $group = $fields->{group};
 622     my $subgroup = $fields->{subgroup};
 623     my $cache_expiry = $fields->{cache_expiry};
 624     my $public = $fields->{public};
 625
 626     if( $cache_expiry >= 2592000 ){
 627       die "Please specify a cache expiry less than 30 days\n";
 628     }
 629
 630     my $dbh        = C4::Context->dbh();
 631     $sql =~ s/(\s*\;\s*)$//;    # removes trailing whitespace and /;/
 632     my $query = "UPDATE saved_sql SET savedsql = ?, last_modified = now(), report_name = ?, report_group = ?, report_subgroup = ?, notes = ?, cache_expiry = ?, public = ? WHERE id = ? ";
 633     $dbh->do($query, undef, $sql, $name, $group, $subgroup, $notes, $cache_expiry, $public, $id );
 634 }
 635
 636 sub store_results {
 637     my ( $id, $json ) = @_;
 638     my $dbh = C4::Context->dbh();
 639     $dbh->do(q|
 640         INSERT INTO saved_reports ( report_id, report, date_run ) VALUES ( ?, ?, NOW() );
 641     |, undef, $id, $json );
 642 }
 643
 644 sub format_results {
 645     my ( $id ) = @_;
 646     my $dbh = C4::Context->dbh();
 647     my ( $report_name, $notes, $json, $date_run ) = $dbh->selectrow_array(q|
 648        SELECT ss.report_name, ss.notes, sr.report, sr.date_run
 649        FROM saved_sql ss
 650        LEFT JOIN saved_reports sr ON sr.report_id = ss.id
 651        WHERE sr.id = ?
 652     |, undef, $id);
 653     return {
 654         report_name => $report_name,
 655         notes => $notes,
 656         results => from_json( $json ),
 657         date_run => $date_run,
 658     };
 659 }
 660
 661 sub delete_report {
 662     my (@ids) = @_;
 663     return unless @ids;
 664     foreach my $id (@ids) {
 665         my $data = Koha::Reports->find($id);
 666         logaction( "REPORTS", "DELETE", $id, $data->report_name." | ".$data->savedsql ) if C4::Context->preference("ReportsLog");
 667     }
 668     my $dbh = C4::Context->dbh;
 669     my $query = 'DELETE FROM saved_sql WHERE id IN (' . join( ',', ('?') x @ids ) . ')';
 670     my $sth = $dbh->prepare($query);
 671     return $sth->execute(@ids);
 672 }
 673
 674 sub get_saved_reports_base_query {
 675     my $area_name_sql_snippet = get_area_name_sql_snippet;
 676     return <<EOQ;
 677 SELECT s.*, $area_name_sql_snippet, av_g.lib AS groupname, av_sg.lib AS subgroupname,
 678 b.firstname AS borrowerfirstname, b.surname AS borrowersurname
 679 FROM saved_sql s
 680 LEFT JOIN saved_reports r ON r.report_id = s.id
 681 LEFT OUTER JOIN authorised_values av_g ON (av_g.category = 'REPORT_GROUP' AND av_g.authorised_value = s.report_group)
 682 LEFT OUTER JOIN authorised_values av_sg ON (av_sg.category = 'REPORT_SUBGROUP' AND av_sg.lib_opac = s.report_group AND av_sg.authorised_value = s.report_subgroup)
 683 LEFT OUTER JOIN borrowers b USING (borrowernumber)
 684 EOQ
 685 }
 686
 687 sub get_saved_reports {
 688 # $filter is either { date => $d, author => $a, keyword => $kw, }
 689 # or $keyword. Optional.
 690     my ($filter) = @_;
 691     $filter = { keyword => $filter } if $filter && !ref( $filter );
 692     my ($group, $subgroup) = @_;
 693
 694     my $dbh   = C4::Context->dbh();
 695     my $query = get_saved_reports_base_query;
 696     my (@cond,@args);
 697     if ($filter) {
 698         if (my $date = $filter->{date}) {
 699             $date = eval { output_pref( { dt => dt_from_string( $date ), dateonly => 1, dateformat => 'iso' }); };
 700             push @cond, "DATE(last_modified) = ? OR
 701                          DATE(last_run) = ?";
 702             push @args, $date, $date, $date;
 703         }
 704         if (my $author = $filter->{author}) {
 705             $author = "%$author%";
 706             push @cond, "surname LIKE ? OR
 707                          firstname LIKE ?";
 708             push @args, $author, $author;
 709         }
 710         if (my $keyword = $filter->{keyword}) {
 711             push @cond, q|
 712                        report LIKE ?
 713                     OR report_name LIKE ?
 714                     OR notes LIKE ?
 715                     OR savedsql LIKE ?
 716                     OR s.id = ?
 717             |;
 718             push @args, "%$keyword%", "%$keyword%", "%$keyword%", "%$keyword%", $keyword;
 719         }
 720         if ($filter->{group}) {
 721             push @cond, "report_group = ?";
 722             push @args, $filter->{group};
 723         }
 724         if ($filter->{subgroup}) {
 725             push @cond, "report_subgroup = ?";
 726             push @args, $filter->{subgroup};
 727         }
 728     }
 729     $query .= " WHERE ".join( " AND ", map "($_)", @cond ) if @cond;
 730     $query .= " GROUP BY s.id, s.borrowernumber, s.date_created, s.last_modified, s.savedsql, s.last_run, s.report_name, s.type, s.notes, s.cache_expiry, s.public, s.report_area, s.report_group, s.report_subgroup, s.mana_id, av_g.lib, av_sg.lib, b.firstname, b.surname";
 731     $query .= " ORDER by date_created";
 732
 733     my $result = $dbh->selectall_arrayref($query, {Slice => {}}, @args);
 734
 735     return $result;
 736 }
 737
 738 =head2 get_column_type($column)
 739
 740 This takes a column name of the format table.column and will return what type it is
 741 (free text, set values, date)
 742
 743 =cut
 744
 745 sub get_column_type {
 746         my ($tablecolumn) = @_;
 747         my ($table,$column) = split(/\./,$tablecolumn);
 748         my $dbh = C4::Context->dbh();
 749         my $catalog;
 750         my $schema;
 751
 752     # mysql doesn't support a column selection, set column to %
 753         my $tempcolumn='%';
 754         my $sth = $dbh->column_info( $catalog, $schema, $table, $tempcolumn ) || die $dbh->errstr;
 755         while (my $info = $sth->fetchrow_hashref()){
 756                 if ($info->{'COLUMN_NAME'} eq $column){
 757                         #column we want
 758                         if ($info->{'TYPE_NAME'} eq 'CHAR' || $info->{'TYPE_NAME'} eq 'VARCHAR'){
 759                                 $info->{'TYPE_NAME'} = 'distinct';
 760                         }
 761                         return $info->{'TYPE_NAME'};
 762                 }
 763         }
 764 }
 765
 766 =head2 get_distinct_values($column)
 767
 768 Given a column name, return an arrary ref of hashrefs suitable for use as a tmpl_loop
 769 with the distinct values of the column
 770
 771 =cut
 772
 773 sub get_distinct_values {
 774         my ($tablecolumn) = @_;
 775         my ($table,$column) = split(/\./,$tablecolumn);
 776         my $dbh = C4::Context->dbh();
 777         my $query =
 778           "SELECT distinct($column) as availablevalues FROM $table";
 779         my $sth = $dbh->prepare($query);
 780         $sth->execute();
 781     return $sth->fetchall_arrayref({});
 782 }
 783
 784 sub save_dictionary {
 785     my ( $name, $description, $sql, $area ) = @_;
 786     my $dbh   = C4::Context->dbh();
 787     my $query = "INSERT INTO reports_dictionary (name,description,saved_sql,report_area,date_created,date_modified)
 788   VALUES (?,?,?,?,now(),now())";
 789     my $sth = $dbh->prepare($query);
 790     $sth->execute($name,$description,$sql,$area) || return 0;
 791     return 1;
 792 }
 793
 794 sub get_from_dictionary {
 795     my ( $area, $id ) = @_;
 796     my $dbh   = C4::Context->dbh();
 797     my $area_name_sql_snippet = get_area_name_sql_snippet;
 798     my $query = <<EOQ;
 799 SELECT d.*, $area_name_sql_snippet
 800 FROM reports_dictionary d
 801 EOQ
 802
 803     if ($area) {
 804         $query .= " WHERE report_area = ?";
 805     } elsif ($id) {
 806         $query .= " WHERE id = ?";
 807     }
 808     my $sth = $dbh->prepare($query);
 809     if ($id) {
 810         $sth->execute($id);
 811     } elsif ($area) {
 812         $sth->execute($area);
 813     } else {
 814         $sth->execute();
 815     }
 816     my @loop;
 817     while ( my $data = $sth->fetchrow_hashref() ) {
 818         push @loop, $data;
 819     }
 820     return ( \@loop );
 821 }
 822
 823 sub delete_definition {
 824         my ($id) = @_ or return;
 825         my $dbh = C4::Context->dbh();
 826         my $query = "DELETE FROM reports_dictionary WHERE id = ?";
 827         my $sth = $dbh->prepare($query);
 828         $sth->execute($id);
 829 }
 830
 831 =head2 get_sql($report_id)
 832
 833 Given a report id, return the SQL statement for that report.
 834 Otherwise, it just returns.
 835
 836 =cut
 837
 838 sub get_sql {
 839         my ($id) = @_ or return;
 840         my $dbh = C4::Context->dbh();
 841         my $query = "SELECT * FROM saved_sql WHERE id = ?";
 842         my $sth = $dbh->prepare($query);
 843         $sth->execute($id);
 844         my $data=$sth->fetchrow_hashref();
 845         return $data->{'savedsql'};
 846 }
 847
 848 sub get_results {
 849     my ( $report_id ) = @_;
 850     my $dbh = C4::Context->dbh;
 851     return $dbh->selectall_arrayref(q|
 852         SELECT id, report, date_run
 853         FROM saved_reports
 854         WHERE report_id = ?
 855     |, { Slice => {} }, $report_id);
 856 }
 857
 858 sub _get_column_defs {
 859     my ($cgi) = @_;
 860     my %columns;
 861     my $columns_def_file = "columns.def";
 862     my $htdocs = C4::Context->config('intrahtdocs');
 863     my $section = 'intranet';
 864
 865     # We need the theme and the lang
 866     # Since columns.def is not in the modules directory, we cannot sent it for the $tmpl var
 867     my ($theme, $lang, $availablethemes) = C4::Templates::themelanguage($htdocs, 'about.tt', $section, $cgi);
 868
 869     my $full_path_to_columns_def_file="$htdocs/$theme/$lang/$columns_def_file";
 870     open (my $fh, '<:encoding(utf-8)', $full_path_to_columns_def_file);
 871     while ( my $input = <$fh> ){
 872         chomp $input;
 873         if ( $input =~ m|<field name="(.*)">(.*)</field>| ) {
 874             my ( $field, $translation ) = ( $1, $2 );
 875             $columns{$field} = $translation;
 876         }
 877     }
 878     close $fh;
 879     return \%columns;
 880 }
 881
 882 =head2 GetReservedAuthorisedValues
 883
 884     my %reserved_authorised_values = GetReservedAuthorisedValues();
 885
 886 Returns a hash containig all reserved words
 887
 888 =cut
 889
 890 sub GetReservedAuthorisedValues {
 891     my %reserved_authorised_values =
 892             map { $_ => 1 } ( 'date',
 893                               'branches',
 894                               'itemtypes',
 895                               'cn_source',
 896                               'categorycode',
 897                               'biblio_framework' );
 898
 899    return \%reserved_authorised_values;
 900 }
 901
 902
 903 =head2 IsAuthorisedValueValid
 904
 905     my $is_valid_ath_value = IsAuthorisedValueValid($authorised_value)
 906
 907 Returns 1 if $authorised_value is on the reserved authorised values list or
 908 in the authorised value categories defined in
 909
 910 =cut
 911
 912 sub IsAuthorisedValueValid {
 913
 914     my $authorised_value = shift;
 915     my $reserved_authorised_values = GetReservedAuthorisedValues();
 916
 917     if ( exists $reserved_authorised_values->{$authorised_value} ||
 918          Koha::AuthorisedValues->search({ category => $authorised_value })->count ) {
 919         return 1;
 920     }
 921
 922     return 0;
 923 }
 924
 925 =head2 GetParametersFromSQL
 926
 927     my @sql_parameters = GetParametersFromSQL($sql)
 928
 929 Returns an arrayref of hashes containing the keys name and authval
 930
 931 =cut
 932
 933 sub GetParametersFromSQL {
 934
 935     my $sql = shift ;
 936     my @split = split(/<<|>>/,$sql);
 937     my @sql_parameters = ();
 938
 939     for ( my $i = 0; $i < ($#split/2) ; $i++ ) {
 940         my ($name,$authval) = split(/\|/,$split[$i*2+1]);
 941         $authval =~ s/\:all$// if $authval;
 942         push @sql_parameters, { 'name' => $name, 'authval' => $authval };
 943     }
 944
 945     return \@sql_parameters;
 946 }
 947
 948 =head2 ValidateSQLParameters
 949
 950     my @problematic_parameters = ValidateSQLParameters($sql)
 951
 952 Returns an arrayref of hashes containing the keys name and authval of
 953 those SQL parameters that do not correspond to valid authorised names
 954
 955 =cut
 956
 957 sub ValidateSQLParameters {
 958
 959     my $sql = shift;
 960     my @problematic_parameters = ();
 961     my $sql_parameters = GetParametersFromSQL($sql);
 962
 963     foreach my $sql_parameter (@$sql_parameters) {
 964         if ( defined $sql_parameter->{'authval'} ) {
 965             push @problematic_parameters, $sql_parameter unless
 966                 IsAuthorisedValueValid($sql_parameter->{'authval'});
 967         }
 968     }
 969
 970     return \@problematic_parameters;
 971 }
 972
 973 =head2 EmailReport
 974
 975     my ( $emails, $arrayrefs ) = EmailReport($report_id, $letter_code, $module, $branch, $email)
 976
 977 Take a report and use it to process a Template Toolkit formatted notice
 978 Returns arrayrefs containing prepared letters and errors respectively
 979
 980 =cut
 981
 982 sub EmailReport {
 983
 984     my $params     = shift;
 985     my $report_id  = $params->{report_id};
 986     my $from       = $params->{from};
 987     my $email_col  = $params->{email} || 'email';
 988     my $module     = $params->{module};
 989     my $code       = $params->{code};
 990     my $branch     = $params->{branch} || "";
 991
 992     my @errors = ();
 993     my @emails = ();
 994
 995     return ( undef, [{ FATAL => "MISSING_PARAMS" }] ) unless ($report_id && $module && $code);
 996
 997     return ( undef, [{ FATAL => "NO_LETTER" }] ) unless
 998     my $letter = Koha::Notice::Templates->find({
 999         module     => $module,
1000         code       => $code,
1001         branchcode => $branch,
1002         message_transport_type => 'email',
1003     });
1004     $letter = $letter->unblessed;
1005
1006     my $report = Koha::Reports->find( $report_id );
1007     my $sql = $report->savedsql;
1008     return ( { FATAL => "NO_REPORT" } ) unless $sql;
1009
1010     my ( $sth, $errors ) = execute_query( $sql ); #don't pass offset or limit, hardcoded limit of 999,999 will be used
1011     return ( undef, [{ FATAL => "REPORT_FAIL" }] ) if $errors;
1012
1013     my $counter = 1;
1014     my $template = $letter->{content};
1015
1016     while ( my $row = $sth->fetchrow_hashref() ) {
1017         my $email;
1018         my $err_count = scalar @errors;
1019         push ( @errors, { NO_BOR_COL => $counter } ) unless defined $row->{borrowernumber};
1020         push ( @errors, { NO_EMAIL_COL => $counter } ) unless ( defined $row->{$email_col} );
1021         push ( @errors, { NO_FROM_COL => $counter } ) unless defined ( $from || $row->{from} );
1022         push ( @errors, { NO_BOR => $row->{borrowernumber} } ) unless Koha::Patrons->find({borrowernumber=>$row->{borrowernumber}});
1023
1024         my $from_address = $from || $row->{from};
1025         my $to_address = $row->{$email_col};
1026         push ( @errors, { NOT_PARSE => $counter } ) unless my $content = _process_row_TT( $row, $template );
1027         $counter++;
1028         next if scalar @errors > $err_count; #If any problems, try next
1029
1030         $letter->{content}       = $content;
1031         $email->{borrowernumber} = $row->{borrowernumber};
1032         $email->{letter}         = { %$letter };
1033         $email->{from_address}   = $from_address;
1034         $email->{to_address}     = $to_address;
1035
1036         push ( @emails, $email );
1037     }
1038
1039     return ( \@emails, \@errors );
1040
1041 }
1042
1043
1044
1045 =head2 ProcessRowTT
1046
1047    my $content = ProcessRowTT($row_hashref, $template);
1048
1049 Accepts a hashref containing values and processes them against Template Toolkit
1050 to produce content
1051
1052 =cut
1053
1054 sub _process_row_TT {
1055
1056     my ($row, $template) = @_;
1057
1058     return 0 unless ($row && $template);
1059     my $content;
1060     my $processor = Template->new();
1061     $processor->process( \$template, $row, \$content);
1062     return $content;
1063
1064 }
1065
1066 sub _get_display_value {
1067     my ( $original_value, $column ) = @_;
1068     if ( $column eq 'periodicity' ) {
1069         my $dbh = C4::Context->dbh();
1070         my $query = "SELECT description FROM subscription_frequencies WHERE id = ?";
1071         my $sth   = $dbh->prepare($query);
1072         $sth->execute($original_value);
1073         return $sth->fetchrow;
1074     }
1075     return $original_value;
1076 }
1077
1078
1079 =head3 convert_sql
1080
1081 my $updated_sql = C4::Reports::Guided::convert_sql( $sql );
1082
1083 Convert a sql query using biblioitems.marcxml to use the new
1084 biblio_metadata.metadata field instead
1085
1086 =cut
1087
1088 sub convert_sql {
1089     my ( $sql ) = @_;
1090     my $updated_sql = $sql;
1091     if ( $sql =~ m|biblioitems| and $sql =~ m|marcxml| ) {
1092         $updated_sql =~ s|biblioitems|biblio_metadata|g;
1093         $updated_sql =~ s|marcxml|metadata|g;
1094     }
1095     return $updated_sql;
1096 }
1097
1098 1;
1099 __END__
1100
1101 =head1 AUTHOR
1102
1103 Chris Cormack <crc@liblime.com>
1104
1105 =cut