opac/unapi

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008-2009 LibLime
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22
  23 =head1 NAME
  24
  25 unapi - implement unAPI for the OPAC
  26
  27 =head1 SYNOPSIS
  28
  29 Retrieve http://library.example.org/cgi-bin/koha/unapi?id=koha:biblionumber:123&format=oai_dc
  30
  31 =head1 DESCRIPTION
  32
  33 Implements unAPI <http://unapi.info>, a small HTTP API for retrieving structured
  34 content from a web application.  The primary application of unAPI in Koha is to
  35 allow tools such as Zotero to identify and grab bibliographic record metadata in
  36 an XML format such as OAI DC, RSS2, MARCXML, or MODS.
  37
  38 =cut
  39
  40 use CGI qw ( -utf8 );
  41 use C4::Context;
  42 use C4::Biblio;
  43 use Koha::XSLT_Handler;
  44
  45 my $cgi = CGI->new();
  46 binmode(STDOUT, ":encoding(UTF-8)"); #output as utf8
  47
  48 =head1 VARIABLES
  49
  50 =head2 $format_to_stylesheet_map
  51
  52 This hashref of hashrefs maps from a MARC flavour and unAPI format
  53 to the stylesheet that should be used to transform the bib MARCXML
  54 to the desired output format.  As new MARC XSLT stylesheets are added,
  55 (particularly for UNIMARC), this map should be updated.  Of course,
  56 if/when we add support for emitting a format that is not genreated
  57 by a stylesheet, the structure of this variable will have to be changed.
  58 At present, this doubles as the list of output formats supported by
  59 this unAPI implementation.
  60
  61 =cut
  62
  63 my $format_to_stylesheet_map = {
  64     'MARC21' => {
  65         'marcxml'      => 'identity.xsl',
  66         'marcxml-full' => 'identity.xsl',
  67         'mods'         => 'MARC21slim2MODS.xsl',
  68         'mods-full'    => 'MARC21slim2MODS.xsl',
  69         'mods3'        => 'MARC21slim2MODS3-1.xsl',
  70         'mods3-full'   => 'MARC21slim2MODS3-1.xsl',
  71         'oai_dc'       => 'MARC21slim2OAIDC.xsl',
  72         'rdfdc',       => 'MARC21slim2RDFDC.xsl',
  73         'rss2'         => 'MARC21slim2RSS2.xsl',
  74         'rss2-full'    => 'MARC21slim2RSS2.xsl',
  75         'srw_dc'       => 'MARC21slim2SRWDC.xsl',
  76     },
  77     'NORMARC' => {
  78         'marcxml'      => 'identity.xsl',
  79         'marcxml-full' => 'identity.xsl',
  80         'mods'         => 'MARC21slim2MODS.xsl',
  81         'mods-full'    => 'MARC21slim2MODS.xsl',
  82         'mods3'        => 'MARC21slim2MODS3-1.xsl',
  83         'mods3-full'   => 'MARC21slim2MODS3-1.xsl',
  84         'oai_dc'       => 'MARC21slim2OAIDC.xsl',
  85         'rdfdc',       => 'MARC21slim2RDFDC.xsl',
  86         'rss2'         => 'MARC21slim2RSS2.xsl',
  87         'rss2-full'    => 'MARC21slim2RSS2.xsl',
  88         'srw_dc'       => 'MARC21slim2SRWDC.xsl',
  89     },
  90     'UNIMARC' => {
  91         'marcxml'      => 'identity.xsl',
  92         'marcxml-full' => 'identity.xsl',
  93         'oai_dc'       => 'UNIMARCslim2OAIDC.xsl',
  94         'rdfdc',       => 'UNIMARCslim2RDFDC.xsl',
  95         'srw_dc'       => 'UNIMARCslim2SRWDC.xsl',
  96     },
  97 };
  98
  99 =head2 $format_info
 100
 101 This hashref maps from unAPI output formats to the <format> elements
 102 used to describe them in an unAPI format request.
 103
 104 =cut
 105
 106 my $format_info = {
 107     'marcxml' => q(<format name="marcxml" type="application/xml" namespace_uri="http://www.loc.gov/MARC21/slim" docs="http://www.loc.gov/marcxml/" schema_location="http://www.loc.gov/standards/marcxml/schema/MARC21slim.xsd"/>),
 108     'marcxml-full' => q(<format name="marcxml-full" type="application/xml" namespace_uri="http://www.loc.gov/MARC21/slim" docs="http://www.loc.gov/marcxml/" schema_location="http://www.loc.gov/standards/marcxml/schema/MARC21slim.xsd"/>),
 109     'mods' => q(<format name="mods" type="application/xml" namespace_uri="http://www.loc.gov/mods/" docs="http://www.loc.gov/mods/" schema_location="http://www.loc.gov/standards/mods/mods.xsd"/>),
 110     'mods-full' => q(<format name="mods-full" type="application/xml" namespace_uri="http://www.loc.gov/mods/" docs="http://www.loc.gov/mods/" schema_location="http://www.loc.gov/standards/mods/mods.xsd"/>),
 111     'mods3' => q(<format name="mods3" type="application/xml" namespace_uri="http://www.loc.gov/mods/v3" docs="http://www.loc.gov/mods/" schema_location="http://www.loc.gov/standards/mods/v3/mods-3-1.xsd"/>),
 112     'mods3-full' => q(<format name="mods3-full" type="application/xml" namespace_uri="http://www.loc.gov/mods/v3" docs="http://www.loc.gov/mods/" schema_location="http://www.loc.gov/standards/mods/v3/mods-3-1.xsd"/>),
 113     'oai_dc' => q(<format name="oai_dc" type="application/xml" namespace_uri="http://www.openarchives.org/OAI/2.0/oai_dc/" schema_location="http://www.openarchives.org/OAI/2.0/oai_dc.xsd"/>),
 114     'rdfdc' => q(<format name="rdfdc" type="application/xml" namespace_uri="http://purl.org/dc/elements/1.1/" schema_location="http://purl.org/dc/elements/1.1/"/>),
 115     'rss2' => q(<format name="rss2" type="application/xml"/>),
 116     'rss2-full' => q(<format name="rss2-full" type="application/xml"/>),
 117     'srw_dc' => q(<format name="srw_dc" type="application/xml" namespace_uri="info:srw/schema/1/dc-schema" schema_location="http://www.loc.gov/z3950/agency/zing/srw/dc-schema.xsd"/>),
 118 };
 119
 120 my $id     = $cgi->param('id');
 121 my $format = $cgi->param('format');
 122
 123 if (not defined $format) {
 124     emit_formats($id, $format_to_stylesheet_map, $format_info, $cgi);
 125 } elsif ($id) {
 126
 127     # koha:biblionumber:0152018484
 128     if ($id =~ /koha:biblionumber:(\d+)/) {
 129         my $biblionumber = $1;
 130
 131         my $content;
 132         eval {
 133             my $marcxml = GetXmlBiblio($biblionumber);
 134             unless (defined $marcxml) {
 135                 # no bib, so 404
 136                 print $cgi->header( -status => '404 record not found');
 137                 exit 0;
 138             }
 139
 140             my $xslt_file = get_xslt_file( $format, $format_to_stylesheet_map, $format_info );
 141             unless( defined $xslt_file ) {
 142                 print $cgi->header( -status => '406 invalid format requested' );
 143                 exit 0;
 144             }
 145             my $xslt_engine = Koha::XSLT_Handler->new;
 146             $content = $xslt_engine->transform({
 147                 xml => $marcxml,
 148                 file => $xslt_file,
 149             });
 150         };
 151         if ($@) {
 152             print $cgi->header( -status => '500 internal error ' . $@ );
 153             exit 0;
 154         }
 155
 156         print $cgi->header( -type =>'application/xml', -charset => 'UTF-8' );
 157         print $content;
 158     } else {
 159         # ID is obviously wrong, so 404
 160         print $cgi->header( -status => '404 record not found');
 161         exit 0;
 162     }
 163 } else {
 164     # supplied a format but no id - caller is doing it wrong
 165     print $cgi->header( -status => '400 bad request - if you specify format, must specify id');
 166     exit 0;
 167 }
 168
 169 exit 0;
 170
 171 sub emit_formats {
 172     my ($id, $format_to_stylesheet_map, $format_info, $cgi) = @_;
 173
 174     if (defined $id) {
 175         print $cgi->header( -type =>'application/xml', -status => '300 multiple choices' );
 176     } else {
 177         print $cgi->header( -type =>'application/xml', -status => '200 Ok' );
 178     }
 179
 180     print "<?xml version='1.0' encoding='utf-8'  ?>\n";
 181     if (defined $id) {
 182         print qq(<formats id="$id">\n);
 183     } else {
 184         print "<formats>\n";
 185     }
 186
 187     my $marcflavour = uc(C4::Context->preference('marcflavour'));
 188     foreach my $format (sort keys %{ $format_to_stylesheet_map->{$marcflavour} }) {
 189         print $format_info->{$format}, "\n";
 190     }
 191     print "</formats>\n";
 192     return;
 193 }
 194
 195
 196 sub get_xslt_file {
 197     my ($format, $format_to_stylesheet_map, $format_info) = @_;
 198     $format = lc $format;
 199
 200     my $marcflavour = uc(C4::Context->preference('marcflavour'));
 201     return unless $format_to_stylesheet_map->{$marcflavour}->{$format};
 202
 203     my $xslt_file = C4::Context->config('intrahtdocs') .
 204                     "/prog/en/xslt/" .
 205                     $format_to_stylesheet_map->{$marcflavour}->{$format};
 206
 207     return $xslt_file;
 208 }
 209
 210 =head1 AUTHOR
 211
 212 Koha Development Team <http://koha-community.org/>
 213
 214 Originally written by Joshua Ferraro <jmf@liblime.com>
 215
 216 Improved by Galen Charlton <galen.charlton@liblime.com>
 217
 218 =cut