serials/serials-edit.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # Parts Copyright 2010 Biblibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 2 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21 =head1 NAME
  22
  23 serials-edit.pl
  24
  25 =head1 Parameters
  26
  27 =over 4
  28
  29 =item op
  30 op can be :
  31     * modsubscriptionhistory :to modify the subscription history
  32     * serialchangestatus     :to modify the status of this subscription
  33
  34 =item subscriptionid
  35
  36 =item user
  37
  38 =item histstartdate
  39
  40 =item enddate
  41
  42 =item recievedlist
  43
  44 =item missinglist
  45
  46 =item opacnote
  47
  48 =item librariannote
  49
  50 =item serialid
  51
  52 =item serialseq
  53
  54 =item planneddate
  55
  56 =item notes
  57
  58 =item status
  59
  60 =back
  61
  62 =cut
  63
  64 use strict;
  65 use warnings;
  66 use CGI;
  67 use C4::Auth;
  68 use C4::Dates qw/format_date format_date_in_iso/;
  69 use C4::Biblio;
  70 use C4::Items;
  71 use C4::Koha;
  72 use C4::Output;
  73 use C4::Context;
  74 use C4::Serials;
  75 use C4::Search qw/enabled_staff_search_views/;
  76 use List::MoreUtils qw/uniq/;
  77
  78 my $query           = CGI->new();
  79 my $dbh             = C4::Context->dbh;
  80 my @serialids       = $query->param('serialid');
  81 my @serialseqs      = $query->param('serialseq');
  82 my @planneddates    = $query->param('planneddate');
  83 my @publisheddates  = $query->param('publisheddate');
  84 my @status          = $query->param('status');
  85 my @notes           = $query->param('notes');
  86 my @subscriptionids = $query->param('subscriptionid');
  87 my $op              = $query->param('op');
  88 if ( scalar(@subscriptionids) == 1 && index( $subscriptionids[0], q|,| ) > 0 ) {
  89     @subscriptionids = split( /,/, $subscriptionids[0] );
  90 }
  91 my @errors;
  92 my @errseq;
  93
  94 # If user comes from subscription details
  95 unless (@serialids) {
  96     my $serstatus = $query->param('serstatus');
  97     if ($serstatus) {
  98         foreach my $subscriptionid (@subscriptionids) {
  99             my @tmpser = GetSerials2( $subscriptionid, $serstatus );
 100             push @serialids, map { $_->{serialid} } @tmpser;
 101         }
 102     }
 103 }
 104
 105 unless ( @serialids ) {
 106     my $string =
 107       'serials-collection.pl?subscriptionid=' . join ',', uniq @subscriptionids;
 108     $string =~ s/,$//;
 109
 110     print $query->redirect($string);
 111 }
 112
 113 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
 114     {
 115         template_name   => 'serials/serials-edit.tmpl',
 116         query           => $query,
 117         type            => 'intranet',
 118         authnotrequired => 0,
 119         flagsrequired   => { serials => 'receive_serials' },
 120         debug           => 1,
 121     }
 122 );
 123
 124 my @serialdatalist;
 125 my %processedserialid;
 126
 127 my $today = C4::Dates->new();
 128 foreach my $serialid (@serialids) {
 129
 130     #filtering serialid for duplication
 131     #NEW serial should appear only once and are created afterwards
 132     if (   $serialid
 133         && $serialid =~ /^[0-9]+$/
 134         && !$processedserialid{$serialid} )
 135     {
 136         my $serinfo = GetSerialInformation($serialid); #TODO duplicates work done by GetSerials2 above
 137         for my $d ( qw( publisheddate planneddate )){
 138             if ( $serinfo->{$d} =~m/^00/ ) {
 139                 $serinfo->{$d} = q{};
 140             }
 141             else {
 142                 $serinfo->{$d} = format_date( $serinfo->{$d} );
 143             }
 144         }
 145         $serinfo->{arriveddate}=$today->output('syspref');
 146
 147         $serinfo->{'editdisable'} = (
 148             (
 149                 HasSubscriptionExpired( $serinfo->{subscriptionid} )
 150                 && $serinfo->{'status1'}
 151             )
 152             || $serinfo->{'cannotedit'}
 153         );
 154         $serinfo->{editdisable} ||= ($serinfo->{status8} and $serinfo->{closed});
 155         push @serialdatalist, $serinfo;
 156         $processedserialid{$serialid} = 1;
 157     }
 158 }
 159 my $biblio = GetBiblioData( $serialdatalist[0]->{'biblionumber'} );
 160
 161 my @newserialloop;
 162 my @subscriptionloop;
 163
 164 # check, for each subscription edited, that we have an empty item line if applicable for the subscription
 165 my %processedsubscriptionid;
 166 foreach my $subscriptionid (@subscriptionids) {
 167
 168     #Do not process subscriptionid twice if it was already processed.
 169     if ( $subscriptionid && !$processedsubscriptionid{$subscriptionid} )
 170     {
 171         my $cell;
 172         if ( $serialdatalist[0]->{'serialsadditems'} ) {
 173
 174             #Create New empty item
 175             $cell =
 176               PrepareItemrecordDisplay( $serialdatalist[0]->{'biblionumber'},
 177                 '', GetSubscription($subscriptionid) );
 178             $cell->{serialsadditems} = 1;
 179         }
 180         $cell->{'subscriptionid'} = $subscriptionid;
 181         $cell->{biblionumber} = $serialdatalist[0]->{'biblionumber'};
 182         $cell->{'itemid'}         = 'NNEW';
 183         $cell->{'serialid'}       = 'NEW';
 184         $cell->{'issuesatonce'}   = 1;
 185         $cell->{arriveddate}=$today->output('syspref');
 186
 187         push @newserialloop, $cell;
 188         push @subscriptionloop,
 189           {
 190             'subscriptionid'      => $subscriptionid,
 191             'abouttoexpire'       => abouttoexpire($subscriptionid),
 192             'subscriptionexpired' => HasSubscriptionExpired($subscriptionid),
 193           };
 194         $processedsubscriptionid{$subscriptionid} = 1;
 195     }
 196 }
 197 $template->param( newserialloop => \@newserialloop );
 198 $template->param( subscriptions => \@subscriptionloop );
 199
 200 if ( $op and $op eq 'serialchangestatus' ) {
 201
 202     # Convert serialseqs to UTF-8 to prevent encoding problems
 203     foreach my $seq (@serialseqs) {
 204         utf8::decode($seq) unless utf8::is_utf8($seq);
 205     }
 206
 207     my $newserial;
 208     for ( my $i = 0 ; $i <= $#serialids ; $i++ ) {
 209         my ($plan_date, $pub_date);
 210
 211         if (defined $planneddates[$i] && $planneddates[$i] ne 'XXX') {
 212             $plan_date = format_date_in_iso( $planneddates[$i] );
 213         }
 214         if (defined $publisheddates[$i] && $publisheddates[$i] ne 'XXX') {
 215             $pub_date = format_date_in_iso( $publisheddates[$i] );
 216         }
 217
 218         if ( $serialids[$i] && $serialids[$i] eq 'NEW' ) {
 219             if ( $serialseqs[$i] ) {
 220
 221             #IF newserial was provided a name Then we have to create a newSerial
 222                 ### FIXME if NewIssue is modified to use subscription biblionumber, then biblionumber would not be useful.
 223                 $newserial = NewIssue(
 224                     $serialseqs[$i],
 225                     $subscriptionids[0],
 226                     $serialdatalist[0]->{'biblionumber'},
 227                     $status[$i],
 228                     $plan_date,
 229                     $pub_date,
 230                     $notes[$i]
 231                 );
 232             }
 233         }
 234         elsif ( $serialids[$i] ) {
 235             ModSerialStatus(
 236                 $serialids[$i],
 237                 $serialseqs[$i],
 238                 $plan_date,
 239                 $pub_date,
 240                 $status[$i],
 241                 $notes[$i]
 242             );
 243         }
 244     }
 245     my @moditems = $query->param('moditem');
 246     if ( scalar(@moditems) ) {
 247         my @tags         = $query->param('tag');
 248         my @subfields    = $query->param('subfield');
 249         my @field_values = $query->param('field_value');
 250         my @serials      = $query->param('serial');
 251         my @bibnums      = $query->param('bibnum');
 252         my @itemid       = $query->param('itemid');
 253         my @ind_tag      = $query->param('ind_tag');
 254         my @indicator    = $query->param('indicator');
 255
 256         #Rebuilding ALL the data for items into a hash
 257         # parting them on $itemid.
 258         my %itemhash;
 259         my $countdistinct;
 260         my $range = scalar(@itemid);
 261         for ( my $i = 0 ; $i < $range ; $i++ ) {
 262             unless ( $itemhash{ $itemid[$i] } ) {
 263                 if (   $serials[$countdistinct]
 264                     && $serials[$countdistinct] ne "NEW" )
 265                 {
 266                     $itemhash{ $itemid[$i] }->{'serial'} =
 267                       $serials[$countdistinct];
 268                 }
 269                 else {
 270                     $itemhash{ $itemid[$i] }->{'serial'} = $newserial;
 271                 }
 272                 $itemhash{ $itemid[$i] }->{'bibnum'} = $bibnums[$countdistinct];
 273                 $countdistinct++;
 274             }
 275             push @{ $itemhash{ $itemid[$i] }->{'tags'} },      $tags[$i];
 276             push @{ $itemhash{ $itemid[$i] }->{'subfields'} }, $subfields[$i];
 277             push @{ $itemhash{ $itemid[$i] }->{'field_values'} },
 278               $field_values[$i];
 279             push @{ $itemhash{ $itemid[$i] }->{'ind_tag'} },   $ind_tag[$i];
 280             push @{ $itemhash{ $itemid[$i] }->{'indicator'} }, $indicator[$i];
 281         }
 282         foreach my $item ( keys %itemhash ) {
 283
 284        # Verify Itemization is "Valid", i.e. serial status is Arrived or Missing
 285             my $index = -1;
 286             for ( my $i = 0 ; $i < scalar(@serialids) ; $i++ ) {
 287                   if (
 288                     $itemhash{$item}->{serial} eq $serialids[$i]
 289                     || (   $itemhash{$item}->{serial} == $newserial
 290                         && $serialids[$i] eq 'NEW' )
 291                 ) {
 292                     $index = $i
 293                   }
 294             }
 295             if ( $index >= 0 && $status[$index] == 2 ) {
 296                 my $xml = TransformHtmlToXml(
 297                     $itemhash{$item}->{'tags'},
 298                     $itemhash{$item}->{'subfields'},
 299                     $itemhash{$item}->{'field_values'},
 300                     $itemhash{$item}->{'indicator'},
 301                     $itemhash{$item}->{'ind_tag'}
 302                 );
 303
 304                 #           warn $xml;
 305                 my $bib_record = MARC::Record::new_from_xml( $xml, 'UTF-8' );
 306                 if ( $item =~ /^N/ ) {
 307
 308                     #New Item
 309
 310                   # if autoBarcode is set to 'incremental', calculate barcode...
 311                     my ( $barcodetagfield, $barcodetagsubfield ) =
 312                       GetMarcFromKohaField(
 313                         'items.barcode',
 314                         GetFrameworkCode(
 315                             $serialdatalist[0]->{'biblionumber'}
 316                         )
 317                       );
 318                     if ( C4::Context->preference('autoBarcode') eq
 319                         'incremental' )
 320                     {
 321                         if (
 322                             !(
 323                                    $bib_record->field($barcodetagfield)
 324                                 && $bib_record->field($barcodetagfield)->subfield($barcodetagsubfield)
 325                             )
 326                           )
 327                         {
 328                             my $sth_barcode = $dbh->prepare(
 329                                 'select max(abs(barcode)) from items');
 330                             $sth_barcode->execute;
 331                             my ($newbarcode) = $sth_barcode->fetchrow;
 332
 333 # OK, we have the new barcode, add the entry in MARC record # FIXME -> should be  using barcode plugin here.
 334                             $bib_record->field($barcodetagfield)
 335                               ->update( $barcodetagsubfield => ++$newbarcode );
 336                         }
 337                     }
 338
 339                     # check for item barcode # being unique
 340                     my $exists;
 341                     if (
 342                         $bib_record->subfield(
 343                             $barcodetagfield, $barcodetagsubfield
 344                         )
 345                       )
 346                     {
 347                         $exists = GetItemnumberFromBarcode(
 348                             $bib_record->subfield(
 349                                 $barcodetagfield, $barcodetagsubfield
 350                             )
 351                         );
 352                     }
 353
 354                     #           push @errors,"barcode_not_unique" if($exists);
 355                     # if barcode exists, don't create, but report The problem.
 356                     if ($exists) {
 357                         push @errors, 'barcode_not_unique';
 358                         push @errseq, { serialseq => $serialseqs[$index] };
 359                     }
 360                     else {
 361                         my ( $biblionumber, $bibitemnum, $itemnumber ) =
 362                           AddItemFromMarc( $bib_record,
 363                             $itemhash{$item}->{bibnum} );
 364                         AddItem2Serial( $itemhash{$item}->{serial},
 365                             $itemnumber );
 366                     }
 367                 }
 368                 else {
 369
 370                     #modify item
 371                     my ( $oldbiblionumber, $oldbibnum, $itemnumber ) =
 372                       ModItemFromMarc( $bib_record,
 373                         $itemhash{$item}->{'bibnum'}, $item );
 374                 }
 375             }
 376         }
 377     }
 378
 379
 380     if ( @errors ) {
 381         $template->param( Errors => 1 );
 382         if ( @errseq ) {
 383             $template->param( barcode_not_unique => 1, errseq => \@errseq );
 384         }
 385     }
 386     else {
 387         my $redirect = 'serials-collection.pl?';
 388         $redirect .= join( '&', map { 'subscriptionid=' . $_ } @subscriptionids );
 389         print $query->redirect($redirect);
 390     }
 391 }
 392 my $location = GetAuthorisedValues('LOC', $serialdatalist[0]->{'location'});
 393 my $locationlib;
 394 foreach (@$location) {
 395     $locationlib = $_->{'lib'} if $_->{'selected'};
 396 }
 397 my $default_bib_view = get_default_view();
 398
 399 $template->param(
 400     serialsadditems => $serialdatalist[0]->{'serialsadditems'},
 401     callnumber       => $serialdatalist[0]->{'callnumber'},
 402     internalnotes   => $serialdatalist[0]->{'internalnotes'},
 403     bibliotitle     => $biblio->{'title'},
 404     biblionumber    => $serialdatalist[0]->{'biblionumber'},
 405     serialslist     => \@serialdatalist,
 406     default_bib_view => $default_bib_view,
 407     location         => $locationlib,
 408     (uc(C4::Context->preference("marcflavour"))) => 1
 409
 410 );
 411 output_html_with_http_headers $query, $cookie, $template->output;
 412
 413 sub get_default_view {
 414     my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 415     my %views       = C4::Search::enabled_staff_search_views();
 416     if ( $defaultview eq 'isbd' && $views{can_view_ISBD} ) {
 417         return 'ISBDdetail';
 418     }
 419     elsif ( $defaultview eq 'marc' && $views{can_view_MARC} ) {
 420         return 'MARCdetail';
 421     }
 422     elsif ( $defaultview eq 'labeled_marc' && $views{can_view_labeledMARC} ) {
 423         return 'labeledMARCdetail';
 424     }
 425     return 'detail';
 426 }