C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 #use warnings; FIXME - Bug 2505
  22 use Carp;
  23
  24 use C4::Debug;
  25 use C4::Context;
  26 use C4::Members qw(AddMember changepassword);
  27 use C4::Members::Attributes;
  28 use C4::Members::AttributeTypes;
  29 use C4::Members::Messaging;
  30 use C4::Auth qw(checkpw_internal);
  31 use Koha::AuthUtils qw(hash_password);
  32 use List::MoreUtils qw( any );
  33 use Net::LDAP;
  34 use Net::LDAP::Filter;
  35
  36 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
  37
  38 BEGIN {
  39         require Exporter;
  40         @ISA    = qw(Exporter);
  41         @EXPORT = qw( checkpw_ldap );
  42 }
  43
  44 # Redefine checkpw_ldap:
  45 # connect to LDAP (named or anonymous)
  46 # ~ retrieves $userid from KOHA_CONF mapping
  47 # ~ then compares $password with userPassword
  48 # ~ then gets the LDAP entry
  49 # ~ and calls the memberadd if necessary
  50
  51 sub ldapserver_error {
  52         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  53 }
  54
  55 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  56 my $context = C4::Context->new()        or die 'C4::Context->new failed';
  57 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  58 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  59 my $base      = $ldap->{base}           or die ldapserver_error('base');
  60 $ldapname     = $ldap->{user}           ;
  61 $ldappassword = $ldap->{pass}           ;
  62 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  63 my @mapkeys = keys %mapping;
  64 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  65 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  66 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  67
  68 my %categorycode_conversions;
  69 my $default_categorycode;
  70 if(defined $ldap->{categorycode_mapping}) {
  71     $default_categorycode = $ldap->{categorycode_mapping}->{default};
  72     foreach my $cat (@{$ldap->{categorycode_mapping}->{categorycode}}) {
  73         $categorycode_conversions{$cat->{value}} = $cat->{content};
  74     }
  75 }
  76
  77 my %config = (
  78         anonymous => ($ldapname and $ldappassword) ? 0 : 1,
  79     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  80        update => defined($ldap->{update}   ) ? $ldap->{update}    : 1,  # update from LDAP to Koha database for existing user
  81 );
  82
  83 sub description {
  84         my $result = shift or return;
  85         return "LDAP error #" . $result->code
  86                         . ": " . $result->error_name . "\n"
  87                         . "# " . $result->error_text . "\n";
  88 }
  89
  90 sub search_method {
  91     my $db     = shift or return;
  92     my $userid = shift or return;
  93         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  94         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  95         my $search = $db->search(
  96                   base => $base,
  97                 filter => $filter,
  98                 # attrs => ['*'],
  99     );
 100     die "LDAP search failed to return object : " . $search->error if $search->code;
 101
 102         my $count = $search->count;
 103         if ($search->code > 0) {
 104                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
 105                 return 0;
 106         }
 107         if ($count != 1) {
 108                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count);
 109                 return 0;
 110         }
 111     return $search;
 112 }
 113
 114 sub checkpw_ldap {
 115     my ($dbh, $userid, $password) = @_;
 116     my @hosts = split(',', $prefhost);
 117     my $db = Net::LDAP->new(\@hosts);
 118     unless ( $db ) {
 119         warn "LDAP connexion failed";
 120         return 0;
 121     }
 122
 123         #$debug and $db->debug(5);
 124     my $userldapentry;
 125
 126     if ( $ldap->{auth_by_bind} ) {
 127         my $principal_name;
 128         if ( $ldap->{anonymous_bind} ) {
 129
 130             # Perform an anonymous bind
 131             my $res = $db->bind;
 132             if ( $res->code ) {
 133                 warn "Anonymous LDAP bind failed: " . description($res);
 134                 return 0;
 135             }
 136
 137             # Perform a LDAP search for the given username
 138             my $search = search_method( $db, $userid )
 139               or return 0;    # warnings are in the sub
 140             $userldapentry = $search->shift_entry;
 141             $principal_name = $userldapentry->dn;
 142         }
 143         else {
 144             $principal_name = $ldap->{principal_name};
 145             if ( $principal_name and $principal_name =~ /\%/ ) {
 146                 $principal_name = sprintf( $principal_name, $userid );
 147             }
 148             else {
 149                 $principal_name = $userid;
 150             }
 151         }
 152
 153         # Perform a LDAP bind for the given username using the matched DN
 154         my $res = $db->bind( $principal_name, password => $password );
 155         if ( $res->code ) {
 156             if ( $ldap->{anonymous_bind} ) {
 157                 # With anonymous_bind approach we can be sure we have found the correct user
 158                 # and that any 'code' response indicates a 'bad' user (be that blocked, banned
 159                 # or password changed). We should not fall back to local accounts in this case.
 160                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 161                 return -1;
 162             } else {
 163                 # Without a anonymous_bind, we cannot be sure we are looking at a valid ldap user
 164                 # at all, and thus we should fall back to local logins to restore previous behaviour
 165                 # see bug 12831
 166                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 167                 return 0;
 168             }
 169         }
 170         if ( !defined($userldapentry)
 171             && ( $config{update} or $config{replicate} ) )
 172         {
 173             my $search = search_method( $db, $userid ) or return 0;
 174             $userldapentry = $search->shift_entry;
 175         }
 176     } else {
 177                 my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 178                 if ($res->code) {               # connection refused
 179                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 180                         return 0;
 181                 }
 182         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 183         $userldapentry = $search->shift_entry;
 184                 my $cmpmesg = $db->compare( $userldapentry, attr=>'userpassword', value => $password );
 185                 if ($cmpmesg->code != 6) {
 186                         warn "LDAP Auth rejected : invalid password for user '$userid'. " . description($cmpmesg);
 187                         return -1;
 188                 }
 189         }
 190
 191     # To get here, LDAP has accepted our user's login attempt.
 192     # But we still have work to do.  See perldoc below for detailed breakdown.
 193
 194     my (%borrower);
 195         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 196
 197     if (( $borrowernumber and $config{update}   ) or
 198         (!$borrowernumber and $config{replicate})   ) {
 199         %borrower = ldap_entry_2_hash($userldapentry,$userid);
 200         $debug and print STDERR "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 201     }
 202
 203     if ($borrowernumber) {
 204         if ($config{update}) { # A1, B1
 205             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 206             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 207         } else { # C1, D1
 208             # maybe update just the password?
 209                 return(1, $cardnumber, $local_userid);
 210         }
 211     } elsif ($config{replicate}) { # A2, C2
 212         $borrowernumber = AddMember(%borrower) or die "AddMember failed";
 213         C4::Members::Messaging::SetMessagingPreferencesFromDefaults( { borrowernumber => $borrowernumber, categorycode => $borrower{'categorycode'} } );
 214    } else {
 215         return 0;   # B2, D2
 216     }
 217     if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 218         foreach my $attribute_type ( C4::Members::AttributeTypes::GetAttributeTypes() ) {
 219             my $code = $attribute_type->{code};
 220             unless (exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) {
 221                 next;
 222             }
 223             if (C4::Members::Attributes::CheckUniqueness($code, $borrower{$code}, $borrowernumber)) {
 224                 C4::Members::Attributes::UpdateBorrowerAttribute($borrowernumber, {code => $code, value => $borrower{$code}});
 225             } else {
 226                 warn "ERROR_extended_unique_id_failed $code $borrower{$code}";
 227             }
 228         }
 229     }
 230     return(1, $cardnumber, $userid);
 231 }
 232
 233 # Pass LDAP entry object and local cardnumber (userid).
 234 # Returns borrower hash.
 235 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 236 # Ensure that mandatory fields are correctly filled!
 237 #
 238 sub ldap_entry_2_hash {
 239         my $userldapentry = shift;
 240         my %borrower = ( cardnumber => shift );
 241         my %memberhash;
 242         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 243         if ($debug) {
 244                 foreach (keys %$userldapentry) {
 245                         print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 246                 }
 247         }
 248         my $x = $userldapentry->{attrs} or return;
 249         foreach (keys %$x) {
 250                 $memberhash{$_} = join ' ', @{$x->{$_}};
 251                 $debug and print STDERR sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 252         }
 253         $debug and print STDERR "Finsihed \%memberhash has ", scalar(keys %memberhash), " keys\n",
 254                                         "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 255         foreach my $key (keys %mapping) {
 256                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
 257                 $debug and printf STDERR "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 258                 unless (defined $data) {
 259                         $data = $mapping{$key}->{content} || '';        # default or failsafe ''
 260                 }
 261                 $borrower{$key} = ($data ne '') ? $data : ' ' ;
 262         }
 263         $borrower{initials} = $memberhash{initials} ||
 264                 ( substr($borrower{'firstname'},0,1)
 265                 . substr($borrower{ 'surname' },0,1)
 266                 . " ");
 267
 268     # categorycode conversions
 269     if(defined $categorycode_conversions{$borrower{categorycode}}) {
 270         $borrower{categorycode} = $categorycode_conversions{$borrower{categorycode}};
 271     }
 272     elsif($default_categorycode) {
 273         $borrower{categorycode} = $default_categorycode;
 274     }
 275
 276         # check if categorycode exists, if not, fallback to default from koha-conf.xml
 277         my $dbh = C4::Context->dbh;
 278         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
 279         $sth->execute( uc($borrower{'categorycode'}) );
 280         unless ( my $row = $sth->fetchrow_hashref ) {
 281                 my $default = $mapping{'categorycode'}->{content};
 282                 $debug && warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
 283                 $borrower{'categorycode'} = $default
 284         }
 285
 286         return %borrower;
 287 }
 288
 289 sub exists_local {
 290         my $arg = shift;
 291         my $dbh = C4::Context->dbh;
 292         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 293
 294         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 295         $sth->execute($arg);
 296         $debug and printf STDERR "Userid '$arg' exists_local? %s\n", $sth->rows;
 297         ($sth->rows == 1) and return $sth->fetchrow;
 298
 299         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 300         $sth->execute($arg);
 301         $debug and printf STDERR "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 302         ($sth->rows == 1) and return $sth->fetchrow;
 303         return 0;
 304 }
 305
 306 # This function performs a password update, given the userid, borrowerid,
 307 # and digested password. It will verify that things are correct and return the
 308 # borrowers cardnumber. The idea is that it is used to keep the local
 309 # passwords in sync with the LDAP passwords.
 310 #
 311 #   $cardnum = _do_changepassword($userid, $borrowerid, $digest)
 312 #
 313 # Note: if the LDAP config has the update_password tag set to a false value,
 314 # then this will not update the password, it will simply return the cardnumber.
 315 sub _do_changepassword {
 316     my ($userid, $borrowerid, $password) = @_;
 317
 318     if ( exists( $ldap->{update_password} ) && !$ldap->{update_password} ) {
 319
 320         # We don't store the password in the database
 321         my $sth = C4::Context->dbh->prepare(
 322             'SELECT cardnumber FROM borrowers WHERE borrowernumber=?');
 323         $sth->execute($borrowerid);
 324         die "Unable to access borrowernumber "
 325             . "with userid=$userid, "
 326             . "borrowernumber=$borrowerid"
 327           if !$sth->rows;
 328         my ($cardnum) = $sth->fetchrow;
 329         $sth = C4::Context->dbh->prepare(
 330             'UPDATE borrowers SET password = null WHERE borrowernumber=?');
 331         $sth->execute($borrowerid);
 332         return $cardnum;
 333     }
 334     my $digest = hash_password($password);
 335
 336     $debug and print STDERR "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 337     changepassword($userid, $borrowerid, $digest);
 338
 339     my ($ok, $cardnum) = checkpw_internal(C4::Context->dbh, $userid, $password);
 340     return $cardnum if $ok;
 341
 342     warn "Password mismatch after update to borrowernumber=$borrowerid";
 343     return;
 344 }
 345
 346 sub update_local {
 347     my $userid     = shift or croak "No userid";
 348     my $password   = shift or croak "No password";
 349     my $borrowerid = shift or croak "No borrowerid";
 350     my $borrower   = shift or croak "No borrower record";
 351
 352     my @keys = keys %$borrower;
 353     my $dbh = C4::Context->dbh;
 354     my $query = "UPDATE  borrowers\nSET     " .
 355         join(',', map {"$_=?"} @keys) .
 356         "\nWHERE   borrowernumber=? ";
 357     my $sth = $dbh->prepare($query);
 358     if ($debug) {
 359         print STDERR $query, "\n",
 360             join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 361         print STDERR "\nuserid = $userid\n";
 362     }
 363     $sth->execute(
 364         ((map {$borrower->{$_}} @keys), $borrowerid)
 365     );
 366
 367     # MODIFY PASSWORD/LOGIN if password was mapped
 368     _do_changepassword($userid, $borrowerid, $password) if $borrower->{'password'};
 369 }
 370
 371 1;
 372 __END__
 373
 374 =head1 NAME
 375
 376 C4::Auth - Authenticates Koha users
 377
 378 =head1 SYNOPSIS
 379
 380   use C4::Auth_with_ldap;
 381
 382 =head1 LDAP Configuration
 383
 384     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 385         working LDAP servers.
 386         To use it :
 387            * Modify ldapserver element in KOHA_CONF
 388            * Establish field mapping in <mapping> element.
 389
 390         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 391         the username would match the "uid" field, and the password should match the "userpassword" field.
 392
 393         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 394         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 395
 396         mysql> show COLUMNS from borrowers;
 397                 +---------------------+--------------+------+-----+---------+----------------+
 398                 | Field               | Type         | Null | Key | Default | Extra          |
 399                 +---------------------+--------------+------+-----+---------+----------------+
 400                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 401                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 402                 | surname             | mediumtext   | NO   |     | NULL    |                |
 403                 | firstname           | text         | YES  |     | NULL    |                |
 404                 | title               | mediumtext   | YES  |     | NULL    |                |
 405                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 406                 | initials            | text         | YES  |     | NULL    |                |
 407                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 408                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 409                 | address             | mediumtext   | NO   |     | NULL    |                |
 410                 | address2            | text         | YES  |     | NULL    |                |
 411                 | city                | mediumtext   | NO   |     | NULL    |                |
 412                 | state               | mediumtext   | YES  |     | NULL    |                |
 413                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 414                 | country             | text         | YES  |     | NULL    |                |
 415                 | email               | mediumtext   | YES  |     | NULL    |                |
 416                 | phone               | text         | YES  |     | NULL    |                |
 417                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 418                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 419                 | emailpro            | text         | YES  |     | NULL    |                |
 420                 | phonepro            | text         | YES  |     | NULL    |                |
 421                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 422                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 423                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 424                 | B_address2          | text         | YES  |     | NULL    |                |
 425                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 426                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 427                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 428                 | B_country           | text         | YES  |     | NULL    |                |
 429                 | B_email             | text         | YES  |     | NULL    |                |
 430                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 431                 | dateofbirth         | date         | YES  |     | NULL    |                |
 432                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 433                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 434                 | dateenrolled        | date         | YES  |     | NULL    |                |
 435                 | dateexpiry          | date         | YES  |     | NULL    |                |
 436                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 437                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 438                 | debarred            | date         | YES  |     | NULL    |                |
 439                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
 440                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 441                 | contactfirstname    | text         | YES  |     | NULL    |                |
 442                 | contacttitle        | text         | YES  |     | NULL    |                |
 443                 | guarantorid         | int(11)      | YES  | MUL | NULL    |                |
 444                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 445                 | relationship        | varchar(100) | YES  |     | NULL    |                |
 446                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 447                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 448                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 449                 | password            | varchar(30)  | YES  |     | NULL    |                |
 450                 | flags               | int(11)      | YES  |     | NULL    |                |
 451                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 452                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 453                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 454                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 455                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 456                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 457                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 458                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 459                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 460                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 461                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 462                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 463                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 464                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 465                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 466                 | privacy             | int(11)      | NO   |     | 1       |                |
 467                 +---------------------+--------------+------+-----+---------+----------------+
 468                 66 rows in set (0.00 sec)
 469                 Where Null="NO", the field is required.
 470
 471 =head1 KOHA_CONF and field mapping
 472
 473 Example XML stanza for LDAP configuration in KOHA_CONF.
 474
 475  <config>
 476   ...
 477   <useldapserver>1</useldapserver>
 478   <!-- LDAP SERVER (optional) -->
 479   <ldapserver id="ldapserver">
 480     <hostname>localhost</hostname>
 481     <base>dc=metavore,dc=com</base>
 482     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 483     <pass>metavore</pass>          <!-- password, if not anonymous -->
 484     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 485     <update>1</update>             <!-- update existing users in Koha database -->
 486     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 487                                         password comparison, e.g., to use Active Directory -->
 488     <anonymous_bind>0</anonymous_bind> <!-- set to 1 if users should be searched using
 489                                             an anonymous bind, even when auth_by_bind is on -->
 490     <principal_name>%s@my_domain.com</principal_name>
 491                                    <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid.
 492                                         Not used with anonymous_bind. -->
 493     <update_password>1</update_password> <!-- set to 0 if you don't want LDAP passwords
 494                                               synced to the local database -->
 495     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 496       <firstname    is="givenname"      ></firstname>
 497       <surname      is="sn"             ></surname>
 498       <address      is="postaladdress"  ></address>
 499       <city         is="l"              >Athens, OH</city>
 500       <zipcode      is="postalcode"     ></zipcode>
 501       <branchcode   is="branch"         >MAIN</branchcode>
 502       <userid       is="uid"            ></userid>
 503       <password     is="userpassword"   ></password>
 504       <email        is="mail"           ></email>
 505       <categorycode is="employeetype"   >PT</categorycode>
 506       <phone        is="telephonenumber"></phone>
 507     </mapping>
 508   </ldapserver>
 509  </config>
 510
 511 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 512 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 513 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 514 patron).
 515
 516 =head1 CONFIGURATION
 517
 518 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 519 your configuration and the presence of a matching Koha user in your local DB:
 520
 521                          LOCAL_USER
 522  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 523    A1      1       1        1      OK : We're updating them anyway.
 524    A2      1       1        0      OK : We're adding them anyway.
 525    B1      1       0        1      OK : We update them.
 526    B2      1       0        0     FAIL: We cannot add new user.
 527    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 528    C2      0       1        0      OK : We add the new user.
 529    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 530    D2      0       0        0     FAIL: We cannot add new user.
 531
 532 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 533 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 534 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 535
 536 If you choose NOT to update local users, the borrowers table will not be affected at all.
 537 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 538 the local table never contained the LDAP values.
 539
 540 =head2 auth_by_bind
 541
 542 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 543
 544 =head2 principal_name
 545
 546 Provides an optional sprintf-style format for manipulating the userid before the bind.
 547 Even though the userPrincipalName is one intended target, any uniquely identifying
 548 attribute that the server allows to be used for binding could be used.
 549
 550 Currently, principal_name only operates when auth_by_bind is enabled.
 551
 552 =head2 update_password
 553
 554 If this tag is left out or set to a true value, then the user's LDAP password
 555 will be stored (hashed) in the local Koha database. If you don't want this
 556 to happen, then set the value of this to '0'. Note that if passwords are not
 557 stored locally, and the connection to the LDAP system fails, then the users
 558 will not be able to log in at all.
 559
 560 =head2 Active Directory
 561
 562 The auth_by_bind and principal_name settings are recommended for Active Directory.
 563
 564 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 565 we would typically under openldap.  Instead of:
 566
 567     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 568
 569 We might get:
 570
 571     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 572
 573 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 574 in Koha userids.  But the userPrincipalName should be consistent, something like:
 575
 576     userPrincipalName: barnes.7@my_company.com
 577
 578 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 579 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 580 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 581 like this:
 582     <principal_name>%s@core.my_company.com</principal_name>
 583
 584 The user of the previous example, barnes.7, would then attempt to bind as:
 585     barnes.7@core.my_company.com
 586
 587 =head1 SEE ALSO
 588
 589 CGI(3)
 590
 591 Net::LDAP()
 592
 593 XML::Simple()
 594
 595 Digest::MD5(3)
 596
 597 sprintf()
 598
 599 =cut
 600
 601 # For reference, here's an important difference in the data structure we rely on.
 602 # ========================================
 603 # Using attrs instead of {asn}->attributes
 604 # ========================================
 605 #
 606 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 607 #       LDAP key: ->{             cn}->{           sss} = sss
 608 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 609 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 610 #
 611 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 612 #       LDAP key: ->{      givenname}->{Steve} = Steve
 613 #