circ/circulation.pl

   1 #!/usr/bin/perl
   2
   3 # script to execute issuing of books
   4
   5 # Copyright 2000-2002 Katipo Communications
   6 # copyright 2010 BibLibre
   7 # Copyright 2011 PTFS-Europe Ltd.
   8 # Copyright 2012 software.coop and MJ Ray
   9 #
  10 # This file is part of Koha.
  11 #
  12 # Koha is free software; you can redistribute it and/or modify it
  13 # under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 3 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # Koha is distributed in the hope that it will be useful, but
  18 # WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  24
  25 # FIXME There are too many calls to Koha::Patrons->find in this script
  26
  27 use Modern::Perl;
  28 use CGI qw ( -utf8 );
  29 use DateTime;
  30 use DateTime::Duration;
  31 use Scalar::Util qw( looks_like_number );
  32 use C4::Output;
  33 use C4::Print;
  34 use C4::Auth qw/:DEFAULT get_session haspermission/;
  35 use C4::Koha;   # GetPrinter
  36 use C4::Circulation;
  37 use C4::Utils::DataTables::Members;
  38 use C4::Members;
  39 use C4::Biblio;
  40 use C4::Search;
  41 use MARC::Record;
  42 use C4::Reserves;
  43 use Koha::Holds;
  44 use C4::Context;
  45 use CGI::Session;
  46 use C4::Members::Attributes qw(GetBorrowerAttributes);
  47 use Koha::AuthorisedValues;
  48 use Koha::CsvProfiles;
  49 use Koha::Patrons;
  50 use Koha::Patron::Debarments qw(GetDebarments);
  51 use Koha::DateUtils;
  52 use Koha::Database;
  53 use Koha::BiblioFrameworks;
  54 use Koha::Items;
  55 use Koha::Patron::Messages;
  56 use Koha::SearchEngine;
  57 use Koha::SearchEngine::Search;
  58 use Koha::Patron::Modifications;
  59
  60 use Date::Calc qw(
  61   Today
  62   Add_Delta_Days
  63   Date_to_Days
  64 );
  65 use List::MoreUtils qw/uniq/;
  66
  67 #
  68 # PARAMETERS READING
  69 #
  70 my $query = new CGI;
  71
  72 my $override_high_holds     = $query->param('override_high_holds');
  73 my $override_high_holds_tmp = $query->param('override_high_holds_tmp');
  74
  75 my $sessionID = $query->cookie("CGISESSID") ;
  76 my $session = get_session($sessionID);
  77 if (!C4::Context->userenv){
  78     if ($session->param('branch') eq 'NO_LIBRARY_SET'){
  79         # no branch set we can't issue
  80         print $query->redirect("/cgi-bin/koha/circ/selectbranchprinter.pl");
  81         exit;
  82     }
  83 }
  84
  85 my $barcodes = [];
  86 my $barcode =  $query->param('barcode');
  87 my $findborrower;
  88 my $autoswitched;
  89 my $borrowernumber = $query->param('borrowernumber');
  90
  91 if (C4::Context->preference("AutoSwitchPatron") && $barcode) {
  92     if (Koha::Patrons->search( { cardnumber => $barcode} )->count() > 0) {
  93         $findborrower = $barcode;
  94         undef $barcode;
  95         undef $borrowernumber;
  96         $autoswitched = 1;
  97     }
  98 }
  99 $findborrower ||= $query->param('findborrower') || q{};
 100 $findborrower =~ s|,| |g;
 101
 102 # Barcode given by user could be '0'
 103 if ( $barcode || ( defined($barcode) && $barcode eq '0' ) ) {
 104     $barcodes = [ $barcode ];
 105 } else {
 106     my $filefh = $query->upload('uploadfile');
 107     if ( $filefh ) {
 108         while ( my $content = <$filefh> ) {
 109             $content =~ s/[\r\n]*$//g;
 110             push @$barcodes, $content if $content;
 111         }
 112     } elsif ( my $list = $query->param('barcodelist') ) {
 113         push @$barcodes, split( /\s\n/, $list );
 114         $barcodes = [ map { $_ =~ /^\s*$/ ? () : $_ } @$barcodes ];
 115     } else {
 116         @$barcodes = $query->multi_param('barcodes');
 117     }
 118 }
 119
 120 $barcodes = [ uniq @$barcodes ];
 121
 122 my $template_name = q|circ/circulation.tt|;
 123 my $patron = $borrowernumber ? Koha::Patrons->find( $borrowernumber ) : undef;
 124 my $batch = $query->param('batch');
 125 my $batch_allowed = 0;
 126 if ( $batch && C4::Context->preference('BatchCheckouts') ) {
 127     $template_name = q|circ/circulation_batch_checkouts.tt|;
 128     my @batch_category_codes = split '\|', C4::Context->preference('BatchCheckoutsValidCategories');
 129     my $categorycode = $patron->categorycode;
 130     if ( $categorycode && grep {/^$categorycode$/} @batch_category_codes ) {
 131         $batch_allowed = 1;
 132     } else {
 133         $barcodes = [];
 134     }
 135 }
 136
 137 my ( $template, $loggedinuser, $cookie ) = get_template_and_user (
 138     {
 139         template_name   => $template_name,
 140         query           => $query,
 141         type            => "intranet",
 142         authnotrequired => 0,
 143         flagsrequired   => { circulate => 'circulate_remaining_permissions' },
 144     }
 145 );
 146 my $logged_in_user = Koha::Patrons->find( $loggedinuser ) or die "Not logged in";
 147
 148 my $force_allow_issue = $query->param('forceallow') || 0;
 149 if (!C4::Auth::haspermission( C4::Context->userenv->{id} , { circulate => 'force_checkout' } )) {
 150     $force_allow_issue = 0;
 151 }
 152
 153 my $onsite_checkout = $query->param('onsite_checkout');
 154
 155 my @failedrenews = $query->multi_param('failedrenew');    # expected to be itemnumbers
 156 our %renew_failed = ();
 157 for (@failedrenews) { $renew_failed{$_} = 1; }
 158
 159 my @failedreturns = $query->multi_param('failedreturn');
 160 our %return_failed = ();
 161 for (@failedreturns) { $return_failed{$_} = 1; }
 162
 163 my $searchtype = $query->param('searchtype') || q{contain};
 164
 165 my $branch = C4::Context->userenv->{'branch'};
 166
 167 if (C4::Context->preference("DisplayClearScreenButton")) {
 168     $template->param(DisplayClearScreenButton => 1);
 169 }
 170
 171 for my $barcode ( @$barcodes ) {
 172     $barcode =~ s/^\s*|\s*$//g; # remove leading/trailing whitespace
 173     $barcode = barcodedecode($barcode)
 174         if( $barcode && C4::Context->preference('itemBarcodeInputFilter'));
 175 }
 176
 177 my $stickyduedate  = $query->param('stickyduedate') || $session->param('stickyduedate');
 178 my $duedatespec    = $query->param('duedatespec')   || $session->param('stickyduedate');
 179 $duedatespec = eval { output_pref( { dt => dt_from_string( $duedatespec ), dateformat => 'iso', timeformat => '24hr' }); }
 180     if ( $duedatespec );
 181 my $restoreduedatespec  = $query->param('restoreduedatespec') || $duedatespec || $session->param('stickyduedate');
 182 if ( $restoreduedatespec && $restoreduedatespec eq "highholds_empty" ) {
 183     undef $restoreduedatespec;
 184 }
 185 my $issueconfirmed = $query->param('issueconfirmed');
 186 my $cancelreserve  = $query->param('cancelreserve');
 187 my $print          = $query->param('print') || q{};
 188 my $debt_confirmed = $query->param('debt_confirmed') || 0; # Don't show the debt error dialog twice
 189 my $charges        = $query->param('charges') || q{};
 190
 191 # Check if stickyduedate is turned off
 192 if ( @$barcodes ) {
 193     # was stickyduedate loaded from session?
 194     if ( $stickyduedate && ! $query->param("stickyduedate") ) {
 195         $session->clear( 'stickyduedate' );
 196         $stickyduedate  = $query->param('stickyduedate');
 197         $duedatespec    = $query->param('duedatespec');
 198     }
 199     $session->param('auto_renew', scalar $query->param('auto_renew'));
 200 }
 201 else {
 202     $session->clear('auto_renew');
 203 }
 204
 205 my ($datedue,$invalidduedate);
 206
 207 my $duedatespec_allow = C4::Context->preference('SpecifyDueDate');
 208 if( $onsite_checkout && !$duedatespec_allow ) {
 209     $datedue = output_pref({ dt => dt_from_string, dateonly => 1, dateformat => 'iso' });
 210     $datedue .= ' 23:59:00';
 211 } elsif( $duedatespec_allow ) {
 212     if ( $duedatespec ) {
 213         $datedue = eval { dt_from_string( $duedatespec ) };
 214         if (! $datedue ) {
 215             $invalidduedate = 1;
 216             $template->param( IMPOSSIBLE=>1, INVALID_DATE=>$duedatespec );
 217         }
 218     }
 219 }
 220
 221 # check and see if we should print
 222 if ( @$barcodes == 0 && $print eq 'maybe' ) {
 223     $print = 'yes';
 224 }
 225
 226 my $inprocess = (@$barcodes == 0) ? '' : $query->param('inprocess');
 227 if ( @$barcodes == 0 && $charges eq 'yes' ) {
 228     $template->param(
 229         PAYCHARGES     => 'yes',
 230         borrowernumber => $borrowernumber
 231     );
 232 }
 233
 234 if ( $print eq 'yes' && $borrowernumber ne '' ) {
 235     if ( C4::Context->boolean_preference('printcirculationslips') ) {
 236         my $letter = IssueSlip($branch, $borrowernumber, "QUICK");
 237         NetworkPrint($letter->{content});
 238     }
 239     $query->param( 'borrowernumber', '' );
 240     $borrowernumber = '';
 241 }
 242
 243 #
 244 # STEP 2 : FIND BORROWER
 245 # if there is a list of find borrowers....
 246 #
 247 my $message;
 248 if ($findborrower) {
 249     my $patron = Koha::Patrons->find( { cardnumber => $findborrower } );
 250     if ( $patron ) {
 251         $borrowernumber = $patron->borrowernumber;
 252     } else {
 253         my $dt_params = { iDisplayLength => -1 };
 254         my $results = C4::Utils::DataTables::Members::search(
 255             {
 256                 searchmember => $findborrower,
 257                 searchtype   => $searchtype,
 258                 dt_params    => $dt_params,
 259             }
 260         );
 261         my $borrowers = $results->{patrons};
 262         if ( scalar @$borrowers == 1 ) {
 263             $borrowernumber = $borrowers->[0]->{borrowernumber};
 264             $query->param( 'borrowernumber', $borrowernumber );
 265             $query->param( 'barcode',           '' );
 266         } elsif ( @$borrowers ) {
 267             $template->param( borrowers => $borrowers );
 268         } else {
 269             $query->param( 'findborrower', '' );
 270             $message = "'$findborrower'";
 271         }
 272     }
 273 }
 274
 275 # get the borrower information.....
 276 my $balance = 0;
 277 $patron ||= Koha::Patrons->find( $borrowernumber ) if $borrowernumber;
 278 if ($patron) {
 279
 280     $template->param( borrowernumber => $patron->borrowernumber );
 281     output_and_exit_if_error( $query, $cookie, $template, { module => 'members', logged_in_user => $logged_in_user, current_patron => $patron } );
 282
 283     my $overdues = $patron->get_overdues;
 284     my $issues = $patron->checkouts;
 285     $balance = $patron->account->balance;
 286
 287
 288     # if the expiry date is before today ie they have expired
 289     if ( $patron->is_expired ) {
 290         #borrowercard expired, no issues
 291         $template->param(
 292             noissues => ($force_allow_issue) ? 0 : "1",
 293             forceallow => $force_allow_issue,
 294             expired => "1",
 295         );
 296     }
 297     # check for NotifyBorrowerDeparture
 298     elsif ( $patron->is_going_to_expire ) {
 299         # borrower card soon to expire warn librarian
 300         $template->param( "warndeparture" => $patron->dateexpiry ,
 301                         );
 302         if (C4::Context->preference('ReturnBeforeExpiry')){
 303             $template->param("returnbeforeexpiry" => 1);
 304         }
 305     }
 306     $template->param(
 307         overduecount => $overdues->count,
 308         issuecount   => $issues->count,
 309         finetotal    => $balance,
 310     );
 311
 312     if ( $patron and $patron->is_debarred ) {
 313         $template->param(
 314             'userdebarred'    => $patron->debarred,
 315             'debarredcomment' => $patron->debarredcomment,
 316         );
 317
 318         if ( $patron->debarred ne "9999-12-31" ) {
 319             $template->param( 'userdebarreddate' => $patron->debarred );
 320         }
 321     }
 322
 323 }
 324
 325 #
 326 # STEP 3 : ISSUING
 327 #
 328 #
 329 if (@$barcodes) {
 330   my $checkout_infos;
 331   for my $barcode ( @$barcodes ) {
 332     my $template_params = { barcode => $barcode };
 333     # always check for blockers on issuing
 334     my ( $error, $question, $alerts, $messages ) = CanBookBeIssued(
 335         $patron,
 336         $barcode, $datedue,
 337         $inprocess,
 338         undef,
 339         {
 340             onsite_checkout     => $onsite_checkout,
 341             override_high_holds => $override_high_holds || $override_high_holds_tmp || 0,
 342         }
 343     );
 344
 345     my $blocker = $invalidduedate ? 1 : 0;
 346
 347     $template_params->{alert} = $alerts;
 348     $template_params->{messages} = $messages;
 349
 350     my $item = Koha::Items->find({ barcode => $barcode });
 351     my ( $biblio, $mss );
 352
 353     if ( $item ) {
 354         $biblio = $item->biblio;
 355         my $mss = Koha::MarcSubfieldStructures->search({ frameworkcode => $biblio->frameworkcode, kohafield => 'items.notforloan', authorised_value => [ -and => {'!=' => undef }, {'!=' => ''}] });
 356         $template_params->{authvalcode_notforloan} = $mss->count ? $mss->next->authorised_value : undef;
 357     }
 358
 359     # Fix for bug 7494: optional checkout-time fallback search for a book
 360
 361     if ( $error->{'UNKNOWN_BARCODE'}
 362         && C4::Context->preference("itemBarcodeFallbackSearch")
 363         && not $batch
 364     )
 365     {
 366      $template_params->{FALLBACK} = 1;
 367
 368         my $searcher = Koha::SearchEngine::Search->new({index => $Koha::SearchEngine::BIBLIOS_INDEX});
 369         my $query = "kw=" . $barcode;
 370         my ( $searcherror, $results, $total_hits ) = $searcher->simple_search_compat($query, 0, 10);
 371
 372         # if multiple hits, offer options to librarian
 373         if ( $total_hits > 0 ) {
 374             my @options = ();
 375             foreach my $hit ( @{$results} ) {
 376                 my $chosen =
 377                   TransformMarcToKoha( C4::Search::new_record_from_zebra('biblioserver',$hit) );
 378
 379                 # offer all barcodes individually
 380                 if ( $chosen->{barcode} ) {
 381                     foreach my $barcode ( sort split(/\s*\|\s*/, $chosen->{barcode}) ) {
 382                         my %chosen_single = %{$chosen};
 383                         $chosen_single{barcode} = $barcode;
 384                         push( @options, \%chosen_single );
 385                     }
 386                 }
 387             }
 388             $template_params->{options} = \@options;
 389         }
 390     }
 391
 392     if ( $error->{UNKNOWN_BARCODE} or not $onsite_checkout or not C4::Context->preference("OnSiteCheckoutsForce") ) {
 393         delete $question->{'DEBT'} if ($debt_confirmed);
 394         foreach my $impossible ( keys %$error ) {
 395             $template_params->{$impossible} = $$error{$impossible};
 396             $template_params->{IMPOSSIBLE} = 1;
 397             $blocker = 1;
 398         }
 399     }
 400
 401     if( $item and ( !$blocker or $force_allow_issue ) ){
 402         my $confirm_required = 0;
 403         unless($issueconfirmed){
 404             #  Get the item title for more information
 405             my $materials = $item->materials;
 406             my $descriptions = Koha::AuthorisedValues->get_description_by_koha_field({ frameworkcode => $biblio->frameworkcode, kohafield => 'items.materials', authorised_value => $materials });
 407             $materials = $descriptions->{lib} // $materials;
 408             $template_params->{additional_materials} = $materials;
 409             $template_params->{itemhomebranch} = $item->homebranch;
 410
 411             # pass needsconfirmation to template if issuing is possible and user hasn't yet confirmed.
 412             foreach my $needsconfirmation ( keys %$question ) {
 413                 $template_params->{$needsconfirmation} = $$question{$needsconfirmation};
 414                 $template_params->{getTitleMessageIteminfo} = $biblio->title;
 415                 $template_params->{getBarcodeMessageIteminfo} = $item->barcode;
 416                 $template_params->{NEEDSCONFIRMATION} = 1;
 417                 $template_params->{onsite_checkout} = $onsite_checkout;
 418                 $template_params->{auto_renew} = $session->param('auto_renew');
 419                 $confirm_required = 1;
 420             }
 421         }
 422         unless($confirm_required) {
 423             my $switch_onsite_checkout = exists $messages->{ONSITE_CHECKOUT_WILL_BE_SWITCHED};
 424             my $issue = AddIssue( $patron->unblessed, $barcode, $datedue, $cancelreserve, undef, undef, { onsite_checkout => $onsite_checkout, auto_renew => $session->param('auto_renew'), switch_onsite_checkout => $switch_onsite_checkout, } );
 425             $template_params->{issue} = $issue;
 426             $session->clear('auto_renew');
 427             $inprocess = 1;
 428         }
 429     }
 430
 431     if ($question->{RESERVE_WAITING} or $question->{RESERVED}){
 432         $template->param(
 433             reserveborrowernumber => $question->{'resborrowernumber'}
 434         );
 435     }
 436
 437
 438     # FIXME If the issue is confirmed, we launch another time checkouts->count, now display the issue count after issue
 439     $patron = Koha::Patrons->find( $borrowernumber );
 440     $template_params->{issuecount} = $patron->checkouts->count;
 441
 442     if ( $item ) {
 443         $template_params->{item} = $item;
 444         $template_params->{biblio} = $biblio;
 445         $template_params->{itembiblionumber} = $biblio->biblionumber;
 446     }
 447     push @$checkout_infos, $template_params;
 448   }
 449   unless ( $batch ) {
 450     $template->param( %{$checkout_infos->[0]} );
 451     $template->param( barcode => $barcodes->[0] );
 452   } else {
 453     my $confirmation_needed = grep { $_->{NEEDSCONFIRMATION} } @$checkout_infos;
 454     $template->param(
 455         checkout_infos => $checkout_infos,
 456         confirmation_needed => $confirmation_needed,
 457     );
 458   }
 459 }
 460
 461 ##################################################################################
 462 # BUILD HTML
 463 # show all reserves of this borrower, and the position of the reservation ....
 464 if ($patron) {
 465     my $holds = Koha::Holds->search( { borrowernumber => $borrowernumber } ); # FIXME must be Koha::Patron->holds
 466     my $waiting_holds = $holds->waiting;
 467     $template->param(
 468         holds_count  => $holds->count(),
 469         WaitingHolds => $waiting_holds,
 470     );
 471 }
 472
 473 if ( $patron ) {
 474     my $noissues;
 475     if ( $patron->gonenoaddress ) {
 476         $template->param( gna => 1 );
 477         $noissues = 1;
 478     }
 479     if ( $patron->lost ) {
 480         $template->param( lost=> 1 );
 481         $noissues = 1;
 482     }
 483     if ( $patron->is_debarred ) {
 484         $template->param( dbarred=> 1 );
 485         $noissues = 1;
 486     }
 487     my $account = $patron->account;
 488     if( ( my $owing = $account->non_issues_charges ) > 0 ) {
 489         my $noissuescharge = C4::Context->preference("noissuescharge") || 5; # FIXME If noissuescharge == 0 then 5, why??
 490         $noissues = ( not C4::Context->preference("AllowFineOverride") and ( $owing > $noissuescharge ) );
 491         $template->param(
 492             charges => 1,
 493             chargesamount => $owing,
 494         )
 495     } elsif ( $balance < 0 ) {
 496         $template->param(
 497             credits => 1,
 498             creditsamount => -$balance,
 499         );
 500     }
 501
 502     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 503     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 504     if ( defined $no_issues_charge_guarantees ) {
 505         my $guarantees_non_issues_charges = 0;
 506         my $guarantees = $patron->guarantees;
 507         while ( my $g = $guarantees->next ) {
 508             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 509         }
 510         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees ) {
 511             $template->param(
 512                 charges_guarantees    => 1,
 513                 chargesamount_guarantees => $guarantees_non_issues_charges,
 514             );
 515             $noissues = 1 unless C4::Context->preference("allowfineoverride");
 516         }
 517     }
 518
 519     if ( $patron->has_overdues ) {
 520         $template->param( odues => 1 );
 521     }
 522
 523     if ( $patron->borrowernotes ) {
 524         my $borrowernotes = $patron->borrowernotes;
 525         $borrowernotes =~ s#\n#<br />#g;
 526         $template->param(
 527             notes =>1,
 528             notesmsg => $borrowernotes,
 529         )
 530     }
 531
 532     if ( $noissues ) {
 533         $template->param(
 534             noissues => ($force_allow_issue) ? 0 : 'true',
 535             forceallow => $force_allow_issue,
 536         );
 537     }
 538 }
 539
 540 if ( $patron && $patron->is_child) {
 541     my $patron_categories = Koha::Patron::Categories->search_limited({ category_type => 'A' }, {order_by => ['categorycode']});
 542     $template->param( 'CATCODE_MULTI' => 1) if $patron_categories->count > 1;
 543     $template->param( 'catcode' => $patron_categories->next->categorycode )  if $patron_categories->count == 1;
 544 }
 545
 546 my $messages = Koha::Patron::Messages->search(
 547     {
 548         'me.borrowernumber' => $borrowernumber,
 549     },
 550     {
 551        join => 'manager',
 552        '+select' => ['manager.surname', 'manager.firstname' ],
 553        '+as' => ['manager_surname', 'manager_firstname'],
 554     }
 555 );
 556
 557 my $fast_cataloging = 0;
 558 if ( Koha::BiblioFrameworks->find('FA') ) {
 559     $fast_cataloging = 1
 560 }
 561
 562 if (C4::Context->preference('ExtendedPatronAttributes')) {
 563     my $attributes = GetBorrowerAttributes($borrowernumber);
 564     $template->param(
 565         ExtendedPatronAttributes => 1,
 566         extendedattributes => $attributes
 567     );
 568 }
 569 my $view = $batch
 570     ?'batch_checkout_view'
 571     : 'circview';
 572
 573 my @relatives;
 574 if ( $borrowernumber ) {
 575     if ( $patron ) {
 576         if ( my $guarantor = $patron->guarantor ) {
 577             push @relatives, $guarantor->borrowernumber;
 578             push @relatives, $_->borrowernumber for $patron->siblings;
 579         } else {
 580             push @relatives, $_->borrowernumber for $patron->guarantees;
 581         }
 582     }
 583 }
 584 my $relatives_issues_count =
 585   Koha::Database->new()->schema()->resultset('Issue')
 586   ->count( { borrowernumber => \@relatives } );
 587
 588 if ( $patron ) {
 589     my $av = Koha::AuthorisedValues->search({ category => 'ROADTYPE', authorised_value => $patron->streettype });
 590     my $roadtype = $av->count ? $av->next->lib : '';
 591     $template->param(
 592         roadtype          => $roadtype,
 593         patron            => $patron,
 594         categoryname      => $patron->category->description,
 595         expiry            => $patron->dateexpiry,
 596     );
 597 }
 598
 599 # Restore date if changed by holds and/or save stickyduedate to session
 600 if ($restoreduedatespec || $stickyduedate) {
 601     $duedatespec = $restoreduedatespec || $duedatespec;
 602
 603     if ($stickyduedate) {
 604         $session->param( 'stickyduedate', $duedatespec );
 605     }
 606 } elsif (defined($duedatespec) && !defined($restoreduedatespec)) {
 607     undef $duedatespec;
 608 }
 609
 610 $template->param(
 611     messages           => $messages,
 612     borrowernumber    => $borrowernumber,
 613     branch            => $branch,
 614     was_renewed       => scalar $query->param('was_renewed') ? 1 : 0,
 615     barcodes          => $barcodes,
 616     stickyduedate     => $stickyduedate,
 617     duedatespec       => $duedatespec,
 618     restoreduedatespec => $restoreduedatespec,
 619     message           => $message,
 620     totaldue          => sprintf('%.2f', $balance), # FIXME not used in template?
 621     inprocess         => $inprocess,
 622     $view             => 1,
 623     batch_allowed     => $batch_allowed,
 624     batch             => $batch,
 625     AudioAlerts           => C4::Context->preference("AudioAlerts"),
 626     fast_cataloging   => $fast_cataloging,
 627     CircAutoPrintQuickSlip   => C4::Context->preference("CircAutoPrintQuickSlip"),
 628     RoutingSerials => C4::Context->preference('RoutingSerials'),
 629     relatives_issues_count => $relatives_issues_count,
 630     relatives_borrowernumbers => \@relatives,
 631 );
 632
 633
 634 if ( C4::Context->preference("ExportCircHistory") ) {
 635     $template->param(csv_profiles => [ Koha::CsvProfiles->search({ type => 'marc' }) ]);
 636 }
 637
 638 my $has_modifications = Koha::Patron::Modifications->search( { borrowernumber => $borrowernumber } )->count;
 639 $template->param(
 640     debt_confirmed            => $debt_confirmed,
 641     SpecifyDueDate            => $duedatespec_allow,
 642     CircAutocompl             => C4::Context->preference("CircAutocompl"),
 643     debarments                => scalar GetDebarments({ borrowernumber => $borrowernumber }),
 644     todaysdate                => output_pref( { dt => dt_from_string()->set(hour => 23)->set(minute => 59), dateformat => 'sql' } ),
 645     has_modifications         => $has_modifications,
 646     override_high_holds       => $override_high_holds,
 647     nopermission              => scalar $query->param('nopermission'),
 648     autoswitched              => $autoswitched,
 649 );
 650
 651 output_html_with_http_headers $query, $cookie, $template->output;