tools/batch_extend_due_dates.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Copyright 2020 Koha Development Team
   6 #
   7 # Koha is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as
   9 # published by the Free Software Foundation; either version 3
  10 # of the License, or (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General
  18 # Public License along with Koha; if not, see
  19 # <http://www.gnu.org/licenses>
  20
  21 use Modern::Perl;
  22
  23 use CGI;
  24
  25 use C4::Auth qw( get_template_and_user );
  26 use C4::Output qw( output_html_with_http_headers );
  27 use Koha::Checkouts;
  28 use Koha::DateUtils qw( dt_from_string );
  29
  30 my $input = new CGI;
  31 my $op = $input->param('op') // q|form|;
  32
  33 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  34     {
  35         template_name   => 'tools/batch_extend_due_dates.tt',
  36         query           => $input,
  37         type            => "intranet",
  38         authnotrequired => 0,
  39         flagsrequired   => { tools => 'batch_extend_due_dates' },
  40     }
  41 );
  42
  43 if ( $op eq 'form' ) {
  44     $template->param( view => 'form', );
  45 }
  46 elsif ( $op eq 'list' ) {
  47
  48     my @categorycodes     = $input->multi_param('categorycodes');
  49     my @branchcodes       = $input->multi_param('branchcodes');
  50     my $from_due_date     = $input->param('from_due_date');
  51     my $to_due_date       = $input->param('to_due_date');
  52     my $new_hard_due_date = $input->param('new_hard_due_date');
  53     my $due_date_days     = $input->param('due_date_days');
  54
  55     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
  56     my $search_params;
  57     if (@categorycodes) {
  58         $search_params->{'borrower.categorycode'} = { -in => \@categorycodes };
  59     }
  60     if (@branchcodes) {
  61         $search_params->{'me.branchcode'} = { -in => \@branchcodes };
  62     }
  63     if ( $from_due_date and $to_due_date ) {
  64         my $to_due_date_endday = dt_from_string($to_due_date);
  65         $to_due_date_endday
  66           ->set(  # We set last second of day to see all checkouts from that day
  67             hour   => 23,
  68             minute => 59,
  69             second => 59
  70           );
  71         $search_params->{'me.date_due'} = {
  72             -between => [
  73                 $dtf->format_datetime( dt_from_string($from_due_date) ),
  74                 $dtf->format_datetime($to_due_date_endday),
  75             ]
  76         };
  77     }
  78     elsif ($from_due_date) {
  79         $search_params->{'me.date_due'} =
  80           { '>=' => $dtf->format_datetime( dt_from_string($from_due_date) ) };
  81     }
  82     elsif ($to_due_date) {
  83         my $to_due_date_endday = dt_from_string($to_due_date);
  84         $to_due_date_endday
  85           ->set(  # We set last second of day to see all checkouts from that day
  86             hour   => 23,
  87             minute => 59,
  88             second => 59
  89           );
  90         $search_params->{'me.date_due'} =
  91           { '<=' => $dtf->format_datetime($to_due_date_endday) };
  92     }
  93
  94     my $checkouts = Koha::Checkouts->search(
  95         $search_params,
  96         {
  97             join => [ 'item', 'borrower' ]
  98         }
  99     );
 100
 101     my @new_due_dates;
 102     if ( not $new_hard_due_date && $due_date_days ) {
 103         while ( my $checkout = $checkouts->next ) {
 104             my $due_date = dt_from_string( $checkout->date_due );
 105             push @new_due_dates, $due_date->add( days => $due_date_days );
 106         }
 107     }
 108     $template->param(
 109         checkouts         => $checkouts,
 110         new_hard_due_date => $new_hard_due_date
 111         ? dt_from_string($new_hard_due_date)
 112         : undef,
 113         due_date_days => $due_date_days,
 114         new_due_dates => \@new_due_dates,
 115         view          => 'list',
 116     );
 117 }
 118 elsif ( $op eq 'modify' ) {
 119
 120     # We want to modify selected checkouts!
 121     my @issue_ids         = $input->multi_param('issue_id');
 122     my $new_hard_due_date = $input->param('new_hard_due_date');
 123     my $due_date_days     = $input->param('due_date_days');
 124
 125     $new_hard_due_date &&= dt_from_string($new_hard_due_date);
 126     my $checkouts =
 127       Koha::Checkouts->search( { issue_id => { -in => \@issue_ids } } );
 128     while ( my $checkout = $checkouts->next ) {
 129         my $new_due_date = $new_hard_due_date
 130           || dt_from_string( $checkout->date_due )->add( days => $due_date_days );
 131
 132         # Update checkout's due date
 133         $checkout->date_due($new_due_date)->store;
 134
 135         # Update items.onloan
 136         $checkout->item->onloan($new_due_date)->store;
 137     }
 138
 139     $template->param(
 140         view      => 'report',
 141         checkouts => $checkouts,
 142     );
 143 }
 144
 145 output_html_with_http_headers $input, $cookie, $template->output;