Koha/Object.pm

   1 package Koha::Object;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright 2016 Koha Development Team
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 3 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21 use Modern::Perl;
  22
  23 use Carp;
  24 use Mojo::JSON;
  25 use Scalar::Util qw( blessed looks_like_number );
  26 use Try::Tiny;
  27
  28 use Koha::Database;
  29 use Koha::Exceptions::Object;
  30 use Koha::DateUtils;
  31
  32 =head1 NAME
  33
  34 Koha::Object - Koha Object base class
  35
  36 =head1 SYNOPSIS
  37
  38     use Koha::Object;
  39     my $object = Koha::Object->new({ property1 => $property1, property2 => $property2, etc... } );
  40
  41 =head1 DESCRIPTION
  42
  43 This class must always be subclassed.
  44
  45 =head1 API
  46
  47 =head2 Class Methods
  48
  49 =cut
  50
  51 =head3 Koha::Object->new();
  52
  53 my $object = Koha::Object->new();
  54 my $object = Koha::Object->new($attributes);
  55
  56 Note that this cannot be used to retrieve record from the DB.
  57
  58 =cut
  59
  60 sub new {
  61     my ( $class, $attributes ) = @_;
  62     my $self = {};
  63
  64     if ($attributes) {
  65         my $schema = Koha::Database->new->schema;
  66
  67         # Remove the arguments which exist, are not defined but NOT NULL to use the default value
  68         my $columns_info = $schema->resultset( $class->_type )->result_source->columns_info;
  69         for my $column_name ( keys %$attributes ) {
  70             my $c_info = $columns_info->{$column_name};
  71             next if $c_info->{is_nullable};
  72             next if not exists $attributes->{$column_name} or defined $attributes->{$column_name};
  73             delete $attributes->{$column_name};
  74         }
  75
  76         $self->{_result} =
  77           $schema->resultset( $class->_type() )->new($attributes);
  78     }
  79
  80     croak("No _type found! Koha::Object must be subclassed!")
  81       unless $class->_type();
  82
  83     bless( $self, $class );
  84
  85 }
  86
  87 =head3 Koha::Object->_new_from_dbic();
  88
  89 my $object = Koha::Object->_new_from_dbic($dbic_row);
  90
  91 =cut
  92
  93 sub _new_from_dbic {
  94     my ( $class, $dbic_row ) = @_;
  95     my $self = {};
  96
  97     # DBIC result row
  98     $self->{_result} = $dbic_row;
  99
 100     croak("No _type found! Koha::Object must be subclassed!")
 101       unless $class->_type();
 102
 103     croak( "DBIC result _type " . ref( $self->{_result} ) . " isn't of the _type " . $class->_type() )
 104       unless ref( $self->{_result} ) eq "Koha::Schema::Result::" . $class->_type();
 105
 106     bless( $self, $class );
 107
 108 }
 109
 110 =head3 $object->store();
 111
 112 Saves the object in storage.
 113 If the object is new, it will be created.
 114 If the object previously existed, it will be updated.
 115
 116 Returns:
 117     $self  if the store was a success
 118     undef  if the store failed
 119
 120 =cut
 121
 122 sub store {
 123     my ($self) = @_;
 124
 125     my $columns_info = $self->_result->result_source->columns_info;
 126
 127     # Handle not null and default values for integers and dates
 128     foreach my $col ( keys %{$columns_info} ) {
 129         # Integers
 130         if ( _numeric_column_type( $columns_info->{$col}->{data_type} ) ) {
 131             # Has been passed but not a number, usually an empty string
 132             if ( defined $self->$col and not looks_like_number( $self->$col ) ) {
 133                 if ( $columns_info->{$col}->{is_nullable} ) {
 134                     # If nullable, default to null
 135                     $self->$col(undef);
 136                 } else {
 137                     # If cannot be null, get the default value
 138                     # What if cannot be null and does not have a default value? Possible?
 139                     $self->$col($columns_info->{$col}->{default_value});
 140                 }
 141             }
 142         }
 143         elsif ( _date_or_datetime_column_type( $columns_info->{$col}->{data_type} ) ) {
 144             # Set to null if an empty string (or == 0 but should not happen)
 145             if ( defined $self->$col and not $self->$col ) {
 146                 if ( $columns_info->{$col}->{is_nullable} ) {
 147                     $self->$col(undef);
 148                 } else {
 149                     $self->$col($columns_info->{$col}->{default_value});
 150                 }
 151             }
 152         }
 153     }
 154
 155     try {
 156         return $self->_result()->update_or_insert() ? $self : undef;
 157     }
 158     catch {
 159         # Catch problems and raise relevant exceptions
 160         if (ref($_) eq 'DBIx::Class::Exception') {
 161             if ( $_->{msg} =~ /Cannot add or update a child row: a foreign key constraint fails/ ) {
 162                 # FK constraints
 163                 # FIXME: MySQL error, if we support more DB engines we should implement this for each
 164                 if ( $_->{msg} =~ /FOREIGN KEY \(`(?<column>.*?)`\)/ ) {
 165                     Koha::Exceptions::Object::FKConstraint->throw(
 166                         error     => 'Broken FK constraint',
 167                         broken_fk => $+{column}
 168                     );
 169                 }
 170             }
 171             elsif( $_->{msg} =~ /Duplicate entry '(.*?)' for key '(?<key>.*?)'/ ) {
 172                 Koha::Exceptions::Object::DuplicateID->throw(
 173                     error => 'Duplicate ID',
 174                     duplicate_id => $+{key}
 175                 );
 176             }
 177             elsif( $_->{msg} =~ /Incorrect (?<type>\w+) value: '(?<value>.*)' for column \W?(?<property>\S+)/ ) { # The optional \W in the regex might be a quote or backtick
 178                 my $type = $+{type};
 179                 my $value = $+{value};
 180                 my $property = $+{property};
 181                 $property =~ s/['`]//g;
 182                 Koha::Exceptions::Object::BadValue->throw(
 183                     type     => $type,
 184                     value    => $value,
 185                     property => $property =~ /(\w+\.\w+)$/ ? $1 : $property, # results in table.column without quotes or backtics
 186                 );
 187             }
 188         }
 189         # Catch-all for foreign key breakages. It will help find other use cases
 190         $_->rethrow();
 191     }
 192 }
 193
 194 =head3 $object->update();
 195
 196 A shortcut for set + store in one call.
 197
 198 =cut
 199
 200 sub update {
 201     my ($self, $values) = @_;
 202     return $self->set($values)->store();
 203 }
 204
 205 =head3 $object->delete();
 206
 207 Removes the object from storage.
 208
 209 Returns:
 210     1  if the deletion was a success
 211     0  if the deletion failed
 212     -1 if the object was never in storage
 213
 214 =cut
 215
 216 sub delete {
 217     my ($self) = @_;
 218
 219     my $deleted = $self->_result()->delete;
 220     if ( ref $deleted ) {
 221         my $object_class  = Koha::Object::_get_object_class( $self->_result->result_class );
 222         $deleted = $object_class->_new_from_dbic($deleted);
 223     }
 224     return $deleted;
 225 }
 226
 227 =head3 $object->set( $properties_hashref )
 228
 229 $object->set(
 230     {
 231         property1 => $property1,
 232         property2 => $property2,
 233         property3 => $propery3,
 234     }
 235 );
 236
 237 Enables multiple properties to be set at once
 238
 239 Returns:
 240     1      if all properties were set.
 241     0      if one or more properties do not exist.
 242     undef  if all properties exist but a different error
 243            prevents one or more properties from being set.
 244
 245 If one or more of the properties do not exist,
 246 no properties will be set.
 247
 248 =cut
 249
 250 sub set {
 251     my ( $self, $properties ) = @_;
 252
 253     my @columns = @{$self->_columns()};
 254
 255     foreach my $p ( keys %$properties ) {
 256         unless ( grep {/^$p$/} @columns ) {
 257             Koha::Exceptions::Object::PropertyNotFound->throw( "No property $p for " . ref($self) );
 258         }
 259     }
 260
 261     return $self->_result()->set_columns($properties) ? $self : undef;
 262 }
 263
 264 =head3 $object->unblessed();
 265
 266 Returns an unblessed representation of object.
 267
 268 =cut
 269
 270 sub unblessed {
 271     my ($self) = @_;
 272
 273     return { $self->_result->get_columns };
 274 }
 275
 276 =head3 $object->get_from_storage;
 277
 278 =cut
 279
 280 sub get_from_storage {
 281     my ( $self, $attrs ) = @_;
 282     my $stored_object = $self->_result->get_from_storage($attrs);
 283     my $object_class  = Koha::Object::_get_object_class( $self->_result->result_class );
 284     return $object_class->_new_from_dbic($stored_object);
 285 }
 286
 287 =head3 $object->TO_JSON
 288
 289 Returns an unblessed representation of the object, suitable for JSON output.
 290
 291 =cut
 292
 293 sub TO_JSON {
 294
 295     my ($self) = @_;
 296
 297     my $unblessed    = $self->unblessed;
 298     my $columns_info = Koha::Database->new->schema->resultset( $self->_type )
 299         ->result_source->{_columns};
 300
 301     foreach my $col ( keys %{$columns_info} ) {
 302
 303         if ( $columns_info->{$col}->{is_boolean} )
 304         {    # Handle booleans gracefully
 305             $unblessed->{$col}
 306                 = ( $unblessed->{$col} )
 307                 ? Mojo::JSON->true
 308                 : Mojo::JSON->false;
 309         }
 310         elsif ( _numeric_column_type( $columns_info->{$col}->{data_type} )
 311             and looks_like_number( $unblessed->{$col} )
 312         ) {
 313
 314             # TODO: Remove once the solution for
 315             # https://rt.cpan.org/Ticket/Display.html?id=119904
 316             # is ported to whatever distro we support by that time
 317             $unblessed->{$col} += 0;
 318         }
 319         elsif ( _datetime_column_type( $columns_info->{$col}->{data_type} ) ) {
 320             eval {
 321                 return unless $unblessed->{$col};
 322                 $unblessed->{$col} = output_pref({
 323                     dateformat => 'rfc3339',
 324                     dt         => dt_from_string($unblessed->{$col}, 'sql'),
 325                 });
 326             };
 327         }
 328     }
 329     return $unblessed;
 330 }
 331
 332 sub _date_or_datetime_column_type {
 333     my ($column_type) = @_;
 334
 335     my @dt_types = (
 336         'timestamp',
 337         'date',
 338         'datetime'
 339     );
 340
 341     return ( grep { $column_type eq $_ } @dt_types) ? 1 : 0;
 342 }
 343 sub _datetime_column_type {
 344     my ($column_type) = @_;
 345
 346     my @dt_types = (
 347         'timestamp',
 348         'datetime'
 349     );
 350
 351     return ( grep { $column_type eq $_ } @dt_types) ? 1 : 0;
 352 }
 353
 354 sub _numeric_column_type {
 355     # TODO: Remove once the solution for
 356     # https://rt.cpan.org/Ticket/Display.html?id=119904
 357     # is ported to whatever distro we support by that time
 358     my ($column_type) = @_;
 359
 360     my @numeric_types = (
 361         'bigint',
 362         'integer',
 363         'int',
 364         'mediumint',
 365         'smallint',
 366         'tinyint',
 367         'decimal',
 368         'double precision',
 369         'float'
 370     );
 371
 372     return ( grep { $column_type eq $_ } @numeric_types) ? 1 : 0;
 373 }
 374
 375 =head3 to_api
 376
 377     my $object_for_api = $object->to_api(
 378         {
 379           [ embed => {
 380                 items => {
 381                     children => {
 382                         holds => {,
 383                             children => {
 384                               ...
 385                             }
 386                         }
 387                     }
 388                 },
 389                 library => {
 390                     ...
 391                 }
 392             },
 393             ...
 394          ]
 395         }
 396     );
 397
 398 Returns a representation of the object, suitable for API output.
 399
 400 =cut
 401
 402 sub to_api {
 403     my ( $self, $params ) = @_;
 404     my $json_object = $self->TO_JSON;
 405
 406     my $to_api_mapping = $self->to_api_mapping;
 407
 408     # Rename attributes if there's a mapping
 409     if ( $self->can('to_api_mapping') ) {
 410         foreach my $column ( keys %{ $self->to_api_mapping } ) {
 411             my $mapped_column = $self->to_api_mapping->{$column};
 412             if ( exists $json_object->{$column}
 413                 && defined $mapped_column )
 414             {
 415                 # key != undef
 416                 $json_object->{$mapped_column} = delete $json_object->{$column};
 417             }
 418             elsif ( exists $json_object->{$column}
 419                 && !defined $mapped_column )
 420             {
 421                 # key == undef
 422                 delete $json_object->{$column};
 423             }
 424         }
 425     }
 426
 427     my $embeds = $params->{embed};
 428
 429     if ($embeds) {
 430         foreach my $embed ( keys %{$embeds} ) {
 431             my $curr = $embed;
 432             my $next = $embeds->{$curr}->{children};
 433
 434             my $children = $self->$curr;
 435
 436             if ( defined $children and ref($children) eq 'ARRAY' ) {
 437                 my @list = map {
 438                     $self->_handle_to_api_child(
 439                         { child => $_, next => $next, curr => $curr } )
 440                 } @{$children};
 441                 $json_object->{$curr} = \@list;
 442             }
 443             else {
 444                 $json_object->{$curr} = $self->_handle_to_api_child(
 445                     { child => $children, next => $next, curr => $curr } );
 446             }
 447         }
 448     }
 449
 450
 451
 452     return $json_object;
 453 }
 454
 455 =head3 to_api_mapping
 456
 457     my $mapping = $object->to_api_mapping;
 458
 459 Generic method that returns the attribute name mappings required to
 460 render the object on the API.
 461
 462 Note: this only returns an empty I<hashref>. Each class should have its
 463 own mapping returned.
 464
 465 =cut
 466
 467 sub to_api_mapping {
 468     return {};
 469 }
 470
 471 =head3 from_api_mapping
 472
 473     my $mapping = $object->from_api_mapping;
 474
 475 Generic method that returns the attribute name mappings so the data that
 476 comes from the API is correctly renamed to match what is required for the DB.
 477
 478 =cut
 479
 480 sub from_api_mapping {
 481     my ( $self ) = @_;
 482
 483     my $to_api_mapping = $self->to_api_mapping;
 484
 485     unless ( $self->{_from_api_mapping} ) {
 486         while (my ($key, $value) = each %{ $to_api_mapping } ) {
 487             $self->{_from_api_mapping}->{$value} = $key
 488                 if defined $value;
 489         }
 490     }
 491
 492     return $self->{_from_api_mapping};
 493 }
 494
 495 =head3 new_from_api
 496
 497     my $object = Koha::Object->new_from_api;
 498     my $object = Koha::Object->new_from_api( $attrs );
 499
 500 Creates a new object, mapping the API attribute names to the ones on the DB schema.
 501
 502 =cut
 503
 504 sub new_from_api {
 505     my ( $class, $params ) = @_;
 506
 507     my $self = $class->new;
 508     return $self->set_from_api( $params );
 509 }
 510
 511 =head3 set_from_api
 512
 513     my $object = Koha::Object->new(...);
 514     $object->set_from_api( $attrs )
 515
 516 Sets the object's attributes mapping API attribute names to the ones on the DB schema.
 517
 518 =cut
 519
 520 sub set_from_api {
 521     my ( $self, $from_api_params ) = @_;
 522
 523     return $self->set( $self->attributes_from_api( $from_api_params ) );
 524 }
 525
 526 =head3 attributes_from_api
 527
 528     my $attributes = attributes_from_api( $params );
 529
 530 Returns the passed params, converted from API naming into the model.
 531
 532 =cut
 533
 534 sub attributes_from_api {
 535     my ( $self, $from_api_params ) = @_;
 536
 537     my $from_api_mapping = $self->from_api_mapping;
 538
 539     my $params;
 540     my $columns_info = $self->_result->result_source->columns_info;
 541
 542     while (my ($key, $value) = each %{ $from_api_params } ) {
 543         my $koha_field_name =
 544           exists $from_api_mapping->{$key}
 545           ? $from_api_mapping->{$key}
 546           : $key;
 547
 548         if ( $columns_info->{$koha_field_name}->{is_boolean} ) {
 549             # TODO: Remove when D8 is formally deprecated
 550             # Handle booleans gracefully
 551             $value = ( $value ) ? 1 : 0;
 552         }
 553         elsif ( _date_or_datetime_column_type( $columns_info->{$koha_field_name}->{data_type} ) ) {
 554             try {
 555                 $value = dt_from_string($value, 'rfc3339');
 556             }
 557             catch {
 558                 Koha::Exceptions::BadParameter->throw( parameter => $key );
 559             };
 560         }
 561
 562         $params->{$koha_field_name} = $value;
 563     }
 564
 565     return $params;
 566 }
 567
 568 =head3 $object->unblessed_all_relateds
 569
 570 my $everything_into_one_hashref = $object->unblessed_all_relateds
 571
 572 The unblessed method only retrieves column' values for the column of the object.
 573 In a *few* cases we want to retrieve the information of all the prefetched data.
 574
 575 =cut
 576
 577 sub unblessed_all_relateds {
 578     my ($self) = @_;
 579
 580     my %data;
 581     my $related_resultsets = $self->_result->{related_resultsets} || {};
 582     my $rs = $self->_result;
 583     while ( $related_resultsets and %$related_resultsets ) {
 584         my @relations = keys %{ $related_resultsets };
 585         if ( @relations ) {
 586             my $relation = $relations[0];
 587             $rs = $rs->related_resultset($relation)->get_cache;
 588             $rs = $rs->[0]; # Does it makes sense to have several values here?
 589             my $object_class = Koha::Object::_get_object_class( $rs->result_class );
 590             my $koha_object = $object_class->_new_from_dbic( $rs );
 591             $related_resultsets = $rs->{related_resultsets};
 592             %data = ( %data, %{ $koha_object->unblessed } );
 593         }
 594     }
 595     %data = ( %data, %{ $self->unblessed } );
 596     return \%data;
 597 }
 598
 599 =head3 $object->_result();
 600
 601 Returns the internal DBIC Row object
 602
 603 =cut
 604
 605 sub _result {
 606     my ($self) = @_;
 607
 608     # If we don't have a dbic row at this point, we need to create an empty one
 609     $self->{_result} ||=
 610       Koha::Database->new()->schema()->resultset( $self->_type() )->new({});
 611
 612     return $self->{_result};
 613 }
 614
 615 =head3 $object->_columns();
 616
 617 Returns an arrayref of the table columns
 618
 619 =cut
 620
 621 sub _columns {
 622     my ($self) = @_;
 623
 624     # If we don't have a dbic row at this point, we need to create an empty one
 625     $self->{_columns} ||= [ $self->_result()->result_source()->columns() ];
 626
 627     return $self->{_columns};
 628 }
 629
 630 sub _get_object_class {
 631     my ( $type ) = @_;
 632     return unless $type;
 633
 634     if( $type->can('koha_object_class') ) {
 635         return $type->koha_object_class;
 636     }
 637     $type =~ s|Schema::Result::||;
 638     return ${type};
 639 }
 640
 641 =head3 AUTOLOAD
 642
 643 The autoload method is used only to get and set values for an objects properties.
 644
 645 =cut
 646
 647 sub AUTOLOAD {
 648     my $self = shift;
 649
 650     my $method = our $AUTOLOAD;
 651     $method =~ s/.*://;
 652
 653     my @columns = @{$self->_columns()};
 654     # Using direct setter/getter like $item->barcode() or $item->barcode($barcode);
 655     if ( grep {/^$method$/} @columns ) {
 656         if ( @_ ) {
 657             $self->_result()->set_column( $method, @_ );
 658             return $self;
 659         } else {
 660             my $value = $self->_result()->get_column( $method );
 661             return $value;
 662         }
 663     }
 664
 665     my @known_methods = qw( is_changed id in_storage get_column discard_changes make_column_dirty );
 666
 667     Koha::Exceptions::Object::MethodNotCoveredByTests->throw(
 668         error      => sprintf("The method %s->%s is not covered by tests!", ref($self), $method),
 669         show_trace => 1
 670     ) unless grep { /^$method$/ } @known_methods;
 671
 672
 673     my $r = eval { $self->_result->$method(@_) };
 674     if ( $@ ) {
 675         Koha::Exceptions::Object->throw( ref($self) . "::$method generated this error: " . $@ );
 676     }
 677     return $r;
 678 }
 679
 680 =head3 _type
 681
 682 This method must be defined in the child class. The value is the name of the DBIC resultset.
 683 For example, for borrowers, the _type method will return "Borrower".
 684
 685 =cut
 686
 687 sub _type { }
 688
 689 =head3 _handle_to_api_child
 690
 691 =cut
 692
 693 sub _handle_to_api_child {
 694     my ($self, $args ) = @_;
 695
 696     my $child = $args->{child};
 697     my $next  = $args->{next};
 698     my $curr  = $args->{curr};
 699
 700     my $res;
 701
 702     if ( defined $child ) {
 703
 704         Koha::Exceptions::Exception->throw( "Asked to embed $curr but its return value doesn't implement to_api" )
 705             if defined $next and blessed $child and !$child->can('to_api');
 706
 707         if ( blessed $child ) {
 708             $res = $child->to_api({ embed => $next });
 709         }
 710         else {
 711             $res = $child;
 712         }
 713     }
 714
 715     return $res;
 716 }
 717
 718 sub DESTROY { }
 719
 720 =head1 AUTHOR
 721
 722 Kyle M Hall <kyle@bywatersolutions.com>
 723
 724 Jonathan Druart <jonathan.druart@bugs.koha-community.org>
 725
 726 =cut
 727
 728 1;