C4/Reserves.pm

   1 package C4::Reserves;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #           2006 SAN Ouest Provence
   5 #           2007-2010 BibLibre Paul POULAIN
   6 #           2011 Catalyst IT
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23
  24 use strict;
  25 #use warnings; FIXME - Bug 2505
  26
  27 use C4::Accounts;
  28 use C4::Biblio;
  29 use C4::Circulation;
  30 use C4::Context;
  31 use C4::Items;
  32 use C4::Letters;
  33 use C4::Log;
  34 use C4::Members::Messaging;
  35 use C4::Members;
  36 use Koha::Account::Lines;
  37 use Koha::Biblios;
  38 use Koha::Calendar;
  39 use Koha::CirculationRules;
  40 use Koha::Database;
  41 use Koha::DateUtils;
  42 use Koha::Hold;
  43 use Koha::Holds;
  44 use Koha::IssuingRules;
  45 use Koha::ItemTypes;
  46 use Koha::Items;
  47 use Koha::Libraries;
  48 use Koha::Old::Hold;
  49 use Koha::Patrons;
  50
  51 use Carp;
  52 use Data::Dumper;
  53 use List::MoreUtils qw( firstidx any );
  54
  55 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  56
  57 =head1 NAME
  58
  59 C4::Reserves - Koha functions for dealing with reservation.
  60
  61 =head1 SYNOPSIS
  62
  63   use C4::Reserves;
  64
  65 =head1 DESCRIPTION
  66
  67 This modules provides somes functions to deal with reservations.
  68
  69   Reserves are stored in reserves table.
  70   The following columns contains important values :
  71   - priority >0      : then the reserve is at 1st stage, and not yet affected to any item.
  72              =0      : then the reserve is being dealed
  73   - found : NULL       : means the patron requested the 1st available, and we haven't chosen the item
  74             T(ransit)  : the reserve is linked to an item but is in transit to the pickup branch
  75             W(aiting)  : the reserve is linked to an item, is at the pickup branch, and is waiting on the hold shelf
  76             F(inished) : the reserve has been completed, and is done
  77   - itemnumber : empty : the reserve is still unaffected to an item
  78                  filled: the reserve is attached to an item
  79   The complete workflow is :
  80   ==== 1st use case ====
  81   patron request a document, 1st available :                      P >0, F=NULL, I=NULL
  82   a library having it run "transfertodo", and clic on the list
  83          if there is no transfer to do, the reserve waiting
  84          patron can pick it up                                    P =0, F=W,    I=filled
  85          if there is a transfer to do, write in branchtransfer    P =0, F=T,    I=filled
  86            The pickup library receive the book, it check in       P =0, F=W,    I=filled
  87   The patron borrow the book                                      P =0, F=F,    I=filled
  88
  89   ==== 2nd use case ====
  90   patron requests a document, a given item,
  91     If pickup is holding branch                                   P =0, F=W,   I=filled
  92     If transfer needed, write in branchtransfer                   P =0, F=T,    I=filled
  93         The pickup library receive the book, it checks it in      P =0, F=W,    I=filled
  94   The patron borrow the book                                      P =0, F=F,    I=filled
  95
  96 =head1 FUNCTIONS
  97
  98 =cut
  99
 100 BEGIN {
 101     require Exporter;
 102     @ISA = qw(Exporter);
 103     @EXPORT = qw(
 104         &AddReserve
 105
 106         &GetReserveStatus
 107
 108         &GetOtherReserves
 109
 110         &ModReserveFill
 111         &ModReserveAffect
 112         &ModReserve
 113         &ModReserveStatus
 114         &ModReserveCancelAll
 115         &ModReserveMinusPriority
 116         &MoveReserve
 117
 118         &CheckReserves
 119         &CanBookBeReserved
 120         &CanItemBeReserved
 121         &CanReserveBeCanceledFromOpac
 122         &CancelExpiredReserves
 123
 124         &AutoUnsuspendReserves
 125
 126         &IsAvailableForItemLevelRequest
 127
 128         &AlterPriority
 129         &ToggleLowestPriority
 130
 131         &ReserveSlip
 132         &ToggleSuspend
 133         &SuspendAll
 134
 135         &GetReservesControlBranch
 136
 137         IsItemOnHoldAndFound
 138
 139         GetMaxPatronHoldsForRecord
 140     );
 141     @EXPORT_OK = qw( MergeHolds );
 142 }
 143
 144 =head2 AddReserve
 145
 146     AddReserve($branch,$borrowernumber,$biblionumber,$bibitems,$priority,$resdate,$expdate,$notes,$title,$checkitem,$found)
 147
 148 Adds reserve and generates HOLDPLACED message.
 149
 150 The following tables are available witin the HOLDPLACED message:
 151
 152     branches
 153     borrowers
 154     biblio
 155     biblioitems
 156     items
 157     reserves
 158
 159 =cut
 160
 161 sub AddReserve {
 162     my (
 163         $branch,   $borrowernumber, $biblionumber, $bibitems,
 164         $priority, $resdate,        $expdate,      $notes,
 165         $title,    $checkitem,      $found,        $itemtype
 166     ) = @_;
 167
 168     $resdate = output_pref( { str => dt_from_string( $resdate ), dateonly => 1, dateformat => 'iso' })
 169         or output_pref({ dt => dt_from_string, dateonly => 1, dateformat => 'iso' });
 170
 171     $expdate = output_pref({ str => $expdate, dateonly => 1, dateformat => 'iso' });
 172
 173     # if we have an item selectionned, and the pickup branch is the same as the holdingbranch
 174     # of the document, we force the value $priority and $found .
 175     if ( $checkitem and not C4::Context->preference('ReservesNeedReturns') ) {
 176         $priority = 0;
 177         my $item = Koha::Items->find( $checkitem ); # FIXME Prevent bad calls
 178         if ( $item->holdingbranch eq $branch ) {
 179             $found = 'W';
 180         }
 181     }
 182
 183     if ( C4::Context->preference('AllowHoldDateInFuture') ) {
 184
 185         # Make room in reserves for this before those of a later reserve date
 186         $priority = _ShiftPriorityByDateAndPriority( $biblionumber, $resdate, $priority );
 187     }
 188
 189     my $waitingdate;
 190
 191     # If the reserv had the waiting status, we had the value of the resdate
 192     if ( $found eq 'W' ) {
 193         $waitingdate = $resdate;
 194     }
 195
 196     # Don't add itemtype limit if specific item is selected
 197     $itemtype = undef if $checkitem;
 198
 199     # updates take place here
 200     my $hold = Koha::Hold->new(
 201         {
 202             borrowernumber => $borrowernumber,
 203             biblionumber   => $biblionumber,
 204             reservedate    => $resdate,
 205             branchcode     => $branch,
 206             priority       => $priority,
 207             reservenotes   => $notes,
 208             itemnumber     => $checkitem,
 209             found          => $found,
 210             waitingdate    => $waitingdate,
 211             expirationdate => $expdate,
 212             itemtype       => $itemtype,
 213         }
 214     )->store();
 215     $hold->set_waiting() if $found eq 'W';
 216
 217     logaction( 'HOLDS', 'CREATE', $hold->id, Dumper($hold->unblessed) )
 218         if C4::Context->preference('HoldsLog');
 219
 220     my $reserve_id = $hold->id();
 221
 222     # add a reserve fee if needed
 223     if ( C4::Context->preference('HoldFeeMode') ne 'any_time_is_collected' ) {
 224         my $reserve_fee = GetReserveFee( $borrowernumber, $biblionumber );
 225         ChargeReserveFee( $borrowernumber, $reserve_fee, $title );
 226     }
 227
 228     _FixPriority({ biblionumber => $biblionumber});
 229
 230     # Send e-mail to librarian if syspref is active
 231     if(C4::Context->preference("emailLibrarianWhenHoldIsPlaced")){
 232         my $patron = Koha::Patrons->find( $borrowernumber );
 233         my $library = $patron->library;
 234         if ( my $letter =  C4::Letters::GetPreparedLetter (
 235             module => 'reserves',
 236             letter_code => 'HOLDPLACED',
 237             branchcode => $branch,
 238             lang => $patron->lang,
 239             tables => {
 240                 'branches'    => $library->unblessed,
 241                 'borrowers'   => $patron->unblessed,
 242                 'biblio'      => $biblionumber,
 243                 'biblioitems' => $biblionumber,
 244                 'items'       => $checkitem,
 245                 'reserves'    => $hold->unblessed,
 246             },
 247         ) ) {
 248
 249             my $admin_email_address = $library->branchemail || C4::Context->preference('KohaAdminEmailAddress');
 250
 251             C4::Letters::EnqueueLetter(
 252                 {   letter                 => $letter,
 253                     borrowernumber         => $borrowernumber,
 254                     message_transport_type => 'email',
 255                     from_address           => $admin_email_address,
 256                     to_address           => $admin_email_address,
 257                 }
 258             );
 259         }
 260     }
 261
 262     return $reserve_id;
 263 }
 264
 265 =head2 CanBookBeReserved
 266
 267   $canReserve = &CanBookBeReserved($borrowernumber, $biblionumber, $branchcode)
 268   if ($canReserve eq 'OK') { #We can reserve this Item! }
 269
 270 See CanItemBeReserved() for possible return values.
 271
 272 =cut
 273
 274 sub CanBookBeReserved{
 275     my ($borrowernumber, $biblionumber, $pickup_branchcode) = @_;
 276
 277     my @itemnumbers = Koha::Items->search({ biblionumber => $biblionumber})->get_column("itemnumber");
 278     #get items linked via host records
 279     my @hostitems = get_hostitemnumbers_of($biblionumber);
 280     if (@hostitems){
 281         push (@itemnumbers, @hostitems);
 282     }
 283
 284     my $canReserve = { status => '' };
 285     foreach my $itemnumber (@itemnumbers) {
 286         $canReserve = CanItemBeReserved( $borrowernumber, $itemnumber, $pickup_branchcode );
 287         return { status => 'OK' } if $canReserve->{status} eq 'OK';
 288     }
 289     return $canReserve;
 290 }
 291
 292 =head2 CanItemBeReserved
 293
 294   $canReserve = &CanItemBeReserved($borrowernumber, $itemnumber, $branchcode)
 295   if ($canReserve->{status} eq 'OK') { #We can reserve this Item! }
 296
 297 @RETURNS { status => OK },              if the Item can be reserved.
 298          { status => ageRestricted },   if the Item is age restricted for this borrower.
 299          { status => damaged },         if the Item is damaged.
 300          { status => cannotReserveFromOtherBranches }, if syspref 'canreservefromotherbranches' is OK.
 301          { status => tooManyReserves, limit => $limit }, if the borrower has exceeded their maximum reserve amount.
 302          { status => notReservable },   if holds on this item are not allowed
 303          { status => libraryNotFound },   if given branchcode is not an existing library
 304          { status => libraryNotPickupLocation },   if given branchcode is not configured to be a pickup location
 305          { status => cannotBeTransferred }, if branch transfer limit applies on given item and branchcode
 306
 307 =cut
 308
 309 sub CanItemBeReserved {
 310     my ( $borrowernumber, $itemnumber, $pickup_branchcode ) = @_;
 311
 312     my $dbh = C4::Context->dbh;
 313     my $ruleitemtype;    # itemtype of the matching issuing rule
 314     my $allowedreserves  = 0; # Total number of holds allowed across all records
 315     my $holds_per_record = 1; # Total number of holds allowed for this one given record
 316     my $holds_per_day;        # Default to unlimited
 317
 318     # we retrieve borrowers and items informations #
 319     # item->{itype} will come for biblioitems if necessery
 320     my $item       = Koha::Items->find($itemnumber);
 321     my $biblio     = $item->biblio;
 322     my $patron = Koha::Patrons->find( $borrowernumber );
 323     my $borrower = $patron->unblessed;
 324
 325     # If an item is damaged and we don't allow holds on damaged items, we can stop right here
 326     return { status =>'damaged' }
 327       if ( $item->damaged
 328         && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 329
 330     # Check for the age restriction
 331     my ( $ageRestriction, $daysToAgeRestriction ) =
 332       C4::Circulation::GetAgeRestriction( $biblio->biblioitem->agerestriction, $borrower );
 333     return { status => 'ageRestricted' } if $daysToAgeRestriction && $daysToAgeRestriction > 0;
 334
 335     # Check that the patron doesn't have an item level hold on this item already
 336     return { status =>'itemAlreadyOnHold' }
 337       if Koha::Holds->search( { borrowernumber => $borrowernumber, itemnumber => $itemnumber } )->count();
 338
 339     my $controlbranch = C4::Context->preference('ReservesControlBranch');
 340
 341     my $querycount = q{
 342         SELECT count(*) AS count
 343           FROM reserves
 344      LEFT JOIN items USING (itemnumber)
 345      LEFT JOIN biblioitems ON (reserves.biblionumber=biblioitems.biblionumber)
 346      LEFT JOIN borrowers USING (borrowernumber)
 347          WHERE borrowernumber = ?
 348     };
 349
 350     my $branchcode  = "";
 351     my $branchfield = "reserves.branchcode";
 352
 353     if ( $controlbranch eq "ItemHomeLibrary" ) {
 354         $branchfield = "items.homebranch";
 355         $branchcode  = $item->homebranch;
 356     }
 357     elsif ( $controlbranch eq "PatronLibrary" ) {
 358         $branchfield = "borrowers.branchcode";
 359         $branchcode  = $borrower->{branchcode};
 360     }
 361
 362     # we retrieve rights
 363     if ( my $rights = GetHoldRule( $borrower->{'categorycode'}, $item->effective_itemtype, $branchcode ) ) {
 364         $ruleitemtype     = $rights->{itemtype};
 365         $allowedreserves  = $rights->{reservesallowed};
 366         $holds_per_record = $rights->{holds_per_record};
 367         $holds_per_day    = $rights->{holds_per_day};
 368     }
 369     else {
 370         $ruleitemtype = '*';
 371     }
 372
 373     my $holds = Koha::Holds->search(
 374         {
 375             borrowernumber => $borrowernumber,
 376             biblionumber   => $item->biblionumber,
 377             found          => undef, # Found holds don't count against a patron's holds limit
 378         }
 379     );
 380     if ( $holds->count() >= $holds_per_record ) {
 381         return { status => "tooManyHoldsForThisRecord", limit => $holds_per_record };
 382     }
 383
 384     my $today_holds = Koha::Holds->search({
 385         borrowernumber => $borrowernumber,
 386         reservedate    => dt_from_string->date
 387     });
 388
 389     if ( defined $holds_per_day &&
 390           (   ( $holds_per_day > 0 && $today_holds->count() >= $holds_per_day )
 391            or ( $holds_per_day == 0 ) )
 392         )  {
 393         return { status => 'tooManyReservesToday', limit => $holds_per_day };
 394     }
 395
 396     # we retrieve count
 397
 398     $querycount .= "AND ( $branchfield = ? OR $branchfield IS NULL )";
 399
 400     # If using item-level itypes, fall back to the record
 401     # level itemtype if the hold has no associated item
 402     $querycount .=
 403       C4::Context->preference('item-level_itypes')
 404       ? " AND COALESCE( items.itype, biblioitems.itemtype ) = ?"
 405       : " AND biblioitems.itemtype = ?"
 406       if ( $ruleitemtype ne "*" );
 407
 408     my $sthcount = $dbh->prepare($querycount);
 409
 410     if ( $ruleitemtype eq "*" ) {
 411         $sthcount->execute( $borrowernumber, $branchcode );
 412     }
 413     else {
 414         $sthcount->execute( $borrowernumber, $branchcode, $ruleitemtype );
 415     }
 416
 417     my $reservecount = "0";
 418     if ( my $rowcount = $sthcount->fetchrow_hashref() ) {
 419         $reservecount = $rowcount->{count};
 420     }
 421
 422     # we check if it's ok or not
 423     if ( $reservecount >= $allowedreserves ) {
 424         return { status => 'tooManyReserves', limit => $allowedreserves };
 425     }
 426
 427     # Now we need to check hold limits by patron category
 428     my $rule = Koha::CirculationRules->get_effective_rule(
 429         {
 430             categorycode => $borrower->{categorycode},
 431             branchcode   => $branchcode,
 432             rule_name    => 'max_holds',
 433         }
 434     );
 435     if ( $rule && defined( $rule->rule_value ) && $rule->rule_value ne '' ) {
 436         my $total_holds_count = Koha::Holds->search(
 437             {
 438                 borrowernumber => $borrower->{borrowernumber}
 439             }
 440         )->count();
 441
 442         return { status => 'tooManyReserves', limit => $rule->rule_value} if $total_holds_count >= $rule->rule_value;
 443     }
 444
 445     my $reserves_control_branch =
 446       GetReservesControlBranch( $item->unblessed(), $borrower );
 447     my $branchitemrule =
 448       C4::Circulation::GetBranchItemRule( $reserves_control_branch, $item->itype ); # FIXME Should not be item->effective_itemtype?
 449
 450     if ( $branchitemrule->{holdallowed} == 0 ) {
 451         return { status => 'notReservable' };
 452     }
 453
 454     if (   $branchitemrule->{holdallowed} == 1
 455         && $borrower->{branchcode} ne $item->homebranch )
 456     {
 457         return { status => 'cannotReserveFromOtherBranches' };
 458     }
 459
 460     # If reservecount is ok, we check item branch if IndependentBranches is ON
 461     # and canreservefromotherbranches is OFF
 462     if ( C4::Context->preference('IndependentBranches')
 463         and !C4::Context->preference('canreservefromotherbranches') )
 464     {
 465         if ( $item->homebranch ne $borrower->{branchcode} ) {
 466             return { status => 'cannotReserveFromOtherBranches' };
 467         }
 468     }
 469
 470     if ($pickup_branchcode) {
 471         my $destination = Koha::Libraries->find({
 472             branchcode => $pickup_branchcode,
 473         });
 474
 475         unless ($destination) {
 476             return { status => 'libraryNotFound' };
 477         }
 478         unless ($destination->pickup_location) {
 479             return { status => 'libraryNotPickupLocation' };
 480         }
 481         unless ($item->can_be_transferred({ to => $destination })) {
 482             return { status => 'cannotBeTransferred' };
 483         }
 484     }
 485
 486     return { status => 'OK' };
 487 }
 488
 489 =head2 CanReserveBeCanceledFromOpac
 490
 491     $number = CanReserveBeCanceledFromOpac($reserve_id, $borrowernumber);
 492
 493     returns 1 if reserve can be cancelled by user from OPAC.
 494     First check if reserve belongs to user, next checks if reserve is not in
 495     transfer or waiting status
 496
 497 =cut
 498
 499 sub CanReserveBeCanceledFromOpac {
 500     my ($reserve_id, $borrowernumber) = @_;
 501
 502     return unless $reserve_id and $borrowernumber;
 503     my $reserve = Koha::Holds->find($reserve_id);
 504
 505     return 0 unless $reserve->borrowernumber == $borrowernumber;
 506     return 0 if ( $reserve->found eq 'W' ) or ( $reserve->found eq 'T' );
 507
 508     return 1;
 509
 510 }
 511
 512 =head2 GetOtherReserves
 513
 514   ($messages,$nextreservinfo)=$GetOtherReserves(itemnumber);
 515
 516 Check queued list of this document and check if this document must be transferred
 517
 518 =cut
 519
 520 sub GetOtherReserves {
 521     my ($itemnumber) = @_;
 522     my $messages;
 523     my $nextreservinfo;
 524     my ( undef, $checkreserves, undef ) = CheckReserves($itemnumber);
 525     if ($checkreserves) {
 526         my $item = Koha::Items->find($itemnumber);
 527         if ( $item->holdingbranch ne $checkreserves->{'branchcode'} ) {
 528             $messages->{'transfert'} = $checkreserves->{'branchcode'};
 529             #minus priorities of others reservs
 530             ModReserveMinusPriority(
 531                 $itemnumber,
 532                 $checkreserves->{'reserve_id'},
 533             );
 534
 535             #launch the subroutine dotransfer
 536             C4::Items::ModItemTransfer(
 537                 $itemnumber,
 538                 $item->holdingbranch,
 539                 $checkreserves->{'branchcode'}
 540               ),
 541               ;
 542         }
 543
 544      #step 2b : case of a reservation on the same branch, set the waiting status
 545         else {
 546             $messages->{'waiting'} = 1;
 547             ModReserveMinusPriority(
 548                 $itemnumber,
 549                 $checkreserves->{'reserve_id'},
 550             );
 551             ModReserveStatus($itemnumber,'W');
 552         }
 553
 554         $nextreservinfo = $checkreserves->{'borrowernumber'};
 555     }
 556
 557     return ( $messages, $nextreservinfo );
 558 }
 559
 560 =head2 ChargeReserveFee
 561
 562     $fee = ChargeReserveFee( $borrowernumber, $fee, $title );
 563
 564     Charge the fee for a reserve (if $fee > 0)
 565
 566 =cut
 567
 568 sub ChargeReserveFee {
 569     my ( $borrowernumber, $fee, $title ) = @_;
 570     return if !$fee || $fee == 0;    # the last test is needed to include 0.00
 571     Koha::Account->new( { patron_id => $borrowernumber } )->add_debit(
 572         {
 573             amount       => $fee,
 574             description  => $title,
 575             note         => undef,
 576             user_id      => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
 577             library_id   => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
 578             interface    => C4::Context->interface,
 579             sip          => undef,
 580             invoice_type => undef,
 581             type         => 'reserve',
 582             item_id      => undef
 583         }
 584     );
 585 }
 586
 587 =head2 GetReserveFee
 588
 589     $fee = GetReserveFee( $borrowernumber, $biblionumber );
 590
 591     Calculate the fee for a reserve (if applicable).
 592
 593 =cut
 594
 595 sub GetReserveFee {
 596     my ( $borrowernumber, $biblionumber ) = @_;
 597     my $borquery = qq{
 598 SELECT reservefee FROM borrowers LEFT JOIN categories ON borrowers.categorycode = categories.categorycode WHERE borrowernumber = ?
 599     };
 600     my $issue_qry = qq{
 601 SELECT COUNT(*) FROM items
 602 LEFT JOIN issues USING (itemnumber)
 603 WHERE items.biblionumber=? AND issues.issue_id IS NULL
 604     };
 605     my $holds_qry = qq{
 606 SELECT COUNT(*) FROM reserves WHERE biblionumber=? AND borrowernumber<>?
 607     };
 608
 609     my $dbh = C4::Context->dbh;
 610     my ( $fee ) = $dbh->selectrow_array( $borquery, undef, ($borrowernumber) );
 611     my $hold_fee_mode = C4::Context->preference('HoldFeeMode') || 'not_always';
 612     if( $fee and $fee > 0 and $hold_fee_mode eq 'not_always' ) {
 613         # This is a reconstruction of the old code:
 614         # Compare number of items with items issued, and optionally check holds
 615         # If not all items are issued and there are no holds: charge no fee
 616         # NOTE: Lost, damaged, not-for-loan, etc. are just ignored here
 617         my ( $notissued, $reserved );
 618         ( $notissued ) = $dbh->selectrow_array( $issue_qry, undef,
 619             ( $biblionumber ) );
 620         if( $notissued ) {
 621             ( $reserved ) = $dbh->selectrow_array( $holds_qry, undef,
 622                 ( $biblionumber, $borrowernumber ) );
 623             $fee = 0 if $reserved == 0;
 624         }
 625     }
 626     return $fee;
 627 }
 628
 629 =head2 GetReserveStatus
 630
 631   $reservestatus = GetReserveStatus($itemnumber);
 632
 633 Takes an itemnumber and returns the status of the reserve placed on it.
 634 If several reserves exist, the reserve with the lower priority is given.
 635
 636 =cut
 637
 638 ## FIXME: I don't think this does what it thinks it does.
 639 ## It only ever checks the first reserve result, even though
 640 ## multiple reserves for that bib can have the itemnumber set
 641 ## the sub is only used once in the codebase.
 642 sub GetReserveStatus {
 643     my ($itemnumber) = @_;
 644
 645     my $dbh = C4::Context->dbh;
 646
 647     my ($sth, $found, $priority);
 648     if ( $itemnumber ) {
 649         $sth = $dbh->prepare("SELECT found, priority FROM reserves WHERE itemnumber = ? order by priority LIMIT 1");
 650         $sth->execute($itemnumber);
 651         ($found, $priority) = $sth->fetchrow_array;
 652     }
 653
 654     if(defined $found) {
 655         return 'Waiting'  if $found eq 'W' and $priority == 0;
 656         return 'Finished' if $found eq 'F';
 657     }
 658
 659     return 'Reserved' if $priority > 0;
 660
 661     return ''; # empty string here will remove need for checking undef, or less log lines
 662 }
 663
 664 =head2 CheckReserves
 665
 666   ($status, $reserve, $all_reserves) = &CheckReserves($itemnumber);
 667   ($status, $reserve, $all_reserves) = &CheckReserves(undef, $barcode);
 668   ($status, $reserve, $all_reserves) = &CheckReserves($itemnumber,undef,$lookahead);
 669
 670 Find a book in the reserves.
 671
 672 C<$itemnumber> is the book's item number.
 673 C<$lookahead> is the number of days to look in advance for future reserves.
 674
 675 As I understand it, C<&CheckReserves> looks for the given item in the
 676 reserves. If it is found, that's a match, and C<$status> is set to
 677 C<Waiting>.
 678
 679 Otherwise, it finds the most important item in the reserves with the
 680 same biblio number as this book (I'm not clear on this) and returns it
 681 with C<$status> set to C<Reserved>.
 682
 683 C<&CheckReserves> returns a two-element list:
 684
 685 C<$status> is either C<Waiting>, C<Reserved> (see above), or 0.
 686
 687 C<$reserve> is the reserve item that matched. It is a
 688 reference-to-hash whose keys are mostly the fields of the reserves
 689 table in the Koha database.
 690
 691 =cut
 692
 693 sub CheckReserves {
 694     my ( $item, $barcode, $lookahead_days, $ignore_borrowers) = @_;
 695     my $dbh = C4::Context->dbh;
 696     my $sth;
 697     my $select;
 698     if (C4::Context->preference('item-level_itypes')){
 699         $select = "
 700            SELECT items.biblionumber,
 701            items.biblioitemnumber,
 702            itemtypes.notforloan,
 703            items.notforloan AS itemnotforloan,
 704            items.itemnumber,
 705            items.damaged,
 706            items.homebranch,
 707            items.holdingbranch
 708            FROM   items
 709            LEFT JOIN biblioitems ON items.biblioitemnumber = biblioitems.biblioitemnumber
 710            LEFT JOIN itemtypes   ON items.itype   = itemtypes.itemtype
 711         ";
 712     }
 713     else {
 714         $select = "
 715            SELECT items.biblionumber,
 716            items.biblioitemnumber,
 717            itemtypes.notforloan,
 718            items.notforloan AS itemnotforloan,
 719            items.itemnumber,
 720            items.damaged,
 721            items.homebranch,
 722            items.holdingbranch
 723            FROM   items
 724            LEFT JOIN biblioitems ON items.biblioitemnumber = biblioitems.biblioitemnumber
 725            LEFT JOIN itemtypes   ON biblioitems.itemtype   = itemtypes.itemtype
 726         ";
 727     }
 728
 729     if ($item) {
 730         $sth = $dbh->prepare("$select WHERE itemnumber = ?");
 731         $sth->execute($item);
 732     }
 733     else {
 734         $sth = $dbh->prepare("$select WHERE barcode = ?");
 735         $sth->execute($barcode);
 736     }
 737     # note: we get the itemnumber because we might have started w/ just the barcode.  Now we know for sure we have it.
 738     my ( $biblio, $bibitem, $notforloan_per_itemtype, $notforloan_per_item, $itemnumber, $damaged, $item_homebranch, $item_holdingbranch ) = $sth->fetchrow_array;
 739
 740     return if ( $damaged && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 741
 742     return unless $itemnumber; # bail if we got nothing.
 743
 744     # if item is not for loan it cannot be reserved either.....
 745     # except where items.notforloan < 0 :  This indicates the item is holdable.
 746     return if  ( $notforloan_per_item > 0 ) or $notforloan_per_itemtype;
 747
 748     # Find this item in the reserves
 749     my @reserves = _Findgroupreserve( $bibitem, $biblio, $itemnumber, $lookahead_days, $ignore_borrowers);
 750
 751     # $priority and $highest are used to find the most important item
 752     # in the list returned by &_Findgroupreserve. (The lower $priority,
 753     # the more important the item.)
 754     # $highest is the most important item we've seen so far.
 755     my $highest;
 756     if (scalar @reserves) {
 757         my $LocalHoldsPriority = C4::Context->preference('LocalHoldsPriority');
 758         my $LocalHoldsPriorityPatronControl = C4::Context->preference('LocalHoldsPriorityPatronControl');
 759         my $LocalHoldsPriorityItemControl = C4::Context->preference('LocalHoldsPriorityItemControl');
 760
 761         my $priority = 10000000;
 762         foreach my $res (@reserves) {
 763             if ( $res->{'itemnumber'} == $itemnumber && $res->{'priority'} == 0) {
 764                 if ($res->{'found'} eq 'W') {
 765                     return ( "Waiting", $res, \@reserves ); # Found it, it is waiting
 766                 } else {
 767                     return ( "Reserved", $res, \@reserves ); # Found determinated hold, e. g. the tranferred one
 768                 }
 769             } else {
 770                 my $patron;
 771                 my $item;
 772                 my $local_hold_match;
 773
 774                 if ($LocalHoldsPriority) {
 775                     $patron = Koha::Patrons->find( $res->{borrowernumber} );
 776                     $item = Koha::Items->find($itemnumber);
 777
 778                     my $local_holds_priority_item_branchcode =
 779                       $item->$LocalHoldsPriorityItemControl;
 780                     my $local_holds_priority_patron_branchcode =
 781                       ( $LocalHoldsPriorityPatronControl eq 'PickupLibrary' )
 782                       ? $res->{branchcode}
 783                       : ( $LocalHoldsPriorityPatronControl eq 'HomeLibrary' )
 784                       ? $patron->branchcode
 785                       : undef;
 786                     $local_hold_match =
 787                       $local_holds_priority_item_branchcode eq
 788                       $local_holds_priority_patron_branchcode;
 789                 }
 790
 791                 # See if this item is more important than what we've got so far
 792                 if ( ( $res->{'priority'} && $res->{'priority'} < $priority ) || $local_hold_match ) {
 793                     $item ||= Koha::Items->find($itemnumber);
 794                     next if $res->{itemtype} && $res->{itemtype} ne $item->effective_itemtype;
 795                     $patron ||= Koha::Patrons->find( $res->{borrowernumber} );
 796                     my $branch = GetReservesControlBranch( $item->unblessed, $patron->unblessed );
 797                     my $branchitemrule = C4::Circulation::GetBranchItemRule($branch,$item->effective_itemtype);
 798                     next if ($branchitemrule->{'holdallowed'} == 0);
 799                     next if (($branchitemrule->{'holdallowed'} == 1) && ($branch ne $patron->branchcode));
 800                     my $hold_fulfillment_policy = $branchitemrule->{hold_fulfillment_policy};
 801                     next if ( ($branchitemrule->{hold_fulfillment_policy} ne 'any') && ($res->{branchcode} ne $item->$hold_fulfillment_policy) );
 802                     next unless $item->can_be_transferred( { to => scalar Koha::Libraries->find( $res->{branchcode} ) } );
 803                     $priority = $res->{'priority'};
 804                     $highest  = $res;
 805                     last if $local_hold_match;
 806                 }
 807             }
 808         }
 809     }
 810
 811     # If we get this far, then no exact match was found.
 812     # We return the most important (i.e. next) reservation.
 813     if ($highest) {
 814         $highest->{'itemnumber'} = $item;
 815         return ( "Reserved", $highest, \@reserves );
 816     }
 817
 818     return ( '' );
 819 }
 820
 821 =head2 CancelExpiredReserves
 822
 823   CancelExpiredReserves();
 824
 825 Cancels all reserves with an expiration date from before today.
 826
 827 =cut
 828
 829 sub CancelExpiredReserves {
 830     my $today = dt_from_string();
 831     my $cancel_on_holidays = C4::Context->preference('ExpireReservesOnHolidays');
 832     my $expireWaiting = C4::Context->preference('ExpireReservesMaxPickUpDelay');
 833
 834     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 835     my $params = { expirationdate => { '<', $dtf->format_date($today) } };
 836     $params->{found} = undef unless $expireWaiting;
 837
 838     # FIXME To move to Koha::Holds->search_expired (?)
 839     my $holds = Koha::Holds->search( $params );
 840
 841     while ( my $hold = $holds->next ) {
 842         my $calendar = Koha::Calendar->new( branchcode => $hold->branchcode );
 843
 844         next if !$cancel_on_holidays && $calendar->is_holiday( $today );
 845
 846         my $cancel_params = {};
 847         if ( $hold->found eq 'W' ) {
 848             $cancel_params->{charge_cancel_fee} = 1;
 849         }
 850         $hold->cancel( $cancel_params );
 851     }
 852 }
 853
 854 =head2 AutoUnsuspendReserves
 855
 856   AutoUnsuspendReserves();
 857
 858 Unsuspends all suspended reserves with a suspend_until date from before today.
 859
 860 =cut
 861
 862 sub AutoUnsuspendReserves {
 863     my $today = dt_from_string();
 864
 865     my @holds = Koha::Holds->search( { suspend_until => { '<=' => $today->ymd() } } );
 866
 867     map { $_->resume() } @holds;
 868 }
 869
 870 =head2 ModReserve
 871
 872   ModReserve({ rank => $rank,
 873                reserve_id => $reserve_id,
 874                branchcode => $branchcode
 875                [, itemnumber => $itemnumber ]
 876                [, biblionumber => $biblionumber, $borrowernumber => $borrowernumber ]
 877               });
 878
 879 Change a hold request's priority or cancel it.
 880
 881 C<$rank> specifies the effect of the change.  If C<$rank>
 882 is 'W' or 'n', nothing happens.  This corresponds to leaving a
 883 request alone when changing its priority in the holds queue
 884 for a bib.
 885
 886 If C<$rank> is 'del', the hold request is cancelled.
 887
 888 If C<$rank> is an integer greater than zero, the priority of
 889 the request is set to that value.  Since priority != 0 means
 890 that the item is not waiting on the hold shelf, setting the
 891 priority to a non-zero value also sets the request's found
 892 status and waiting date to NULL.
 893
 894 The optional C<$itemnumber> parameter is used only when
 895 C<$rank> is a non-zero integer; if supplied, the itemnumber
 896 of the hold request is set accordingly; if omitted, the itemnumber
 897 is cleared.
 898
 899 B<FIXME:> Note that the forgoing can have the effect of causing
 900 item-level hold requests to turn into title-level requests.  This
 901 will be fixed once reserves has separate columns for requested
 902 itemnumber and supplying itemnumber.
 903
 904 =cut
 905
 906 sub ModReserve {
 907     my ( $params ) = @_;
 908
 909     my $rank = $params->{'rank'};
 910     my $reserve_id = $params->{'reserve_id'};
 911     my $branchcode = $params->{'branchcode'};
 912     my $itemnumber = $params->{'itemnumber'};
 913     my $suspend_until = $params->{'suspend_until'};
 914     my $borrowernumber = $params->{'borrowernumber'};
 915     my $biblionumber = $params->{'biblionumber'};
 916
 917     return if $rank eq "W";
 918     return if $rank eq "n";
 919
 920     return unless ( $reserve_id || ( $borrowernumber && ( $biblionumber || $itemnumber ) ) );
 921
 922     my $hold;
 923     unless ( $reserve_id ) {
 924         my $holds = Koha::Holds->search({ biblionumber => $biblionumber, borrowernumber => $borrowernumber, itemnumber => $itemnumber });
 925         return unless $holds->count; # FIXME Should raise an exception
 926         $hold = $holds->next;
 927         $reserve_id = $hold->reserve_id;
 928     }
 929
 930     $hold ||= Koha::Holds->find($reserve_id);
 931
 932     if ( $rank eq "del" ) {
 933         $hold->cancel;
 934     }
 935     elsif ($rank =~ /^\d+/ and $rank > 0) {
 936         logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, Dumper($hold->unblessed) )
 937             if C4::Context->preference('HoldsLog');
 938
 939         $hold->set(
 940             {
 941                 priority    => $rank,
 942                 branchcode  => $branchcode,
 943                 itemnumber  => $itemnumber,
 944                 found       => undef,
 945                 waitingdate => undef
 946             }
 947         )->store();
 948
 949         if ( defined( $suspend_until ) ) {
 950             if ( $suspend_until ) {
 951                 $suspend_until = eval { dt_from_string( $suspend_until ) };
 952                 $hold->suspend_hold( $suspend_until );
 953             } else {
 954                 # If the hold is suspended leave the hold suspended, but convert it to an indefinite hold.
 955                 # If the hold is not suspended, this does nothing.
 956                 $hold->set( { suspend_until => undef } )->store();
 957             }
 958         }
 959
 960         _FixPriority({ reserve_id => $reserve_id, rank =>$rank });
 961     }
 962 }
 963
 964 =head2 ModReserveFill
 965
 966   &ModReserveFill($reserve);
 967
 968 Fill a reserve. If I understand this correctly, this means that the
 969 reserved book has been found and given to the patron who reserved it.
 970
 971 C<$reserve> specifies the reserve to fill. It is a reference-to-hash
 972 whose keys are fields from the reserves table in the Koha database.
 973
 974 =cut
 975
 976 sub ModReserveFill {
 977     my ($res) = @_;
 978     my $reserve_id = $res->{'reserve_id'};
 979
 980     my $hold = Koha::Holds->find($reserve_id);
 981
 982     # get the priority on this record....
 983     my $priority = $hold->priority;
 984
 985     # update the hold statuses, no need to store it though, we will be deleting it anyway
 986     $hold->set(
 987         {
 988             found    => 'F',
 989             priority => 0,
 990         }
 991     );
 992
 993     # FIXME Must call Koha::Hold->cancel ? => No, should call ->filled and add the correct log
 994     Koha::Old::Hold->new( $hold->unblessed() )->store();
 995
 996     $hold->delete();
 997
 998     if ( C4::Context->preference('HoldFeeMode') eq 'any_time_is_collected' ) {
 999         my $reserve_fee = GetReserveFee( $hold->borrowernumber, $hold->biblionumber );
1000         ChargeReserveFee( $hold->borrowernumber, $reserve_fee, $hold->biblio->title );
1001     }
1002
1003     # now fix the priority on the others (if the priority wasn't
1004     # already sorted!)....
1005     unless ( $priority == 0 ) {
1006         _FixPriority( { reserve_id => $reserve_id, biblionumber => $hold->biblionumber } );
1007     }
1008 }
1009
1010 =head2 ModReserveStatus
1011
1012   &ModReserveStatus($itemnumber, $newstatus);
1013
1014 Update the reserve status for the active (priority=0) reserve.
1015
1016 $itemnumber is the itemnumber the reserve is on
1017
1018 $newstatus is the new status.
1019
1020 =cut
1021
1022 sub ModReserveStatus {
1023
1024     #first : check if we have a reservation for this item .
1025     my ($itemnumber, $newstatus) = @_;
1026     my $dbh = C4::Context->dbh;
1027
1028     my $query = "UPDATE reserves SET found = ?, waitingdate = NOW() WHERE itemnumber = ? AND found IS NULL AND priority = 0";
1029     my $sth_set = $dbh->prepare($query);
1030     $sth_set->execute( $newstatus, $itemnumber );
1031
1032     my $item = Koha::Items->find($itemnumber);
1033     if ( ( $item->location eq 'CART' && $item->permanent_location ne 'CART'  ) && $newstatus ) {
1034       CartToShelf( $itemnumber );
1035     }
1036 }
1037
1038 =head2 ModReserveAffect
1039
1040   &ModReserveAffect($itemnumber,$borrowernumber,$diffBranchSend,$reserve_id);
1041
1042 This function affect an item and a status for a given reserve, either fetched directly
1043 by record_id, or by borrowernumber and itemnumber or biblionumber. If only biblionumber
1044 is given, only first reserve returned is affected, which is ok for anything but
1045 multi-item holds.
1046
1047 if $transferToDo is not set, then the status is set to "Waiting" as well.
1048 otherwise, a transfer is on the way, and the end of the transfer will
1049 take care of the waiting status
1050
1051 =cut
1052
1053 sub ModReserveAffect {
1054     my ( $itemnumber, $borrowernumber, $transferToDo, $reserve_id ) = @_;
1055     my $dbh = C4::Context->dbh;
1056
1057     # we want to attach $itemnumber to $borrowernumber, find the biblionumber
1058     # attached to $itemnumber
1059     my $sth = $dbh->prepare("SELECT biblionumber FROM items WHERE itemnumber=?");
1060     $sth->execute($itemnumber);
1061     my ($biblionumber) = $sth->fetchrow;
1062
1063     # get request - need to find out if item is already
1064     # waiting in order to not send duplicate hold filled notifications
1065
1066     my $hold;
1067     # Find hold by id if we have it
1068     $hold = Koha::Holds->find( $reserve_id ) if $reserve_id;
1069     # Find item level hold for this item if there is one
1070     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, itemnumber => $itemnumber } )->next();
1071     # Find record level hold if there is no item level hold
1072     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, biblionumber => $biblionumber } )->next();
1073
1074     return unless $hold;
1075
1076     my $already_on_shelf = $hold->found && $hold->found eq 'W';
1077
1078     $hold->itemnumber($itemnumber);
1079     $hold->set_waiting($transferToDo);
1080
1081     _koha_notify_reserve( $hold->reserve_id )
1082       if ( !$transferToDo && !$already_on_shelf );
1083
1084     _FixPriority( { biblionumber => $biblionumber } );
1085     my $item = Koha::Items->find($itemnumber);
1086     if ( ( $item->location eq 'CART' && $item->permanent_location ne 'CART'  ) ) {
1087       CartToShelf( $itemnumber );
1088     }
1089
1090     return;
1091 }
1092
1093 =head2 ModReserveCancelAll
1094
1095   ($messages,$nextreservinfo) = &ModReserveCancelAll($itemnumber,$borrowernumber);
1096
1097 function to cancel reserv,check other reserves, and transfer document if it's necessary
1098
1099 =cut
1100
1101 sub ModReserveCancelAll {
1102     my $messages;
1103     my $nextreservinfo;
1104     my ( $itemnumber, $borrowernumber ) = @_;
1105
1106     #step 1 : cancel the reservation
1107     my $holds = Koha::Holds->search({ itemnumber => $itemnumber, borrowernumber => $borrowernumber });
1108     return unless $holds->count;
1109     $holds->next->cancel;
1110
1111     #step 2 launch the subroutine of the others reserves
1112     ( $messages, $nextreservinfo ) = GetOtherReserves($itemnumber);
1113
1114     return ( $messages, $nextreservinfo );
1115 }
1116
1117 =head2 ModReserveMinusPriority
1118
1119   &ModReserveMinusPriority($itemnumber,$borrowernumber,$biblionumber)
1120
1121 Reduce the values of queued list
1122
1123 =cut
1124
1125 sub ModReserveMinusPriority {
1126     my ( $itemnumber, $reserve_id ) = @_;
1127
1128     #first step update the value of the first person on reserv
1129     my $dbh   = C4::Context->dbh;
1130     my $query = "
1131         UPDATE reserves
1132         SET    priority = 0 , itemnumber = ?
1133         WHERE  reserve_id = ?
1134     ";
1135     my $sth_upd = $dbh->prepare($query);
1136     $sth_upd->execute( $itemnumber, $reserve_id );
1137     # second step update all others reserves
1138     _FixPriority({ reserve_id => $reserve_id, rank => '0' });
1139 }
1140
1141 =head2 IsAvailableForItemLevelRequest
1142
1143   my $is_available = IsAvailableForItemLevelRequest( $item_record, $borrower_record, $pickup_branchcode );
1144
1145 Checks whether a given item record is available for an
1146 item-level hold request.  An item is available if
1147
1148 * it is not lost AND
1149 * it is not damaged AND
1150 * it is not withdrawn AND
1151 * a waiting or in transit reserve is placed on
1152 * does not have a not for loan value > 0
1153
1154 Need to check the issuingrules onshelfholds column,
1155 if this is set items on the shelf can be placed on hold
1156
1157 Note that IsAvailableForItemLevelRequest() does not
1158 check if the staff operator is authorized to place
1159 a request on the item - in particular,
1160 this routine does not check IndependentBranches
1161 and canreservefromotherbranches.
1162
1163 =cut
1164
1165 sub IsAvailableForItemLevelRequest {
1166     my ( $item, $patron, $pickup_branchcode ) = @_;
1167
1168     my $dbh = C4::Context->dbh;
1169     # must check the notforloan setting of the itemtype
1170     # FIXME - a lot of places in the code do this
1171     #         or something similar - need to be
1172     #         consolidated
1173     my $itemtype = $item->effective_itemtype;
1174     my $notforloan_per_itemtype = Koha::ItemTypes->find($itemtype)->notforloan;
1175
1176     return 0 if
1177         $notforloan_per_itemtype ||
1178         $item->itemlost        ||
1179         $item->notforloan > 0  ||
1180         $item->withdrawn        ||
1181         ($item->damaged && !C4::Context->preference('AllowHoldsOnDamagedItems'));
1182
1183     my $on_shelf_holds = Koha::IssuingRules->get_onshelfholds_policy( { item => $item, patron => $patron } );
1184
1185     if ($pickup_branchcode) {
1186         my $destination = Koha::Libraries->find($pickup_branchcode);
1187         return 0 unless $destination;
1188         return 0 unless $destination->pickup_location;
1189         return 0 unless $item->can_be_transferred( { to => $destination } );
1190     }
1191
1192     if ( $on_shelf_holds == 1 ) {
1193         return 1;
1194     } elsif ( $on_shelf_holds == 2 ) {
1195         my @items =
1196           Koha::Items->search( { biblionumber => $item->biblionumber } );
1197
1198         my $any_available = 0;
1199
1200         foreach my $i (@items) {
1201             my $reserves_control_branch = GetReservesControlBranch( $i->unblessed(), $patron->unblessed );
1202             my $branchitemrule = C4::Circulation::GetBranchItemRule( $reserves_control_branch, $i->itype );
1203
1204             $any_available = 1
1205               unless $i->itemlost
1206               || $i->notforloan > 0
1207               || $i->withdrawn
1208               || $i->onloan
1209               || IsItemOnHoldAndFound( $i->id )
1210               || ( $i->damaged
1211                 && !C4::Context->preference('AllowHoldsOnDamagedItems') )
1212               || Koha::ItemTypes->find( $i->effective_itemtype() )->notforloan
1213               || $branchitemrule->{holdallowed} == 1 && $patron->branchcode ne $i->homebranch;
1214         }
1215
1216         return $any_available ? 0 : 1;
1217     } else { # on_shelf_holds == 0 "If any unavailable" (the description is rather cryptic and could still be improved)
1218         return $item->onloan || IsItemOnHoldAndFound( $item->itemnumber );
1219     }
1220 }
1221
1222 sub _get_itype {
1223     my $item = shift;
1224
1225     my $itype;
1226     if (C4::Context->preference('item-level_itypes')) {
1227         # We can't trust GetItem to honour the syspref, so safest to do it ourselves
1228         # When GetItem is fixed, we can remove this
1229         $itype = $item->{itype};
1230     }
1231     else {
1232         # XXX This is a bit dodgy. It relies on biblio itemtype column having different name.
1233         # So if we already have a biblioitems join when calling this function,
1234         # we don't need to access the database again
1235         $itype = $item->{itemtype};
1236     }
1237     unless ($itype) {
1238         my $dbh = C4::Context->dbh;
1239         my $query = "SELECT itemtype FROM biblioitems WHERE biblioitemnumber = ? ";
1240         my $sth = $dbh->prepare($query);
1241         $sth->execute($item->{biblioitemnumber});
1242         if (my $data = $sth->fetchrow_hashref()){
1243             $itype = $data->{itemtype};
1244         }
1245     }
1246     return $itype;
1247 }
1248
1249 =head2 AlterPriority
1250
1251   AlterPriority( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority );
1252
1253 This function changes a reserve's priority up, down, to the top, or to the bottom.
1254 Input: $where is 'up', 'down', 'top' or 'bottom'. Biblionumber, Date reserve was placed
1255
1256 =cut
1257
1258 sub AlterPriority {
1259     my ( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority ) = @_;
1260
1261     my $hold = Koha::Holds->find( $reserve_id );
1262     return unless $hold;
1263
1264     if ( $hold->cancellationdate ) {
1265         warn "I cannot alter the priority for reserve_id $reserve_id, the reserve has been cancelled (" . $hold->cancellationdate . ')';
1266         return;
1267     }
1268
1269     if ( $where eq 'up' ) {
1270       return unless $prev_priority;
1271       _FixPriority({ reserve_id => $reserve_id, rank => $prev_priority })
1272     } elsif ( $where eq 'down' ) {
1273       return unless $next_priority;
1274       _FixPriority({ reserve_id => $reserve_id, rank => $next_priority })
1275     } elsif ( $where eq 'top' ) {
1276       _FixPriority({ reserve_id => $reserve_id, rank => $first_priority })
1277     } elsif ( $where eq 'bottom' ) {
1278       _FixPriority({ reserve_id => $reserve_id, rank => $last_priority });
1279     }
1280
1281     # FIXME Should return the new priority
1282 }
1283
1284 =head2 ToggleLowestPriority
1285
1286   ToggleLowestPriority( $borrowernumber, $biblionumber );
1287
1288 This function sets the lowestPriority field to true if is false, and false if it is true.
1289
1290 =cut
1291
1292 sub ToggleLowestPriority {
1293     my ( $reserve_id ) = @_;
1294
1295     my $dbh = C4::Context->dbh;
1296
1297     my $sth = $dbh->prepare( "UPDATE reserves SET lowestPriority = NOT lowestPriority WHERE reserve_id = ?");
1298     $sth->execute( $reserve_id );
1299
1300     _FixPriority({ reserve_id => $reserve_id, rank => '999999' });
1301 }
1302
1303 =head2 ToggleSuspend
1304
1305   ToggleSuspend( $reserve_id );
1306
1307 This function sets the suspend field to true if is false, and false if it is true.
1308 If the reserve is currently suspended with a suspend_until date, that date will
1309 be cleared when it is unsuspended.
1310
1311 =cut
1312
1313 sub ToggleSuspend {
1314     my ( $reserve_id, $suspend_until ) = @_;
1315
1316     $suspend_until = dt_from_string($suspend_until) if ($suspend_until);
1317
1318     my $hold = Koha::Holds->find( $reserve_id );
1319
1320     if ( $hold->is_suspended ) {
1321         $hold->resume()
1322     } else {
1323         $hold->suspend_hold( $suspend_until );
1324     }
1325 }
1326
1327 =head2 SuspendAll
1328
1329   SuspendAll(
1330       borrowernumber   => $borrowernumber,
1331       [ biblionumber   => $biblionumber, ]
1332       [ suspend_until  => $suspend_until, ]
1333       [ suspend        => $suspend ]
1334   );
1335
1336   This function accepts a set of hash keys as its parameters.
1337   It requires either borrowernumber or biblionumber, or both.
1338
1339   suspend_until is wholly optional.
1340
1341 =cut
1342
1343 sub SuspendAll {
1344     my %params = @_;
1345
1346     my $borrowernumber = $params{'borrowernumber'} || undef;
1347     my $biblionumber   = $params{'biblionumber'}   || undef;
1348     my $suspend_until  = $params{'suspend_until'}  || undef;
1349     my $suspend = defined( $params{'suspend'} ) ? $params{'suspend'} : 1;
1350
1351     $suspend_until = eval { dt_from_string($suspend_until) }
1352       if ( defined($suspend_until) );
1353
1354     return unless ( $borrowernumber || $biblionumber );
1355
1356     my $params;
1357     $params->{found}          = undef;
1358     $params->{borrowernumber} = $borrowernumber if $borrowernumber;
1359     $params->{biblionumber}   = $biblionumber if $biblionumber;
1360
1361     my @holds = Koha::Holds->search($params);
1362
1363     if ($suspend) {
1364         map { $_->suspend_hold($suspend_until) } @holds;
1365     }
1366     else {
1367         map { $_->resume() } @holds;
1368     }
1369 }
1370
1371
1372 =head2 _FixPriority
1373
1374   _FixPriority({
1375     reserve_id => $reserve_id,
1376     [rank => $rank,]
1377     [ignoreSetLowestRank => $ignoreSetLowestRank]
1378   });
1379
1380   or
1381
1382   _FixPriority({ biblionumber => $biblionumber});
1383
1384 This routine adjusts the priority of a hold request and holds
1385 on the same bib.
1386
1387 In the first form, where a reserve_id is passed, the priority of the
1388 hold is set to supplied rank, and other holds for that bib are adjusted
1389 accordingly.  If the rank is "del", the hold is cancelled.  If no rank
1390 is supplied, all of the holds on that bib have their priority adjusted
1391 as if the second form had been used.
1392
1393 In the second form, where a biblionumber is passed, the holds on that
1394 bib (that are not captured) are sorted in order of increasing priority,
1395 then have reserves.priority set so that the first non-captured hold
1396 has its priority set to 1, the second non-captured hold has its priority
1397 set to 2, and so forth.
1398
1399 In both cases, holds that have the lowestPriority flag on are have their
1400 priority adjusted to ensure that they remain at the end of the line.
1401
1402 Note that the ignoreSetLowestRank parameter is meant to be used only
1403 when _FixPriority calls itself.
1404
1405 =cut
1406
1407 sub _FixPriority {
1408     my ( $params ) = @_;
1409     my $reserve_id = $params->{reserve_id};
1410     my $rank = $params->{rank} // '';
1411     my $ignoreSetLowestRank = $params->{ignoreSetLowestRank};
1412     my $biblionumber = $params->{biblionumber};
1413
1414     my $dbh = C4::Context->dbh;
1415
1416     my $hold;
1417     if ( $reserve_id ) {
1418         $hold = Koha::Holds->find( $reserve_id );
1419         return unless $hold;
1420     }
1421
1422     unless ( $biblionumber ) { # FIXME This is a very weird API
1423         $biblionumber = $hold->biblionumber;
1424     }
1425
1426     if ( $rank eq "del" ) { # FIXME will crash if called without $hold
1427         $hold->cancel;
1428     }
1429     elsif ( $rank eq "W" || $rank eq "0" ) {
1430
1431         # make sure priority for waiting or in-transit items is 0
1432         my $query = "
1433             UPDATE reserves
1434             SET    priority = 0
1435             WHERE reserve_id = ?
1436             AND found IN ('W', 'T')
1437         ";
1438         my $sth = $dbh->prepare($query);
1439         $sth->execute( $reserve_id );
1440     }
1441     my @priority;
1442
1443     # get whats left
1444     my $query = "
1445         SELECT reserve_id, borrowernumber, reservedate
1446         FROM   reserves
1447         WHERE  biblionumber   = ?
1448           AND  ((found <> 'W' AND found <> 'T') OR found IS NULL)
1449         ORDER BY priority ASC
1450     ";
1451     my $sth = $dbh->prepare($query);
1452     $sth->execute( $biblionumber );
1453     while ( my $line = $sth->fetchrow_hashref ) {
1454         push( @priority,     $line );
1455     }
1456
1457     # To find the matching index
1458     my $i;
1459     my $key = -1;    # to allow for 0 to be a valid result
1460     for ( $i = 0 ; $i < @priority ; $i++ ) {
1461         if ( $reserve_id == $priority[$i]->{'reserve_id'} ) {
1462             $key = $i;    # save the index
1463             last;
1464         }
1465     }
1466
1467     # if index exists in array then move it to new position
1468     if ( $key > -1 && $rank ne 'del' && $rank > 0 ) {
1469         my $new_rank = $rank -
1470           1;    # $new_rank is what you want the new index to be in the array
1471         my $moving_item = splice( @priority, $key, 1 );
1472         splice( @priority, $new_rank, 0, $moving_item );
1473     }
1474
1475     # now fix the priority on those that are left....
1476     $query = "
1477         UPDATE reserves
1478         SET    priority = ?
1479         WHERE  reserve_id = ?
1480     ";
1481     $sth = $dbh->prepare($query);
1482     for ( my $j = 0 ; $j < @priority ; $j++ ) {
1483         $sth->execute(
1484             $j + 1,
1485             $priority[$j]->{'reserve_id'}
1486         );
1487     }
1488
1489     $sth = $dbh->prepare( "SELECT reserve_id FROM reserves WHERE lowestPriority = 1 ORDER BY priority" );
1490     $sth->execute();
1491
1492     unless ( $ignoreSetLowestRank ) {
1493       while ( my $res = $sth->fetchrow_hashref() ) {
1494         _FixPriority({
1495             reserve_id => $res->{'reserve_id'},
1496             rank => '999999',
1497             ignoreSetLowestRank => 1
1498         });
1499       }
1500     }
1501 }
1502
1503 =head2 _Findgroupreserve
1504
1505   @results = &_Findgroupreserve($biblioitemnumber, $biblionumber, $itemnumber, $lookahead, $ignore_borrowers);
1506
1507 Looks for a holds-queue based item-specific match first, then for a holds-queue title-level match, returning the
1508 first match found.  If neither, then we look for non-holds-queue based holds.
1509 Lookahead is the number of days to look in advance.
1510
1511 C<&_Findgroupreserve> returns :
1512 C<@results> is an array of references-to-hash whose keys are mostly
1513 fields from the reserves table of the Koha database, plus
1514 C<biblioitemnumber>.
1515
1516 =cut
1517
1518 sub _Findgroupreserve {
1519     my ( $bibitem, $biblio, $itemnumber, $lookahead, $ignore_borrowers) = @_;
1520     my $dbh   = C4::Context->dbh;
1521
1522     # TODO: consolidate at least the SELECT portion of the first 2 queries to a common $select var.
1523     # check for exact targeted match
1524     my $item_level_target_query = qq{
1525         SELECT reserves.biblionumber        AS biblionumber,
1526                reserves.borrowernumber      AS borrowernumber,
1527                reserves.reservedate         AS reservedate,
1528                reserves.branchcode          AS branchcode,
1529                reserves.cancellationdate    AS cancellationdate,
1530                reserves.found               AS found,
1531                reserves.reservenotes        AS reservenotes,
1532                reserves.priority            AS priority,
1533                reserves.timestamp           AS timestamp,
1534                biblioitems.biblioitemnumber AS biblioitemnumber,
1535                reserves.itemnumber          AS itemnumber,
1536                reserves.reserve_id          AS reserve_id,
1537                reserves.itemtype            AS itemtype
1538         FROM reserves
1539         JOIN biblioitems USING (biblionumber)
1540         JOIN hold_fill_targets USING (biblionumber, borrowernumber, itemnumber)
1541         WHERE found IS NULL
1542         AND priority > 0
1543         AND item_level_request = 1
1544         AND itemnumber = ?
1545         AND reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1546         AND suspend = 0
1547         ORDER BY priority
1548     };
1549     my $sth = $dbh->prepare($item_level_target_query);
1550     $sth->execute($itemnumber, $lookahead||0);
1551     my @results;
1552     if ( my $data = $sth->fetchrow_hashref ) {
1553         push( @results, $data )
1554           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1555     }
1556     return @results if @results;
1557
1558     # check for title-level targeted match
1559     my $title_level_target_query = qq{
1560         SELECT reserves.biblionumber        AS biblionumber,
1561                reserves.borrowernumber      AS borrowernumber,
1562                reserves.reservedate         AS reservedate,
1563                reserves.branchcode          AS branchcode,
1564                reserves.cancellationdate    AS cancellationdate,
1565                reserves.found               AS found,
1566                reserves.reservenotes        AS reservenotes,
1567                reserves.priority            AS priority,
1568                reserves.timestamp           AS timestamp,
1569                biblioitems.biblioitemnumber AS biblioitemnumber,
1570                reserves.itemnumber          AS itemnumber,
1571                reserves.reserve_id          AS reserve_id,
1572                reserves.itemtype            AS itemtype
1573         FROM reserves
1574         JOIN biblioitems USING (biblionumber)
1575         JOIN hold_fill_targets USING (biblionumber, borrowernumber)
1576         WHERE found IS NULL
1577         AND priority > 0
1578         AND item_level_request = 0
1579         AND hold_fill_targets.itemnumber = ?
1580         AND reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1581         AND suspend = 0
1582         ORDER BY priority
1583     };
1584     $sth = $dbh->prepare($title_level_target_query);
1585     $sth->execute($itemnumber, $lookahead||0);
1586     @results = ();
1587     if ( my $data = $sth->fetchrow_hashref ) {
1588         push( @results, $data )
1589           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1590     }
1591     return @results if @results;
1592
1593     my $query = qq{
1594         SELECT reserves.biblionumber               AS biblionumber,
1595                reserves.borrowernumber             AS borrowernumber,
1596                reserves.reservedate                AS reservedate,
1597                reserves.waitingdate                AS waitingdate,
1598                reserves.branchcode                 AS branchcode,
1599                reserves.cancellationdate           AS cancellationdate,
1600                reserves.found                      AS found,
1601                reserves.reservenotes               AS reservenotes,
1602                reserves.priority                   AS priority,
1603                reserves.timestamp                  AS timestamp,
1604                reserves.itemnumber                 AS itemnumber,
1605                reserves.reserve_id                 AS reserve_id,
1606                reserves.itemtype                   AS itemtype
1607         FROM reserves
1608         WHERE reserves.biblionumber = ?
1609           AND (reserves.itemnumber IS NULL OR reserves.itemnumber = ?)
1610           AND reserves.reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1611           AND suspend = 0
1612           ORDER BY priority
1613     };
1614     $sth = $dbh->prepare($query);
1615     $sth->execute( $biblio, $itemnumber, $lookahead||0);
1616     @results = ();
1617     while ( my $data = $sth->fetchrow_hashref ) {
1618         push( @results, $data )
1619           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1620     }
1621     return @results;
1622 }
1623
1624 =head2 _koha_notify_reserve
1625
1626   _koha_notify_reserve( $hold->reserve_id );
1627
1628 Sends a notification to the patron that their hold has been filled (through
1629 ModReserveAffect, _not_ ModReserveFill)
1630
1631 The letter code for this notice may be found using the following query:
1632
1633     select distinct letter_code
1634     from message_transports
1635     inner join message_attributes using (message_attribute_id)
1636     where message_name = 'Hold_Filled'
1637
1638 This will probably sipmly be 'HOLD', but because it is defined in the database,
1639 it is subject to addition or change.
1640
1641 The following tables are availalbe witin the notice:
1642
1643     branches
1644     borrowers
1645     biblio
1646     biblioitems
1647     reserves
1648     items
1649
1650 =cut
1651
1652 sub _koha_notify_reserve {
1653     my $reserve_id = shift;
1654     my $hold = Koha::Holds->find($reserve_id);
1655     my $borrowernumber = $hold->borrowernumber;
1656
1657     my $patron = Koha::Patrons->find( $borrowernumber );
1658
1659     # Try to get the borrower's email address
1660     my $to_address = $patron->notice_email_address;
1661
1662     my $messagingprefs = C4::Members::Messaging::GetMessagingPreferences( {
1663             borrowernumber => $borrowernumber,
1664             message_name => 'Hold_Filled'
1665     } );
1666
1667     my $library = Koha::Libraries->find( $hold->branchcode )->unblessed;
1668
1669     my $admin_email_address = $library->{branchemail} || C4::Context->preference('KohaAdminEmailAddress');
1670
1671     my %letter_params = (
1672         module => 'reserves',
1673         branchcode => $hold->branchcode,
1674         lang => $patron->lang,
1675         tables => {
1676             'branches'       => $library,
1677             'borrowers'      => $patron->unblessed,
1678             'biblio'         => $hold->biblionumber,
1679             'biblioitems'    => $hold->biblionumber,
1680             'reserves'       => $hold->unblessed,
1681             'items'          => $hold->itemnumber,
1682         },
1683     );
1684
1685     my $notification_sent = 0; #Keeping track if a Hold_filled message is sent. If no message can be sent, then default to a print message.
1686     my $send_notification = sub {
1687         my ( $mtt, $letter_code ) = (@_);
1688         return unless defined $letter_code;
1689         $letter_params{letter_code} = $letter_code;
1690         $letter_params{message_transport_type} = $mtt;
1691         my $letter =  C4::Letters::GetPreparedLetter ( %letter_params );
1692         unless ($letter) {
1693             warn "Could not find a letter called '$letter_params{'letter_code'}' for $mtt in the 'reserves' module";
1694             return;
1695         }
1696
1697         C4::Letters::EnqueueLetter( {
1698             letter => $letter,
1699             borrowernumber => $borrowernumber,
1700             from_address => $admin_email_address,
1701             message_transport_type => $mtt,
1702         } );
1703     };
1704
1705     while ( my ( $mtt, $letter_code ) = each %{ $messagingprefs->{transports} } ) {
1706         next if (
1707                ( $mtt eq 'email' and not $to_address ) # No email address
1708             or ( $mtt eq 'sms'   and not $patron->smsalertnumber ) # No SMS number
1709             or ( $mtt eq 'phone' and C4::Context->preference('TalkingTechItivaPhoneNotification') ) # Notice is handled by TalkingTech_itiva_outbound.pl
1710         );
1711
1712         &$send_notification($mtt, $letter_code);
1713         $notification_sent++;
1714     }
1715     #Making sure that a print notification is sent if no other transport types can be utilized.
1716     if (! $notification_sent) {
1717         &$send_notification('print', 'HOLD');
1718     }
1719
1720 }
1721
1722 =head2 _ShiftPriorityByDateAndPriority
1723
1724   $new_priority = _ShiftPriorityByDateAndPriority( $biblionumber, $reservedate, $priority );
1725
1726 This increments the priority of all reserves after the one
1727 with either the lowest date after C<$reservedate>
1728 or the lowest priority after C<$priority>.
1729
1730 It effectively makes room for a new reserve to be inserted with a certain
1731 priority, which is returned.
1732
1733 This is most useful when the reservedate can be set by the user.  It allows
1734 the new reserve to be placed before other reserves that have a later
1735 reservedate.  Since priority also is set by the form in reserves/request.pl
1736 the sub accounts for that too.
1737
1738 =cut
1739
1740 sub _ShiftPriorityByDateAndPriority {
1741     my ( $biblio, $resdate, $new_priority ) = @_;
1742
1743     my $dbh = C4::Context->dbh;
1744     my $query = "SELECT priority FROM reserves WHERE biblionumber = ? AND ( reservedate > ? OR priority > ? ) ORDER BY priority ASC LIMIT 1";
1745     my $sth = $dbh->prepare( $query );
1746     $sth->execute( $biblio, $resdate, $new_priority );
1747     my $min_priority = $sth->fetchrow;
1748     # if no such matches are found, $new_priority remains as original value
1749     $new_priority = $min_priority if ( $min_priority );
1750
1751     # Shift the priority up by one; works in conjunction with the next SQL statement
1752     $query = "UPDATE reserves
1753               SET priority = priority+1
1754               WHERE biblionumber = ?
1755               AND borrowernumber = ?
1756               AND reservedate = ?
1757               AND found IS NULL";
1758     my $sth_update = $dbh->prepare( $query );
1759
1760     # Select all reserves for the biblio with priority greater than $new_priority, and order greatest to least
1761     $query = "SELECT borrowernumber, reservedate FROM reserves WHERE priority >= ? AND biblionumber = ? ORDER BY priority DESC";
1762     $sth = $dbh->prepare( $query );
1763     $sth->execute( $new_priority, $biblio );
1764     while ( my $row = $sth->fetchrow_hashref ) {
1765         $sth_update->execute( $biblio, $row->{borrowernumber}, $row->{reservedate} );
1766     }
1767
1768     return $new_priority;  # so the caller knows what priority they wind up receiving
1769 }
1770
1771 =head2 MoveReserve
1772
1773   MoveReserve( $itemnumber, $borrowernumber, $cancelreserve )
1774
1775 Use when checking out an item to handle reserves
1776 If $cancelreserve boolean is set to true, it will remove existing reserve
1777
1778 =cut
1779
1780 sub MoveReserve {
1781     my ( $itemnumber, $borrowernumber, $cancelreserve ) = @_;
1782
1783     my $lookahead = C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
1784     my ( $restype, $res, $all_reserves ) = CheckReserves( $itemnumber, undef, $lookahead );
1785     return unless $res;
1786
1787     my $biblionumber     =  $res->{biblionumber};
1788
1789     if ($res->{borrowernumber} == $borrowernumber) {
1790         ModReserveFill($res);
1791     }
1792     else {
1793         # warn "Reserved";
1794         # The item is reserved by someone else.
1795         # Find this item in the reserves
1796
1797         my $borr_res;
1798         foreach (@$all_reserves) {
1799             $_->{'borrowernumber'} == $borrowernumber or next;
1800             $_->{'biblionumber'}   == $biblionumber   or next;
1801
1802             $borr_res = $_;
1803             last;
1804         }
1805
1806         if ( $borr_res ) {
1807             # The item is reserved by the current patron
1808             ModReserveFill($borr_res);
1809         }
1810
1811         if ( $cancelreserve eq 'revert' ) { ## Revert waiting reserve to priority 1
1812             RevertWaitingStatus({ itemnumber => $itemnumber });
1813         }
1814         elsif ( $cancelreserve eq 'cancel' || $cancelreserve ) { # cancel reserves on this item
1815             my $hold = Koha::Holds->find( $res->{reserve_id} );
1816             $hold->cancel;
1817         }
1818     }
1819 }
1820
1821 =head2 MergeHolds
1822
1823   MergeHolds($dbh,$to_biblio, $from_biblio);
1824
1825 This shifts the holds from C<$from_biblio> to C<$to_biblio> and reorders them by the date they were placed
1826
1827 =cut
1828
1829 sub MergeHolds {
1830     my ( $dbh, $to_biblio, $from_biblio ) = @_;
1831     my $sth = $dbh->prepare(
1832         "SELECT count(*) as reserve_count FROM reserves WHERE biblionumber = ?"
1833     );
1834     $sth->execute($from_biblio);
1835     if ( my $data = $sth->fetchrow_hashref() ) {
1836
1837         # holds exist on old record, if not we don't need to do anything
1838         $sth = $dbh->prepare(
1839             "UPDATE reserves SET biblionumber = ? WHERE biblionumber = ?");
1840         $sth->execute( $to_biblio, $from_biblio );
1841
1842         # Reorder by date
1843         # don't reorder those already waiting
1844
1845         $sth = $dbh->prepare(
1846 "SELECT * FROM reserves WHERE biblionumber = ? AND (found <> ? AND found <> ? OR found is NULL) ORDER BY reservedate ASC"
1847         );
1848         my $upd_sth = $dbh->prepare(
1849 "UPDATE reserves SET priority = ? WHERE biblionumber = ? AND borrowernumber = ?
1850         AND reservedate = ? AND (itemnumber = ? or itemnumber is NULL) "
1851         );
1852         $sth->execute( $to_biblio, 'W', 'T' );
1853         my $priority = 1;
1854         while ( my $reserve = $sth->fetchrow_hashref() ) {
1855             $upd_sth->execute(
1856                 $priority,                    $to_biblio,
1857                 $reserve->{'borrowernumber'}, $reserve->{'reservedate'},
1858                 $reserve->{'itemnumber'}
1859             );
1860             $priority++;
1861         }
1862     }
1863 }
1864
1865 =head2 RevertWaitingStatus
1866
1867   RevertWaitingStatus({ itemnumber => $itemnumber });
1868
1869   Reverts a 'waiting' hold back to a regular hold with a priority of 1.
1870
1871   Caveat: Any waiting hold fixed with RevertWaitingStatus will be an
1872           item level hold, even if it was only a bibliolevel hold to
1873           begin with. This is because we can no longer know if a hold
1874           was item-level or bib-level after a hold has been set to
1875           waiting status.
1876
1877 =cut
1878
1879 sub RevertWaitingStatus {
1880     my ( $params ) = @_;
1881     my $itemnumber = $params->{'itemnumber'};
1882
1883     return unless ( $itemnumber );
1884
1885     my $dbh = C4::Context->dbh;
1886
1887     ## Get the waiting reserve we want to revert
1888     my $query = "
1889         SELECT * FROM reserves
1890         WHERE itemnumber = ?
1891         AND found IS NOT NULL
1892     ";
1893     my $sth = $dbh->prepare( $query );
1894     $sth->execute( $itemnumber );
1895     my $reserve = $sth->fetchrow_hashref();
1896
1897     ## Increment the priority of all other non-waiting
1898     ## reserves for this bib record
1899     $query = "
1900         UPDATE reserves
1901         SET
1902           priority = priority + 1
1903         WHERE
1904           biblionumber =  ?
1905         AND
1906           priority > 0
1907     ";
1908     $sth = $dbh->prepare( $query );
1909     $sth->execute( $reserve->{'biblionumber'} );
1910
1911     ## Fix up the currently waiting reserve
1912     $query = "
1913     UPDATE reserves
1914     SET
1915       priority = 1,
1916       found = NULL,
1917       waitingdate = NULL
1918     WHERE
1919       reserve_id = ?
1920     ";
1921     $sth = $dbh->prepare( $query );
1922     $sth->execute( $reserve->{'reserve_id'} );
1923     _FixPriority( { biblionumber => $reserve->{biblionumber} } );
1924 }
1925
1926 =head2 ReserveSlip
1927
1928 ReserveSlip(
1929     {
1930         branchcode     => $branchcode,
1931         borrowernumber => $borrowernumber,
1932         biblionumber   => $biblionumber,
1933         [ itemnumber   => $itemnumber, ]
1934         [ barcode      => $barcode, ]
1935     }
1936   )
1937
1938 Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
1939
1940 The letter code will be HOLD_SLIP, and the following tables are
1941 available within the slip:
1942
1943     reserves
1944     branches
1945     borrowers
1946     biblio
1947     biblioitems
1948     items
1949
1950 =cut
1951
1952 sub ReserveSlip {
1953     my ($args) = @_;
1954     my $branchcode     = $args->{branchcode};
1955     my $borrowernumber = $args->{borrowernumber};
1956     my $biblionumber   = $args->{biblionumber};
1957     my $itemnumber     = $args->{itemnumber};
1958     my $barcode        = $args->{barcode};
1959
1960
1961     my $patron = Koha::Patrons->find($borrowernumber);
1962
1963     my $hold;
1964     if ($itemnumber || $barcode ) {
1965         $itemnumber ||= Koha::Items->find( { barcode => $barcode } )->itemnumber;
1966
1967         $hold = Koha::Holds->search(
1968             {
1969                 biblionumber   => $biblionumber,
1970                 borrowernumber => $borrowernumber,
1971                 itemnumber     => $itemnumber
1972             }
1973         )->next;
1974     }
1975     else {
1976         $hold = Koha::Holds->search(
1977             {
1978                 biblionumber   => $biblionumber,
1979                 borrowernumber => $borrowernumber
1980             }
1981         )->next;
1982     }
1983
1984     return unless $hold;
1985     my $reserve = $hold->unblessed;
1986
1987     return  C4::Letters::GetPreparedLetter (
1988         module => 'circulation',
1989         letter_code => 'HOLD_SLIP',
1990         branchcode => $branchcode,
1991         lang => $patron->lang,
1992         tables => {
1993             'reserves'    => $reserve,
1994             'branches'    => $reserve->{branchcode},
1995             'borrowers'   => $reserve->{borrowernumber},
1996             'biblio'      => $reserve->{biblionumber},
1997             'biblioitems' => $reserve->{biblionumber},
1998             'items'       => $reserve->{itemnumber},
1999         },
2000     );
2001 }
2002
2003 =head2 GetReservesControlBranch
2004
2005   my $reserves_control_branch = GetReservesControlBranch($item, $borrower);
2006
2007   Return the branchcode to be used to determine which reserves
2008   policy applies to a transaction.
2009
2010   C<$item> is a hashref for an item. Only 'homebranch' is used.
2011
2012   C<$borrower> is a hashref to borrower. Only 'branchcode' is used.
2013
2014 =cut
2015
2016 sub GetReservesControlBranch {
2017     my ( $item, $borrower ) = @_;
2018
2019     my $reserves_control = C4::Context->preference('ReservesControlBranch');
2020
2021     my $branchcode =
2022         ( $reserves_control eq 'ItemHomeLibrary' ) ? $item->{'homebranch'}
2023       : ( $reserves_control eq 'PatronLibrary' )   ? $borrower->{'branchcode'}
2024       :                                              undef;
2025
2026     return $branchcode;
2027 }
2028
2029 =head2 CalculatePriority
2030
2031     my $p = CalculatePriority($biblionumber, $resdate);
2032
2033 Calculate priority for a new reserve on biblionumber, placing it at
2034 the end of the line of all holds whose start date falls before
2035 the current system time and that are neither on the hold shelf
2036 or in transit.
2037
2038 The reserve date parameter is optional; if it is supplied, the
2039 priority is based on the set of holds whose start date falls before
2040 the parameter value.
2041
2042 After calculation of this priority, it is recommended to call
2043 _ShiftPriorityByDateAndPriority. Note that this is currently done in
2044 AddReserves.
2045
2046 =cut
2047
2048 sub CalculatePriority {
2049     my ( $biblionumber, $resdate ) = @_;
2050
2051     my $sql = q{
2052         SELECT COUNT(*) FROM reserves
2053         WHERE biblionumber = ?
2054         AND   priority > 0
2055         AND   (found IS NULL OR found = '')
2056     };
2057     #skip found==W or found==T (waiting or transit holds)
2058     if( $resdate ) {
2059         $sql.= ' AND ( reservedate <= ? )';
2060     }
2061     else {
2062         $sql.= ' AND ( reservedate < NOW() )';
2063     }
2064     my $dbh = C4::Context->dbh();
2065     my @row = $dbh->selectrow_array(
2066         $sql,
2067         undef,
2068         $resdate ? ($biblionumber, $resdate) : ($biblionumber)
2069     );
2070
2071     return @row ? $row[0]+1 : 1;
2072 }
2073
2074 =head2 IsItemOnHoldAndFound
2075
2076     my $bool = IsItemFoundHold( $itemnumber );
2077
2078     Returns true if the item is currently on hold
2079     and that hold has a non-null found status ( W, T, etc. )
2080
2081 =cut
2082
2083 sub IsItemOnHoldAndFound {
2084     my ($itemnumber) = @_;
2085
2086     my $rs = Koha::Database->new()->schema()->resultset('Reserve');
2087
2088     my $found = $rs->count(
2089         {
2090             itemnumber => $itemnumber,
2091             found      => { '!=' => undef }
2092         }
2093     );
2094
2095     return $found;
2096 }
2097
2098 =head2 GetMaxPatronHoldsForRecord
2099
2100 my $holds_per_record = ReservesControlBranch( $borrowernumber, $biblionumber );
2101
2102 For multiple holds on a given record for a given patron, the max
2103 number of record level holds that a patron can be placed is the highest
2104 value of the holds_per_record rule for each item if the record for that
2105 patron. This subroutine finds and returns the highest holds_per_record
2106 rule value for a given patron id and record id.
2107
2108 =cut
2109
2110 sub GetMaxPatronHoldsForRecord {
2111     my ( $borrowernumber, $biblionumber ) = @_;
2112
2113     my $patron = Koha::Patrons->find($borrowernumber);
2114     my @items = Koha::Items->search( { biblionumber => $biblionumber } );
2115
2116     my $controlbranch = C4::Context->preference('ReservesControlBranch');
2117
2118     my $categorycode = $patron->categorycode;
2119     my $branchcode;
2120     $branchcode = $patron->branchcode if ( $controlbranch eq "PatronLibrary" );
2121
2122     my $max = 0;
2123     foreach my $item (@items) {
2124         my $itemtype = $item->effective_itemtype();
2125
2126         $branchcode = $item->homebranch if ( $controlbranch eq "ItemHomeLibrary" );
2127
2128         my $rule = GetHoldRule( $categorycode, $itemtype, $branchcode );
2129         my $holds_per_record = $rule ? $rule->{holds_per_record} : 0;
2130         $max = $holds_per_record if $holds_per_record > $max;
2131     }
2132
2133     return $max;
2134 }
2135
2136 =head2 GetHoldRule
2137
2138 my $rule = GetHoldRule( $categorycode, $itemtype, $branchcode );
2139
2140 Returns the matching hold related issuingrule fields for a given
2141 patron category, itemtype, and library.
2142
2143 =cut
2144
2145 sub GetHoldRule {
2146     my ( $categorycode, $itemtype, $branchcode ) = @_;
2147
2148     my $dbh = C4::Context->dbh;
2149
2150     my $sth = $dbh->prepare(
2151         q{
2152          SELECT categorycode, itemtype, branchcode, reservesallowed, holds_per_record, holds_per_day
2153            FROM issuingrules
2154           WHERE (categorycode in (?,'*') )
2155             AND (itemtype IN (?,'*'))
2156             AND (branchcode IN (?,'*'))
2157        ORDER BY categorycode DESC,
2158                 itemtype     DESC,
2159                 branchcode   DESC
2160         }
2161     );
2162
2163     $sth->execute( $categorycode, $itemtype, $branchcode );
2164
2165     return $sth->fetchrow_hashref();
2166 }
2167
2168 =head1 AUTHOR
2169
2170 Koha Development Team <http://koha-community.org/>
2171
2172 =cut
2173
2174 1;