t/db_dependent/Members.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Test::More tests => 47;
  21 use Test::MockModule;
  22 use Test::Exception;
  23
  24 use Data::Dumper qw/Dumper/;
  25 use C4::Context;
  26 use Koha::Database;
  27 use Koha::Holds;
  28 use Koha::List::Patron;
  29 use Koha::Patrons;
  30 use Koha::Patron::Relationship;
  31
  32 use t::lib::Mocks;
  33 use t::lib::TestBuilder;
  34
  35 BEGIN {
  36         use_ok('C4::Members');
  37 }
  38
  39 my $schema = Koha::Database->schema;
  40 $schema->storage->txn_begin;
  41 my $builder = t::lib::TestBuilder->new;
  42 my $dbh = C4::Context->dbh;
  43
  44 my $library1 = $builder->build({
  45     source => 'Branch',
  46 });
  47 my $library2 = $builder->build({
  48     source => 'Branch',
  49 });
  50 my $patron_category = $builder->build({ source => 'Category' });
  51 my $CARDNUMBER   = 'TESTCARD01';
  52 my $FIRSTNAME    = 'Marie';
  53 my $SURNAME      = 'Mcknight';
  54 my $BRANCHCODE   = $library1->{branchcode};
  55
  56 my $CHANGED_FIRSTNAME = "Marry Ann";
  57 my $EMAIL             = "Marie\@email.com";
  58 my $EMAILPRO          = "Marie\@work.com";
  59 my $PHONE             = "555-12123";
  60
  61 # XXX should be randomised and checked against the database
  62 my $IMPOSSIBLE_CARDNUMBER = "XYZZZ999";
  63
  64 t::lib::Mocks::mock_userenv();
  65
  66 # Make a borrower for testing
  67 my %data = (
  68     cardnumber => $CARDNUMBER,
  69     firstname =>  $FIRSTNAME . q{ },
  70     surname => $SURNAME,
  71     categorycode => $patron_category->{categorycode},
  72     branchcode => $BRANCHCODE,
  73     dateofbirth => '',
  74     dateexpiry => '9999-12-31',
  75     userid => 'tomasito'
  76 );
  77
  78 my $addmem=Koha::Patron->new(\%data)->store->borrowernumber;
  79 ok($addmem, "Koha::Patron->store()");
  80
  81 my $patron = Koha::Patrons->find( { cardnumber => $CARDNUMBER } )
  82   or BAIL_OUT("Cannot read member with card $CARDNUMBER");
  83 my $member = $patron->unblessed;
  84
  85 ok ( $member->{firstname}    eq $FIRSTNAME    &&
  86      $member->{surname}      eq $SURNAME      &&
  87      $member->{categorycode} eq $patron_category->{categorycode} &&
  88      $member->{branchcode}   eq $BRANCHCODE
  89      , "Got member")
  90   or diag("Mismatching member details: ".Dumper(\%data, $member));
  91
  92 is($member->{dateofbirth}, undef, "Empty dates handled correctly");
  93
  94 $member->{firstname} = $CHANGED_FIRSTNAME . q{ };
  95 $member->{email}     = $EMAIL;
  96 $member->{phone}     = $PHONE;
  97 $member->{emailpro}  = $EMAILPRO;
  98 $patron->set($member)->store;
  99 my $changedmember = Koha::Patrons->find( { cardnumber => $CARDNUMBER } )->unblessed;
 100 ok ( $changedmember->{firstname} eq $CHANGED_FIRSTNAME &&
 101      $changedmember->{email}     eq $EMAIL             &&
 102      $changedmember->{phone}     eq $PHONE             &&
 103      $changedmember->{emailpro}  eq $EMAILPRO
 104      , "Member Changed")
 105   or diag("Mismatching member details: ".Dumper($member, $changedmember));
 106
 107 t::lib::Mocks::mock_preference( 'CardnumberLength', '' );
 108 C4::Context->clear_syspref_cache();
 109
 110 my $checkcardnum=C4::Members::checkcardnumber($CARDNUMBER, "");
 111 is ($checkcardnum, "1", "Card No. in use");
 112
 113 $checkcardnum=C4::Members::checkcardnumber($IMPOSSIBLE_CARDNUMBER, "");
 114 is ($checkcardnum, "0", "Card No. not used");
 115
 116 t::lib::Mocks::mock_preference( 'CardnumberLength', '4' );
 117 C4::Context->clear_syspref_cache();
 118
 119 $checkcardnum=C4::Members::checkcardnumber($IMPOSSIBLE_CARDNUMBER, "");
 120 is ($checkcardnum, "2", "Card number is too long");
 121
 122
 123 # Add a new borrower
 124 %data = (
 125     cardnumber   => "123456789",
 126     firstname    => "Tomasito",
 127     surname      => "None",
 128     categorycode => $patron_category->{categorycode},
 129     branchcode   => $library2->{branchcode},
 130     dateofbirth  => '',
 131     debarred     => '',
 132     dateexpiry   => '',
 133     dateenrolled => '',
 134 );
 135 my $borrowernumber = Koha::Patron->new( \%data )->store->borrowernumber;
 136 $patron = Koha::Patrons->find( $borrowernumber );
 137 my $borrower = $patron->unblessed;
 138 is( $borrower->{dateofbirth}, undef, 'Koha::Patron->store should undef dateofbirth if empty string is given');
 139 is( $borrower->{debarred}, undef, 'Koha::Patron->store should undef debarred if empty string is given');
 140 isnt( $borrower->{dateexpiry}, '0000-00-00', 'Koha::Patron->store should not set dateexpiry to 0000-00-00 if empty string is given');
 141 isnt( $borrower->{dateenrolled}, '0000-00-00', 'Koha::Patron->store should not set dateenrolled to 0000-00-00 if empty string is given');
 142
 143 $patron->set({ dateofbirth => '', debarred => '', dateexpiry => '', dateenrolled => '' })->store;
 144 $borrower = Koha::Patrons->find( $borrowernumber )->unblessed;
 145 is( $borrower->{dateofbirth}, undef, 'Koha::Patron->store should undef dateofbirth if empty string is given');
 146 is( $borrower->{debarred}, undef, 'Koha::Patron->store should undef debarred if empty string is given');
 147 isnt( $borrower->{dateexpiry}, '0000-00-00', 'Koha::Patron->store should not set dateexpiry to 0000-00-00 if empty string is given');
 148 isnt( $borrower->{dateenrolled}, '0000-00-00', 'Koha::Patron->store should not set dateenrolled to 0000-00-00 if empty string is given');
 149
 150 $patron->set({ dateofbirth => '1970-01-01', debarred => '2042-01-01', dateexpiry => '9999-12-31', dateenrolled => '2015-09-06' })->store;
 151 $borrower = Koha::Patrons->find( $borrowernumber )->unblessed;
 152 is( $borrower->{dateofbirth}, '1970-01-01', 'Koha::Patron->store should correctly set dateofbirth if a valid date is given');
 153 is( $borrower->{debarred}, '2042-01-01', 'Koha::Patron->store should correctly set debarred if a valid date is given');
 154 is( $borrower->{dateexpiry}, '9999-12-31', 'Koha::Patron->store should correctly set dateexpiry if a valid date is given');
 155 is( $borrower->{dateenrolled}, '2015-09-06', 'Koha::Patron->store should correctly set dateenrolled if a valid date is given');
 156
 157 subtest 'Koha::Patron->store should not update userid if not true' => sub {
 158     plan tests => 3;
 159
 160     # TODO Move this to t/db_dependent/Koha/Patrons.t subtest ->store
 161
 162     $data{ cardnumber } = "234567890";
 163     $data{userid} = 'a_user_id';
 164     $borrowernumber = Koha::Patron->new( \%data )->store->borrowernumber;
 165     my $patron = Koha::Patrons->find( $borrowernumber );
 166     my $borrower = $patron->unblessed;
 167
 168     $patron->set( { firstname => 'Tomas', userid => '' } )->store;
 169     $borrower = Koha::Patrons->find( $borrowernumber )->unblessed;
 170     is ( $borrower->{userid}, $data{userid}, 'Koha::Patron->store should not update the userid with an empty string' );
 171     $patron->set( { firstname => 'Tomas', userid => 0 } )->store;
 172     $borrower = Koha::Patrons->find( $borrowernumber )->unblessed;
 173     is ( $borrower->{userid}, $data{userid}, 'Koha::Patron->store should not update the userid with an 0');
 174     $patron->set( { firstname => 'Tomas', userid => undef } )->store;
 175     $borrower = Koha::Patrons->find( $borrowernumber )->unblessed;
 176     is ( $borrower->{userid}, $data{userid}, 'Koha::Patron->store should not update the userid with an undefined value');
 177 };
 178
 179 #Regression tests for bug 10612
 180 my $library3 = $builder->build({
 181     source => 'Branch',
 182 });
 183 $builder->build({
 184         source => 'Category',
 185         value => {
 186             categorycode         => 'STAFFER',
 187             description          => 'Staff dont batch del',
 188             category_type        => 'S',
 189         },
 190 });
 191
 192 $builder->build({
 193         source => 'Category',
 194         value => {
 195             categorycode         => 'CIVILIAN',
 196             description          => 'Civilian batch del',
 197             category_type        => 'A',
 198         },
 199 });
 200
 201 $builder->build({
 202         source => 'Category',
 203         value => {
 204             categorycode         => 'KIDclamp',
 205             description          => 'Kid to be guaranteed',
 206             category_type        => 'C',
 207         },
 208 });
 209
 210 my $borrower1 = $builder->build({
 211         source => 'Borrower',
 212         value  => {
 213             categorycode=>'STAFFER',
 214             branchcode => $library3->{branchcode},
 215             dateexpiry => '2015-01-01',
 216         },
 217 });
 218 my $bor1inlist = $borrower1->{borrowernumber};
 219 my $borrower2 = $builder->build({
 220         source => 'Borrower',
 221         value  => {
 222             categorycode=>'STAFFER',
 223             branchcode => $library3->{branchcode},
 224             dateexpiry => '2015-01-01',
 225         },
 226 });
 227
 228 my $guarantee = $builder->build({
 229         source => 'Borrower',
 230         value  => {
 231             categorycode=>'KIDclamp',
 232             branchcode => $library3->{branchcode},
 233             dateexpiry => '2015-01-01',
 234         },
 235 });
 236
 237 my $bor2inlist = $borrower2->{borrowernumber};
 238
 239 $builder->build({
 240         source => 'OldIssue',
 241         value  => {
 242             borrowernumber => $bor2inlist,
 243             timestamp => '2016-01-01',
 244         },
 245 });
 246
 247 # The following calls to GetBorrowersToExpunge are assuming that the pref
 248 # IndependentBranches is off.
 249 t::lib::Mocks::mock_preference('IndependentBranches', 0);
 250
 251 my $owner = Koha::Patron->new({ categorycode => 'STAFFER', branchcode => $library2->{branchcode} })->store->borrowernumber;
 252 my $list1 = AddPatronList( { name => 'Test List 1', owner => $owner } );
 253 my @listpatrons = ($bor1inlist, $bor2inlist);
 254 AddPatronsToList(  { list => $list1, borrowernumbers => \@listpatrons });
 255 my $patstodel = GetBorrowersToExpunge( {patron_list_id => $list1->patron_list_id() } );
 256 is( scalar(@$patstodel),0,'No staff deleted from list of all staff');
 257 Koha::Patrons->find($bor2inlist)->set({ categorycode => 'CIVILIAN' })->store;
 258 $patstodel = GetBorrowersToExpunge( {patron_list_id => $list1->patron_list_id()} );
 259 ok( scalar(@$patstodel)== 1 && $patstodel->[0]->{'borrowernumber'} eq $bor2inlist,'Staff patron not deleted from list');
 260 $patstodel = GetBorrowersToExpunge( {branchcode => $library3->{branchcode},patron_list_id => $list1->patron_list_id() } );
 261 ok( scalar(@$patstodel) == 1 && $patstodel->[0]->{'borrowernumber'} eq $bor2inlist,'Staff patron not deleted by branchcode and list');
 262 $patstodel = GetBorrowersToExpunge( {expired_before => '2015-01-02', patron_list_id => $list1->patron_list_id() } );
 263 ok( scalar(@$patstodel) == 1 && $patstodel->[0]->{'borrowernumber'} eq $bor2inlist,'Staff patron not deleted by expirationdate and list');
 264 $patstodel = GetBorrowersToExpunge( {not_borrowed_since => '2016-01-02', patron_list_id => $list1->patron_list_id() } );
 265 ok( scalar(@$patstodel) == 1 && $patstodel->[0]->{'borrowernumber'} eq $bor2inlist,'Staff patron not deleted by last issue date');
 266
 267 Koha::Patrons->find($bor1inlist)->set({ categorycode => 'CIVILIAN' })->store;
 268
 269 t::lib::Mocks::mock_preference( 'borrowerRelationship', 'test' );
 270
 271 my $relationship = Koha::Patron::Relationship->new( { guarantor_id => $bor1inlist, guarantee_id => $guarantee->{borrowernumber}, relationship => 'test' } )->store();
 272
 273 $patstodel = GetBorrowersToExpunge( {patron_list_id => $list1->patron_list_id()} );
 274 ok( scalar(@$patstodel)== 1 && $patstodel->[0]->{'borrowernumber'} eq $bor2inlist,'Guarantor patron not deleted from list');
 275 $patstodel = GetBorrowersToExpunge( {branchcode => $library3->{branchcode},patron_list_id => $list1->patron_list_id() } );
 276 ok( scalar(@$patstodel) == 1 && $patstodel->[0]->{'borrowernumber'} eq $bor2inlist,'Guarantor patron not deleted by branchcode and list');
 277 $patstodel = GetBorrowersToExpunge( {expired_before => '2015-01-02', patron_list_id => $list1->patron_list_id() } );
 278 ok( scalar(@$patstodel) == 1 && $patstodel->[0]->{'borrowernumber'} eq $bor2inlist,'Guarantor patron not deleted by expirationdate and list');
 279 $patstodel = GetBorrowersToExpunge( {not_borrowed_since => '2016-01-02', patron_list_id => $list1->patron_list_id() } );
 280 ok( scalar(@$patstodel) == 1 && $patstodel->[0]->{'borrowernumber'} eq $bor2inlist,'Guarantor patron not deleted by last issue date');
 281 $relationship->delete();
 282
 283 $builder->build({
 284         source => 'Issue',
 285         value  => {
 286             borrowernumber => $bor2inlist,
 287         },
 288 });
 289 $patstodel = GetBorrowersToExpunge( {patron_list_id => $list1->patron_list_id()} );
 290 is( scalar(@$patstodel),1,'Borrower with issue not deleted from list');
 291 $patstodel = GetBorrowersToExpunge( {branchcode => $library3->{branchcode},patron_list_id => $list1->patron_list_id() } );
 292 is( scalar(@$patstodel),1,'Borrower with issue not deleted by branchcode and list');
 293 $patstodel = GetBorrowersToExpunge( {category_code => 'CIVILIAN',patron_list_id => $list1->patron_list_id() } );
 294 is( scalar(@$patstodel),1,'Borrower with issue not deleted by category_code and list');
 295 $patstodel = GetBorrowersToExpunge( {expired_before => '2015-01-02',patron_list_id => $list1->patron_list_id() } );
 296 is( scalar(@$patstodel),1,'Borrower with issue not deleted by expiration_date and list');
 297 $builder->schema->resultset( 'Issue' )->delete_all;
 298 $patstodel = GetBorrowersToExpunge( {patron_list_id => $list1->patron_list_id()} );
 299 ok( scalar(@$patstodel)== 2,'Borrowers without issue deleted from list');
 300 $patstodel = GetBorrowersToExpunge( {category_code => 'CIVILIAN',patron_list_id => $list1->patron_list_id() } );
 301 is( scalar(@$patstodel),2,'Borrowers without issues deleted by category_code and list');
 302 $patstodel = GetBorrowersToExpunge( {expired_before => '2015-01-02',patron_list_id => $list1->patron_list_id() } );
 303 is( scalar(@$patstodel),2,'Borrowers without issues deleted by expiration_date and list');
 304 $patstodel = GetBorrowersToExpunge( {not_borrowed_since => '2016-01-02', patron_list_id => $list1->patron_list_id() } );
 305 is( scalar(@$patstodel),2,'Borrowers without issues deleted by last issue date');
 306
 307 # Test GetBorrowersToExpunge and TrackLastPatronActivity
 308 $dbh->do(q|UPDATE borrowers SET lastseen=NULL|);
 309 $builder->build({ source => 'Borrower', value => { lastseen => '2016-01-01 01:01:01', categorycode => 'CIVILIAN' } } );
 310 $builder->build({ source => 'Borrower', value => { lastseen => '2016-02-02 02:02:02', categorycode => 'CIVILIAN' } } );
 311 $builder->build({ source => 'Borrower', value => { lastseen => '2016-03-03 03:03:03', categorycode => 'CIVILIAN' } } );
 312 $patstodel = GetBorrowersToExpunge( { last_seen => '1999-12-12' });
 313 is( scalar @$patstodel, 0, 'TrackLastPatronActivity - 0 patrons must be deleted' );
 314 $patstodel = GetBorrowersToExpunge( { last_seen => '2016-02-15' });
 315 is( scalar @$patstodel, 2, 'TrackLastPatronActivity - 2 patrons must be deleted' );
 316 $patstodel = GetBorrowersToExpunge( { last_seen => '2016-04-04' });
 317 is( scalar @$patstodel, 3, 'TrackLastPatronActivity - 3 patrons must be deleted' );
 318 my $patron2 = $builder->build({ source => 'Borrower', value => { lastseen => undef } });
 319 t::lib::Mocks::mock_preference( 'TrackLastPatronActivity', '0' );
 320 Koha::Patrons->find( $patron2->{borrowernumber} )->track_login;
 321 is( Koha::Patrons->find( $patron2->{borrowernumber} )->lastseen, undef, 'Lastseen should not be changed' );
 322 Koha::Patrons->find( $patron2->{borrowernumber} )->track_login({ force => 1 });
 323 isnt( Koha::Patrons->find( $patron2->{borrowernumber} )->lastseen, undef, 'Lastseen should be changed now' );
 324
 325 # Regression tests for BZ13502
 326 ## Remove all entries with userid='' (should be only 1 max)
 327 $dbh->do(q|DELETE FROM borrowers WHERE userid = ''|);
 328 ## And create a patron with a userid=''
 329 $borrowernumber = Koha::Patron->new({ categorycode => $patron_category->{categorycode}, branchcode => $library2->{branchcode} })->store->borrowernumber;
 330 $dbh->do(q|UPDATE borrowers SET userid = '' WHERE borrowernumber = ?|, undef, $borrowernumber);
 331 # Create another patron and verify the userid has been generated
 332 $borrowernumber = Koha::Patron->new({ categorycode => $patron_category->{categorycode}, branchcode => $library2->{branchcode} })->store->borrowernumber;
 333 ok( $borrowernumber > 0, 'Koha::Patron->store should have inserted the patron even if no userid is given' );
 334 $borrower = Koha::Patrons->find( $borrowernumber )->unblessed;
 335 ok( $borrower->{userid},  'A userid should have been generated correctly' );
 336
 337 subtest 'purgeSelfRegistration' => sub {
 338     plan tests => 5;
 339
 340     #purge unverified
 341     my $d=360;
 342     C4::Members::DeleteUnverifiedOpacRegistrations($d);
 343     foreach(1..3) {
 344         $dbh->do("INSERT INTO borrower_modifications (timestamp, borrowernumber, verification_token) VALUES ('2014-01-01 01:02:03',0,?)", undef, (scalar localtime)."_$_");
 345     }
 346     is( C4::Members::DeleteUnverifiedOpacRegistrations($d), 3, 'Test for DeleteUnverifiedOpacRegistrations' );
 347
 348     #purge members in temporary category
 349     my $c= 'XYZ';
 350     $dbh->do("INSERT IGNORE INTO categories (categorycode) VALUES ('$c')");
 351     t::lib::Mocks::mock_preference('PatronSelfRegistrationDefaultCategory', $c );
 352     t::lib::Mocks::mock_preference('PatronSelfRegistrationExpireTemporaryAccountsDelay', 360);
 353     C4::Members::DeleteExpiredOpacRegistrations();
 354     my $self_reg = $builder->build_object({
 355         class => 'Koha::Patrons',
 356         value => {
 357             dateenrolled => '2014-01-01 01:02:03',
 358             categorycode => $c
 359         }
 360     });
 361
 362     my $checkout     = $builder->build_object({
 363         class=>'Koha::Checkouts',
 364         value=>{
 365             borrowernumber=>$self_reg->borrowernumber
 366         }
 367     });
 368     is( C4::Members::DeleteExpiredOpacRegistrations(), 0, "DeleteExpiredOpacRegistrations doesn't delete borrower with checkout");
 369
 370     my $account_line = $builder->build_object({
 371         class=>'Koha::Account::Lines',
 372         value=>{
 373             borrowernumber=>$self_reg->borrowernumber,
 374             amountoutstanding=>5
 375         }
 376     });
 377     is( C4::Members::DeleteExpiredOpacRegistrations(), 0, "DeleteExpiredOpacRegistrations doesn't delete borrower with checkout and fine");
 378
 379     $checkout->delete;
 380     is( C4::Members::DeleteExpiredOpacRegistrations(), 0, "DeleteExpiredOpacRegistrations doesn't delete borrower with fine and no checkout");
 381
 382     $account_line->delete;
 383     is( C4::Members::DeleteExpiredOpacRegistrations(), 1, "DeleteExpiredOpacRegistrations does delete borrower with no fines and no checkouts");
 384
 385 };
 386
 387 sub _find_member {
 388     my ($resultset) = @_;
 389     my $found = $resultset && grep( { $_->{cardnumber} && $_->{cardnumber} eq $CARDNUMBER } @$resultset );
 390     return $found;
 391 }
 392
 393 $schema->storage->txn_rollback;
 394
 395 subtest 'Koha::Patron->store (invalid categorycode) tests' => sub {
 396     plan tests => 1;
 397     # TODO Move this to t/db_dependent/Koha/Patrons.t subtest ->store
 398
 399     $schema->storage->txn_begin;
 400
 401     my $category    = $builder->build_object({ class => 'Koha::Patron::Categories' });
 402     my $category_id = $category->id;
 403     # Remove category to make sure the id is not on the DB
 404     $category->delete;
 405
 406     my $patron_data = {
 407         categorycode => $category_id
 408     };
 409
 410     throws_ok
 411         { Koha::Patron->new( $patron_data )->store; }
 412         'Koha::Exceptions::Object::FKConstraint',
 413         'AddMember raises an exception on invalid categorycode';
 414
 415     $schema->storage->txn_rollback;
 416 };