C4/ShelfBrowser.pm

   1 #!/usr/bin/perl
   2
   3 package C4::ShelfBrowser;
   4
   5 # Copyright 2010 Catalyst IT
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 use strict;
  23 use warnings;
  24
  25 use C4::Biblio;
  26 use C4::Context;
  27 use C4::Koha;
  28 use Koha::Libraries;
  29
  30 use vars qw(@ISA @EXPORT @EXPORT_OK);
  31
  32 BEGIN {
  33         require Exporter;
  34         @ISA    = qw(Exporter);
  35         @EXPORT = qw(
  36             &GetNearbyItems
  37     );
  38     @EXPORT_OK = qw(
  39     );
  40 }
  41
  42 =head1 NAME
  43
  44 C4::ShelfBrowser - functions that deal with the shelf browser feature found in
  45 the OPAC.
  46
  47 =head1 SYNOPSIS
  48
  49   use C4::ShelfBrowser;
  50
  51 =head1 DESCRIPTION
  52
  53 This module provides functions to get items nearby to another item, for use
  54 in the shelf browser function.
  55
  56 'Nearby' is controlled by a handful of system preferences that specify what
  57 to take into account.
  58
  59 =head1 FUNCTIONS
  60
  61 =head2 GetNearbyItems($itemnumber, [$num_each_side])
  62
  63   $nearby = GetNearbyItems($itemnumber, [$num_each_side]);
  64
  65   @items = @{ $nearby->{items} };
  66
  67   foreach (@items) {
  68       # These won't format well like this, but here are the fields
  69           print $_->{title};
  70           print $_->{biblionumber};
  71           print $_->{itemnumber};
  72           print $_->{browser_normalized_upc};
  73           print $_->{browser_normalized_oclc};
  74           print $_->{browser_normalized_isbn};
  75       print $_->{browser_normalized_ean};
  76   }
  77
  78   # This is the information required to scroll the browser to the next left
  79   # or right set. Can be derived from next/prev, but it's here for convenience.
  80   print $nearby->{prev_item}{itemnumber};
  81   print $nearby->{next_item}{itemnumber};
  82   print $nearby->{prev_item}{biblionumber};
  83   print $nearby->{next_item}{biblionumber};
  84
  85   # These will be undef if the values are not used to calculate the
  86   # nearby items.
  87   print $nearby->{starting_homebranch}->{code};
  88   print $nearby->{starting_homebranch}->{description};
  89   print $nearby->{starting_location}->{code};
  90   print $nearby->{starting_location}->{description};
  91   print $nearby->{starting_ccode}->{code};
  92   print $nearby->{starting_ccode}->{description};
  93
  94 This finds the items that are nearby to the supplied item, and supplies
  95 those previous and next, along with the other useful information for displaying
  96 the shelf browser.
  97
  98 It automatically applies the following user preferences to work out how to
  99 calculate things: C<ShelfBrowserUsesLocation>, C<ShelfBrowserUsesHomeBranch>,
 100 C<ShelfBrowserUsesCcode>.
 101
 102 The option C<$num_each_side> value determines how many items will be fetched
 103 each side of the supplied item. Note that the item itself is the first entry
 104 in the 'next' set, and counts towards this limit (this is to keep the
 105 behaviour consistent with the code that this is a refactor of.) Default is
 106 3.
 107
 108 This will throw an exception if something went wrong.
 109
 110 =cut
 111
 112 sub GetNearbyItems {
 113     my ( $itemnumber, $num_each_side, $gap) = @_;
 114     $num_each_side ||= 3;
 115     $gap ||= 7; # Should be > $num_each_side
 116     die "BAD CALL in C4::ShelfBrowser::GetNearbyItems, gap should be > num_each_side"
 117         if $gap <= $num_each_side;
 118
 119     my $dbh         = C4::Context->dbh;
 120
 121     my $sth_get_item_details = $dbh->prepare("SELECT cn_sort,homebranch,location,ccode from items where itemnumber=?");
 122     $sth_get_item_details->execute($itemnumber);
 123     my $item_details_result = $sth_get_item_details->fetchrow_hashref();
 124     die "Unable to find item '$itemnumber' for shelf browser" if (!$sth_get_item_details);
 125     my $start_cn_sort = $item_details_result->{'cn_sort'};
 126
 127     my ($start_homebranch, $start_location, $start_ccode);
 128     if (C4::Context->preference('ShelfBrowserUsesHomeBranch') &&
 129         defined($item_details_result->{'homebranch'})) {
 130         $start_homebranch->{code} = $item_details_result->{'homebranch'};
 131         $start_homebranch->{description} = Koha::Libraries->find($item_details_result->{'homebranch'})->branchname;
 132     }
 133     if (C4::Context->preference('ShelfBrowserUsesLocation') &&
 134         defined($item_details_result->{'location'})) {
 135         $start_location->{code} = $item_details_result->{'location'};
 136         $start_location->{description} = GetAuthorisedValueDesc('','',$item_details_result->{'location'},'','','LOC','opac');
 137     }
 138     if (C4::Context->preference('ShelfBrowserUsesCcode') &&
 139         defined($item_details_result->{'ccode'})) {
 140         $start_ccode->{code} = $item_details_result->{'ccode'};
 141         $start_ccode->{description} = GetAuthorisedValueDesc('', '', $item_details_result->{'ccode'}, '', '', 'CCODE', 'opac');
 142     }
 143
 144     # Build the query for previous and next items
 145     my $prev_query ='
 146         SELECT itemnumber, biblionumber, cn_sort, itemcallnumber
 147         FROM items
 148         WHERE
 149             ((cn_sort = ? AND itemnumber < ?) OR cn_sort < ?) ';
 150     my $next_query ='
 151         SELECT itemnumber, biblionumber, cn_sort, itemcallnumber
 152         FROM items
 153         WHERE
 154             ((cn_sort = ? AND itemnumber >= ?) OR cn_sort > ?) ';
 155     my @params;
 156     my $query_cond;
 157     push @params, ($start_cn_sort, $itemnumber, $start_cn_sort);
 158     if ($start_homebranch) {
 159         $query_cond .= 'AND homebranch = ? ';
 160         push @params, $start_homebranch->{code};
 161     }
 162     if ($start_location) {
 163         $query_cond .= 'AND location = ? ';
 164         push @params, $start_location->{code};
 165     }
 166     if ($start_ccode) {
 167         $query_cond .= 'AND ccode = ? ';
 168         push @params, $start_ccode->{code};
 169     }
 170
 171     my @prev_items = @{
 172         $dbh->selectall_arrayref(
 173             $prev_query . $query_cond . ' ORDER BY cn_sort DESC, itemnumber DESC LIMIT ?',
 174             { Slice => {} },
 175             ( @params, $gap )
 176         )
 177     };
 178     my @next_items = @{
 179         $dbh->selectall_arrayref(
 180             $next_query . $query_cond . ' ORDER BY cn_sort, itemnumber LIMIT ?',
 181             { Slice => {} },
 182             ( @params, $gap + 1 )
 183         )
 184     };
 185
 186     my $prev_item = $prev_items[-1];
 187     my $next_item = $next_items[-1];
 188     @next_items = splice( @next_items, 0, $num_each_side + 1 );
 189     @prev_items = reverse splice( @prev_items, 0, $num_each_side );
 190     my @items = ( @prev_items, @next_items );
 191
 192     $next_item = undef
 193         if not $next_item
 194             or ( $next_item->{itemnumber} == $items[-1]->{itemnumber}
 195                 and ( @prev_items or @next_items <= 1 )
 196             );
 197     $prev_item = undef
 198         if not $prev_item
 199             or ( $prev_item->{itemnumber} == $items[0]->{itemnumber}
 200                 and ( @next_items or @prev_items <= 1 )
 201             );
 202
 203     # populate the items
 204     @items = GetShelfInfo( @items );
 205
 206     return {
 207         items               => \@items,
 208         next_item           => $next_item,
 209         prev_item           => $prev_item,
 210         starting_homebranch => $start_homebranch,
 211         starting_location   => $start_location,
 212         starting_ccode      => $start_ccode,
 213     };
 214 }
 215
 216 # populate an item list with its title and upc, oclc and isbn normalized.
 217 # Not really intended to be exported.
 218 sub GetShelfInfo {
 219     my @items = @_;
 220     my $marcflavour = C4::Context->preference("marcflavour");
 221     my @valid_items;
 222     for my $item ( @items ) {
 223         my $this_biblio = GetBibData($item->{biblionumber});
 224         next unless defined $this_biblio;
 225         $item->{'title'} = $this_biblio->{'title'};
 226         $item->{'subtitle'} = $this_biblio->{'subtitle'},
 227         $item->{'medium'} = $this_biblio->{'medium'};
 228         $item->{'part_number'} = $this_biblio->{'part_number'};
 229         $item->{'part_name'} = $this_biblio->{'part_name'};
 230         my $this_record = GetMarcBiblio({ biblionumber => $this_biblio->{'biblionumber'} });
 231         $item->{'browser_normalized_upc'} = GetNormalizedUPC($this_record,$marcflavour);
 232         $item->{'browser_normalized_oclc'} = GetNormalizedOCLCNumber($this_record,$marcflavour);
 233         $item->{'browser_normalized_isbn'} = GetNormalizedISBN(undef,$this_record,$marcflavour);
 234         $item->{'browser_normalized_ean'} = GetNormalizedEAN($this_record,$marcflavour);
 235         push @valid_items, $item;
 236     }
 237     return @valid_items;
 238 }
 239
 240 # Fetches some basic biblio data needed by the shelf stuff
 241 sub GetBibData {
 242         my ($bibnum) = @_;
 243
 244     my $dbh         = C4::Context->dbh;
 245     my $sth = $dbh->prepare("SELECT biblionumber, title, subtitle, medium, part_number, part_name FROM biblio WHERE biblionumber=?");
 246     $sth->execute($bibnum);
 247     my $bib = $sth->fetchrow_hashref();
 248     return $bib;
 249 }
 250
 251 1;