misc/cronjobs/fines.pl

   1 #!/usr/bin/perl
   2
   3 #  This script loops through each overdue item, determines the fine,
   4 #  and updates the total amount of fines due by each user.  It relies on
   5 #  the existence of /tmp/fines, which is created by ???
   6 # Doesn't really rely on it, it relys on being able to write to /tmp/
   7 # It creates the fines file
   8 #
   9 #  This script is meant to be run nightly out of cron.
  10
  11 # Copyright 2000-2002 Katipo Communications
  12 # Copyright 2011 PTFS-Europe Ltd
  13 #
  14 # This file is part of Koha.
  15 #
  16 # Koha is free software; you can redistribute it and/or modify it
  17 # under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 3 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # Koha is distributed in the hope that it will be useful, but
  22 # WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  24 # GNU General Public License for more details.
  25 #
  26 # You should have received a copy of the GNU General Public License
  27 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  28
  29 use strict;
  30 use warnings;
  31 use 5.010;
  32
  33 use Koha::Script -cron;
  34 use C4::Context;
  35 use C4::Overdues;
  36 use Getopt::Long;
  37 use Carp;
  38 use File::Spec;
  39 use Try::Tiny;
  40
  41 use Koha::Calendar;
  42 use Koha::DateUtils;
  43 use Koha::Patrons;
  44 use C4::Log;
  45
  46 my $help;
  47 my $verbose;
  48 my $output_dir;
  49 my $log;
  50 my $maxdays;
  51
  52 GetOptions(
  53     'h|help'    => \$help,
  54     'v|verbose' => \$verbose,
  55     'l|log'     => \$log,
  56     'o|out:s'   => \$output_dir,
  57     'm|maxdays:i' => \$maxdays,
  58 );
  59 my $usage = << 'ENDUSAGE';
  60
  61 This script calculates and charges overdue fines
  62 to patron accounts.  The Koha system preference 'finesMode' controls
  63 whether the fines are calculated and charged to the patron accounts ("Calculate and charge");
  64 or not calculated ("Don't calculate").
  65
  66 This script has the following parameters :
  67     -h --help: this message
  68     -l --log: log the output to a file (optional if the -o parameter is given)
  69     -o --out:  ouput directory for logs (defaults to env or /tmp if !exist)
  70     -v --verbose
  71     -m --maxdays: how many days back of overdues to process
  72
  73 ENDUSAGE
  74
  75 if ($help) {
  76     print $usage;
  77     exit;
  78 }
  79
  80 my $script_handler = Koha::Script->new({ script => $0 });
  81
  82 try {
  83     $script_handler->lock_exec;
  84 }
  85 catch {
  86     my $message = "Skipping execution of $0 ($_)";
  87     print STDERR "$message\n"
  88         if $verbose;
  89     cronlogaction( $message );
  90     exit;
  91 };
  92
  93 cronlogaction();
  94
  95 my @borrower_fields =
  96   qw(cardnumber categorycode surname firstname email phone address citystate);
  97 my @item_fields  = qw(itemnumber barcode date_due);
  98 my @other_fields = qw(days_overdue fine);
  99 my $libname      = C4::Context->preference('LibraryName');
 100 my $control      = C4::Context->preference('CircControl');
 101 my $mode         = C4::Context->preference('finesMode');
 102 my $delim = "\t";    # ?  C4::Context->preference('delimiter') || "\t";
 103
 104 my %is_holiday;
 105 my $today = dt_from_string();
 106 my $filename;
 107 if ($log or $output_dir) {
 108     $filename = get_filename($output_dir);
 109 }
 110
 111 my $fh;
 112 if ($filename) {
 113     open $fh, '>>', $filename or croak "Cannot write file $filename: $!";
 114     print {$fh} join $delim, ( @borrower_fields, @item_fields, @other_fields );
 115     print {$fh} "\n";
 116 }
 117 my $counted = 0;
 118 my $params;
 119 $params->{maximumdays} = $maxdays if $maxdays;
 120 my $overdues = Getoverdues($params);
 121 for my $overdue ( @{$overdues} ) {
 122     next if $overdue->{itemlost};
 123
 124     if ( !defined $overdue->{borrowernumber} ) {
 125         carp
 126 "ERROR in Getoverdues : issues.borrowernumber IS NULL.  Repair 'issues' table now!  Skipping record.\n";
 127         next;
 128     }
 129     my $patron = Koha::Patrons->find( $overdue->{borrowernumber} );
 130     my $branchcode =
 131         ( $control eq 'ItemHomeLibrary' ) ? $overdue->{homebranch}
 132       : ( $control eq 'PatronLibrary' )   ? $patron->branchcode
 133       :                                     $overdue->{branchcode};
 134
 135 # In final case, CircControl must be PickupLibrary. (branchcode comes from issues table here).
 136     if ( !exists $is_holiday{$branchcode} ) {
 137         $is_holiday{$branchcode} = set_holiday( $branchcode, $today );
 138     }
 139
 140     my $datedue = dt_from_string( $overdue->{date_due} );
 141     if ( DateTime->compare( $datedue, $today ) == 1 ) {
 142         next;    # not overdue
 143     }
 144     ++$counted;
 145
 146     my ( $amount, $unitcounttotal, $unitcount ) =
 147       CalcFine( $overdue, $patron->categorycode,
 148         $branchcode, $datedue, $today );
 149
 150     # Don't update the fine if today is a holiday.
 151     # This ensures that dropbox mode will remove the correct amount of fine.
 152     if ( $mode eq 'production' && !$is_holiday{$branchcode} ) {
 153         if ( $amount && $amount > 0 ) {
 154             UpdateFine(
 155                 {
 156                     issue_id       => $overdue->{issue_id},
 157                     itemnumber     => $overdue->{itemnumber},
 158                     borrowernumber => $overdue->{borrowernumber},
 159                     amount         => $amount,
 160                     due            => output_pref($datedue),
 161                 }
 162             );
 163         }
 164     }
 165     my $borrower = $patron->unblessed;
 166     if ($filename) {
 167         my @cells;
 168         push @cells,
 169           map { defined $borrower->{$_} ? $borrower->{$_} : q{} }
 170           @borrower_fields;
 171         push @cells, map { $overdue->{$_} } @item_fields;
 172         push @cells, $unitcounttotal, $amount;
 173         say {$fh} join $delim, @cells;
 174     }
 175 }
 176 if ($filename){
 177     close $fh;
 178 }
 179
 180 if ($verbose) {
 181     my $overdue_items = @{$overdues};
 182     print <<"EOM";
 183 Fines assessment -- $today
 184 EOM
 185     if ($filename) {
 186         say "Saved to $filename";
 187     }
 188     print <<"EOM";
 189 Number of Overdue Items:
 190      counted $overdue_items
 191     reported $counted
 192
 193 EOM
 194 }
 195
 196 sub set_holiday {
 197     my ( $branch, $dt ) = @_;
 198
 199     my $calendar = Koha::Calendar->new( branchcode => $branch );
 200     return $calendar->is_holiday($dt);
 201 }
 202
 203 sub get_filename {
 204     my $directory = shift;
 205     if ( !$directory ) {
 206         $directory = C4::Context::temporary_directory;
 207     }
 208     if ( !-d $directory ) {
 209         carp "Could not write to $directory ... does not exist!";
 210     }
 211     my $name = C4::Context->config('database');
 212     $name =~ s/\W//;
 213     $name .= join q{}, q{_}, $today->ymd(), '.log';
 214     $name = File::Spec->catfile( $directory, $name );
 215     if ($verbose && $log) {
 216         say "writing to $name";
 217     }
 218     return $name;
 219 }