cataloguing/value_builder/callnumber-KU.pl

   1 #!/usr/bin/perl
   2
   3 # Converted to new plugin style (Bug 13437)
   4
   5 # Copyright 2012 CatalystIT Ltd
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 use Modern::Perl;
  23 use CGI qw ( -utf8 );
  24
  25 use C4::Auth;
  26 use C4::Context;
  27 use C4::Output;
  28
  29 =head1 DESCRIPTION
  30
  31 Is used for callnumber computation.
  32
  33 User must supply a letter prefix (unspecified length) followed by an empty space followed by a "number".
  34 "Number" is 4 character long, and is either a number sequence which is 01 padded.
  35 If input does not conform with this format any processing is omitted.
  36
  37 Some examples of legal values that trigger auto allocation:
  38
  39 AAA 0  - returns first unused number AAA 0xxx starting with AAA 0001
  40 BBB 12 - returns first unused number BBB 12xx starting with BBB 1201
  41 CCC QW - returns first unused number CCC QWxx starting with CCC QW01
  42
  43 =cut
  44
  45 my $builder = sub {
  46     my ( $params ) = @_;
  47     my $res="
  48     <script type='text/javascript'>
  49         function Click$params->{id}() {
  50                 var code = document.getElementById('$params->{id}');
  51                 var url = '../cataloguing/plugin_launcher.pl?plugin_name=callnumber-KU.pl&code=' + code.value;
  52                 var req = \$.get(url);
  53                 req.done(function(resp){
  54                     code.value = resp;
  55                     return 1;
  56                 });
  57             return 1;
  58         }
  59     </script>
  60     ";
  61     return $res;
  62 };
  63
  64 my $launcher = sub {
  65     my ( $params ) = @_;
  66     my $input = $params->{cgi};
  67     my $code = $input->param('code');
  68
  69     my ($template, $loggedinuser, $cookie) = get_template_and_user({
  70         template_name   => "cataloguing/value_builder/ajax.tt",
  71         query           => $input,
  72         type            => "intranet",
  73         authnotrequired => 0,
  74         flagsrequired   => {editcatalogue => '*'},
  75         debug           => 1,
  76     });
  77
  78     my $BASE_CALLNUMBER_RE = qr/^(\w+) (\w+)$/;
  79     my $ret;
  80     my ($alpha, $num) = ($code =~ $BASE_CALLNUMBER_RE);
  81     if (defined $num) { # otherwise no point
  82         my ($num_alpha, $num_num) = ($num =~ m/^(\D+)?(\d+)?$/);
  83         $num_alpha ||= '';
  84         my $pad_len = 4 - length($num);
  85
  86         if ($pad_len > 0) {
  87             my $num_padded = $num_num;
  88             $num_padded .= "0" x ($pad_len - 1) if $pad_len > 1;
  89             $num_padded .= "1";
  90             my $padded = "$alpha $num_alpha" . $num_padded;
  91
  92             my $dbh = C4::Context->dbh;
  93             if ( my $first = $dbh->selectrow_array("SELECT itemcallnumber
  94                                                     FROM items
  95                                                     WHERE itemcallnumber = ?", undef, $padded) ) {
  96                 my $icn = $dbh->selectcol_arrayref("SELECT DISTINCT itemcallnumber
  97                                                     FROM items
  98                                                     WHERE itemcallnumber LIKE ?
  99                                                       AND itemcallnumber >   ?
 100                                                     ORDER BY itemcallnumber", undef, "$alpha $num_alpha%", $first);
 101                 my $next = $num_padded + 1;
 102                 my $len = length($num_padded);
 103                 foreach (@$icn) {
 104                     my ($num1) = ( m/(\d+)$/o );
 105                     if ($num1 > $next) { # a hole in numbering found, stop
 106                         last;
 107                     }
 108                     $next++;
 109                 }
 110                 $ret = "$alpha $num_alpha" . sprintf("%0${len}d", $next) if length($next) <= $len; # no overflow
 111             }
 112             else {
 113                 $ret = $padded;
 114             }
 115         }
 116     }
 117
 118     $template->param(
 119         return => $ret || $code
 120     );
 121     output_html_with_http_headers $input, $cookie, $template->output;
 122 };
 123
 124 return { builder => $builder, launcher => $launcher };