catalogue/ISBDdetail.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 NAME
  21
  22 ISBDdetail.pl : script to show a biblio in ISBD format
  23
  24 =head1 SYNOPSIS
  25
  26 =cut
  27
  28 =head1 DESCRIPTION
  29
  30 This script needs a biblionumber as parameter
  31
  32 =head1 FUNCTIONS
  33
  34 =cut
  35
  36 use Modern::Perl;
  37
  38 use HTML::Entities;
  39 use C4::Auth;
  40 use C4::Context;
  41 use C4::Output;
  42 use CGI qw ( -utf8 );
  43 use C4::Koha;
  44 use C4::Biblio;
  45 use C4::Items;
  46 use C4::Members; # to use GetMember
  47 use C4::Serials;    # CountSubscriptionFromBiblionumber
  48 use C4::Search;         # enabled_staff_search_views
  49 use C4::Acquisition qw(GetOrdersByBiblionumber);
  50 use Koha::RecordProcessor;
  51
  52
  53 my $query = new CGI;
  54 my $dbh = C4::Context->dbh;
  55
  56 my $biblionumber = $query->param('biblionumber');
  57 $biblionumber = HTML::Entities::encode($biblionumber);
  58
  59 # open template
  60 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  61     {
  62         template_name => "catalogue/ISBDdetail.tt",
  63         query         => $query,
  64         type          => "intranet",
  65         authnotrequired => 0,
  66         flagsrequired   => { catalogue => 1 },
  67     }
  68 );
  69
  70 if ( not defined $biblionumber ) {
  71        # biblionumber invalid -> report and exit
  72        $template->param( unknownbiblionumber => 1,
  73                                 biblionumber => $biblionumber
  74        );
  75        output_html_with_http_headers $query, $cookie, $template->output;
  76        exit;
  77 }
  78
  79 my $record = GetMarcBiblio($biblionumber,1);
  80
  81 if ( not defined $record ) {
  82        # biblionumber invalid -> report and exit
  83        $template->param( unknownbiblionumber => 1,
  84                                 biblionumber => $biblionumber
  85        );
  86        output_html_with_http_headers $query, $cookie, $template->output;
  87        exit;
  88 }
  89
  90 my $framework = GetFrameworkCode( $biblionumber );
  91 my $record_processor = Koha::RecordProcessor->new({
  92     filters => 'ViewPolicy',
  93     options => {
  94         interface => 'intranet',
  95         frameworkcode => $framework
  96     },
  97 });
  98 $record_processor->process($record);
  99
 100 my $res = GetISBDView({
 101     'record'    => $record,
 102     'template'  => 'intranet',
 103     'framework' => $framework,
 104 });
 105
 106 if($query->cookie("holdfor")){
 107     my $holdfor_patron = GetMember('borrowernumber' => $query->cookie("holdfor"));
 108     $template->param(
 109         holdfor => $query->cookie("holdfor"),
 110         holdfor_surname => $holdfor_patron->{'surname'},
 111         holdfor_firstname => $holdfor_patron->{'firstname'},
 112         holdfor_cardnumber => $holdfor_patron->{'cardnumber'},
 113     );
 114 }
 115
 116 # count of item linked with biblio
 117 my $itemcount = GetItemsCount($biblionumber);
 118 $template->param( count => $itemcount);
 119 my $subscriptionsnumber = CountSubscriptionFromBiblionumber($biblionumber);
 120
 121 if ($subscriptionsnumber) {
 122     my $subscriptions     = GetSubscriptionsFromBiblionumber($biblionumber);
 123     my $subscriptiontitle = $subscriptions->[0]{'bibliotitle'};
 124     $template->param(
 125         subscriptionsnumber => $subscriptionsnumber,
 126         subscriptiontitle   => $subscriptiontitle,
 127     );
 128 }
 129
 130 $template->param (
 131     ISBD                => $res,
 132     biblionumber        => $biblionumber,
 133     isbdview            => 1,
 134     z3950_search_params => C4::Search::z3950_search_args(GetBiblioData($biblionumber)),
 135     ocoins => GetCOinSBiblio($record),
 136     C4::Search::enabled_staff_search_views,
 137     searchid            => scalar $query->param('searchid'),
 138 );
 139
 140 my @allorders_using_biblio = GetOrdersByBiblionumber ($biblionumber);
 141 my @deletedorders_using_biblio;
 142 my @orders_using_biblio;
 143 my @baskets_orders;
 144 my @baskets_deletedorders;
 145
 146 foreach my $myorder (@allorders_using_biblio) {
 147     my $basket = $myorder->{'basketno'};
 148     if ((defined $myorder->{'datecancellationprinted'}) and  ($myorder->{'datecancellationprinted'} ne '0000-00-00') ){
 149         push @deletedorders_using_biblio, $myorder;
 150         unless (grep(/^$basket$/, @baskets_deletedorders)){
 151             push @baskets_deletedorders,$myorder->{'basketno'};
 152         }
 153     }
 154     else {
 155         push @orders_using_biblio, $myorder;
 156         unless (grep(/^$basket$/, @baskets_orders)){
 157             push @baskets_orders,$myorder->{'basketno'};
 158             }
 159     }
 160 }
 161
 162 my $count_orders_using_biblio = scalar @orders_using_biblio ;
 163 $template->param (countorders => $count_orders_using_biblio);
 164
 165 my $count_deletedorders_using_biblio = scalar @deletedorders_using_biblio ;
 166 $template->param (countdeletedorders => $count_deletedorders_using_biblio);
 167
 168 my $holds = C4::Reserves::GetReservesFromBiblionumber({ biblionumber => $biblionumber, all_dates => 1 });
 169 my $holdcount = scalar( @$holds );
 170 $template->param( holdcount => scalar ( @$holds ) );
 171
 172 output_html_with_http_headers $query, $cookie, $template->output;
 173