members/statistics.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2012 BibLibre
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along with
  16 # Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 =head1 members/statistics.pl
  20
  21   Generate statistic issues for a member
  22
  23 =cut
  24
  25 use Modern::Perl;
  26
  27 use CGI;
  28 use C4::Auth;
  29 use C4::Branch;
  30 use C4::Context;
  31 use C4::Members;
  32 use C4::Members::Statistics;
  33 use C4::Members::Attributes qw(GetBorrowerAttributes);
  34 use C4::Output;
  35
  36 my $input = new CGI;
  37
  38 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  39     {   template_name   => "members/statistics.tt",
  40         query           => $input,
  41         type            => "intranet",
  42         authnotrequired => 0,
  43         flagsrequired   => { borrowers => 1 },
  44         debug           => 1,
  45     }
  46 );
  47
  48 my $borrowernumber = $input->param('borrowernumber');
  49
  50 # Set informations for the patron
  51 my $borrower = GetMemberDetails( $borrowernumber, 0 );
  52 if ( not defined $borrower ) {
  53     $template->param (unknowuser => 1);
  54     output_html_with_http_headers $input, $cookie, $template->output;
  55     exit;
  56 }
  57
  58 foreach my $key ( keys %$borrower ) {
  59     $template->param( $key => $borrower->{$key} );
  60 }
  61 $template->param(
  62     categoryname    => $borrower->{'description'},
  63     branchname      => GetBranchName($borrower->{'branchcode'}),
  64 );
  65 # Construct column names
  66 my $fields = C4::Members::Statistics::get_fields();
  67 our @statistic_column_names = split '\|', $fields;
  68 our @value_column_names = ( 'count_precedent_state', 'count_total_issues_today', 'count_total_issues_returned_today' );
  69 our @column_names = ( @statistic_column_names, @value_column_names );
  70
  71 # Get statistics
  72 my $precedent_state = GetPrecedentStateByBorrower( $borrowernumber );
  73 my $total_issues_today = GetTotalIssuesTodayByBorrower( $borrowernumber );
  74 my $total_issues_returned_today = GetTotalIssuesReturnedTodayByBorrower( $borrowernumber );
  75 my $r = merge (
  76     @$precedent_state, @$total_issues_today, @$total_issues_returned_today
  77 );
  78
  79 add_actual_state( $r );
  80 my ( $total, $datas ) = build_array( $r );
  81
  82 # Gettings sums
  83 my $count_total_precedent_state = $total->{count_precedent_state} || 0;
  84 my $count_total_issues = $total->{count_total_issues_today} || 0;
  85 my $count_total_issues_returned = $total->{count_total_issues_returned_today} || 0;
  86 my $count_total_actual_state = ($count_total_precedent_state - $count_total_issues_returned + $count_total_issues);
  87
  88 if (C4::Context->preference('ExtendedPatronAttributes')) {
  89     my $attributes = GetBorrowerAttributes($borrowernumber);
  90     $template->param(
  91         ExtendedPatronAttributes => 1,
  92         extendedattributes => $attributes
  93     );
  94 }
  95
  96 my ($picture, $dberror) = GetPatronImage($borrower->{'borrowernumber'});
  97 $template->param( picture => 1 ) if $picture;
  98
  99 # Computes full borrower address
 100 my $roadtype = C4::Koha::GetAuthorisedValueByCode( 'ROADTYPE', $borrower->{streettype} );
 101 my $address = $borrower->{'streetnumber'} . " $roadtype " . $borrower->{'address'};
 102
 103 $template->param(
 104     statisticsview => 1,
 105     datas          => $datas,
 106     address        => $address,
 107     column_names   => \@statistic_column_names,
 108     count_total_issues => $count_total_issues,
 109     count_total_issues_returned => $count_total_issues_returned,
 110     count_total_precedent_state => $count_total_precedent_state,
 111     count_total_actual_state => $count_total_actual_state,
 112     RoutingSerials => C4::Context->preference('RoutingSerials'),
 113 );
 114
 115 output_html_with_http_headers $input, $cookie, $template->output;
 116
 117
 118 =head1 FUNCTIONS
 119
 120 =head2 add_actual_state
 121
 122   Add a 'count_actual_state' key in all hashes
 123   count_actual_state = count_precedent_state - count_total_issues_returned_today + count_total_issues_today
 124
 125 =cut
 126
 127 sub add_actual_state {
 128     my ( $array ) = @_;
 129     for my $hash ( @$array ) {
 130         $hash->{count_actual_state} = ( $hash->{count_precedent_state} // 0 ) - ( $hash->{count_total_issues_returned_today} // 0 ) + ( $hash->{count_total_issues_today} // 0 );
 131     }
 132 }
 133
 134 =head2 build_array
 135
 136   Build a new array containing values of hashes.
 137   It used by template whitch display silly values.
 138   ex:
 139     $array = [
 140       {
 141         'count_total_issues_returned_today' => 1,
 142         'ccode' => 'ccode',
 143         'count_actual_state' => 1,
 144         'count_precedent_state' => 1,
 145         'homebranch' => 'homebranch',
 146         'count_total_issues_today' => 1,
 147         'itype' => 'itype'
 148       }
 149     ];
 150   and returns:
 151     [
 152       [
 153         'homebranch',
 154         'itype',
 155         'ccode',
 156         1,
 157         1,
 158         1,
 159         1
 160       ]
 161     ];
 162
 163 =cut
 164
 165 sub build_array {
 166     my ( $array ) = @_;
 167     my ( @r, $total );
 168     for my $hash ( @$array) {
 169         my @line;
 170         for my $cn ( ( @column_names, 'count_actual_state') ) {
 171             if ( grep /$cn/, ( @value_column_names, 'count_actual_state') ) {
 172                 $hash->{$cn} //= 0;
 173                 if ( exists $total->{$cn} ) {
 174                     $total->{$cn} += $hash->{$cn} if $hash->{$cn};
 175                 } else {
 176                     $total->{$cn} = $hash->{$cn};
 177                 }
 178             }
 179             push @line, $hash->{$cn};
 180         }
 181         push @r, \@line;
 182     }
 183     return ( $total, \@r );
 184 }
 185
 186 =head2 merge
 187
 188   Merge hashes with the same statistic column names into one
 189   param: array, a arrayref of arrayrefs
 190   ex:
 191   @array = (
 192      {
 193        'ccode' => 'ccode',
 194        'count_precedent_state' => '1',
 195        'homebranch' => 'homebranch',
 196        'itype' => 'itype'
 197      },
 198      {
 199        'count_total_issues_returned_today' => '1',
 200        'ccode' => 'ccode',
 201        'homebranch' => 'homebranch',
 202        'itype' => 'itype'
 203      }
 204    );
 205    and returns:
 206    [
 207      {
 208        'count_total_issues_returned_today' => '1',
 209        'ccode' => 'ccode',
 210        'count_precedent_state' => '1',
 211        'homebranch' => 'homebranch',
 212        'itype' => 'itype'
 213      }
 214    ];
 215
 216 =cut
 217
 218 sub merge {
 219     my @array = @_;
 220     my @r;
 221     for my $h ( @array ) {
 222         my $exists = 0;
 223         for my $ch ( @r ) {
 224             $exists = 1;
 225             for my $cn ( @statistic_column_names ) {
 226                 if ( $ch->{$cn} and not $ch->{$cn} eq $h->{$cn} ) {
 227                     $exists = 0;
 228                     last;
 229                 }
 230             }
 231             if ($exists){
 232                 for my $cn ( @value_column_names ) {
 233                     next if not exists $h->{$cn};
 234                     $ch->{$cn} = $h->{$cn} ? $h->{$cn} : 0;
 235                 }
 236                 last;
 237             }
 238         }
 239
 240         if ( not $exists ) {push @r, $h;}
 241     }
 242     return \@r;
 243 }