circ/circulation.pl

   1 #!/usr/bin/perl
   2
   3 # script to execute issuing of books
   4
   5 # Copyright 2000-2002 Katipo Communications
   6 # copyright 2010 BibLibre
   7 # Copyright 2011 PTFS-Europe Ltd.
   8 # Copyright 2012 software.coop and MJ Ray
   9 #
  10 # This file is part of Koha.
  11 #
  12 # Koha is free software; you can redistribute it and/or modify it under the
  13 # terms of the GNU General Public License as published by the Free Software
  14 # Foundation; either version 2 of the License, or (at your option) any later
  15 # version.
  16 #
  17 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  18 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  19 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU General Public License along
  22 # with Koha; if not, write to the Free Software Foundation, Inc.,
  23 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  24
  25 use strict;
  26 use warnings;
  27 use CGI;
  28 use C4::Output;
  29 use C4::Print;
  30 use C4::Auth qw/:DEFAULT get_session/;
  31 use C4::Dates qw/format_date/;
  32 use C4::Branch; # GetBranches
  33 use C4::Koha;   # GetPrinter
  34 use C4::Circulation;
  35 use C4::Members;
  36 use C4::Biblio;
  37 use C4::Search;
  38 use MARC::Record;
  39 use C4::Reserves;
  40 use C4::Context;
  41 use CGI::Session;
  42 use C4::Members::Attributes qw(GetBorrowerAttributes);
  43 use Koha::Borrower::Debarments qw(GetDebarments);
  44 use Koha::DateUtils;
  45
  46 use Date::Calc qw(
  47   Today
  48   Add_Delta_YM
  49   Add_Delta_Days
  50   Date_to_Days
  51 );
  52 use List::MoreUtils qw/uniq/;
  53
  54
  55 #
  56 # PARAMETERS READING
  57 #
  58 my $query = new CGI;
  59
  60 my $sessionID = $query->cookie("CGISESSID") ;
  61 my $session = get_session($sessionID);
  62
  63 # branch and printer are now defined by the userenv
  64 # but first we have to check if someone has tried to change them
  65
  66 my $branch = $query->param('branch');
  67 if ($branch){
  68     # update our session so the userenv is updated
  69     $session->param('branch', $branch);
  70     $session->param('branchname', GetBranchName($branch));
  71 }
  72
  73 my $printer = $query->param('printer');
  74 if ($printer){
  75     # update our session so the userenv is updated
  76     $session->param('branchprinter', $printer);
  77 }
  78
  79 if (!C4::Context->userenv && !$branch){
  80     if ($session->param('branch') eq 'NO_LIBRARY_SET'){
  81         # no branch set we can't issue
  82         print $query->redirect("/cgi-bin/koha/circ/selectbranchprinter.pl");
  83         exit;
  84     }
  85 }
  86
  87 my ( $template, $loggedinuser, $cookie ) = get_template_and_user (
  88     {
  89         template_name   => 'circ/circulation.tmpl',
  90         query           => $query,
  91         type            => "intranet",
  92         authnotrequired => 0,
  93         flagsrequired   => { circulate => 'circulate_remaining_permissions' },
  94     }
  95 );
  96
  97 my $branches = GetBranches();
  98
  99 my @failedrenews = $query->param('failedrenew');    # expected to be itemnumbers
 100 our %renew_failed = ();
 101 for (@failedrenews) { $renew_failed{$_} = 1; }
 102
 103 my @failedreturns = $query->param('failedreturn');
 104 our %return_failed = ();
 105 for (@failedreturns) { $return_failed{$_} = 1; }
 106
 107 my $findborrower = $query->param('findborrower') || q{};
 108 $findborrower =~ s|,| |g;
 109 my $borrowernumber = $query->param('borrowernumber');
 110
 111 $branch  = C4::Context->userenv->{'branch'};
 112 $printer = C4::Context->userenv->{'branchprinter'};
 113
 114
 115 # If AutoLocation is not activated, we show the Circulation Parameters to chage settings of librarian
 116 if (C4::Context->preference("AutoLocation") != 1) {
 117     $template->param(ManualLocation => 1);
 118 }
 119
 120 if (C4::Context->preference("DisplayClearScreenButton")) {
 121     $template->param(DisplayClearScreenButton => 1);
 122 }
 123
 124 if (C4::Context->preference("UseTablesortForCirc")) {
 125     $template->param(UseTablesortForCirc => 1);
 126 }
 127
 128 my $barcode        = $query->param('barcode') || q{};
 129 $barcode =~  s/^\s*|\s*$//g; # remove leading/trailing whitespace
 130
 131 $barcode = barcodedecode($barcode) if( $barcode && C4::Context->preference('itemBarcodeInputFilter'));
 132 my $stickyduedate  = $query->param('stickyduedate') || $session->param('stickyduedate');
 133 my $duedatespec    = $query->param('duedatespec')   || $session->param('stickyduedate');
 134 my $issueconfirmed = $query->param('issueconfirmed');
 135 my $cancelreserve  = $query->param('cancelreserve');
 136 my $print          = $query->param('print') || q{};
 137 my $debt_confirmed = $query->param('debt_confirmed') || 0; # Don't show the debt error dialog twice
 138 my $charges        = $query->param('charges') || q{};
 139
 140 # Check if stickyduedate is turned off
 141 if ( $barcode ) {
 142     # was stickyduedate loaded from session?
 143     if ( $stickyduedate && ! $query->param("stickyduedate") ) {
 144         $session->clear( 'stickyduedate' );
 145         $stickyduedate  = $query->param('stickyduedate');
 146         $duedatespec    = $query->param('duedatespec');
 147     }
 148 }
 149
 150 my ($datedue,$invalidduedate);
 151
 152 my $duedatespec_allow = C4::Context->preference('SpecifyDueDate');
 153 if($duedatespec_allow){
 154     if ($duedatespec) {
 155         if ($duedatespec =~ C4::Dates->regexp('syspref')) {
 156                 $datedue = dt_from_string($duedatespec);
 157         } else {
 158             $invalidduedate = 1;
 159             $template->param(IMPOSSIBLE=>1, INVALID_DATE=>$duedatespec);
 160         }
 161     }
 162 }
 163
 164 our $todaysdate = C4::Dates->new->output('iso');
 165
 166 # check and see if we should print
 167 if ( $barcode eq '' && $print eq 'maybe' ) {
 168     $print = 'yes';
 169 }
 170
 171 my $inprocess = ($barcode eq '') ? '' : $query->param('inprocess');
 172 if ( $barcode eq '' && $charges eq 'yes' ) {
 173     $template->param(
 174         PAYCHARGES     => 'yes',
 175         borrowernumber => $borrowernumber
 176     );
 177 }
 178
 179 if ( $print eq 'yes' && $borrowernumber ne '' ) {
 180     if ( C4::Context->boolean_preference('printcirculationslips') ) {
 181         my $letter = IssueSlip($branch, $borrowernumber, "QUICK");
 182         NetworkPrint($letter->{content});
 183     }
 184     $query->param( 'borrowernumber', '' );
 185     $borrowernumber = '';
 186 }
 187
 188 #
 189 # STEP 2 : FIND BORROWER
 190 # if there is a list of find borrowers....
 191 #
 192 my $borrowerslist;
 193 my $message;
 194 if ($findborrower) {
 195     my $borrowers = Search($findborrower, 'cardnumber') || [];
 196     if (C4::Context->preference("AddPatronLists")) {
 197         $template->param(
 198             "AddPatronLists_".C4::Context->preference("AddPatronLists")=> "1",
 199         );
 200         if (C4::Context->preference("AddPatronLists")=~/code/){
 201             my $categories = GetBorrowercategoryList;
 202             $categories->[0]->{'first'} = 1;
 203             $template->param(categories=>$categories);
 204         }
 205     }
 206     if ( @$borrowers == 0 ) {
 207         $query->param( 'findborrower', '' );
 208         $message = "'$findborrower'";
 209     }
 210     elsif ( @$borrowers == 1 ) {
 211         $borrowernumber = $borrowers->[0]->{'borrowernumber'};
 212         $query->param( 'borrowernumber', $borrowernumber );
 213         $query->param( 'barcode',           '' );
 214     }
 215     else {
 216         $borrowerslist = $borrowers;
 217     }
 218 }
 219
 220 # get the borrower information.....
 221 my $borrower;
 222 if ($borrowernumber) {
 223     $borrower = GetMemberDetails( $borrowernumber, 0 );
 224     my ( $od, $issue, $fines ) = GetMemberIssuesAndFines( $borrowernumber );
 225
 226     # Warningdate is the date that the warning starts appearing
 227     my (  $today_year,   $today_month,   $today_day) = Today();
 228     my ($warning_year, $warning_month, $warning_day) = split /-/, $borrower->{'dateexpiry'};
 229     my (  $enrol_year,   $enrol_month,   $enrol_day) = split /-/, $borrower->{'dateenrolled'};
 230     # Renew day is calculated by adding the enrolment period to today
 231     my (  $renew_year,   $renew_month,   $renew_day);
 232     if ($enrol_year*$enrol_month*$enrol_day>0) {
 233         (  $renew_year,   $renew_month,   $renew_day) =
 234         Add_Delta_YM( $enrol_year, $enrol_month, $enrol_day,
 235             0 , $borrower->{'enrolmentperiod'});
 236     }
 237     # if the expiry date is before today ie they have expired
 238     if ( !$borrower->{'dateexpiry'} || $warning_year*$warning_month*$warning_day==0
 239         || Date_to_Days($today_year,     $today_month, $today_day  )
 240          > Date_to_Days($warning_year, $warning_month, $warning_day) )
 241     {
 242         #borrowercard expired, no issues
 243         $template->param(
 244             flagged  => "1",
 245             noissues => "1",
 246             expired => "1",
 247             renewaldate => format_date("$renew_year-$renew_month-$renew_day")
 248         );
 249     }
 250     # check for NotifyBorrowerDeparture
 251     elsif ( C4::Context->preference('NotifyBorrowerDeparture') &&
 252             Date_to_Days(Add_Delta_Days($warning_year,$warning_month,$warning_day,- C4::Context->preference('NotifyBorrowerDeparture'))) <
 253             Date_to_Days( $today_year, $today_month, $today_day ) )
 254     {
 255         # borrower card soon to expire warn librarian
 256         $template->param("warndeparture" => format_date($borrower->{dateexpiry}),
 257         flagged       => "1",);
 258         if (C4::Context->preference('ReturnBeforeExpiry')){
 259             $template->param("returnbeforeexpiry" => 1);
 260         }
 261     }
 262     $template->param(
 263         overduecount => $od,
 264         issuecount   => $issue,
 265         finetotal    => $fines
 266     );
 267
 268     $template->param(
 269         'userdebarred'    => $borrower->{debarred},
 270         'debarredcomment' => $borrower->{debarredcomment},
 271     );
 272     if ( $borrower->{debarred} ne "9999-12-31" ) {
 273         $template->param( 'userdebarreddate' => C4::Dates::format_date( $borrower->{debarred} ) );
 274     }
 275
 276 }
 277
 278 #
 279 # STEP 3 : ISSUING
 280 #
 281 #
 282 if ($barcode) {
 283     # always check for blockers on issuing
 284     my ( $error, $question, $alerts ) =
 285     CanBookBeIssued( $borrower, $barcode, $datedue , $inprocess );
 286     my $blocker = $invalidduedate ? 1 : 0;
 287
 288     $template->param( alert => $alerts );
 289
 290     #  Get the item title for more information
 291     my $getmessageiteminfo = GetBiblioFromItemNumber(undef,$barcode);
 292     $template->param(
 293         authvalcode_notforloan => C4::Koha::GetAuthValCode('items.notforloan', $getmessageiteminfo->{'frameworkcode'}),
 294     );
 295     # Fix for bug 7494: optional checkout-time fallback search for a book
 296
 297     if ( $error->{'UNKNOWN_BARCODE'}
 298         && C4::Context->preference("itemBarcodeFallbackSearch") )
 299     {
 300      $template->param( FALLBACK => 1 );
 301
 302         my $query = "kw=" . $barcode;
 303         my ( $searcherror, $results, $total_hits ) = SimpleSearch($query);
 304
 305         # if multiple hits, offer options to librarian
 306         if ( $total_hits > 0 ) {
 307             my @options = ();
 308             foreach my $hit ( @{$results} ) {
 309                 my $chosen =
 310                   TransformMarcToKoha( C4::Context->dbh,
 311                     C4::Search::new_record_from_zebra('biblioserver',$hit) );
 312
 313                 # offer all barcodes individually
 314                 foreach my $barcode ( sort split(/\s*\|\s*/, $chosen->{barcode}) ) {
 315                     my %chosen_single = %{$chosen};
 316                     $chosen_single{barcode} = $barcode;
 317                     push( @options, \%chosen_single );
 318                 }
 319             }
 320             $template->param( options => \@options );
 321         }
 322     }
 323
 324     delete $question->{'DEBT'} if ($debt_confirmed);
 325     foreach my $impossible ( keys %$error ) {
 326         $template->param(
 327             $impossible => $$error{$impossible},
 328             IMPOSSIBLE  => 1
 329         );
 330         $blocker = 1;
 331     }
 332     if( !$blocker ){
 333         my $confirm_required = 0;
 334         unless($issueconfirmed){
 335             #  Get the item title for more information
 336             my $getmessageiteminfo  = GetBiblioFromItemNumber(undef,$barcode);
 337             $template->{VARS}->{'additional_materials'} = $getmessageiteminfo->{'materials'};
 338             $template->param( itemhomebranch => $getmessageiteminfo->{'homebranch'} );
 339
 340             # pass needsconfirmation to template if issuing is possible and user hasn't yet confirmed.
 341             foreach my $needsconfirmation ( keys %$question ) {
 342                 $template->param(
 343                     $needsconfirmation => $$question{$needsconfirmation},
 344                     getTitleMessageIteminfo => $getmessageiteminfo->{'title'},
 345                     getBarcodeMessageIteminfo => $getmessageiteminfo->{'barcode'},
 346                     NEEDSCONFIRMATION  => 1
 347                 );
 348                 $confirm_required = 1;
 349             }
 350         }
 351         unless($confirm_required) {
 352             AddIssue( $borrower, $barcode, $datedue, $cancelreserve );
 353             $inprocess = 1;
 354         }
 355     }
 356
 357     # FIXME If the issue is confirmed, we launch another time GetMemberIssuesAndFines, now display the issue count after issue
 358     my ( $od, $issue, $fines ) = GetMemberIssuesAndFines( $borrowernumber );
 359     $template->param( issuecount   => $issue );
 360 }
 361
 362 # reload the borrower info for the sake of reseting the flags.....
 363 if ($borrowernumber) {
 364     $borrower = GetMemberDetails( $borrowernumber, 0 );
 365 }
 366
 367 ##################################################################################
 368 # BUILD HTML
 369 # show all reserves of this borrower, and the position of the reservation ....
 370 if ($borrowernumber) {
 371
 372     # new op dev
 373     # now we show the status of the borrower's reservations
 374     my @borrowerreserv = GetReservesFromBorrowernumber($borrowernumber );
 375     my @reservloop;
 376     my @WaitingReserveLoop;
 377
 378     foreach my $num_res (@borrowerreserv) {
 379         my %getreserv;
 380         my %getWaitingReserveInfo;
 381         my $getiteminfo  = GetBiblioFromItemNumber( $num_res->{'itemnumber'} );
 382         my $itemtypeinfo = getitemtypeinfo( (C4::Context->preference('item-level_itypes')) ? $getiteminfo->{'itype'} : $getiteminfo->{'itemtype'} );
 383         my ( $transfertwhen, $transfertfrom, $transfertto ) =
 384           GetTransfers( $num_res->{'itemnumber'} );
 385
 386         $getreserv{waiting}       = 0;
 387         $getreserv{transfered}    = 0;
 388         $getreserv{nottransfered} = 0;
 389
 390         $getreserv{reservedate}    = format_date( $num_res->{'reservedate'} );
 391         $getreserv{reserve_id}  = $num_res->{'reserve_id'};
 392         $getreserv{title}          = $getiteminfo->{'title'};
 393         $getreserv{subtitle}       = GetRecordValue('subtitle', GetMarcBiblio($getiteminfo->{biblionumber}), GetFrameworkCode($getiteminfo->{biblionumber}));
 394         $getreserv{itemtype}       = $itemtypeinfo->{'description'};
 395         $getreserv{author}         = $getiteminfo->{'author'};
 396         $getreserv{barcodereserv}  = $getiteminfo->{'barcode'};
 397         $getreserv{itemcallnumber} = $getiteminfo->{'itemcallnumber'};
 398         $getreserv{biblionumber}   = $getiteminfo->{'biblionumber'};
 399         $getreserv{waitingat}      = GetBranchName( $num_res->{'branchcode'} );
 400         $getreserv{suspend}        = $num_res->{'suspend'};
 401         $getreserv{suspend_until}  = $num_res->{'suspend_until'};
 402         #         check if we have a waiting status for reservations
 403         if ( $num_res->{'found'} && $num_res->{'found'} eq 'W' ) {
 404             $getreserv{color}   = 'reserved';
 405             $getreserv{waiting} = 1;
 406 #     genarate information displaying only waiting reserves
 407         $getWaitingReserveInfo{title}        = $getiteminfo->{'title'};
 408         $getWaitingReserveInfo{biblionumber} = $getiteminfo->{'biblionumber'};
 409         $getWaitingReserveInfo{itemtype}     = $itemtypeinfo->{'description'};
 410         $getWaitingReserveInfo{author}       = $getiteminfo->{'author'};
 411         $getWaitingReserveInfo{itemcallnumber} = $getiteminfo->{'itemcallnumber'};
 412         $getWaitingReserveInfo{reservedate}  = format_date( $num_res->{'reservedate'} );
 413         $getWaitingReserveInfo{waitingat}    = GetBranchName( $num_res->{'branchcode'} );
 414         $getWaitingReserveInfo{waitinghere}  = 1 if $num_res->{'branchcode'} eq $branch;
 415         }
 416         #         check transfers with the itemnumber foud in th reservation loop
 417         if ($transfertwhen) {
 418             $getreserv{color}      = 'transfered';
 419             $getreserv{transfered} = 1;
 420             $getreserv{datesent}   = format_date($transfertwhen);
 421             $getreserv{frombranch} = GetBranchName($transfertfrom);
 422         } elsif ($getiteminfo->{'holdingbranch'} ne $num_res->{'branchcode'}) {
 423             $getreserv{nottransfered}   = 1;
 424             $getreserv{nottransferedby} = GetBranchName( $getiteminfo->{'holdingbranch'} );
 425         }
 426
 427 #         if we don't have a reserv on item, we put the biblio infos and the waiting position
 428         if ( $getiteminfo->{'title'} eq '' ) {
 429             my $getbibinfo = GetBiblioData( $num_res->{'biblionumber'} );
 430
 431             $getreserv{color}           = 'inwait';
 432             $getreserv{title}           = $getbibinfo->{'title'};
 433             $getreserv{subtitle}        = GetRecordValue('subtitle', GetMarcBiblio($num_res->{biblionumber}), GetFrameworkCode($num_res->{biblionumber}));
 434             $getreserv{nottransfered}   = 0;
 435             $getreserv{itemtype}        = $itemtypeinfo->{'description'};
 436             $getreserv{author}          = $getbibinfo->{'author'};
 437             $getreserv{biblionumber}    = $num_res->{'biblionumber'};
 438         }
 439         $getreserv{waitingposition} = $num_res->{'priority'};
 440         $getreserv{expirationdate} = $num_res->{'expirationdate'};
 441         push( @reservloop, \%getreserv );
 442
 443 #         if we have a reserve waiting, initiate waitingreserveloop
 444         if ($getreserv{waiting} == 1) {
 445         push (@WaitingReserveLoop, \%getWaitingReserveInfo)
 446         }
 447
 448     }
 449
 450     # return result to the template
 451     $template->param(
 452         countreserv => scalar @reservloop,
 453         reservloop  => \@reservloop ,
 454         WaitingReserveLoop  => \@WaitingReserveLoop,
 455     );
 456     $template->param( adultborrower => 1 ) if ( $borrower->{'category_type'} eq 'A' );
 457 }
 458
 459 # make the issued books table.
 460 my $todaysissues = '';
 461 my $previssues   = '';
 462 our @todaysissues   = ();
 463 our @previousissues = ();
 464 our @relissues      = ();
 465 our @relprevissues  = ();
 466 my $displayrelissues;
 467
 468 our $totalprice = 0;
 469
 470 sub build_issue_data {
 471     my $issueslist = shift;
 472     my $relatives = shift;
 473
 474     # split in 2 arrays for today & previous
 475     foreach my $it ( @$issueslist ) {
 476         my $itemtypeinfo = getitemtypeinfo( (C4::Context->preference('item-level_itypes')) ? $it->{'itype'} : $it->{'itemtype'} );
 477
 478         # set itemtype per item-level_itype syspref - FIXME this is an ugly hack
 479         $it->{'itemtype'} = ( C4::Context->preference( 'item-level_itypes' ) ) ? $it->{'itype'} : $it->{'itemtype'};
 480
 481         ($it->{'charge'}, $it->{'itemtype_charge'}) = GetIssuingCharges(
 482             $it->{'itemnumber'}, $it->{'borrowernumber'}
 483         );
 484         $it->{'charge'} = sprintf("%.2f", $it->{'charge'});
 485         my ($can_renew, $can_renew_error) = CanBookBeRenewed(
 486             $it->{'borrowernumber'},$it->{'itemnumber'}
 487         );
 488         $it->{"renew_error_${can_renew_error}"} = 1 if defined $can_renew_error;
 489         my $restype = C4::Reserves::GetReserveStatus( $it->{'itemnumber'} );
 490         $it->{'can_renew'} = $can_renew;
 491         $it->{'can_confirm'} = !$can_renew && !$restype;
 492         $it->{'renew_error'} = ( $restype eq "Waiting" or $restype eq "Reserved" ) ? 1 : 0;
 493         $it->{'checkoutdate'} = C4::Dates->new($it->{'issuedate'},'iso')->output('syspref');
 494         $it->{'issuingbranchname'} = GetBranchName($it->{'branchcode'});
 495
 496         $totalprice += $it->{'replacementprice'} || 0;
 497         $it->{'itemtype'} = $itemtypeinfo->{'description'};
 498         $it->{'itemtype_image'} = $itemtypeinfo->{'imageurl'};
 499         $it->{'dd_sort'} = $it->{'date_due'};
 500         $it->{'dd'} = output_pref($it->{'date_due'});
 501         $it->{'displaydate_sort'} = $it->{'issuedate'};
 502         $it->{'displaydate'} = output_pref($it->{'issuedate'});
 503         #$it->{'od'} = ( $it->{'date_due'} lt $todaysdate ) ? 1 : 0 ;
 504         $it->{'od'} = $it->{'overdue'};
 505         $it->{'subtitle'} = GetRecordValue('subtitle', GetMarcBiblio($it->{biblionumber}), GetFrameworkCode($it->{biblionumber}));
 506         $it->{'renew_failed'} = $renew_failed{$it->{'itemnumber'}};
 507         $it->{'return_failed'} = $return_failed{$it->{'barcode'}};
 508
 509         if ( ( $it->{'issuedate'} && $it->{'issuedate'} gt $todaysdate )
 510           || ( $it->{'lastreneweddate'} && $it->{'lastreneweddate'} gt $todaysdate ) ) {
 511             (!$relatives) ? push @todaysissues, $it : push @relissues, $it;
 512         } else {
 513             (!$relatives) ? push @previousissues, $it : push @relprevissues, $it;
 514         }
 515         ($it->{'renewcount'},$it->{'renewsallowed'},$it->{'renewsleft'}) = C4::Circulation::GetRenewCount($it->{'borrowernumber'},$it->{'itemnumber'}); #Add renewal count to item data display
 516     }
 517 }
 518
 519 if ($borrower) {
 520
 521     # Getting borrower relatives
 522     my @relborrowernumbers = GetMemberRelatives($borrower->{'borrowernumber'});
 523     #push @borrowernumbers, $borrower->{'borrowernumber'};
 524
 525     # get each issue of the borrower & separate them in todayissues & previous issues
 526     my $issueslist = GetPendingIssues($borrower->{'borrowernumber'});
 527     my $relissueslist = [];
 528     if ( @relborrowernumbers ) {
 529         $relissueslist = GetPendingIssues(@relborrowernumbers);
 530     }
 531
 532     build_issue_data($issueslist, 0);
 533     build_issue_data($relissueslist, 1);
 534
 535     $displayrelissues = scalar($relissueslist);
 536
 537     if ( C4::Context->preference( "todaysIssuesDefaultSortOrder" ) eq 'asc' ) {
 538         @todaysissues   = sort { $a->{'timestamp'} cmp $b->{'timestamp'} } @todaysissues;
 539     }
 540     else {
 541         @todaysissues   = sort { $b->{'timestamp'} cmp $a->{'timestamp'} } @todaysissues;
 542     }
 543
 544     if ( C4::Context->preference( "previousIssuesDefaultSortOrder" ) eq 'asc' ){
 545         @previousissues = sort { $a->{'date_due'} cmp $b->{'date_due'} } @previousissues;
 546     }
 547     else {
 548         @previousissues = sort { $b->{'date_due'} cmp $a->{'date_due'} } @previousissues;
 549     }
 550 }
 551
 552
 553 my @values;
 554 my %labels;
 555 my $CGIselectborrower;
 556 if ($borrowerslist) {
 557     foreach (
 558         sort {(lc $a->{'surname'} cmp lc $b->{'surname'} || lc $a->{'firstname'} cmp lc $b->{'firstname'})
 559         } @$borrowerslist
 560       )
 561     {
 562         push @values, $_->{'borrowernumber'};
 563         $labels{ $_->{'borrowernumber'} } =
 564 "$_->{'surname'}, $_->{'firstname'} ... ($_->{'cardnumber'} - $_->{'categorycode'} - $_->{'branchcode'}) ...  $_->{'address'} ";
 565     }
 566     $CGIselectborrower = CGI::scrolling_list(
 567         -name     => 'borrowernumber',
 568         -class    => 'focus',
 569         -id       => 'borrowernumber',
 570         -values   => \@values,
 571         -labels   => \%labels,
 572         -ondblclick => 'document.forms[\'mainform\'].submit()',
 573         -size     => 7,
 574         -tabindex => '',
 575         -multiple => 0
 576     );
 577 }
 578
 579 #title
 580 my $flags = $borrower->{'flags'};
 581 foreach my $flag ( sort keys %$flags ) {
 582     $template->param( flagged=> 1);
 583     $flags->{$flag}->{'message'} =~ s#\n#<br />#g;
 584     if ( $flags->{$flag}->{'noissues'} ) {
 585         $template->param(
 586             noissues => 'true',
 587         );
 588         if ( $flag eq 'GNA' ) {
 589             $template->param( gna => 'true' );
 590         }
 591         elsif ( $flag eq 'LOST' ) {
 592             $template->param( lost => 'true' );
 593         }
 594         elsif ( $flag eq 'DBARRED' ) {
 595             $template->param( dbarred => 'true' );
 596         }
 597         elsif ( $flag eq 'CHARGES' ) {
 598             $template->param(
 599                 charges    => 'true',
 600                 chargesmsg => $flags->{'CHARGES'}->{'message'},
 601                 chargesamount => $flags->{'CHARGES'}->{'amount'},
 602                 charges_is_blocker => 1
 603             );
 604         }
 605         elsif ( $flag eq 'CREDITS' ) {
 606             $template->param(
 607                 credits    => 'true',
 608                 creditsmsg => $flags->{'CREDITS'}->{'message'},
 609                 creditsamount => sprintf("%.02f", -($flags->{'CREDITS'}->{'amount'})), # from patron's pov
 610             );
 611         }
 612     }
 613     else {
 614         if ( $flag eq 'CHARGES' ) {
 615             $template->param(
 616                 charges    => 'true',
 617                 chargesmsg => $flags->{'CHARGES'}->{'message'},
 618                 chargesamount => $flags->{'CHARGES'}->{'amount'},
 619             );
 620         }
 621         elsif ( $flag eq 'CREDITS' ) {
 622             $template->param(
 623                 credits    => 'true',
 624                 creditsmsg => $flags->{'CREDITS'}->{'message'},
 625                 creditsamount => sprintf("%.02f", -($flags->{'CREDITS'}->{'amount'})), # from patron's pov
 626             );
 627         }
 628         elsif ( $flag eq 'ODUES' ) {
 629             $template->param(
 630                 odues    => 'true',
 631                 oduesmsg => $flags->{'ODUES'}->{'message'}
 632             );
 633
 634             my $items = $flags->{$flag}->{'itemlist'};
 635             if ( ! $query->param('module') || $query->param('module') ne 'returns' ) {
 636                 $template->param( nonreturns => 'true' );
 637             }
 638         }
 639         elsif ( $flag eq 'NOTES' ) {
 640             $template->param(
 641                 notes    => 'true',
 642                 notesmsg => $flags->{'NOTES'}->{'message'}
 643             );
 644         }
 645     }
 646 }
 647
 648 my $amountold = $borrower->{flags}->{'CHARGES'}->{'message'} || 0;
 649 $amountold =~ s/^.*\$//;    # remove upto the $, if any
 650
 651 my ( $total, $accts, $numaccts) = GetMemberAccountRecords( $borrowernumber );
 652
 653 if ( $borrower->{'category_type'} eq 'C') {
 654     my  ( $catcodes, $labels ) =  GetborCatFromCatType( 'A', 'WHERE category_type = ?' );
 655     my $cnt = scalar(@$catcodes);
 656     $template->param( 'CATCODE_MULTI' => 1) if $cnt > 1;
 657     $template->param( 'catcode' =>    $catcodes->[0])  if $cnt == 1;
 658 }
 659
 660 my $lib_messages_loop = GetMessages( $borrowernumber, 'L', $branch );
 661 if($lib_messages_loop){ $template->param(flagged => 1 ); }
 662
 663 my $bor_messages_loop = GetMessages( $borrowernumber, 'B', $branch );
 664 if($bor_messages_loop){ $template->param(flagged => 1 ); }
 665
 666 # Computes full borrower address
 667 my @fulladdress;
 668 push @fulladdress, $borrower->{'streetnumber'} if ( $borrower->{'streetnumber'} );
 669 push @fulladdress, C4::Koha::GetAuthorisedValueByCode( 'ROADTYPE', $borrower->{'streettype'} ) if ( $borrower->{'streettype'} );
 670 push @fulladdress, $borrower->{'address'} if ( $borrower->{'address'} );
 671
 672 my $fast_cataloging = 0;
 673 if (defined getframeworkinfo('FA')) {
 674     $fast_cataloging = 1
 675 }
 676
 677 if (C4::Context->preference('ExtendedPatronAttributes')) {
 678     my $attributes = GetBorrowerAttributes($borrowernumber);
 679     $template->param(
 680         ExtendedPatronAttributes => 1,
 681         extendedattributes => $attributes
 682     );
 683 }
 684
 685 $template->param(
 686     lib_messages_loop => $lib_messages_loop,
 687     bor_messages_loop => $bor_messages_loop,
 688     all_messages_del  => C4::Context->preference('AllowAllMessageDeletion'),
 689     findborrower      => $findborrower,
 690     borrower          => $borrower,
 691     borrowernumber    => $borrowernumber,
 692     branch            => $branch,
 693     branchname        => GetBranchName($borrower->{'branchcode'}),
 694     printer           => $printer,
 695     printername       => $printer,
 696     firstname         => $borrower->{'firstname'},
 697     surname           => $borrower->{'surname'},
 698     showname          => $borrower->{'showname'},
 699     category_type     => $borrower->{'category_type'},
 700     was_renewed       => $query->param('was_renewed') ? 1 : 0,
 701     expiry            => format_date($borrower->{'dateexpiry'}),
 702     categorycode      => $borrower->{'categorycode'},
 703     categoryname      => $borrower->{description},
 704     address           => join(' ', @fulladdress),
 705     address2          => $borrower->{'address2'},
 706     email             => $borrower->{'email'},
 707     emailpro          => $borrower->{'emailpro'},
 708     borrowernotes     => $borrower->{'borrowernotes'},
 709     city              => $borrower->{'city'},
 710     state              => $borrower->{'state'},
 711     zipcode           => $borrower->{'zipcode'},
 712     country           => $borrower->{'country'},
 713     phone             => $borrower->{'phone'} || $borrower->{'mobile'},
 714     cardnumber        => $borrower->{'cardnumber'},
 715     othernames        => $borrower->{'othernames'},
 716     amountold         => $amountold,
 717     barcode           => $barcode,
 718     stickyduedate     => $stickyduedate,
 719     duedatespec       => $duedatespec,
 720     message           => $message,
 721     CGIselectborrower => $CGIselectborrower,
 722     totalprice        => sprintf('%.2f', $totalprice),
 723     totaldue          => sprintf('%.2f', $total),
 724     todayissues       => \@todaysissues,
 725     previssues        => \@previousissues,
 726     relissues                   => \@relissues,
 727     relprevissues               => \@relprevissues,
 728     displayrelissues            => $displayrelissues,
 729     inprocess         => $inprocess,
 730     is_child          => ($borrower->{'category_type'} eq 'C'),
 731     circview => 1,
 732     soundon           => C4::Context->preference("SoundOn"),
 733     fast_cataloging   => $fast_cataloging,
 734     CircAutoPrintQuickSlip   => C4::Context->preference("CircAutoPrintQuickSlip"),
 735     activeBorrowerRelationship => (C4::Context->preference('borrowerRelationship') ne ''),
 736     SuspendHoldsIntranet => C4::Context->preference('SuspendHoldsIntranet'),
 737     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 738     RoutingSerials => C4::Context->preference('RoutingSerials'),
 739 );
 740
 741 # save stickyduedate to session
 742 if ($stickyduedate) {
 743     $session->param( 'stickyduedate', $duedatespec );
 744 }
 745
 746 my ($picture, $dberror) = GetPatronImage($borrower->{'borrowernumber'});
 747 $template->param( picture => 1 ) if $picture;
 748
 749 # get authorised values with type of BOR_NOTES
 750
 751 my $canned_notes = GetAuthorisedValues("BOR_NOTES");
 752
 753 $template->param(
 754     debt_confirmed            => $debt_confirmed,
 755     SpecifyDueDate            => $duedatespec_allow,
 756     CircAutocompl             => C4::Context->preference("CircAutocompl"),
 757     AllowRenewalLimitOverride => C4::Context->preference("AllowRenewalLimitOverride"),
 758     export_remove_fields      => C4::Context->preference("ExportRemoveFields"),
 759     export_with_csv_profile   => C4::Context->preference("ExportWithCsvProfile"),
 760     canned_bor_notes_loop     => $canned_notes,
 761     debarments                => GetDebarments({ borrowernumber => $borrowernumber }),
 762 );
 763
 764 output_html_with_http_headers $query, $cookie, $template->output;