C4/Acquisition.pm

   1 package C4::Acquisition;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20
  21 use strict;
  22 use warnings;
  23 use Carp;
  24 use C4::Context;
  25 use C4::Debug;
  26 use C4::Dates qw(format_date format_date_in_iso);
  27 use MARC::Record;
  28 use C4::Suggestions;
  29 use C4::Biblio;
  30 use C4::Debug;
  31 use C4::SQLHelper qw(InsertInTable);
  32 use C4::Bookseller qw(GetBookSellerFromId);
  33 use C4::Templates qw(gettemplate);
  34
  35 use Time::localtime;
  36 use HTML::Entities;
  37
  38 use vars qw($VERSION @ISA @EXPORT);
  39
  40 BEGIN {
  41     # set the version for version checking
  42     $VERSION = 3.07.00.049;
  43     require Exporter;
  44     @ISA    = qw(Exporter);
  45     @EXPORT = qw(
  46         &GetBasket &NewBasket &CloseBasket &DelBasket &ModBasket
  47         &GetBasketAsCSV &GetBasketGroupAsCSV
  48         &GetBasketsByBookseller &GetBasketsByBasketgroup
  49         &GetBasketsInfosByBookseller
  50
  51         &ModBasketHeader
  52
  53         &ModBasketgroup &NewBasketgroup &DelBasketgroup &GetBasketgroup &CloseBasketgroup
  54         &GetBasketgroups &ReOpenBasketgroup
  55
  56         &NewOrder &DelOrder &ModOrder &GetPendingOrders &GetOrder &GetOrders &GetOrdersByBiblionumber
  57         &GetLateOrders &GetOrderFromItemnumber
  58         &SearchOrder &GetHistory &GetRecentAcqui
  59         &ModReceiveOrder &CancelReceipt
  60         &GetCancelledOrders
  61         &GetLastOrderNotReceivedFromSubscriptionid &GetLastOrderReceivedFromSubscriptionid
  62         &NewOrderItem &ModItemOrder
  63
  64         &GetParcels &GetParcel
  65         &GetContracts &GetContract
  66
  67         &GetInvoices
  68         &GetInvoice
  69         &GetInvoiceDetails
  70         &AddInvoice
  71         &ModInvoice
  72         &CloseInvoice
  73         &ReopenInvoice
  74         &DelInvoice
  75
  76         &GetItemnumbersFromOrder
  77
  78         &AddClaim
  79     );
  80 }
  81
  82
  83
  84
  85
  86 sub GetOrderFromItemnumber {
  87     my ($itemnumber) = @_;
  88     my $dbh          = C4::Context->dbh;
  89     my $query        = qq|
  90
  91     SELECT  * from aqorders    LEFT JOIN aqorders_items
  92     ON (     aqorders.ordernumber = aqorders_items.ordernumber   )
  93     WHERE itemnumber = ?  |;
  94
  95     my $sth = $dbh->prepare($query);
  96
  97 #    $sth->trace(3);
  98
  99     $sth->execute($itemnumber);
 100
 101     my $order = $sth->fetchrow_hashref;
 102     return ( $order  );
 103
 104 }
 105
 106 # Returns the itemnumber(s) associated with the ordernumber given in parameter
 107 sub GetItemnumbersFromOrder {
 108     my ($ordernumber) = @_;
 109     my $dbh          = C4::Context->dbh;
 110     my $query        = "SELECT itemnumber FROM aqorders_items WHERE ordernumber=?";
 111     my $sth = $dbh->prepare($query);
 112     $sth->execute($ordernumber);
 113     my @tab;
 114
 115     while (my $order = $sth->fetchrow_hashref) {
 116     push @tab, $order->{'itemnumber'};
 117     }
 118
 119     return @tab;
 120
 121 }
 122
 123
 124
 125
 126
 127
 128 =head1 NAME
 129
 130 C4::Acquisition - Koha functions for dealing with orders and acquisitions
 131
 132 =head1 SYNOPSIS
 133
 134 use C4::Acquisition;
 135
 136 =head1 DESCRIPTION
 137
 138 The functions in this module deal with acquisitions, managing book
 139 orders, basket and parcels.
 140
 141 =head1 FUNCTIONS
 142
 143 =head2 FUNCTIONS ABOUT BASKETS
 144
 145 =head3 GetBasket
 146
 147   $aqbasket = &GetBasket($basketnumber);
 148
 149 get all basket informations in aqbasket for a given basket
 150
 151 B<returns:> informations for a given basket returned as a hashref.
 152
 153 =cut
 154
 155 sub GetBasket {
 156     my ($basketno) = @_;
 157     my $dbh        = C4::Context->dbh;
 158     my $query = "
 159         SELECT  aqbasket.*,
 160                 concat( b.firstname,' ',b.surname) AS authorisedbyname,
 161                 b.branchcode AS branch
 162         FROM    aqbasket
 163         LEFT JOIN borrowers b ON aqbasket.authorisedby=b.borrowernumber
 164         WHERE basketno=?
 165     ";
 166     my $sth=$dbh->prepare($query);
 167     $sth->execute($basketno);
 168     my $basket = $sth->fetchrow_hashref;
 169     return ( $basket );
 170 }
 171
 172 #------------------------------------------------------------#
 173
 174 =head3 NewBasket
 175
 176   $basket = &NewBasket( $booksellerid, $authorizedby, $basketname,
 177       $basketnote, $basketbooksellernote, $basketcontractnumber, $deliveryplace, $billingplace );
 178
 179 Create a new basket in aqbasket table
 180
 181 =over
 182
 183 =item C<$booksellerid> is a foreign key in the aqbasket table
 184
 185 =item C<$authorizedby> is the username of who created the basket
 186
 187 =back
 188
 189 The other parameters are optional, see ModBasketHeader for more info on them.
 190
 191 =cut
 192
 193 sub NewBasket {
 194     my ( $booksellerid, $authorisedby, $basketname, $basketnote,
 195         $basketbooksellernote, $basketcontractnumber, $deliveryplace,
 196         $billingplace ) = @_;
 197     my $dbh = C4::Context->dbh;
 198     my $query =
 199         'INSERT INTO aqbasket (creationdate,booksellerid,authorisedby) '
 200       . 'VALUES  (now(),?,?)';
 201     $dbh->do( $query, {}, $booksellerid, $authorisedby );
 202
 203     my $basket = $dbh->{mysql_insertid};
 204     $basketname           ||= q{}; # default to empty strings
 205     $basketnote           ||= q{};
 206     $basketbooksellernote ||= q{};
 207     ModBasketHeader( $basket, $basketname, $basketnote, $basketbooksellernote,
 208         $basketcontractnumber, $booksellerid, $deliveryplace, $billingplace );
 209     return $basket;
 210 }
 211
 212 #------------------------------------------------------------#
 213
 214 =head3 CloseBasket
 215
 216   &CloseBasket($basketno);
 217
 218 close a basket (becomes unmodifiable,except for recieves)
 219
 220 =cut
 221
 222 sub CloseBasket {
 223     my ($basketno) = @_;
 224     my $dbh        = C4::Context->dbh;
 225     my $query = "
 226         UPDATE aqbasket
 227         SET    closedate=now()
 228         WHERE  basketno=?
 229     ";
 230     my $sth = $dbh->prepare($query);
 231     $sth->execute($basketno);
 232 }
 233
 234 #------------------------------------------------------------#
 235
 236 =head3 GetBasketAsCSV
 237
 238   &GetBasketAsCSV($basketno);
 239
 240 Export a basket as CSV
 241
 242 $cgi parameter is needed for column name translation
 243
 244 =cut
 245
 246 sub GetBasketAsCSV {
 247     my ($basketno, $cgi) = @_;
 248     my $basket = GetBasket($basketno);
 249     my @orders = GetOrders($basketno);
 250     my $contract = GetContract($basket->{'contractnumber'});
 251
 252     my $template = C4::Templates::gettemplate("acqui/csv/basket.tmpl", "intranet", $cgi);
 253
 254     my @rows;
 255     foreach my $order (@orders) {
 256         my $bd = GetBiblioData( $order->{'biblionumber'} );
 257         my $row = {
 258             contractname => $contract->{'contractname'},
 259             ordernumber => $order->{'ordernumber'},
 260             entrydate => $order->{'entrydate'},
 261             isbn => $order->{'isbn'},
 262             author => $bd->{'author'},
 263             title => $bd->{'title'},
 264             publicationyear => $bd->{'publicationyear'},
 265             publishercode => $bd->{'publishercode'},
 266             collectiontitle => $bd->{'collectiontitle'},
 267             notes => $order->{'notes'},
 268             quantity => $order->{'quantity'},
 269             rrp => $order->{'rrp'},
 270             deliveryplace => C4::Branch::GetBranchName( $basket->{'deliveryplace'} ),
 271             billingplace => C4::Branch::GetBranchName( $basket->{'billingplace'} ),
 272         };
 273         foreach(qw(
 274             contractname author title publishercode collectiontitle notes
 275             deliveryplace billingplace
 276         ) ) {
 277             # Double the quotes to not be interpreted as a field end
 278             $row->{$_} =~ s/"/""/g if $row->{$_};
 279         }
 280         push @rows, $row;
 281     }
 282
 283     @rows = sort {
 284         if(defined $a->{publishercode} and defined $b->{publishercode}) {
 285             $a->{publishercode} cmp $b->{publishercode};
 286         }
 287     } @rows;
 288
 289     $template->param(rows => \@rows);
 290
 291     return $template->output;
 292 }
 293
 294
 295 =head3 GetBasketGroupAsCSV
 296
 297 =over 4
 298
 299 &GetBasketGroupAsCSV($basketgroupid);
 300
 301 Export a basket group as CSV
 302
 303 $cgi parameter is needed for column name translation
 304
 305 =back
 306
 307 =cut
 308
 309 sub GetBasketGroupAsCSV {
 310     my ($basketgroupid, $cgi) = @_;
 311     my $baskets = GetBasketsByBasketgroup($basketgroupid);
 312
 313     my $template = C4::Templates::gettemplate('acqui/csv/basketgroup.tmpl', 'intranet', $cgi);
 314
 315     my @rows;
 316     for my $basket (@$baskets) {
 317         my @orders     = GetOrders( $$basket{basketno} );
 318         my $contract   = GetContract( $$basket{contractnumber} );
 319         my $bookseller = GetBookSellerFromId( $$basket{booksellerid} );
 320         my $basketgroup = GetBasketgroup( $$basket{basketgroupid} );
 321
 322         foreach my $order (@orders) {
 323             my $bd = GetBiblioData( $order->{'biblionumber'} );
 324             my $row = {
 325                 clientnumber => $bookseller->{accountnumber},
 326                 basketname => $basket->{basketname},
 327                 ordernumber => $order->{ordernumber},
 328                 author => $bd->{author},
 329                 title => $bd->{title},
 330                 publishercode => $bd->{publishercode},
 331                 publicationyear => $bd->{publicationyear},
 332                 collectiontitle => $bd->{collectiontitle},
 333                 isbn => $order->{isbn},
 334                 quantity => $order->{quantity},
 335                 rrp => $order->{rrp},
 336                 discount => $bookseller->{discount},
 337                 ecost => $order->{ecost},
 338                 notes => $order->{notes},
 339                 entrydate => $order->{entrydate},
 340                 booksellername => $bookseller->{name},
 341                 bookselleraddress => $bookseller->{address1},
 342                 booksellerpostal => $bookseller->{postal},
 343                 contractnumber => $contract->{contractnumber},
 344                 contractname => $contract->{contractname},
 345                 basketgroupdeliveryplace => C4::Branch::GetBranchName( $basketgroup->{deliveryplace} ),
 346                 basketgroupbillingplace => C4::Branch::GetBranchName( $basketgroup->{billingplace} ),
 347                 basketdeliveryplace => C4::Branch::GetBranchName( $basket->{deliveryplace} ),
 348                 basketbillingplace => C4::Branch::GetBranchName( $basket->{billingplace} ),
 349             };
 350             foreach(qw(
 351                 basketname author title publishercode collectiontitle notes
 352                 booksellername bookselleraddress booksellerpostal contractname
 353                 basketgroupdeliveryplace basketgroupbillingplace
 354                 basketdeliveryplace basketbillingplace
 355             ) ) {
 356                 # Double the quotes to not be interpreted as a field end
 357                 $row->{$_} =~ s/"/""/g if $row->{$_};
 358             }
 359             push @rows, $row;
 360          }
 361      }
 362     $template->param(rows => \@rows);
 363
 364     return $template->output;
 365
 366 }
 367
 368 =head3 CloseBasketgroup
 369
 370   &CloseBasketgroup($basketgroupno);
 371
 372 close a basketgroup
 373
 374 =cut
 375
 376 sub CloseBasketgroup {
 377     my ($basketgroupno) = @_;
 378     my $dbh        = C4::Context->dbh;
 379     my $sth = $dbh->prepare("
 380         UPDATE aqbasketgroups
 381         SET    closed=1
 382         WHERE  id=?
 383     ");
 384     $sth->execute($basketgroupno);
 385 }
 386
 387 #------------------------------------------------------------#
 388
 389 =head3 ReOpenBaskergroup($basketgroupno)
 390
 391   &ReOpenBaskergroup($basketgroupno);
 392
 393 reopen a basketgroup
 394
 395 =cut
 396
 397 sub ReOpenBasketgroup {
 398     my ($basketgroupno) = @_;
 399     my $dbh        = C4::Context->dbh;
 400     my $sth = $dbh->prepare("
 401         UPDATE aqbasketgroups
 402         SET    closed=0
 403         WHERE  id=?
 404     ");
 405     $sth->execute($basketgroupno);
 406 }
 407
 408 #------------------------------------------------------------#
 409
 410
 411 =head3 DelBasket
 412
 413   &DelBasket($basketno);
 414
 415 Deletes the basket that has basketno field $basketno in the aqbasket table.
 416
 417 =over
 418
 419 =item C<$basketno> is the primary key of the basket in the aqbasket table.
 420
 421 =back
 422
 423 =cut
 424
 425 sub DelBasket {
 426     my ( $basketno ) = @_;
 427     my $query = "DELETE FROM aqbasket WHERE basketno=?";
 428     my $dbh = C4::Context->dbh;
 429     my $sth = $dbh->prepare($query);
 430     $sth->execute($basketno);
 431     $sth->finish;
 432 }
 433
 434 #------------------------------------------------------------#
 435
 436 =head3 ModBasket
 437
 438   &ModBasket($basketinfo);
 439
 440 Modifies a basket, using a hashref $basketinfo for the relevant information, only $basketinfo->{'basketno'} is required.
 441
 442 =over
 443
 444 =item C<$basketno> is the primary key of the basket in the aqbasket table.
 445
 446 =back
 447
 448 =cut
 449
 450 sub ModBasket {
 451     my $basketinfo = shift;
 452     my $query = "UPDATE aqbasket SET ";
 453     my @params;
 454     foreach my $key (keys %$basketinfo){
 455         if ($key ne 'basketno'){
 456             $query .= "$key=?, ";
 457             push(@params, $basketinfo->{$key} || undef );
 458         }
 459     }
 460 # get rid of the "," at the end of $query
 461     if (substr($query, length($query)-2) eq ', '){
 462         chop($query);
 463         chop($query);
 464         $query .= ' ';
 465     }
 466     $query .= "WHERE basketno=?";
 467     push(@params, $basketinfo->{'basketno'});
 468     my $dbh = C4::Context->dbh;
 469     my $sth = $dbh->prepare($query);
 470     $sth->execute(@params);
 471     $sth->finish;
 472 }
 473
 474 #------------------------------------------------------------#
 475
 476 =head3 ModBasketHeader
 477
 478   &ModBasketHeader($basketno, $basketname, $note, $booksellernote, $contractnumber, $booksellerid);
 479
 480 Modifies a basket's header.
 481
 482 =over
 483
 484 =item C<$basketno> is the "basketno" field in the "aqbasket" table;
 485
 486 =item C<$basketname> is the "basketname" field in the "aqbasket" table;
 487
 488 =item C<$note> is the "note" field in the "aqbasket" table;
 489
 490 =item C<$booksellernote> is the "booksellernote" field in the "aqbasket" table;
 491
 492 =item C<$contractnumber> is the "contractnumber" (foreign) key in the "aqbasket" table.
 493
 494 =item C<$booksellerid> is the id (foreign) key in the "aqbooksellers" table for the vendor.
 495
 496 =item C<$deliveryplace> is the "deliveryplace" field in the aqbasket table.
 497
 498 =item C<$billingplace> is the "billingplace" field in the aqbasket table.
 499
 500 =back
 501
 502 =cut
 503
 504 sub ModBasketHeader {
 505     my ($basketno, $basketname, $note, $booksellernote, $contractnumber, $booksellerid, $deliveryplace, $billingplace) = @_;
 506     my $query = qq{
 507         UPDATE aqbasket
 508         SET basketname=?, note=?, booksellernote=?, booksellerid=?, deliveryplace=?, billingplace=?
 509         WHERE basketno=?
 510     };
 511
 512     my $dbh = C4::Context->dbh;
 513     my $sth = $dbh->prepare($query);
 514     $sth->execute($basketname, $note, $booksellernote, $booksellerid, $deliveryplace, $billingplace, $basketno);
 515
 516     if ( $contractnumber ) {
 517         my $query2 ="UPDATE aqbasket SET contractnumber=? WHERE basketno=?";
 518         my $sth2 = $dbh->prepare($query2);
 519         $sth2->execute($contractnumber,$basketno);
 520         $sth2->finish;
 521     }
 522     $sth->finish;
 523 }
 524
 525 #------------------------------------------------------------#
 526
 527 =head3 GetBasketsByBookseller
 528
 529   @results = &GetBasketsByBookseller($booksellerid, $extra);
 530
 531 Returns a list of hashes of all the baskets that belong to bookseller 'booksellerid'.
 532
 533 =over
 534
 535 =item C<$booksellerid> is the 'id' field of the bookseller in the aqbooksellers table
 536
 537 =item C<$extra> is the extra sql parameters, can be
 538
 539  $extra->{groupby}: group baskets by column
 540     ex. $extra->{groupby} = aqbasket.basketgroupid
 541  $extra->{orderby}: order baskets by column
 542  $extra->{limit}: limit number of results (can be helpful for pagination)
 543
 544 =back
 545
 546 =cut
 547
 548 sub GetBasketsByBookseller {
 549     my ($booksellerid, $extra) = @_;
 550     my $query = "SELECT * FROM aqbasket WHERE booksellerid=?";
 551     if ($extra){
 552         if ($extra->{groupby}) {
 553             $query .= " GROUP by $extra->{groupby}";
 554         }
 555         if ($extra->{orderby}){
 556             $query .= " ORDER by $extra->{orderby}";
 557         }
 558         if ($extra->{limit}){
 559             $query .= " LIMIT $extra->{limit}";
 560         }
 561     }
 562     my $dbh = C4::Context->dbh;
 563     my $sth = $dbh->prepare($query);
 564     $sth->execute($booksellerid);
 565     my $results = $sth->fetchall_arrayref({});
 566     $sth->finish;
 567     return $results
 568 }
 569
 570 =head3 GetBasketsInfosByBookseller
 571
 572     my $baskets = GetBasketsInfosByBookseller($supplierid, $allbaskets);
 573
 574 The optional second parameter allbaskets is a boolean allowing you to
 575 select all baskets from the supplier; by default only active baskets (open or
 576 closed but still something to receive) are returned.
 577
 578 Returns in a arrayref of hashref all about booksellers baskets, plus:
 579     total_biblios: Number of distinct biblios in basket
 580     total_items: Number of items in basket
 581     expected_items: Number of non-received items in basket
 582
 583 =cut
 584
 585 sub GetBasketsInfosByBookseller {
 586     my ($supplierid, $allbaskets) = @_;
 587
 588     return unless $supplierid;
 589
 590     my $dbh = C4::Context->dbh;
 591     my $query = qq{
 592         SELECT aqbasket.*,
 593           SUM(aqorders.quantity) AS total_items,
 594           COUNT(DISTINCT aqorders.biblionumber) AS total_biblios,
 595           SUM(
 596             IF(aqorders.datereceived IS NULL
 597               AND aqorders.datecancellationprinted IS NULL
 598             , aqorders.quantity
 599             , 0)
 600           ) AS expected_items
 601         FROM aqbasket
 602           LEFT JOIN aqorders ON aqorders.basketno = aqbasket.basketno
 603         WHERE booksellerid = ?};
 604     if(!$allbaskets) {
 605         $query.=" AND (closedate IS NULL OR (aqorders.quantity > aqorders.quantityreceived AND datecancellationprinted IS NULL))";
 606     }
 607     $query.=" GROUP BY aqbasket.basketno";
 608
 609     my $sth = $dbh->prepare($query);
 610     $sth->execute($supplierid);
 611     return $sth->fetchall_arrayref({});
 612 }
 613
 614
 615 #------------------------------------------------------------#
 616
 617 =head3 GetBasketsByBasketgroup
 618
 619   $baskets = &GetBasketsByBasketgroup($basketgroupid);
 620
 621 Returns a reference to all baskets that belong to basketgroup $basketgroupid.
 622
 623 =cut
 624
 625 sub GetBasketsByBasketgroup {
 626     my $basketgroupid = shift;
 627     my $query = qq{
 628         SELECT *, aqbasket.booksellerid as booksellerid
 629         FROM aqbasket
 630         LEFT JOIN aqcontract USING(contractnumber) WHERE basketgroupid=?
 631     };
 632     my $dbh = C4::Context->dbh;
 633     my $sth = $dbh->prepare($query);
 634     $sth->execute($basketgroupid);
 635     my $results = $sth->fetchall_arrayref({});
 636     $sth->finish;
 637     return $results
 638 }
 639
 640 #------------------------------------------------------------#
 641
 642 =head3 NewBasketgroup
 643
 644   $basketgroupid = NewBasketgroup(\%hashref);
 645
 646 Adds a basketgroup to the aqbasketgroups table, and add the initial baskets to it.
 647
 648 $hashref->{'booksellerid'} is the 'id' field of the bookseller in the aqbooksellers table,
 649
 650 $hashref->{'name'} is the 'name' field of the basketgroup in the aqbasketgroups table,
 651
 652 $hashref->{'basketlist'} is a list reference of the 'id's of the baskets that belong to this group,
 653
 654 $hashref->{'billingplace'} is the 'billingplace' field of the basketgroup in the aqbasketgroups table,
 655
 656 $hashref->{'deliveryplace'} is the 'deliveryplace' field of the basketgroup in the aqbasketgroups table,
 657
 658 $hashref->{'freedeliveryplace'} is the 'freedeliveryplace' field of the basketgroup in the aqbasketgroups table,
 659
 660 $hashref->{'deliverycomment'} is the 'deliverycomment' field of the basketgroup in the aqbasketgroups table,
 661
 662 $hashref->{'closed'} is the 'closed' field of the aqbasketgroups table, it is false if 0, true otherwise.
 663
 664 =cut
 665
 666 sub NewBasketgroup {
 667     my $basketgroupinfo = shift;
 668     die "booksellerid is required to create a basketgroup" unless $basketgroupinfo->{'booksellerid'};
 669     my $query = "INSERT INTO aqbasketgroups (";
 670     my @params;
 671     foreach my $field (qw(name billingplace deliveryplace freedeliveryplace deliverycomment closed)) {
 672         if ( defined $basketgroupinfo->{$field} ) {
 673             $query .= "$field, ";
 674             push(@params, $basketgroupinfo->{$field});
 675         }
 676     }
 677     $query .= "booksellerid) VALUES (";
 678     foreach (@params) {
 679         $query .= "?, ";
 680     }
 681     $query .= "?)";
 682     push(@params, $basketgroupinfo->{'booksellerid'});
 683     my $dbh = C4::Context->dbh;
 684     my $sth = $dbh->prepare($query);
 685     $sth->execute(@params);
 686     my $basketgroupid = $dbh->{'mysql_insertid'};
 687     if( $basketgroupinfo->{'basketlist'} ) {
 688         foreach my $basketno (@{$basketgroupinfo->{'basketlist'}}) {
 689             my $query2 = "UPDATE aqbasket SET basketgroupid=? WHERE basketno=?";
 690             my $sth2 = $dbh->prepare($query2);
 691             $sth2->execute($basketgroupid, $basketno);
 692         }
 693     }
 694     return $basketgroupid;
 695 }
 696
 697 #------------------------------------------------------------#
 698
 699 =head3 ModBasketgroup
 700
 701   ModBasketgroup(\%hashref);
 702
 703 Modifies a basketgroup in the aqbasketgroups table, and add the baskets to it.
 704
 705 $hashref->{'id'} is the 'id' field of the basketgroup in the aqbasketgroup table, this parameter is mandatory,
 706
 707 $hashref->{'name'} is the 'name' field of the basketgroup in the aqbasketgroups table,
 708
 709 $hashref->{'basketlist'} is a list reference of the 'id's of the baskets that belong to this group,
 710
 711 $hashref->{'billingplace'} is the 'billingplace' field of the basketgroup in the aqbasketgroups table,
 712
 713 $hashref->{'deliveryplace'} is the 'deliveryplace' field of the basketgroup in the aqbasketgroups table,
 714
 715 $hashref->{'freedeliveryplace'} is the 'freedeliveryplace' field of the basketgroup in the aqbasketgroups table,
 716
 717 $hashref->{'deliverycomment'} is the 'deliverycomment' field of the basketgroup in the aqbasketgroups table,
 718
 719 $hashref->{'closed'} is the 'closed' field of the aqbasketgroups table, it is false if 0, true otherwise.
 720
 721 =cut
 722
 723 sub ModBasketgroup {
 724     my $basketgroupinfo = shift;
 725     die "basketgroup id is required to edit a basketgroup" unless $basketgroupinfo->{'id'};
 726     my $dbh = C4::Context->dbh;
 727     my $query = "UPDATE aqbasketgroups SET ";
 728     my @params;
 729     foreach my $field (qw(name billingplace deliveryplace freedeliveryplace deliverycomment closed)) {
 730         if ( defined $basketgroupinfo->{$field} ) {
 731             $query .= "$field=?, ";
 732             push(@params, $basketgroupinfo->{$field});
 733         }
 734     }
 735     chop($query);
 736     chop($query);
 737     $query .= " WHERE id=?";
 738     push(@params, $basketgroupinfo->{'id'});
 739     my $sth = $dbh->prepare($query);
 740     $sth->execute(@params);
 741
 742     $sth = $dbh->prepare('UPDATE aqbasket SET basketgroupid = NULL WHERE basketgroupid = ?');
 743     $sth->execute($basketgroupinfo->{'id'});
 744
 745     if($basketgroupinfo->{'basketlist'} && @{$basketgroupinfo->{'basketlist'}}){
 746         $sth = $dbh->prepare("UPDATE aqbasket SET basketgroupid=? WHERE basketno=?");
 747         foreach my $basketno (@{$basketgroupinfo->{'basketlist'}}) {
 748             $sth->execute($basketgroupinfo->{'id'}, $basketno);
 749             $sth->finish;
 750         }
 751     }
 752     $sth->finish;
 753 }
 754
 755 #------------------------------------------------------------#
 756
 757 =head3 DelBasketgroup
 758
 759   DelBasketgroup($basketgroupid);
 760
 761 Deletes a basketgroup in the aqbasketgroups table, and removes the reference to it from the baskets,
 762
 763 =over
 764
 765 =item C<$basketgroupid> is the 'id' field of the basket in the aqbasketgroup table
 766
 767 =back
 768
 769 =cut
 770
 771 sub DelBasketgroup {
 772     my $basketgroupid = shift;
 773     die "basketgroup id is required to edit a basketgroup" unless $basketgroupid;
 774     my $query = "DELETE FROM aqbasketgroups WHERE id=?";
 775     my $dbh = C4::Context->dbh;
 776     my $sth = $dbh->prepare($query);
 777     $sth->execute($basketgroupid);
 778     $sth->finish;
 779 }
 780
 781 #------------------------------------------------------------#
 782
 783
 784 =head2 FUNCTIONS ABOUT ORDERS
 785
 786 =head3 GetBasketgroup
 787
 788   $basketgroup = &GetBasketgroup($basketgroupid);
 789
 790 Returns a reference to the hash containing all infermation about the basketgroup.
 791
 792 =cut
 793
 794 sub GetBasketgroup {
 795     my $basketgroupid = shift;
 796     die "basketgroup id is required to edit a basketgroup" unless $basketgroupid;
 797     my $query = "SELECT * FROM aqbasketgroups WHERE id=?";
 798     my $dbh = C4::Context->dbh;
 799     my $sth = $dbh->prepare($query);
 800     $sth->execute($basketgroupid);
 801     my $result = $sth->fetchrow_hashref;
 802     $sth->finish;
 803     return $result
 804 }
 805
 806 #------------------------------------------------------------#
 807
 808 =head3 GetBasketgroups
 809
 810   $basketgroups = &GetBasketgroups($booksellerid);
 811
 812 Returns a reference to the array of all the basketgroups of bookseller $booksellerid.
 813
 814 =cut
 815
 816 sub GetBasketgroups {
 817     my $booksellerid = shift;
 818     die 'bookseller id is required to edit a basketgroup' unless $booksellerid;
 819     my $query = 'SELECT * FROM aqbasketgroups WHERE booksellerid=? ORDER BY id DESC';
 820     my $dbh = C4::Context->dbh;
 821     my $sth = $dbh->prepare($query);
 822     $sth->execute($booksellerid);
 823     return $sth->fetchall_arrayref({});
 824 }
 825
 826 #------------------------------------------------------------#
 827
 828 =head2 FUNCTIONS ABOUT ORDERS
 829
 830 =cut
 831
 832 #------------------------------------------------------------#
 833
 834 =head3 GetPendingOrders
 835
 836 $orders = &GetPendingOrders($supplierid,$grouped,$owner,$basketno,$ordernumber,$search,$ean);
 837
 838 Finds pending orders from the bookseller with the given ID. Ignores
 839 completed and cancelled orders.
 840
 841 C<$booksellerid> contains the bookseller identifier
 842 C<$owner> contains 0 or 1. 0 means any owner. 1 means only the list of orders entered by the user itself.
 843 C<$grouped> is a boolean that, if set to 1 will group all order lines of the same basket
 844 in a single result line
 845 C<$orders> is a reference-to-array; each element is a reference-to-hash.
 846
 847 Used also by the filter in parcel.pl
 848 I have added:
 849
 850 C<$ordernumber>
 851 C<$search>
 852 C<$ean>
 853
 854 These give the value of the corresponding field in the aqorders table
 855 of the Koha database.
 856
 857 Results are ordered from most to least recent.
 858
 859 =cut
 860
 861 sub GetPendingOrders {
 862     my ($supplierid,$grouped,$owner,$basketno,$ordernumber,$search,$ean) = @_;
 863     my $dbh = C4::Context->dbh;
 864     my $strsth = "
 865         SELECT ".($grouped?"count(*),":"")."aqbasket.basketno,
 866                surname,firstname,biblio.*,biblioitems.isbn,
 867                aqbasket.closedate, aqbasket.creationdate, aqbasket.basketname,
 868                aqorders.*
 869         FROM aqorders
 870         LEFT JOIN aqbasket ON aqbasket.basketno=aqorders.basketno
 871         LEFT JOIN borrowers ON aqbasket.authorisedby=borrowers.borrowernumber
 872         LEFT JOIN biblio ON biblio.biblionumber=aqorders.biblionumber
 873         LEFT JOIN biblioitems ON biblioitems.biblionumber=biblio.biblionumber
 874         WHERE (quantity > quantityreceived OR quantityreceived is NULL)
 875         AND datecancellationprinted IS NULL";
 876     my @query_params;
 877     my $userenv = C4::Context->userenv;
 878     if ( C4::Context->preference("IndependentBranches") ) {
 879         if ( ($userenv) && ( $userenv->{flags} != 1 ) ) {
 880             $strsth .= " AND (borrowers.branchcode = ?
 881                         or borrowers.branchcode  = '')";
 882             push @query_params, $userenv->{branch};
 883         }
 884     }
 885     if ($supplierid) {
 886         $strsth .= " AND aqbasket.booksellerid = ?";
 887         push @query_params, $supplierid;
 888     }
 889     if($ordernumber){
 890         $strsth .= " AND (aqorders.ordernumber=?)";
 891         push @query_params, $ordernumber;
 892     }
 893     if($search){
 894         $strsth .= " AND (biblio.title like ? OR biblio.author LIKE ? OR biblioitems.isbn like ?)";
 895         push @query_params, ("%$search%","%$search%","%$search%");
 896     }
 897     if ($ean) {
 898         $strsth .= " AND biblioitems.ean = ?";
 899         push @query_params, $ean;
 900     }
 901     if ($basketno) {
 902         $strsth .= " AND aqbasket.basketno=? ";
 903         push @query_params, $basketno;
 904     }
 905     if ($owner) {
 906         $strsth .= " AND aqbasket.authorisedby=? ";
 907         push @query_params, $userenv->{'number'};
 908     }
 909     $strsth .= " group by aqbasket.basketno" if $grouped;
 910     $strsth .= " order by aqbasket.basketno";
 911     my $sth = $dbh->prepare($strsth);
 912     $sth->execute( @query_params );
 913     my $results = $sth->fetchall_arrayref({});
 914     $sth->finish;
 915     return $results;
 916 }
 917
 918 #------------------------------------------------------------#
 919
 920 =head3 GetOrders
 921
 922   @orders = &GetOrders($basketnumber, $orderby);
 923
 924 Looks up the pending (non-cancelled) orders with the given basket
 925 number. If C<$booksellerID> is non-empty, only orders from that seller
 926 are returned.
 927
 928 return :
 929 C<&basket> returns a two-element array. C<@orders> is an array of
 930 references-to-hash, whose keys are the fields from the aqorders,
 931 biblio, and biblioitems tables in the Koha database.
 932
 933 =cut
 934
 935 sub GetOrders {
 936     my ( $basketno, $orderby ) = @_;
 937     my $dbh   = C4::Context->dbh;
 938     my $query  ="
 939         SELECT biblio.*,biblioitems.*,
 940                 aqorders.*,
 941                 aqbudgets.*,
 942                 biblio.title
 943         FROM    aqorders
 944             LEFT JOIN aqbudgets        ON aqbudgets.budget_id = aqorders.budget_id
 945             LEFT JOIN biblio           ON biblio.biblionumber = aqorders.biblionumber
 946             LEFT JOIN biblioitems      ON biblioitems.biblionumber =biblio.biblionumber
 947         WHERE   basketno=?
 948             AND (datecancellationprinted IS NULL OR datecancellationprinted='0000-00-00')
 949     ";
 950
 951     $orderby = "biblioitems.publishercode,biblio.title" unless $orderby;
 952     $query .= " ORDER BY $orderby";
 953     my $sth = $dbh->prepare($query);
 954     $sth->execute($basketno);
 955     my $results = $sth->fetchall_arrayref({});
 956     $sth->finish;
 957     return @$results;
 958 }
 959
 960 #------------------------------------------------------------#
 961 =head3 GetOrdersByBiblionumber
 962
 963   @orders = &GetOrdersByBiblionumber($biblionumber);
 964
 965 Looks up the orders with linked to a specific $biblionumber, including
 966 cancelled orders and received orders.
 967
 968 return :
 969 C<@orders> is an array of references-to-hash, whose keys are the
 970 fields from the aqorders, biblio, and biblioitems tables in the Koha database.
 971
 972 =cut
 973
 974 sub GetOrdersByBiblionumber {
 975     my $biblionumber = shift;
 976     return unless $biblionumber;
 977     my $dbh   = C4::Context->dbh;
 978     my $query  ="
 979         SELECT biblio.*,biblioitems.*,
 980                 aqorders.*,
 981                 aqbudgets.*
 982         FROM    aqorders
 983             LEFT JOIN aqbudgets        ON aqbudgets.budget_id = aqorders.budget_id
 984             LEFT JOIN biblio           ON biblio.biblionumber = aqorders.biblionumber
 985             LEFT JOIN biblioitems      ON biblioitems.biblionumber =biblio.biblionumber
 986         WHERE   aqorders.biblionumber=?
 987     ";
 988     my $sth = $dbh->prepare($query);
 989     $sth->execute($biblionumber);
 990     my $results = $sth->fetchall_arrayref({});
 991     $sth->finish;
 992     return @$results;
 993 }
 994
 995 #------------------------------------------------------------#
 996
 997 =head3 GetOrder
 998
 999   $order = &GetOrder($ordernumber);
1000
1001 Looks up an order by order number.
1002
1003 Returns a reference-to-hash describing the order. The keys of
1004 C<$order> are fields from the biblio, biblioitems, aqorders tables of the Koha database.
1005
1006 =cut
1007
1008 sub GetOrder {
1009     my ($ordernumber) = @_;
1010     my $dbh      = C4::Context->dbh;
1011     my $query = "
1012         SELECT biblioitems.*, biblio.*, aqorders.*
1013         FROM   aqorders
1014         LEFT JOIN biblio on           biblio.biblionumber=aqorders.biblionumber
1015         LEFT JOIN biblioitems on       biblioitems.biblionumber=aqorders.biblionumber
1016         WHERE aqorders.ordernumber=?
1017
1018     ";
1019     my $sth= $dbh->prepare($query);
1020     $sth->execute($ordernumber);
1021     my $data = $sth->fetchrow_hashref;
1022     $sth->finish;
1023     return $data;
1024 }
1025
1026 =head3 GetLastOrderNotReceivedFromSubscriptionid
1027
1028   $order = &GetLastOrderNotReceivedFromSubscriptionid($subscriptionid);
1029
1030 Returns a reference-to-hash describing the last order not received for a subscription.
1031
1032 =cut
1033
1034 sub GetLastOrderNotReceivedFromSubscriptionid {
1035     my ( $subscriptionid ) = @_;
1036     my $dbh                = C4::Context->dbh;
1037     my $query              = qq|
1038         SELECT * FROM aqorders
1039         LEFT JOIN subscription
1040             ON ( aqorders.subscriptionid = subscription.subscriptionid )
1041         WHERE aqorders.subscriptionid = ?
1042             AND aqorders.datereceived IS NULL
1043         LIMIT 1
1044     |;
1045     my $sth = $dbh->prepare( $query );
1046     $sth->execute( $subscriptionid );
1047     my $order = $sth->fetchrow_hashref;
1048     return $order;
1049 }
1050
1051 =head3 GetLastOrderReceivedFromSubscriptionid
1052
1053   $order = &GetLastOrderReceivedFromSubscriptionid($subscriptionid);
1054
1055 Returns a reference-to-hash describing the last order received for a subscription.
1056
1057 =cut
1058
1059 sub GetLastOrderReceivedFromSubscriptionid {
1060     my ( $subscriptionid ) = @_;
1061     my $dbh                = C4::Context->dbh;
1062     my $query              = qq|
1063         SELECT * FROM aqorders
1064         LEFT JOIN subscription
1065             ON ( aqorders.subscriptionid = subscription.subscriptionid )
1066         WHERE aqorders.subscriptionid = ?
1067             AND aqorders.datereceived =
1068                 (
1069                     SELECT MAX( aqorders.datereceived )
1070                     FROM aqorders
1071                     LEFT JOIN subscription
1072                         ON ( aqorders.subscriptionid = subscription.subscriptionid )
1073                         WHERE aqorders.subscriptionid = ?
1074                             AND aqorders.datereceived IS NOT NULL
1075                 )
1076         ORDER BY ordernumber DESC
1077         LIMIT 1
1078     |;
1079     my $sth = $dbh->prepare( $query );
1080     $sth->execute( $subscriptionid, $subscriptionid );
1081     my $order = $sth->fetchrow_hashref;
1082     return $order;
1083
1084 }
1085
1086
1087 #------------------------------------------------------------#
1088
1089 =head3 NewOrder
1090
1091   &NewOrder(\%hashref);
1092
1093 Adds a new order to the database. Any argument that isn't described
1094 below is the new value of the field with the same name in the aqorders
1095 table of the Koha database.
1096
1097 =over
1098
1099 =item $hashref->{'basketno'} is the basketno foreign key in aqorders, it is mandatory
1100
1101 =item $hashref->{'ordernumber'} is a "minimum order number."
1102
1103 =item $hashref->{'budgetdate'} is effectively ignored.
1104 If it's undef (anything false) or the string 'now', the current day is used.
1105 Else, the upcoming July 1st is used.
1106
1107 =item $hashref->{'subscription'} may be either "yes", or anything else for "no".
1108
1109 =item $hashref->{'uncertainprice'} may be 0 for "the price is known" or 1 for "the price is uncertain"
1110
1111 =item defaults entrydate to Now
1112
1113 The following keys are used: "biblionumber", "title", "basketno", "quantity", "notes", "rrp", "ecost", "gstrate", "unitprice", "subscription", "sort1", "sort2", "booksellerinvoicenumber", "listprice", "budgetdate", "purchaseordernumber", "branchcode", "booksellerinvoicenumber", "budget_id".
1114
1115 =back
1116
1117 =cut
1118
1119 sub NewOrder {
1120     my $orderinfo = shift;
1121 #### ------------------------------
1122     my $dbh = C4::Context->dbh;
1123     my @params;
1124
1125
1126     # if these parameters are missing, we can't continue
1127     for my $key (qw/basketno quantity biblionumber budget_id/) {
1128         croak "Mandatory parameter $key missing" unless $orderinfo->{$key};
1129     }
1130
1131     if ( defined $orderinfo->{subscription} && $orderinfo->{'subscription'} eq 'yes' ) {
1132         $orderinfo->{'subscription'} = 1;
1133     } else {
1134         $orderinfo->{'subscription'} = 0;
1135     }
1136     $orderinfo->{'entrydate'} ||= C4::Dates->new()->output("iso");
1137     if (!$orderinfo->{quantityreceived}) {
1138         $orderinfo->{quantityreceived} = 0;
1139     }
1140
1141     my $ordernumber=InsertInTable("aqorders",$orderinfo);
1142     if (not $orderinfo->{parent_ordernumber}) {
1143         my $sth = $dbh->prepare("
1144             UPDATE aqorders
1145             SET parent_ordernumber = ordernumber
1146             WHERE ordernumber = ?
1147         ");
1148         $sth->execute($ordernumber);
1149     }
1150     return ( $orderinfo->{'basketno'}, $ordernumber );
1151 }
1152
1153
1154
1155 #------------------------------------------------------------#
1156
1157 =head3 NewOrderItem
1158
1159   &NewOrderItem();
1160
1161 =cut
1162
1163 sub NewOrderItem {
1164     my ($itemnumber, $ordernumber)  = @_;
1165     my $dbh = C4::Context->dbh;
1166     my $query = qq|
1167             INSERT INTO aqorders_items
1168                 (itemnumber, ordernumber)
1169             VALUES (?,?)    |;
1170
1171     my $sth = $dbh->prepare($query);
1172     $sth->execute( $itemnumber, $ordernumber);
1173 }
1174
1175 #------------------------------------------------------------#
1176
1177 =head3 ModOrder
1178
1179   &ModOrder(\%hashref);
1180
1181 Modifies an existing order. Updates the order with order number
1182 $hashref->{'ordernumber'} and biblionumber $hashref->{'biblionumber'}. All
1183 other keys of the hash update the fields with the same name in the aqorders
1184 table of the Koha database.
1185
1186 =cut
1187
1188 sub ModOrder {
1189     my $orderinfo = shift;
1190
1191     die "Ordernumber is required"     if $orderinfo->{'ordernumber'} eq  '' ;
1192     die "Biblionumber is required"  if  $orderinfo->{'biblionumber'} eq '';
1193
1194     my $dbh = C4::Context->dbh;
1195     my @params;
1196
1197     # update uncertainprice to an integer, just in case (under FF, checked boxes have the value "ON" by default)
1198     $orderinfo->{uncertainprice}=1 if $orderinfo->{uncertainprice};
1199
1200 #    delete($orderinfo->{'branchcode'});
1201     # the hash contains a lot of entries not in aqorders, so get the columns ...
1202     my $sth = $dbh->prepare("SELECT * FROM aqorders LIMIT 1;");
1203     $sth->execute;
1204     my $colnames = $sth->{NAME};
1205         #FIXME Be careful. If aqorders would have columns with diacritics,
1206         #you should need to decode what you get back from NAME.
1207         #See report 10110 and guided_reports.pl
1208     my $query = "UPDATE aqorders SET ";
1209
1210     foreach my $orderinfokey (grep(!/ordernumber/, keys %$orderinfo)){
1211         # ... and skip hash entries that are not in the aqorders table
1212         # FIXME : probably not the best way to do it (would be better to have a correct hash)
1213         next unless grep(/^$orderinfokey$/, @$colnames);
1214             $query .= "$orderinfokey=?, ";
1215             push(@params, $orderinfo->{$orderinfokey});
1216     }
1217
1218     $query .= "timestamp=NOW()  WHERE  ordernumber=?";
1219 #   push(@params, $specorderinfo{'ordernumber'});
1220     push(@params, $orderinfo->{'ordernumber'} );
1221     $sth = $dbh->prepare($query);
1222     $sth->execute(@params);
1223     $sth->finish;
1224 }
1225
1226 #------------------------------------------------------------#
1227
1228 =head3 ModItemOrder
1229
1230     ModItemOrder($itemnumber, $ordernumber);
1231
1232 Modifies the ordernumber of an item in aqorders_items.
1233
1234 =cut
1235
1236 sub ModItemOrder {
1237     my ($itemnumber, $ordernumber) = @_;
1238
1239     return unless ($itemnumber and $ordernumber);
1240
1241     my $dbh = C4::Context->dbh;
1242     my $query = qq{
1243         UPDATE aqorders_items
1244         SET ordernumber = ?
1245         WHERE itemnumber = ?
1246     };
1247     my $sth = $dbh->prepare($query);
1248     return $sth->execute($ordernumber, $itemnumber);
1249 }
1250
1251 #------------------------------------------------------------#
1252
1253 =head3 GetCancelledOrders
1254
1255   my @orders = GetCancelledOrders($basketno, $orderby);
1256
1257 Returns cancelled orders for a basket
1258
1259 =cut
1260
1261 sub GetCancelledOrders {
1262     my ( $basketno, $orderby ) = @_;
1263
1264     return () unless $basketno;
1265
1266     my $dbh   = C4::Context->dbh;
1267     my $query = "
1268         SELECT biblio.*, biblioitems.*, aqorders.*, aqbudgets.*
1269         FROM aqorders
1270           LEFT JOIN aqbudgets   ON aqbudgets.budget_id = aqorders.budget_id
1271           LEFT JOIN biblio      ON biblio.biblionumber = aqorders.biblionumber
1272           LEFT JOIN biblioitems ON biblioitems.biblionumber = biblio.biblionumber
1273         WHERE basketno = ?
1274           AND (datecancellationprinted IS NOT NULL
1275                AND datecancellationprinted <> '0000-00-00')
1276     ";
1277
1278     $orderby = "aqorders.datecancellationprinted desc, aqorders.timestamp desc"
1279         unless $orderby;
1280     $query .= " ORDER BY $orderby";
1281     my $sth = $dbh->prepare($query);
1282     $sth->execute($basketno);
1283     my $results = $sth->fetchall_arrayref( {} );
1284
1285     return @$results;
1286 }
1287
1288
1289 #------------------------------------------------------------#
1290
1291 =head3 ModReceiveOrder
1292
1293   &ModReceiveOrder($biblionumber, $ordernumber, $quantityreceived, $user,
1294     $cost, $ecost, $invoiceid, rrp, budget_id, datereceived, \@received_itemnumbers);
1295
1296 Updates an order, to reflect the fact that it was received, at least
1297 in part. All arguments not mentioned below update the fields with the
1298 same name in the aqorders table of the Koha database.
1299
1300 If a partial order is received, splits the order into two.
1301
1302 Updates the order with bibilionumber C<$biblionumber> and ordernumber
1303 C<$ordernumber>.
1304
1305 =cut
1306
1307
1308 sub ModReceiveOrder {
1309     my (
1310         $biblionumber,    $ordernumber,  $quantrec, $user, $cost, $ecost,
1311         $invoiceid, $rrp, $budget_id, $datereceived, $received_items
1312     )
1313     = @_;
1314
1315     my $dbh = C4::Context->dbh;
1316     $datereceived = C4::Dates->output('iso') unless $datereceived;
1317     my $suggestionid = GetSuggestionFromBiblionumber( $biblionumber );
1318     if ($suggestionid) {
1319         ModSuggestion( {suggestionid=>$suggestionid,
1320                         STATUS=>'AVAILABLE',
1321                         biblionumber=> $biblionumber}
1322                         );
1323     }
1324
1325     my $sth=$dbh->prepare("
1326         SELECT * FROM   aqorders
1327         WHERE           biblionumber=? AND aqorders.ordernumber=?");
1328
1329     $sth->execute($biblionumber,$ordernumber);
1330     my $order = $sth->fetchrow_hashref();
1331     $sth->finish();
1332
1333     my $new_ordernumber = $ordernumber;
1334     if ( $order->{quantity} > $quantrec ) {
1335         # Split order line in two parts: the first is the original order line
1336         # without received items (the quantity is decreased),
1337         # the second part is a new order line with quantity=quantityrec
1338         # (entirely received)
1339         $sth=$dbh->prepare("
1340             UPDATE aqorders
1341             SET quantity = ?
1342             WHERE ordernumber = ?
1343         ");
1344
1345         $sth->execute($order->{quantity} - $quantrec, $ordernumber);
1346
1347         $sth->finish;
1348
1349         delete $order->{'ordernumber'};
1350         $order->{'quantity'} = $quantrec;
1351         $order->{'quantityreceived'} = $quantrec;
1352         $order->{'datereceived'} = $datereceived;
1353         $order->{'invoiceid'} = $invoiceid;
1354         $order->{'unitprice'} = $cost;
1355         $order->{'rrp'} = $rrp;
1356         $order->{ecost} = $ecost;
1357         $order->{'orderstatus'} = 3;    # totally received
1358         my $basketno;
1359         ( $basketno, $new_ordernumber ) = NewOrder($order);
1360
1361         if ($received_items) {
1362             foreach my $itemnumber (@$received_items) {
1363                 ModItemOrder($itemnumber, $new_ordernumber);
1364             }
1365         }
1366     } else {
1367         $sth=$dbh->prepare("update aqorders
1368                             set quantityreceived=?,datereceived=?,invoiceid=?,
1369                                 unitprice=?,rrp=?,ecost=?
1370                             where biblionumber=? and ordernumber=?");
1371         $sth->execute($quantrec,$datereceived,$invoiceid,$cost,$rrp,$ecost,$biblionumber,$ordernumber);
1372         $sth->finish;
1373     }
1374     return ($datereceived, $new_ordernumber);
1375 }
1376
1377 =head3 CancelReceipt
1378
1379     my $parent_ordernumber = CancelReceipt($ordernumber);
1380
1381     Cancel an order line receipt and update the parent order line, as if no
1382     receipt was made.
1383     If items are created at receipt (AcqCreateItem = receiving) then delete
1384     these items.
1385
1386 =cut
1387
1388 sub CancelReceipt {
1389     my $ordernumber = shift;
1390
1391     return unless $ordernumber;
1392
1393     my $dbh = C4::Context->dbh;
1394     my $query = qq{
1395         SELECT datereceived, parent_ordernumber, quantity
1396         FROM aqorders
1397         WHERE ordernumber = ?
1398     };
1399     my $sth = $dbh->prepare($query);
1400     $sth->execute($ordernumber);
1401     my $order = $sth->fetchrow_hashref;
1402     unless($order) {
1403         warn "CancelReceipt: order $ordernumber does not exist";
1404         return;
1405     }
1406     unless($order->{'datereceived'}) {
1407         warn "CancelReceipt: order $ordernumber is not received";
1408         return;
1409     }
1410
1411     my $parent_ordernumber = $order->{'parent_ordernumber'};
1412
1413     if($parent_ordernumber == $ordernumber || not $parent_ordernumber) {
1414         # The order line has no parent, just mark it as not received
1415         $query = qq{
1416             UPDATE aqorders
1417             SET quantityreceived = ?,
1418                 datereceived = ?,
1419                 invoiceid = ?
1420             WHERE ordernumber = ?
1421         };
1422         $sth = $dbh->prepare($query);
1423         $sth->execute(0, undef, undef, $ordernumber);
1424     } else {
1425         # The order line has a parent, increase parent quantity and delete
1426         # the order line.
1427         $query = qq{
1428             SELECT quantity, datereceived
1429             FROM aqorders
1430             WHERE ordernumber = ?
1431         };
1432         $sth = $dbh->prepare($query);
1433         $sth->execute($parent_ordernumber);
1434         my $parent_order = $sth->fetchrow_hashref;
1435         unless($parent_order) {
1436             warn "Parent order $parent_ordernumber does not exist.";
1437             return;
1438         }
1439         if($parent_order->{'datereceived'}) {
1440             warn "CancelReceipt: parent order is received.".
1441                 " Can't cancel receipt.";
1442             return;
1443         }
1444         $query = qq{
1445             UPDATE aqorders
1446             SET quantity = ?
1447             WHERE ordernumber = ?
1448         };
1449         $sth = $dbh->prepare($query);
1450         my $rv = $sth->execute(
1451             $order->{'quantity'} + $parent_order->{'quantity'},
1452             $parent_ordernumber
1453         );
1454         unless($rv) {
1455             warn "Cannot update parent order line, so do not cancel".
1456                 " receipt";
1457             return;
1458         }
1459         if(C4::Context->preference('AcqCreateItem') eq 'receiving') {
1460             # Remove items that were created at receipt
1461             $query = qq{
1462                 DELETE FROM items, aqorders_items
1463                 USING items, aqorders_items
1464                 WHERE items.itemnumber = ? AND aqorders_items.itemnumber = ?
1465             };
1466             $sth = $dbh->prepare($query);
1467             my @itemnumbers = GetItemnumbersFromOrder($ordernumber);
1468             foreach my $itemnumber (@itemnumbers) {
1469                 $sth->execute($itemnumber, $itemnumber);
1470             }
1471         } else {
1472             # Update items
1473             my @itemnumbers = GetItemnumbersFromOrder($ordernumber);
1474             foreach my $itemnumber (@itemnumbers) {
1475                 ModItemOrder($itemnumber, $parent_ordernumber);
1476             }
1477         }
1478         # Delete order line
1479         $query = qq{
1480             DELETE FROM aqorders
1481             WHERE ordernumber = ?
1482         };
1483         $sth = $dbh->prepare($query);
1484         $sth->execute($ordernumber);
1485
1486     }
1487
1488     return $parent_ordernumber;
1489 }
1490
1491 #------------------------------------------------------------#
1492
1493 =head3 SearchOrder
1494
1495 @results = &SearchOrder($search, $biblionumber, $complete);
1496
1497 Searches for orders.
1498
1499 C<$search> may take one of several forms: if it is an ISBN,
1500 C<&ordersearch> returns orders with that ISBN. If C<$search> is an
1501 order number, C<&ordersearch> returns orders with that order number
1502 and biblionumber C<$biblionumber>. Otherwise, C<$search> is considered
1503 to be a space-separated list of search terms; in this case, all of the
1504 terms must appear in the title (matching the beginning of title
1505 words).
1506
1507 If C<$complete> is C<yes>, the results will include only completed
1508 orders. In any case, C<&ordersearch> ignores cancelled orders.
1509
1510 C<&ordersearch> returns an array.
1511 C<@results> is an array of references-to-hash with the following keys:
1512
1513 =over 4
1514
1515 =item C<author>
1516
1517 =item C<seriestitle>
1518
1519 =item C<branchcode>
1520
1521 =item C<budget_id>
1522
1523 =back
1524
1525 =cut
1526
1527 sub SearchOrder {
1528 #### -------- SearchOrder-------------------------------
1529     my ( $ordernumber, $search, $ean, $supplierid, $basket ) = @_;
1530
1531     my $dbh = C4::Context->dbh;
1532     my @args = ();
1533     my $query =
1534             "SELECT *
1535             FROM aqorders
1536             LEFT JOIN biblio ON aqorders.biblionumber=biblio.biblionumber
1537             LEFT JOIN biblioitems ON biblioitems.biblionumber=biblio.biblionumber
1538             LEFT JOIN aqbasket ON aqorders.basketno = aqbasket.basketno
1539                 WHERE  (datecancellationprinted is NULL)";
1540
1541     if($ordernumber){
1542         $query .= " AND (aqorders.ordernumber=?)";
1543         push @args, $ordernumber;
1544     }
1545     if($search){
1546         $query .= " AND (biblio.title like ? OR biblio.author LIKE ? OR biblioitems.isbn like ?)";
1547         push @args, ("%$search%","%$search%","%$search%");
1548     }
1549     if ($ean) {
1550         $query .= " AND biblioitems.ean = ?";
1551         push @args, $ean;
1552     }
1553     if ($supplierid) {
1554         $query .= "AND aqbasket.booksellerid = ?";
1555         push @args, $supplierid;
1556     }
1557     if($basket){
1558         $query .= "AND aqorders.basketno = ?";
1559         push @args, $basket;
1560     }
1561
1562     my $sth = $dbh->prepare($query);
1563     $sth->execute(@args);
1564     my $results = $sth->fetchall_arrayref({});
1565     $sth->finish;
1566     return $results;
1567 }
1568
1569 #------------------------------------------------------------#
1570
1571 =head3 DelOrder
1572
1573   &DelOrder($biblionumber, $ordernumber);
1574
1575 Cancel the order with the given order and biblio numbers. It does not
1576 delete any entries in the aqorders table, it merely marks them as
1577 cancelled.
1578
1579 =cut
1580
1581 sub DelOrder {
1582     my ( $bibnum, $ordernumber ) = @_;
1583     my $dbh = C4::Context->dbh;
1584     my $query = "
1585         UPDATE aqorders
1586         SET    datecancellationprinted=now()
1587         WHERE  biblionumber=? AND ordernumber=?
1588     ";
1589     my $sth = $dbh->prepare($query);
1590     $sth->execute( $bibnum, $ordernumber );
1591     $sth->finish;
1592     my @itemnumbers = GetItemnumbersFromOrder( $ordernumber );
1593     foreach my $itemnumber (@itemnumbers){
1594         C4::Items::DelItem( $dbh, $bibnum, $itemnumber );
1595     }
1596
1597 }
1598
1599 =head2 FUNCTIONS ABOUT PARCELS
1600
1601 =cut
1602
1603 #------------------------------------------------------------#
1604
1605 =head3 GetParcel
1606
1607   @results = &GetParcel($booksellerid, $code, $date);
1608
1609 Looks up all of the received items from the supplier with the given
1610 bookseller ID at the given date, for the given code (bookseller Invoice number). Ignores cancelled and completed orders.
1611
1612 C<@results> is an array of references-to-hash. The keys of each element are fields from
1613 the aqorders, biblio, and biblioitems tables of the Koha database.
1614
1615 C<@results> is sorted alphabetically by book title.
1616
1617 =cut
1618
1619 sub GetParcel {
1620     #gets all orders from a certain supplier, orders them alphabetically
1621     my ( $supplierid, $code, $datereceived ) = @_;
1622     my $dbh     = C4::Context->dbh;
1623     my @results = ();
1624     $code .= '%'
1625     if $code;  # add % if we search on a given code (otherwise, let him empty)
1626     my $strsth ="
1627         SELECT  authorisedby,
1628                 creationdate,
1629                 aqbasket.basketno,
1630                 closedate,surname,
1631                 firstname,
1632                 aqorders.biblionumber,
1633                 aqorders.ordernumber,
1634                 aqorders.parent_ordernumber,
1635                 aqorders.quantity,
1636                 aqorders.quantityreceived,
1637                 aqorders.unitprice,
1638                 aqorders.listprice,
1639                 aqorders.rrp,
1640                 aqorders.ecost,
1641                 aqorders.gstrate,
1642                 biblio.title
1643         FROM aqorders
1644         LEFT JOIN aqbasket ON aqbasket.basketno=aqorders.basketno
1645         LEFT JOIN borrowers ON aqbasket.authorisedby=borrowers.borrowernumber
1646         LEFT JOIN biblio ON aqorders.biblionumber=biblio.biblionumber
1647         LEFT JOIN aqinvoices ON aqorders.invoiceid = aqinvoices.invoiceid
1648         WHERE
1649             aqbasket.booksellerid = ?
1650             AND aqinvoices.invoicenumber LIKE ?
1651             AND aqorders.datereceived = ? ";
1652
1653     my @query_params = ( $supplierid, $code, $datereceived );
1654     if ( C4::Context->preference("IndependentBranches") ) {
1655         my $userenv = C4::Context->userenv;
1656         if ( ($userenv) && ( $userenv->{flags} != 1 ) ) {
1657             $strsth .= " and (borrowers.branchcode = ?
1658                         or borrowers.branchcode  = '')";
1659             push @query_params, $userenv->{branch};
1660         }
1661     }
1662     $strsth .= " ORDER BY aqbasket.basketno";
1663     # ## parcelinformation : $strsth
1664     my $sth = $dbh->prepare($strsth);
1665     $sth->execute( @query_params );
1666     while ( my $data = $sth->fetchrow_hashref ) {
1667         push( @results, $data );
1668     }
1669     # ## countparcelbiblio: scalar(@results)
1670     $sth->finish;
1671
1672     return @results;
1673 }
1674
1675 #------------------------------------------------------------#
1676
1677 =head3 GetParcels
1678
1679   $results = &GetParcels($bookseller, $order, $code, $datefrom, $dateto);
1680
1681 get a lists of parcels.
1682
1683 * Input arg :
1684
1685 =over
1686
1687 =item $bookseller
1688 is the bookseller this function has to get parcels.
1689
1690 =item $order
1691 To know on what criteria the results list has to be ordered.
1692
1693 =item $code
1694 is the booksellerinvoicenumber.
1695
1696 =item $datefrom & $dateto
1697 to know on what date this function has to filter its search.
1698
1699 =back
1700
1701 * return:
1702 a pointer on a hash list containing parcel informations as such :
1703
1704 =over
1705
1706 =item Creation date
1707
1708 =item Last operation
1709
1710 =item Number of biblio
1711
1712 =item Number of items
1713
1714 =back
1715
1716 =cut
1717
1718 sub GetParcels {
1719     my ($bookseller,$order, $code, $datefrom, $dateto) = @_;
1720     my $dbh    = C4::Context->dbh;
1721     my @query_params = ();
1722     my $strsth ="
1723         SELECT  aqinvoices.invoicenumber,
1724                 datereceived,purchaseordernumber,
1725                 count(DISTINCT biblionumber) AS biblio,
1726                 sum(quantity) AS itemsexpected,
1727                 sum(quantityreceived) AS itemsreceived
1728         FROM   aqorders LEFT JOIN aqbasket ON aqbasket.basketno = aqorders.basketno
1729         LEFT JOIN aqinvoices ON aqorders.invoiceid = aqinvoices.invoiceid
1730         WHERE aqbasket.booksellerid = ? and datereceived IS NOT NULL
1731     ";
1732     push @query_params, $bookseller;
1733
1734     if ( defined $code ) {
1735         $strsth .= ' and aqinvoices.invoicenumber like ? ';
1736         # add a % to the end of the code to allow stemming.
1737         push @query_params, "$code%";
1738     }
1739
1740     if ( defined $datefrom ) {
1741         $strsth .= ' and datereceived >= ? ';
1742         push @query_params, $datefrom;
1743     }
1744
1745     if ( defined $dateto ) {
1746         $strsth .=  'and datereceived <= ? ';
1747         push @query_params, $dateto;
1748     }
1749
1750     $strsth .= "group by aqinvoices.invoicenumber,datereceived ";
1751
1752     # can't use a placeholder to place this column name.
1753     # but, we could probably be checking to make sure it is a column that will be fetched.
1754     $strsth .= "order by $order " if ($order);
1755
1756     my $sth = $dbh->prepare($strsth);
1757
1758     $sth->execute( @query_params );
1759     my $results = $sth->fetchall_arrayref({});
1760     $sth->finish;
1761     return @$results;
1762 }
1763
1764 #------------------------------------------------------------#
1765
1766 =head3 GetLateOrders
1767
1768   @results = &GetLateOrders;
1769
1770 Searches for bookseller with late orders.
1771
1772 return:
1773 the table of supplier with late issues. This table is full of hashref.
1774
1775 =cut
1776
1777 sub GetLateOrders {
1778     my $delay      = shift;
1779     my $supplierid = shift;
1780     my $branch     = shift;
1781     my $estimateddeliverydatefrom = shift;
1782     my $estimateddeliverydateto = shift;
1783
1784     my $dbh = C4::Context->dbh;
1785
1786     #BEWARE, order of parenthesis and LEFT JOIN is important for speed
1787     my $dbdriver = C4::Context->config("db_scheme") || "mysql";
1788
1789     my @query_params = ();
1790     my $select = "
1791     SELECT aqbasket.basketno,
1792         aqorders.ordernumber,
1793         DATE(aqbasket.closedate)  AS orderdate,
1794         aqorders.rrp              AS unitpricesupplier,
1795         aqorders.ecost            AS unitpricelib,
1796         aqorders.claims_count     AS claims_count,
1797         aqorders.claimed_date     AS claimed_date,
1798         aqbudgets.budget_name     AS budget,
1799         borrowers.branchcode      AS branch,
1800         aqbooksellers.name        AS supplier,
1801         aqbooksellers.id          AS supplierid,
1802         biblio.author, biblio.title,
1803         biblioitems.publishercode AS publisher,
1804         biblioitems.publicationyear,
1805         ADDDATE(aqbasket.closedate, INTERVAL aqbooksellers.deliverytime DAY) AS estimateddeliverydate,
1806     ";
1807     my $from = "
1808     FROM
1809         aqorders LEFT JOIN biblio     ON biblio.biblionumber         = aqorders.biblionumber
1810         LEFT JOIN biblioitems         ON biblioitems.biblionumber    = biblio.biblionumber
1811         LEFT JOIN aqbudgets           ON aqorders.budget_id          = aqbudgets.budget_id,
1812         aqbasket LEFT JOIN borrowers  ON aqbasket.authorisedby       = borrowers.borrowernumber
1813         LEFT JOIN aqbooksellers       ON aqbasket.booksellerid       = aqbooksellers.id
1814         WHERE aqorders.basketno = aqbasket.basketno
1815         AND ( datereceived = ''
1816             OR datereceived IS NULL
1817             OR aqorders.quantityreceived < aqorders.quantity
1818         )
1819         AND aqbasket.closedate IS NOT NULL
1820         AND (aqorders.datecancellationprinted IS NULL OR aqorders.datecancellationprinted='0000-00-00')
1821     ";
1822     my $having = "";
1823     if ($dbdriver eq "mysql") {
1824         $select .= "
1825         aqorders.quantity - COALESCE(aqorders.quantityreceived,0)                 AS quantity,
1826         (aqorders.quantity - COALESCE(aqorders.quantityreceived,0)) * aqorders.rrp AS subtotal,
1827         DATEDIFF(CAST(now() AS date),closedate) AS latesince
1828         ";
1829         if ( defined $delay ) {
1830             $from .= " AND (closedate <= DATE_SUB(CAST(now() AS date),INTERVAL ? DAY)) " ;
1831             push @query_params, $delay;
1832         }
1833         $having = "
1834         HAVING quantity          <> 0
1835             AND unitpricesupplier <> 0
1836             AND unitpricelib      <> 0
1837         ";
1838     } else {
1839         # FIXME: account for IFNULL as above
1840         $select .= "
1841                 aqorders.quantity                AS quantity,
1842                 aqorders.quantity * aqorders.rrp AS subtotal,
1843                 (CAST(now() AS date) - closedate)            AS latesince
1844         ";
1845         if ( defined $delay ) {
1846             $from .= " AND (closedate <= (CAST(now() AS date) -(INTERVAL ? DAY)) ";
1847             push @query_params, $delay;
1848         }
1849     }
1850     if (defined $supplierid) {
1851         $from .= ' AND aqbasket.booksellerid = ? ';
1852         push @query_params, $supplierid;
1853     }
1854     if (defined $branch) {
1855         $from .= ' AND borrowers.branchcode LIKE ? ';
1856         push @query_params, $branch;
1857     }
1858
1859     if ( defined $estimateddeliverydatefrom or defined $estimateddeliverydateto ) {
1860         $from .= ' AND aqbooksellers.deliverytime IS NOT NULL ';
1861     }
1862     if ( defined $estimateddeliverydatefrom ) {
1863         $from .= ' AND ADDDATE(aqbasket.closedate, INTERVAL aqbooksellers.deliverytime DAY) >= ?';
1864         push @query_params, $estimateddeliverydatefrom;
1865     }
1866     if ( defined $estimateddeliverydateto ) {
1867         $from .= ' AND ADDDATE(aqbasket.closedate, INTERVAL aqbooksellers.deliverytime DAY) <= ?';
1868         push @query_params, $estimateddeliverydateto;
1869     }
1870     if ( defined $estimateddeliverydatefrom and not defined $estimateddeliverydateto ) {
1871         $from .= ' AND ADDDATE(aqbasket.closedate, INTERVAL aqbooksellers.deliverytime DAY) <= CAST(now() AS date)';
1872     }
1873     if (C4::Context->preference("IndependentBranches")
1874             && C4::Context->userenv
1875             && C4::Context->userenv->{flags} != 1 ) {
1876         $from .= ' AND borrowers.branchcode LIKE ? ';
1877         push @query_params, C4::Context->userenv->{branch};
1878     }
1879     my $query = "$select $from $having\nORDER BY latesince, basketno, borrowers.branchcode, supplier";
1880     $debug and print STDERR "GetLateOrders query: $query\nGetLateOrders args: " . join(" ",@query_params);
1881     my $sth = $dbh->prepare($query);
1882     $sth->execute(@query_params);
1883     my @results;
1884     while (my $data = $sth->fetchrow_hashref) {
1885         $data->{orderdate} = format_date($data->{orderdate});
1886         $data->{claimed_date} = format_date($data->{claimed_date});
1887         push @results, $data;
1888     }
1889     return @results;
1890 }
1891
1892 #------------------------------------------------------------#
1893
1894 =head3 GetHistory
1895
1896   (\@order_loop, $total_qty, $total_price, $total_qtyreceived) = GetHistory( %params );
1897
1898 Retreives some acquisition history information
1899
1900 params:
1901   title
1902   author
1903   name
1904   from_placed_on
1905   to_placed_on
1906   basket                  - search both basket name and number
1907   booksellerinvoicenumber
1908
1909 returns:
1910     $order_loop is a list of hashrefs that each look like this:
1911             {
1912                 'author'           => 'Twain, Mark',
1913                 'basketno'         => '1',
1914                 'biblionumber'     => '215',
1915                 'count'            => 1,
1916                 'creationdate'     => 'MM/DD/YYYY',
1917                 'datereceived'     => undef,
1918                 'ecost'            => '1.00',
1919                 'id'               => '1',
1920                 'invoicenumber'    => undef,
1921                 'name'             => '',
1922                 'ordernumber'      => '1',
1923                 'quantity'         => 1,
1924                 'quantityreceived' => undef,
1925                 'title'            => 'The Adventures of Huckleberry Finn'
1926             }
1927     $total_qty is the sum of all of the quantities in $order_loop
1928     $total_price is the cost of each in $order_loop times the quantity
1929     $total_qtyreceived is the sum of all of the quantityreceived entries in $order_loop
1930
1931 =cut
1932
1933 sub GetHistory {
1934 # don't run the query if there are no parameters (list would be too long for sure !)
1935     croak "No search params" unless @_;
1936     my %params = @_;
1937     my $title = $params{title};
1938     my $author = $params{author};
1939     my $isbn   = $params{isbn};
1940     my $ean    = $params{ean};
1941     my $name = $params{name};
1942     my $from_placed_on = $params{from_placed_on};
1943     my $to_placed_on = $params{to_placed_on};
1944     my $basket = $params{basket};
1945     my $booksellerinvoicenumber = $params{booksellerinvoicenumber};
1946     my $basketgroupname = $params{basketgroupname};
1947     my @order_loop;
1948     my $total_qty         = 0;
1949     my $total_qtyreceived = 0;
1950     my $total_price       = 0;
1951
1952     my $dbh   = C4::Context->dbh;
1953     my $query ="
1954         SELECT
1955             biblio.title,
1956             biblio.author,
1957             biblioitems.isbn,
1958         biblioitems.ean,
1959             aqorders.basketno,
1960             aqbasket.basketname,
1961             aqbasket.basketgroupid,
1962             aqbasketgroups.name as groupname,
1963             aqbooksellers.name,
1964             aqbasket.creationdate,
1965             aqorders.datereceived,
1966             aqorders.quantity,
1967             aqorders.quantityreceived,
1968             aqorders.ecost,
1969             aqorders.ordernumber,
1970             aqorders.invoiceid,
1971             aqinvoices.invoicenumber,
1972             aqbooksellers.id as id,
1973             aqorders.biblionumber
1974         FROM aqorders
1975         LEFT JOIN aqbasket ON aqorders.basketno=aqbasket.basketno
1976         LEFT JOIN aqbasketgroups ON aqbasket.basketgroupid=aqbasketgroups.id
1977         LEFT JOIN aqbooksellers ON aqbasket.booksellerid=aqbooksellers.id
1978         LEFT JOIN biblioitems ON biblioitems.biblionumber=aqorders.biblionumber
1979         LEFT JOIN biblio ON biblio.biblionumber=aqorders.biblionumber
1980     LEFT JOIN aqinvoices ON aqorders.invoiceid = aqinvoices.invoiceid";
1981
1982     $query .= " LEFT JOIN borrowers ON aqbasket.authorisedby=borrowers.borrowernumber"
1983     if ( C4::Context->preference("IndependentBranches") );
1984
1985     $query .= " WHERE (datecancellationprinted is NULL or datecancellationprinted='0000-00-00') ";
1986
1987     my @query_params  = ();
1988
1989     if ( $title ) {
1990         $query .= " AND biblio.title LIKE ? ";
1991         $title =~ s/\s+/%/g;
1992         push @query_params, "%$title%";
1993     }
1994
1995     if ( $author ) {
1996         $query .= " AND biblio.author LIKE ? ";
1997         push @query_params, "%$author%";
1998     }
1999
2000     if ( $isbn ) {
2001         $query .= " AND biblioitems.isbn LIKE ? ";
2002         push @query_params, "%$isbn%";
2003     }
2004     if ( defined $ean and $ean ) {
2005         $query .= " AND biblioitems.ean = ? ";
2006         push @query_params, "$ean";
2007     }
2008     if ( $name ) {
2009         $query .= " AND aqbooksellers.name LIKE ? ";
2010         push @query_params, "%$name%";
2011     }
2012
2013     if ( $from_placed_on ) {
2014         $query .= " AND creationdate >= ? ";
2015         push @query_params, $from_placed_on;
2016     }
2017
2018     if ( $to_placed_on ) {
2019         $query .= " AND creationdate <= ? ";
2020         push @query_params, $to_placed_on;
2021     }
2022
2023     if ($basket) {
2024         if ($basket =~ m/^\d+$/) {
2025             $query .= " AND aqorders.basketno = ? ";
2026             push @query_params, $basket;
2027         } else {
2028             $query .= " AND aqbasket.basketname LIKE ? ";
2029             push @query_params, "%$basket%";
2030         }
2031     }
2032
2033     if ($booksellerinvoicenumber) {
2034         $query .= " AND aqinvoices.invoicenumber LIKE ? ";
2035         push @query_params, "%$booksellerinvoicenumber%";
2036     }
2037
2038     if ($basketgroupname) {
2039         $query .= " AND aqbasketgroups.name LIKE ? ";
2040         push @query_params, "%$basketgroupname%";
2041     }
2042
2043     if ( C4::Context->preference("IndependentBranches") ) {
2044         my $userenv = C4::Context->userenv;
2045         if ( $userenv && ($userenv->{flags} || 0) != 1 ) {
2046             $query .= " AND (borrowers.branchcode = ? OR borrowers.branchcode ='' ) ";
2047             push @query_params, $userenv->{branch};
2048         }
2049     }
2050     $query .= " ORDER BY id";
2051     my $sth = $dbh->prepare($query);
2052     $sth->execute( @query_params );
2053     my $cnt = 1;
2054     while ( my $line = $sth->fetchrow_hashref ) {
2055         $line->{count} = $cnt++;
2056         $line->{toggle} = 1 if $cnt % 2;
2057         push @order_loop, $line;
2058         $total_qty         += $line->{'quantity'};
2059         $total_qtyreceived += $line->{'quantityreceived'};
2060         $total_price       += $line->{'quantity'} * $line->{'ecost'};
2061     }
2062     return \@order_loop, $total_qty, $total_price, $total_qtyreceived;
2063 }
2064
2065 =head2 GetRecentAcqui
2066
2067   $results = GetRecentAcqui($days);
2068
2069 C<$results> is a ref to a table which containts hashref
2070
2071 =cut
2072
2073 sub GetRecentAcqui {
2074     my $limit  = shift;
2075     my $dbh    = C4::Context->dbh;
2076     my $query = "
2077         SELECT *
2078         FROM   biblio
2079         ORDER BY timestamp DESC
2080         LIMIT  0,".$limit;
2081
2082     my $sth = $dbh->prepare($query);
2083     $sth->execute;
2084     my $results = $sth->fetchall_arrayref({});
2085     return $results;
2086 }
2087
2088 =head3 GetContracts
2089
2090   $contractlist = &GetContracts($booksellerid, $activeonly);
2091
2092 Looks up the contracts that belong to a bookseller
2093
2094 Returns a list of contracts
2095
2096 =over
2097
2098 =item C<$booksellerid> is the "id" field in the "aqbooksellers" table.
2099
2100 =item C<$activeonly> if exists get only contracts that are still active.
2101
2102 =back
2103
2104 =cut
2105
2106 sub GetContracts {
2107     my ( $booksellerid, $activeonly ) = @_;
2108     my $dbh = C4::Context->dbh;
2109     my $query;
2110     if (! $activeonly) {
2111         $query = "
2112             SELECT *
2113             FROM   aqcontract
2114             WHERE  booksellerid=?
2115         ";
2116     } else {
2117         $query = "SELECT *
2118             FROM aqcontract
2119             WHERE booksellerid=?
2120                 AND contractenddate >= CURDATE( )";
2121     }
2122     my $sth = $dbh->prepare($query);
2123     $sth->execute( $booksellerid );
2124     my @results;
2125     while (my $data = $sth->fetchrow_hashref ) {
2126         push(@results, $data);
2127     }
2128     $sth->finish;
2129     return @results;
2130 }
2131
2132 #------------------------------------------------------------#
2133
2134 =head3 GetContract
2135
2136   $contract = &GetContract($contractID);
2137
2138 Looks up the contract that has PRIMKEY (contractnumber) value $contractID
2139
2140 Returns a contract
2141
2142 =cut
2143
2144 sub GetContract {
2145     my ( $contractno ) = @_;
2146     my $dbh = C4::Context->dbh;
2147     my $query = "
2148         SELECT *
2149         FROM   aqcontract
2150         WHERE  contractnumber=?
2151         ";
2152
2153     my $sth = $dbh->prepare($query);
2154     $sth->execute( $contractno );
2155     my $result = $sth->fetchrow_hashref;
2156     return $result;
2157 }
2158
2159 =head3 AddClaim
2160
2161 =over 4
2162
2163 &AddClaim($ordernumber);
2164
2165 Add a claim for an order
2166
2167 =back
2168
2169 =cut
2170 sub AddClaim {
2171     my ($ordernumber) = @_;
2172     my $dbh          = C4::Context->dbh;
2173     my $query        = "
2174         UPDATE aqorders SET
2175             claims_count = claims_count + 1,
2176             claimed_date = CURDATE()
2177         WHERE ordernumber = ?
2178         ";
2179     my $sth = $dbh->prepare($query);
2180     $sth->execute($ordernumber);
2181 }
2182
2183 =head3 GetInvoices
2184
2185     my @invoices = GetInvoices(
2186         invoicenumber => $invoicenumber,
2187         suppliername => $suppliername,
2188         shipmentdatefrom => $shipmentdatefrom, # ISO format
2189         shipmentdateto => $shipmentdateto, # ISO format
2190         billingdatefrom => $billingdatefrom, # ISO format
2191         billingdateto => $billingdateto, # ISO format
2192         isbneanissn => $isbn_or_ean_or_issn,
2193         title => $title,
2194         author => $author,
2195         publisher => $publisher,
2196         publicationyear => $publicationyear,
2197         branchcode => $branchcode,
2198         order_by => $order_by
2199     );
2200
2201 Return a list of invoices that match all given criteria.
2202
2203 $order_by is "column_name (asc|desc)", where column_name is any of
2204 'invoicenumber', 'booksellerid', 'shipmentdate', 'billingdate', 'closedate',
2205 'shipmentcost', 'shipmentcost_budgetid'.
2206
2207 asc is the default if omitted
2208
2209 =cut
2210
2211 sub GetInvoices {
2212     my %args = @_;
2213
2214     my @columns = qw(invoicenumber booksellerid shipmentdate billingdate
2215         closedate shipmentcost shipmentcost_budgetid);
2216
2217     my $dbh = C4::Context->dbh;
2218     my $query = qq{
2219         SELECT aqinvoices.*, aqbooksellers.name AS suppliername,
2220           COUNT(
2221             DISTINCT IF(
2222               aqorders.datereceived IS NOT NULL,
2223               aqorders.biblionumber,
2224               NULL
2225             )
2226           ) AS receivedbiblios,
2227           SUM(aqorders.quantityreceived) AS receiveditems
2228         FROM aqinvoices
2229           LEFT JOIN aqbooksellers ON aqbooksellers.id = aqinvoices.booksellerid
2230           LEFT JOIN aqorders ON aqorders.invoiceid = aqinvoices.invoiceid
2231           LEFT JOIN biblio ON aqorders.biblionumber = biblio.biblionumber
2232           LEFT JOIN biblioitems ON biblio.biblionumber = biblioitems.biblionumber
2233           LEFT JOIN subscription ON biblio.biblionumber = subscription.biblionumber
2234     };
2235
2236     my @bind_args;
2237     my @bind_strs;
2238     if($args{supplierid}) {
2239         push @bind_strs, " aqinvoices.booksellerid = ? ";
2240         push @bind_args, $args{supplierid};
2241     }
2242     if($args{invoicenumber}) {
2243         push @bind_strs, " aqinvoices.invoicenumber LIKE ? ";
2244         push @bind_args, "%$args{invoicenumber}%";
2245     }
2246     if($args{suppliername}) {
2247         push @bind_strs, " aqbooksellers.name LIKE ? ";
2248         push @bind_args, "%$args{suppliername}%";
2249     }
2250     if($args{shipmentdatefrom}) {
2251         push @bind_strs, " aqinvoices.shipementdate >= ? ";
2252         push @bind_args, $args{shipmentdatefrom};
2253     }
2254     if($args{shipmentdateto}) {
2255         push @bind_strs, " aqinvoices.shipementdate <= ? ";
2256         push @bind_args, $args{shipmentdateto};
2257     }
2258     if($args{billingdatefrom}) {
2259         push @bind_strs, " aqinvoices.billingdate >= ? ";
2260         push @bind_args, $args{billingdatefrom};
2261     }
2262     if($args{billingdateto}) {
2263         push @bind_strs, " aqinvoices.billingdate <= ? ";
2264         push @bind_args, $args{billingdateto};
2265     }
2266     if($args{isbneanissn}) {
2267         push @bind_strs, " (biblioitems.isbn LIKE ? OR biblioitems.ean LIKE ? OR biblioitems.issn LIKE ? ) ";
2268         push @bind_args, $args{isbneanissn}, $args{isbneanissn}, $args{isbneanissn};
2269     }
2270     if($args{title}) {
2271         push @bind_strs, " biblio.title LIKE ? ";
2272         push @bind_args, $args{title};
2273     }
2274     if($args{author}) {
2275         push @bind_strs, " biblio.author LIKE ? ";
2276         push @bind_args, $args{author};
2277     }
2278     if($args{publisher}) {
2279         push @bind_strs, " biblioitems.publishercode LIKE ? ";
2280         push @bind_args, $args{publisher};
2281     }
2282     if($args{publicationyear}) {
2283         push @bind_strs, " biblioitems.publicationyear = ? ";
2284         push @bind_args, $args{publicationyear};
2285     }
2286     if($args{branchcode}) {
2287         push @bind_strs, " aqorders.branchcode = ? ";
2288         push @bind_args, $args{branchcode};
2289     }
2290
2291     $query .= " WHERE " . join(" AND ", @bind_strs) if @bind_strs;
2292     $query .= " GROUP BY aqinvoices.invoiceid ";
2293
2294     if($args{order_by}) {
2295         my ($column, $direction) = split / /, $args{order_by};
2296         if(grep /^$column$/, @columns) {
2297             $direction ||= 'ASC';
2298             $query .= " ORDER BY $column $direction";
2299         }
2300     }
2301
2302     my $sth = $dbh->prepare($query);
2303     $sth->execute(@bind_args);
2304
2305     my $results = $sth->fetchall_arrayref({});
2306     return @$results;
2307 }
2308
2309 =head3 GetInvoice
2310
2311     my $invoice = GetInvoice($invoiceid);
2312
2313 Get informations about invoice with given $invoiceid
2314
2315 Return a hash filled with aqinvoices.* fields
2316
2317 =cut
2318
2319 sub GetInvoice {
2320     my ($invoiceid) = @_;
2321     my $invoice;
2322
2323     return unless $invoiceid;
2324
2325     my $dbh = C4::Context->dbh;
2326     my $query = qq{
2327         SELECT *
2328         FROM aqinvoices
2329         WHERE invoiceid = ?
2330     };
2331     my $sth = $dbh->prepare($query);
2332     $sth->execute($invoiceid);
2333
2334     $invoice = $sth->fetchrow_hashref;
2335     return $invoice;
2336 }
2337
2338 =head3 GetInvoiceDetails
2339
2340     my $invoice = GetInvoiceDetails($invoiceid)
2341
2342 Return informations about an invoice + the list of related order lines
2343
2344 Orders informations are in $invoice->{orders} (array ref)
2345
2346 =cut
2347
2348 sub GetInvoiceDetails {
2349     my ($invoiceid) = @_;
2350
2351     if ( !defined $invoiceid ) {
2352         carp 'GetInvoiceDetails called without an invoiceid';
2353         return;
2354     }
2355
2356     my $dbh = C4::Context->dbh;
2357     my $query = qq{
2358         SELECT aqinvoices.*, aqbooksellers.name AS suppliername
2359         FROM aqinvoices
2360           LEFT JOIN aqbooksellers ON aqinvoices.booksellerid = aqbooksellers.id
2361         WHERE invoiceid = ?
2362     };
2363     my $sth = $dbh->prepare($query);
2364     $sth->execute($invoiceid);
2365
2366     my $invoice = $sth->fetchrow_hashref;
2367
2368     $query = qq{
2369         SELECT aqorders.*, biblio.*
2370         FROM aqorders
2371           LEFT JOIN biblio ON aqorders.biblionumber = biblio.biblionumber
2372         WHERE invoiceid = ?
2373     };
2374     $sth = $dbh->prepare($query);
2375     $sth->execute($invoiceid);
2376     $invoice->{orders} = $sth->fetchall_arrayref({});
2377     $invoice->{orders} ||= []; # force an empty arrayref if fetchall_arrayref fails
2378
2379     return $invoice;
2380 }
2381
2382 =head3 AddInvoice
2383
2384     my $invoiceid = AddInvoice(
2385         invoicenumber => $invoicenumber,
2386         booksellerid => $booksellerid,
2387         shipmentdate => $shipmentdate,
2388         billingdate => $billingdate,
2389         closedate => $closedate,
2390         shipmentcost => $shipmentcost,
2391         shipmentcost_budgetid => $shipmentcost_budgetid
2392     );
2393
2394 Create a new invoice and return its id or undef if it fails.
2395
2396 =cut
2397
2398 sub AddInvoice {
2399     my %invoice = @_;
2400
2401     return unless(%invoice and $invoice{invoicenumber});
2402
2403     my @columns = qw(invoicenumber booksellerid shipmentdate billingdate
2404         closedate shipmentcost shipmentcost_budgetid);
2405
2406     my @set_strs;
2407     my @set_args;
2408     foreach my $key (keys %invoice) {
2409         if(0 < grep(/^$key$/, @columns)) {
2410             push @set_strs, "$key = ?";
2411             push @set_args, ($invoice{$key} || undef);
2412         }
2413     }
2414
2415     my $rv;
2416     if(@set_args > 0) {
2417         my $dbh = C4::Context->dbh;
2418         my $query = "INSERT INTO aqinvoices SET ";
2419         $query .= join (",", @set_strs);
2420         my $sth = $dbh->prepare($query);
2421         $rv = $sth->execute(@set_args);
2422         if($rv) {
2423             $rv = $dbh->last_insert_id(undef, undef, 'aqinvoices', undef);
2424         }
2425     }
2426     return $rv;
2427 }
2428
2429 =head3 ModInvoice
2430
2431     ModInvoice(
2432         invoiceid => $invoiceid,    # Mandatory
2433         invoicenumber => $invoicenumber,
2434         booksellerid => $booksellerid,
2435         shipmentdate => $shipmentdate,
2436         billingdate => $billingdate,
2437         closedate => $closedate,
2438         shipmentcost => $shipmentcost,
2439         shipmentcost_budgetid => $shipmentcost_budgetid
2440     );
2441
2442 Modify an invoice, invoiceid is mandatory.
2443
2444 Return undef if it fails.
2445
2446 =cut
2447
2448 sub ModInvoice {
2449     my %invoice = @_;
2450
2451     return unless(%invoice and $invoice{invoiceid});
2452
2453     my @columns = qw(invoicenumber booksellerid shipmentdate billingdate
2454         closedate shipmentcost shipmentcost_budgetid);
2455
2456     my @set_strs;
2457     my @set_args;
2458     foreach my $key (keys %invoice) {
2459         if(0 < grep(/^$key$/, @columns)) {
2460             push @set_strs, "$key = ?";
2461             push @set_args, ($invoice{$key} || undef);
2462         }
2463     }
2464
2465     my $dbh = C4::Context->dbh;
2466     my $query = "UPDATE aqinvoices SET ";
2467     $query .= join(",", @set_strs);
2468     $query .= " WHERE invoiceid = ?";
2469
2470     my $sth = $dbh->prepare($query);
2471     $sth->execute(@set_args, $invoice{invoiceid});
2472 }
2473
2474 =head3 CloseInvoice
2475
2476     CloseInvoice($invoiceid);
2477
2478 Close an invoice.
2479
2480 Equivalent to ModInvoice(invoiceid => $invoiceid, closedate => undef);
2481
2482 =cut
2483
2484 sub CloseInvoice {
2485     my ($invoiceid) = @_;
2486
2487     return unless $invoiceid;
2488
2489     my $dbh = C4::Context->dbh;
2490     my $query = qq{
2491         UPDATE aqinvoices
2492         SET closedate = CAST(NOW() AS DATE)
2493         WHERE invoiceid = ?
2494     };
2495     my $sth = $dbh->prepare($query);
2496     $sth->execute($invoiceid);
2497 }
2498
2499 =head3 ReopenInvoice
2500
2501     ReopenInvoice($invoiceid);
2502
2503 Reopen an invoice
2504
2505 Equivalent to ModInvoice(invoiceid => $invoiceid, closedate => C4::Dates->new()->output('iso'))
2506
2507 =cut
2508
2509 sub ReopenInvoice {
2510     my ($invoiceid) = @_;
2511
2512     return unless $invoiceid;
2513
2514     my $dbh = C4::Context->dbh;
2515     my $query = qq{
2516         UPDATE aqinvoices
2517         SET closedate = NULL
2518         WHERE invoiceid = ?
2519     };
2520     my $sth = $dbh->prepare($query);
2521     $sth->execute($invoiceid);
2522 }
2523
2524 =head3 DelInvoice
2525
2526     DelInvoice($invoiceid);
2527
2528 Delete an invoice if there are no items attached to it.
2529
2530 =cut
2531
2532 sub DelInvoice {
2533     my ($invoiceid) = @_;
2534
2535     return unless $invoiceid;
2536
2537     my $dbh   = C4::Context->dbh;
2538     my $query = qq{
2539         SELECT COUNT(*)
2540         FROM aqorders
2541         WHERE invoiceid = ?
2542     };
2543     my $sth = $dbh->prepare($query);
2544     $sth->execute($invoiceid);
2545     my $res = $sth->fetchrow_arrayref;
2546     if ( $res && $res->[0] == 0 ) {
2547         $query = qq{
2548             DELETE FROM aqinvoices
2549             WHERE invoiceid = ?
2550         };
2551         my $sth = $dbh->prepare($query);
2552         return ( $sth->execute($invoiceid) > 0 );
2553     }
2554     return;
2555 }
2556
2557 1;
2558 __END__
2559
2560 =head1 AUTHOR
2561
2562 Koha Development Team <http://koha-community.org/>
2563
2564 =cut