admin/library_groups.pl

   1 #! /usr/bin/perl
   2
   3 # Copyright 2016 ByWater Solutions
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use CGI qw ( -utf8 );
  22 use C4::Context;
  23 use C4::Auth;
  24 use C4::Output;
  25
  26 use Koha::Libraries;
  27 use Koha::Library::Group;
  28 use Koha::Library::Groups;
  29
  30 my $cgi = CGI->new;
  31
  32 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  33     {
  34         template_name   => "admin/library_groups.tt",
  35         query           => $cgi,
  36         type            => "intranet",
  37         flagsrequired   => { parameters => 'manage_libraries' },
  38         debug           => 1,
  39     }
  40 );
  41
  42 my $action = $cgi->param('action') || q{};
  43 my @messages;
  44
  45 if ( $action eq 'add' ) {
  46     my $parent_id   = $cgi->param('parent_id')   || undef;
  47     my $title       = $cgi->param('title')       || undef;
  48     my $description = $cgi->param('description') || undef;
  49     my $branchcode  = $cgi->param('branchcode')  || undef;
  50     my $ft_hide_patron_info    = $cgi->param('ft_hide_patron_info')    || 0;
  51     my $ft_search_groups_opac  = $cgi->param('ft_search_groups_opac')  || 0;
  52     my $ft_search_groups_staff = $cgi->param('ft_search_groups_staff') || 0;
  53     my $ft_local_hold_group = $cgi->param('ft_local_hold_group') || 0;
  54
  55     if ( !$branchcode && Koha::Library::Groups->search( { title => $title } )->count() ) {
  56         $template->param( error_duplicate_title => $title );
  57     }
  58     else {
  59         my $group = eval {
  60             Koha::Library::Group->new(
  61                 {
  62                     parent_id              => $parent_id,
  63                     title                  => $title,
  64                     description            => $description,
  65                     ft_hide_patron_info    => $ft_hide_patron_info,
  66                     ft_search_groups_opac  => $ft_search_groups_opac,
  67                     ft_search_groups_staff => $ft_search_groups_staff,
  68                     ft_local_hold_group    => $ft_local_hold_group,
  69                     branchcode             => $branchcode,
  70                 }
  71             )->store();
  72         };
  73         if ($@) {
  74             push @messages, { type => 'alert', code => 'error_on_insert' };
  75         }
  76         else {
  77             $template->param( added => $group );
  78         }
  79     }
  80 }
  81 elsif ( $action eq 'edit' ) {
  82     my $id          = $cgi->param('id')          || undef;
  83     my $title       = $cgi->param('title')       || undef;
  84     my $description = $cgi->param('description') || undef;
  85     my $ft_hide_patron_info    = $cgi->param('ft_hide_patron_info')    || 0;
  86     my $ft_search_groups_opac  = $cgi->param('ft_search_groups_opac')  || 0;
  87     my $ft_search_groups_staff = $cgi->param('ft_search_groups_staff') || 0;
  88     my $ft_local_hold_group = $cgi->param('ft_local_hold_group') || 0;
  89
  90     if ($id) {
  91         my $group = Koha::Library::Groups->find($id);
  92
  93         $group->set(
  94             {
  95                 title       => $title,
  96                 description => $description,
  97                 ft_hide_patron_info      => $ft_hide_patron_info,
  98                 ft_search_groups_opac    => $ft_search_groups_opac,
  99                 ft_search_groups_staff   => $ft_search_groups_staff,
 100                 ft_local_hold_group   => $ft_local_hold_group,
 101             }
 102         )->store();
 103
 104         $template->param( edited => $group );
 105     }
 106 }
 107 elsif ( $action eq 'delete' ) {
 108     my $id = $cgi->param('id');
 109
 110     my $group = Koha::Library::Groups->find($id);
 111
 112     if ($group) {
 113         $group->delete();
 114         $template->param(
 115             deleted => {
 116                 title   => $group->title(),
 117                 library => $group->library()
 118                 ? $group->library()->branchname
 119                 : undef
 120             }
 121         );
 122     }
 123 }
 124
 125 my $root_groups = Koha::Library::Groups->get_root_groups();
 126
 127 $template->param( root_groups => $root_groups, messages => \@messages, );
 128
 129 output_html_with_http_headers $cgi, $cookie, $template->output;