acqui/lateorders.pl

   1 #!/usr/bin/perl
   2
   3
   4 # Copyright 2005 Biblibre
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 NAME
  21
  22 lateorders.pl
  23
  24 =head1 DESCRIPTION
  25
  26 this script shows late orders for a specific supplier, branch and delay
  27 given on input arg.
  28
  29 =head1 CGI PARAMETERS
  30
  31 =over 4
  32
  33 =item booksellerid
  34 To know on which supplier this script have to display late order.
  35
  36 =item delay
  37 To know the time boundary. Default value is 30 days.
  38
  39 =item branch
  40 To know on which branch this script have to display late order.
  41
  42 =back
  43
  44 =cut
  45
  46 use Modern::Perl;
  47 use CGI qw ( -utf8 );
  48 use C4::Auth;
  49 use C4::Koha;
  50 use C4::Output;
  51 use C4::Context;
  52 use C4::Acquisition;
  53 use C4::Letters;
  54 use Koha::DateUtils;
  55 use Koha::Acquisition::Orders;
  56 use Koha::CsvProfiles;
  57
  58 my $input = new CGI;
  59 my ($template, $loggedinuser, $cookie) = get_template_and_user(
  60     {
  61         template_name   => "acqui/lateorders.tt",
  62         query           => $input,
  63         type            => "intranet",
  64         flagsrequired   => { acquisition => 'order_receive' },
  65         debug           => 1,
  66     }
  67 );
  68
  69 my $booksellerid = $input->param('booksellerid');
  70 my $delay        = $input->param('delay') // 0;
  71
  72 # Get the "date from" param if !defined is today
  73 my $estimateddeliverydatefrom = $input->param('estimateddeliverydatefrom');
  74 my $estimateddeliverydateto   = $input->param('estimateddeliverydateto');
  75
  76 my $estimateddeliverydatefrom_dt =
  77   $estimateddeliverydatefrom
  78   ? dt_from_string($estimateddeliverydatefrom)
  79   : undef;
  80
  81 # Get the "date to" param. If it is not defined and $delay is not defined too, it is the today's date.
  82 my $estimateddeliverydateto_dt = $estimateddeliverydateto
  83     ? dt_from_string($estimateddeliverydateto)
  84     : ( not defined $delay and not defined $estimateddeliverydatefrom)
  85         ? dt_from_string()
  86         : undef;
  87
  88 # Format the output of "date from" and "date to"
  89 if ($estimateddeliverydatefrom_dt) {
  90     $estimateddeliverydatefrom = output_pref({dt => $estimateddeliverydatefrom_dt, dateonly => 1});
  91 }
  92 if ($estimateddeliverydateto_dt) {
  93     $estimateddeliverydateto = output_pref({dt => $estimateddeliverydateto_dt, dateonly => 1});
  94 }
  95
  96 my $branch     = $input->param('branch');
  97 my $op         = $input->param('op');
  98
  99 my @errors = ();
 100 if ( $delay and not $delay =~ /^\d{1,3}$/ ) {
 101     push @errors, {delay_digits => 1, bad_delay => $delay};
 102 }
 103
 104 if ($op and $op eq "send_alert"){
 105     my @ordernums = $input->multi_param("ordernumber");
 106     my $err;
 107     eval {
 108         $err = SendAlerts( 'claimacquisition', \@ordernums, $input->param("letter_code") );
 109         if ( not ref $err or not exists $err->{error} ) {
 110             Koha::Acquisition::Orders->find($_)->claim() for @ordernums;
 111         }
 112     };
 113
 114     if ( ref $err and exists $err->{error} and $err->{error} eq "no_email" ) {
 115         $template->{VARS}->{'error_claim'} = "no_email";
 116     } elsif ( ref $err and exists $err->{error} and $err->{error} eq "no_order_selected"){
 117         $template->{VARS}->{'error_claim'} = "no_order_selected";
 118     } elsif ( $@ or ref $err and exists $err->{error} ) {
 119         $template->param(error_claim => $@ || $err->{error});
 120     } else {
 121         $template->{VARS}->{'info_claim'} = 1;
 122     }
 123 }
 124
 125 my @lateorders = Koha::Acquisition::Orders->filter_by_lates(
 126     {
 127         delay        => $delay,
 128         (
 129             $estimateddeliverydatefrom_dt
 130             ? ( estimated_from => $estimateddeliverydatefrom_dt )
 131             : ()
 132         ),
 133         (
 134             $estimateddeliverydateto_dt
 135             ? ( estimated_to => $estimateddeliverydateto_dt )
 136             : ()
 137         )
 138     },
 139 )->as_list;
 140
 141 my $booksellers = Koha::Acquisition::Booksellers->search(
 142     {
 143         id => {
 144             -in => [ map { $_->basket->booksellerid } @lateorders ]
 145         },
 146     }
 147 );
 148
 149 @lateorders = grep { $_->basket->booksellerid eq $booksellerid } @lateorders if $booksellerid;
 150
 151 my $letters = GetLetters({ module => "claimacquisition" });
 152
 153 $template->param(ERROR_LOOP => \@errors) if (@errors);
 154 $template->param(
 155     lateorders => \@lateorders,
 156     booksellers => $booksellers,
 157     bookseller_filter => ( $booksellerid ? $booksellers->find($booksellerid) : undef),
 158         delay => $delay,
 159     letters => $letters,
 160     estimateddeliverydatefrom => $estimateddeliverydatefrom,
 161     estimateddeliverydateto   => $estimateddeliverydateto,
 162         intranetcolorstylesheet => C4::Context->preference("intranetcolorstylesheet"),
 163     csv_profiles         => [ Koha::CsvProfiles->search({ type => 'sql', used_for => 'late_orders' }) ],
 164 );
 165 output_html_with_http_headers $input, $cookie, $template->output;