opac/tracklinks.pl

   1 #!/usr/bin/perl
   2
   3 # script to log clicks on links to external urls
   4
   5 # Copyright 2012 Catalyst IT
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use C4::Context;
  23 use C4::Auth qw(checkauth);
  24 use C4::Biblio;
  25 use Koha::Items;
  26 use Koha::Linktracker;
  27 use CGI qw ( -utf8 );
  28
  29 my $cgi = new CGI;
  30 my $uri = $cgi->param('uri') || '';
  31
  32 my $tracker = Koha::Linktracker->new(
  33     { trackingmethod => C4::Context->preference('TrackClicks') } );
  34
  35 if ($uri) {
  36     if (   $tracker->trackingmethod() eq 'track'
  37         || $tracker->trackingmethod() eq 'anonymous' )
  38     {
  39         my $borrowernumber = 0;
  40
  41         # we have a uri and we want to track
  42         if ( $tracker->trackingmethod() eq 'track' ) {
  43             my ( $user, $cookie, $sessionID, $flags ) =
  44               checkauth( $cgi, 1, {}, 'opac' );
  45             my $userenv = C4::Context->userenv;
  46
  47             if (   defined($userenv)
  48                 && ref($userenv) eq 'HASH'
  49                 && $userenv->{number} )
  50             {
  51                 $borrowernumber = $userenv->{number};
  52             }
  53
  54             # get borrower info
  55         }
  56         my $biblionumber = $cgi->param('biblionumber') || 0;
  57         my $itemnumber   = $cgi->param('itemnumber')   || 0;
  58
  59         my $record = C4::Biblio::GetMarcBiblio({ biblionumber => $biblionumber });
  60         my $marc_urls = C4::Biblio::GetMarcUrls($record, C4::Context->preference('marcflavour'));
  61         if ( ( grep { $_ eq $uri } map { $_->{MARCURL} } @$marc_urls )
  62             || Koha::Items->search( { itemnumber => $itemnumber, uri => $uri } )->count )
  63         {
  64             $tracker->trackclick(
  65                 {
  66                     uri            => $uri,
  67                     biblionumber   => $biblionumber,
  68                     borrowernumber => $borrowernumber,
  69                     itemnumber     => $itemnumber
  70                 }
  71             );
  72             print $cgi->redirect($uri);
  73             exit;
  74         }
  75     }
  76     else {
  77
  78         # We have a valid url, but we shouldn't track it, just redirect
  79         print $cgi->redirect($uri);
  80         exit;
  81     }
  82 }
  83
  84 print $cgi->redirect("/cgi-bin/koha/errors/404.pl");    # escape early
  85 exit;