opac/opac-downloadshelf.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 BibLibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23 use Encode qw(encode);
  24
  25 use C4::Auth;
  26 use C4::Biblio;
  27 use C4::Items;
  28 use C4::Output;
  29 use C4::Record;
  30 use C4::Ris;
  31 use Koha::CsvProfiles;
  32 use Koha::RecordProcessor;
  33 use Koha::Virtualshelves;
  34
  35 use utf8;
  36 my $query = new CGI;
  37
  38 # if virtualshelves is disabled, leave immediately
  39 if ( ! C4::Context->preference('virtualshelves') ) {
  40     print $query->redirect("/cgi-bin/koha/errors/404.pl");
  41     exit;
  42 }
  43
  44 my ( $template, $borrowernumber, $cookie ) = get_template_and_user (
  45     {
  46         template_name   => "opac-downloadshelf.tt",
  47         query           => $query,
  48         type            => "opac",
  49         authnotrequired => ( C4::Context->preference("OpacPublic") ? 1 : 0 ),
  50     }
  51 );
  52
  53 my $borcat = q{};
  54 if ( C4::Context->preference('OpacHiddenItemsExceptions') ) {
  55     # we need to fetch the borrower info here, so we can pass the category
  56     my $borrower = Koha::Patrons->find( { borrowernumber => $borrowernumber } );
  57     $borcat = $borrower ? $borrower->categorycode : $borcat;
  58 }
  59
  60 my $shelfnumber = $query->param('shelfnumber');
  61 my $format  = $query->param('format');
  62 my $context = $query->param('context');
  63
  64 my $shelf = Koha::Virtualshelves->find( $shelfnumber );
  65 if ( $shelf and $shelf->can_be_viewed( $borrowernumber ) ) {
  66
  67     if ($shelfnumber && $format) {
  68
  69
  70         my $contents = $shelf->get_contents;
  71         my $marcflavour = C4::Context->preference('marcflavour');
  72         my $output;
  73         my $extension;
  74         my $type;
  75
  76        # CSV
  77         if ($format =~ /^\d+$/) {
  78
  79             my $csv_profile = Koha::CsvProfiles->find($format);
  80             if ( not $csv_profile or $csv_profile->staff_only ) {
  81                 print $query->redirect('/cgi-bin/koha/errors/404.pl');
  82                 exit;
  83             }
  84
  85             my @biblios;
  86             while ( my $content = $contents->next ) {
  87                 push @biblios, $content->biblionumber;
  88             }
  89             $output = marc2csv(\@biblios, $format);
  90         # Other formats
  91         } else {
  92             my $record_processor = Koha::RecordProcessor->new({
  93                 filters => 'ViewPolicy'
  94             });
  95             while ( my $content = $contents->next ) {
  96                 my $biblionumber = $content->biblionumber;
  97
  98                 my $record = GetMarcBiblio({
  99                     biblionumber => $biblionumber,
 100                     embed_items  => 1,
 101                     opac         => 1,
 102                     borcat       => $borcat });
 103                 my $framework = &GetFrameworkCode( $biblionumber );
 104                 $record_processor->options({
 105                     interface => 'opac',
 106                     frameworkcode => $framework
 107                 });
 108                 $record_processor->process($record);
 109                 next unless $record;
 110
 111                 if ($format eq 'iso2709') {
 112                     $output .= $record->as_usmarc();
 113                 }
 114                 elsif ($format eq 'ris' ) {
 115                     $output .= marc2ris($record);
 116                 }
 117                 elsif ($format eq 'bibtex') {
 118                     $output .= marc2bibtex($record, $biblionumber);
 119                 }
 120                 elsif ( $format eq 'isbd' ) {
 121                     $output   .= GetISBDView({
 122                         'record'    => $record,
 123                         'template'  => 'opac',
 124                         'framework' => $framework,
 125                     });
 126                     $extension = "txt";
 127                     $type      = "text/plain";
 128                 }
 129             }
 130         }
 131
 132         # If it was a CSV export we change the format after the export so the file extension is fine
 133         $format = "csv" if ($format =~ m/^\d+$/);
 134
 135         print $query->header(
 136                                    -type => ($type) ? $type : 'application/octet-stream',
 137             -'Content-Transfer-Encoding' => 'binary',
 138                              -attachment => ($extension) ? "shelf.$format.$extension" : "shelf.$format"
 139         );
 140         print $output;
 141
 142     } else {
 143
 144         # if modal context is passed set a variable so that page markup can be different
 145         if($context eq "modal"){
 146             $template->param(modal => 1);
 147         } else {
 148             $template->param(fullpage => 1);
 149         }
 150         $template->param(
 151             csv_profiles => [
 152                 Koha::CsvProfiles->search(
 153                     {
 154                         type       => 'marc',
 155                         used_for   => 'export_records',
 156                         staff_only => 0
 157                     }
 158                 )
 159             ]
 160         );
 161         $template->param( shelf => $shelf );
 162         output_html_with_http_headers $query, $cookie, $template->output;
 163     }
 164
 165 } else {
 166     $template->param(invalidlist => 1);
 167     output_html_with_http_headers $query, $cookie, $template->output;
 168 }