members/paycollect.pl

   1 #!/usr/bin/perl
   2 # Copyright 2009,2010 PTFS Inc.
   3 # Copyright 2011 PTFS-Europe Ltd
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use URI::Escape;
  22 use CGI qw ( -utf8 );
  23
  24 use C4::Context;
  25 use C4::Auth;
  26 use C4::Output;
  27 use C4::Members;
  28 use C4::Accounts;
  29 use C4::Koha;
  30
  31 use Koha::Patrons;
  32 use Koha::Patron::Categories;
  33 use Koha::AuthorisedValues;
  34 use Koha::Account;
  35 use Koha::Token;
  36
  37 my $input = CGI->new();
  38
  39 my $payment_id          = $input->param('payment_id');
  40 my $writeoff_individual = $input->param('writeoff_individual');
  41 my $type                = scalar $input->param('type') || 'payment';
  42
  43 my $updatecharges_permissions = ($writeoff_individual || $type eq 'writeoff') ? 'writeoff' : 'remaining_permissions';
  44 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  45     {   template_name   => 'members/paycollect.tt',
  46         query           => $input,
  47         type            => 'intranet',
  48         authnotrequired => 0,
  49         flagsrequired   => { borrowers => 'edit_borrowers', updatecharges => $updatecharges_permissions },
  50         debug           => 1,
  51     }
  52 );
  53
  54 # get borrower details
  55 my $borrowernumber = $input->param('borrowernumber');
  56 my $logged_in_user = Koha::Patrons->find( $loggedinuser ) or die "Not logged in";
  57 my $patron         = Koha::Patrons->find( $borrowernumber );
  58 output_and_exit_if_error( $input, $cookie, $template, { module => 'members', logged_in_user => $logged_in_user, current_patron => $patron } );
  59
  60 my $borrower       = $patron->unblessed;
  61 my $account        = $patron->account;
  62 my $category       = $patron->category;
  63 my $user           = $input->remote_user;
  64
  65 my $library_id = C4::Context->userenv->{'branch'};
  66 my $total_due  = $account->outstanding_debits->total_outstanding;
  67
  68 my $total_paid = $input->param('paid');
  69
  70 my $select_lines = $input->param('selected');
  71 my $pay_individual   = $input->param('pay_individual');
  72 my $select       = $input->param('selected_accts');
  73 my $payment_note = uri_unescape scalar $input->param('payment_note');
  74 my $payment_type = scalar $input->param('payment_type');
  75 my $accountlines_id;
  76
  77 if ( $pay_individual || $writeoff_individual ) {
  78     if ($pay_individual) {
  79         $template->param( pay_individual => 1 );
  80     } elsif ($writeoff_individual) {
  81         $template->param( writeoff_individual => 1 );
  82     }
  83     my $accounttype       = $input->param('accounttype');
  84     $accountlines_id       = $input->param('accountlines_id');
  85     my $amount            = $input->param('amount');
  86     my $amountoutstanding = $input->param('amountoutstanding');
  87     my $itemnumber  = $input->param('itemnumber');
  88     my $description  = $input->param('description');
  89     my $title        = $input->param('title');
  90     $total_due = $amountoutstanding;
  91     $template->param(
  92         accounttype       => $accounttype,
  93         accountlines_id    => $accountlines_id,
  94         amount            => $amount,
  95         amountoutstanding => $amountoutstanding,
  96         title             => $title,
  97         itemnumber        => $itemnumber,
  98         individual_description => $description,
  99         payment_note    => $payment_note,
 100     );
 101 } elsif ($select_lines) {
 102     $total_due = $input->param('amt');
 103     $template->param(
 104         selected_accts => $select_lines,
 105         amt            => $total_due,
 106         selected_accts_notes => scalar $input->param('notes'),
 107     );
 108 }
 109
 110 if ( $total_paid and $total_paid ne '0.00' ) {
 111     if ( $total_paid < 0 or $total_paid > $total_due ) {
 112         $template->param(
 113             error_over => 1,
 114             total_due => $total_due
 115         );
 116     } else {
 117         output_and_exit( $input, $cookie, $template,  'wrong_csrf_token' )
 118             unless Koha::Token->new->check_csrf( {
 119                 session_id => $input->cookie('CGISESSID'),
 120                 token  => scalar $input->param('csrf_token'),
 121             });
 122
 123         if ($pay_individual) {
 124             my $line = Koha::Account::Lines->find($accountlines_id);
 125             $payment_id = $account->pay(
 126                 {
 127                     lines        => [$line],
 128                     amount       => $total_paid,
 129                     library_id   => $library_id,
 130                     note         => $payment_note,
 131                     interface    => C4::Context->interface,
 132                     payment_type => $payment_type,
 133                 }
 134             );
 135             print $input->redirect(
 136                 "/cgi-bin/koha/members/pay.pl?borrowernumber=$borrowernumber&payment_id=$payment_id");
 137         } else {
 138             if ($select) {
 139                 if ( $select =~ /^([\d,]*).*/ ) {
 140                     $select = $1;    # ensure passing no junk
 141                 }
 142                 my @acc = split /,/, $select;
 143                 my $note = $input->param('selected_accts_notes');
 144
 145                 my @lines = Koha::Account::Lines->search(
 146                     {
 147                         borrowernumber    => $borrowernumber,
 148                         amountoutstanding => { '<>' => 0 },
 149                         accountlines_id   => { 'IN' => \@acc },
 150                     },
 151                     { order_by => 'date' }
 152                 );
 153
 154                 $payment_id = $account->pay(
 155                     {
 156                         type         => $type,
 157                         amount       => $total_paid,
 158                         library_id   => $library_id,
 159                         lines        => \@lines,
 160                         note         => $note,
 161                         interface    => C4::Context->interface,
 162                         payment_type => $payment_type,
 163                     }
 164                   );
 165             }
 166             else {
 167                 my $note = $input->param('selected_accts_notes');
 168                 $payment_id = $account->pay(
 169                     {
 170                         amount       => $total_paid,
 171                         library_id   => $library_id,
 172                         note         => $note,
 173                         payment_type => $payment_type,
 174                         interface    => C4::Context->interface
 175                     }
 176                 );
 177             }
 178
 179             print $input->redirect("/cgi-bin/koha/members/boraccount.pl?borrowernumber=$borrowernumber&payment_id=$payment_id");
 180         }
 181     }
 182 } else {
 183     $total_paid = '0.00';    #TODO not right with pay_individual
 184 }
 185
 186 $template->param(%$borrower);
 187
 188 if ( $input->param('error_over') ) {
 189     $template->param( error_over => 1, total_due => scalar $input->param('amountoutstanding') );
 190 }
 191
 192 $template->param(
 193     payment_id => $payment_id,
 194
 195     type           => $type,
 196     borrowernumber => $borrowernumber,    # some templates require global
 197     patron         => $patron,
 198     total          => $total_due,
 199
 200     csrf_token => Koha::Token->new->generate_csrf( { session_id => scalar $input->cookie('CGISESSID') } ),
 201 );
 202
 203 output_html_with_http_headers $input, $cookie, $template->output;