C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use Koha::DateUtils;
  25 use C4::Context;
  26 use C4::Stats;
  27 use C4::Reserves;
  28 use C4::Biblio;
  29 use C4::Items;
  30 use C4::Members;
  31 use C4::Accounts;
  32 use C4::ItemCirculationAlertPreference;
  33 use C4::Message;
  34 use C4::Debug;
  35 use C4::Log; # logaction
  36 use C4::Overdues qw(CalcFine UpdateFine get_chargeable_units);
  37 use C4::RotatingCollections qw(GetCollectionItemBranches);
  38 use Algorithm::CheckDigits;
  39
  40 use Data::Dumper;
  41 use Koha::Account;
  42 use Koha::AuthorisedValues;
  43 use Koha::Biblioitems;
  44 use Koha::DateUtils;
  45 use Koha::Calendar;
  46 use Koha::Checkouts;
  47 use Koha::Illrequests;
  48 use Koha::Items;
  49 use Koha::Patrons;
  50 use Koha::Patron::Debarments;
  51 use Koha::Database;
  52 use Koha::Libraries;
  53 use Koha::Account::Lines;
  54 use Koha::Holds;
  55 use Koha::Account::Lines;
  56 use Koha::Account::Offsets;
  57 use Koha::Config::SysPrefs;
  58 use Koha::Charges::Fees;
  59 use Koha::Util::SystemPreferences;
  60 use Koha::Checkouts::ReturnClaims;
  61 use Carp;
  62 use List::MoreUtils qw( uniq any );
  63 use Scalar::Util qw( looks_like_number );
  64 use Try::Tiny;
  65 use Date::Calc qw(
  66   Today
  67   Today_and_Now
  68   Add_Delta_YM
  69   Add_Delta_DHMS
  70   Date_to_Days
  71   Day_of_Week
  72   Add_Delta_Days
  73 );
  74 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  75
  76 BEGIN {
  77         require Exporter;
  78         @ISA    = qw(Exporter);
  79
  80         # FIXME subs that should probably be elsewhere
  81         push @EXPORT, qw(
  82                 &barcodedecode
  83         &LostItem
  84         &ReturnLostItem
  85         &GetPendingOnSiteCheckouts
  86         );
  87
  88         # subs to deal with issuing a book
  89         push @EXPORT, qw(
  90                 &CanBookBeIssued
  91                 &CanBookBeRenewed
  92                 &AddIssue
  93                 &AddRenewal
  94                 &GetRenewCount
  95         &GetSoonestRenewDate
  96         &GetLatestAutoRenewDate
  97                 &GetIssuingCharges
  98         &GetBranchBorrowerCircRule
  99         &GetBranchItemRule
 100                 &GetBiblioIssues
 101                 &GetOpenIssue
 102         &CheckIfIssuedToPatron
 103         &IsItemIssued
 104         GetTopIssues
 105         );
 106
 107         # subs to deal with returns
 108         push @EXPORT, qw(
 109                 &AddReturn
 110         &MarkIssueReturned
 111         );
 112
 113         # subs to deal with transfers
 114         push @EXPORT, qw(
 115                 &transferbook
 116                 &GetTransfers
 117                 &GetTransfersFromTo
 118                 &updateWrongTransfer
 119                 &DeleteTransfer
 120                 &IsBranchTransferAllowed
 121                 &CreateBranchTransferLimit
 122                 &DeleteBranchTransferLimits
 123         &TransferSlip
 124         );
 125
 126     # subs to deal with offline circulation
 127     push @EXPORT, qw(
 128       &GetOfflineOperations
 129       &GetOfflineOperation
 130       &AddOfflineOperation
 131       &DeleteOfflineOperation
 132       &ProcessOfflineOperation
 133     );
 134 }
 135
 136 =head1 NAME
 137
 138 C4::Circulation - Koha circulation module
 139
 140 =head1 SYNOPSIS
 141
 142 use C4::Circulation;
 143
 144 =head1 DESCRIPTION
 145
 146 The functions in this module deal with circulation, issues, and
 147 returns, as well as general information about the library.
 148 Also deals with inventory.
 149
 150 =head1 FUNCTIONS
 151
 152 =head2 barcodedecode
 153
 154   $str = &barcodedecode($barcode, [$filter]);
 155
 156 Generic filter function for barcode string.
 157 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 158 Will do some manipulation of the barcode for systems that deliver a barcode
 159 to circulation.pl that differs from the barcode stored for the item.
 160 For proper functioning of this filter, calling the function on the
 161 correct barcode string (items.barcode) should return an unaltered barcode.
 162
 163 The optional $filter argument is to allow for testing or explicit
 164 behavior that ignores the System Pref.  Valid values are the same as the
 165 System Pref options.
 166
 167 =cut
 168
 169 # FIXME -- the &decode fcn below should be wrapped into this one.
 170 # FIXME -- these plugins should be moved out of Circulation.pm
 171 #
 172 sub barcodedecode {
 173     my ($barcode, $filter) = @_;
 174     my $branch = C4::Context::mybranch();
 175     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 176     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 177         if ($filter eq 'whitespace') {
 178                 $barcode =~ s/\s//g;
 179         } elsif ($filter eq 'cuecat') {
 180                 chomp($barcode);
 181             my @fields = split( /\./, $barcode );
 182             my @results = map( decode($_), @fields[ 1 .. $#fields ] );
 183             ($#results == 2) and return $results[2];
 184         } elsif ($filter eq 'T-prefix') {
 185                 if ($barcode =~ /^[Tt](\d)/) {
 186                         (defined($1) and $1 eq '0') and return $barcode;
 187             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 188                 }
 189         return sprintf("T%07d", $barcode);
 190         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 191         # Why drop the nonzero digit after the T?
 192         # Why pass non-digits (or empty string) to "T%07d"?
 193         } elsif ($filter eq 'libsuite8') {
 194                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 195                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 196                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 197                         }else{
 198                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 199                         }
 200                 }
 201     } elsif ($filter eq 'EAN13') {
 202         my $ean = CheckDigits('ean');
 203         if ( $ean->is_valid($barcode) ) {
 204             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 205             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 206         } else {
 207             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 208         }
 209         }
 210     return $barcode;    # return barcode, modified or not
 211 }
 212
 213 =head2 decode
 214
 215   $str = &decode($chunk);
 216
 217 Decodes a segment of a string emitted by a CueCat barcode scanner and
 218 returns it.
 219
 220 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 221 or Javascript based decoding on the client side.
 222
 223 =cut
 224
 225 sub decode {
 226     my ($encoded) = @_;
 227     my $seq =
 228       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 229     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 230     my $l = ( $#s + 1 ) % 4;
 231     if ($l) {
 232         if ( $l == 1 ) {
 233             # warn "Error: Cuecat decode parsing failed!";
 234             return;
 235         }
 236         $l = 4 - $l;
 237         $#s += $l;
 238     }
 239     my $r = '';
 240     while ( $#s >= 0 ) {
 241         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 242         $r .=
 243             chr( ( $n >> 16 ) ^ 67 )
 244          .chr( ( $n >> 8 & 255 ) ^ 67 )
 245          .chr( ( $n & 255 ) ^ 67 );
 246         @s = @s[ 4 .. $#s ];
 247     }
 248     $r = substr( $r, 0, length($r) - $l );
 249     return $r;
 250 }
 251
 252 =head2 transferbook
 253
 254   ($dotransfer, $messages, $iteminformation) = &transferbook({
 255                                                    from_branch => $frombranch
 256                                                    to_branch => $tobranch,
 257                                                    barcode => $barcode,
 258                                                    ignore_reserves => $ignore_reserves,
 259                                                    trigger => $trigger
 260                                                 });
 261
 262 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 263
 264 C<$fbr> is the code for the branch initiating the transfer.
 265 C<$tbr> is the code for the branch to which the item should be transferred.
 266
 267 C<$barcode> is the barcode of the item to be transferred.
 268
 269 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 270 Otherwise, if an item is reserved, the transfer fails.
 271
 272 C<$trigger> is the enum value for what triggered the transfer.
 273
 274 Returns three values:
 275
 276 =over
 277
 278 =item $dotransfer
 279
 280 is true if the transfer was successful.
 281
 282 =item $messages
 283
 284 is a reference-to-hash which may have any of the following keys:
 285
 286 =over
 287
 288 =item C<BadBarcode>
 289
 290 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 291
 292 =item C<DestinationEqualsHolding>
 293
 294 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 295
 296 =item C<WasReturned>
 297
 298 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 299
 300 =item C<ResFound>
 301
 302 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 303
 304 =item C<WasTransferred>
 305
 306 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 307
 308 =back
 309
 310 =back
 311
 312 =cut
 313
 314 sub transferbook {
 315     my $params = shift;
 316     my $tbr      = $params->{to_branch};
 317     my $fbr      = $params->{from_branch};
 318     my $ignoreRs = $params->{ignore_reserves};
 319     my $barcode  = $params->{barcode};
 320     my $trigger  = $params->{trigger};
 321     my $messages;
 322     my $dotransfer      = 1;
 323     my $item = Koha::Items->find( { barcode => $barcode } );
 324
 325     Koha::Exceptions::MissingParameter->throw(
 326         "Missing mandatory parameter: from_branch")
 327       unless $fbr;
 328
 329     Koha::Exceptions::MissingParameter->throw(
 330         "Missing mandatory parameter: to_branch")
 331       unless $tbr;
 332
 333     # bad barcode..
 334     unless ( $item ) {
 335         $messages->{'BadBarcode'} = $barcode;
 336         $dotransfer = 0;
 337         return ( $dotransfer, $messages );
 338     }
 339
 340     my $itemnumber = $item->itemnumber;
 341     # get branches of book...
 342     my $hbr = $item->homebranch;
 343
 344     # if using Branch Transfer Limits
 345     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 346         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 347         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 348             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 349                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 350                 $dotransfer = 0;
 351             }
 352         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 353             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 354             $dotransfer = 0;
 355         }
 356     }
 357
 358     # can't transfer book if is already there....
 359     if ( $fbr eq $tbr ) {
 360         $messages->{'DestinationEqualsHolding'} = 1;
 361         $dotransfer = 0;
 362     }
 363
 364     # check if it is still issued to someone, return it...
 365     my $issue = Koha::Checkouts->find({ itemnumber => $itemnumber });
 366     if ( $issue ) {
 367         AddReturn( $barcode, $fbr );
 368         $messages->{'WasReturned'} = $issue->borrowernumber;
 369     }
 370
 371     # find reserves.....
 372     # That'll save a database query.
 373     my ( $resfound, $resrec, undef ) =
 374       CheckReserves( $itemnumber );
 375     if ( $resfound and not $ignoreRs ) {
 376         $resrec->{'ResFound'} = $resfound;
 377         $messages->{'ResFound'} = $resrec;
 378         $dotransfer = 1;
 379     }
 380
 381     #actually do the transfer....
 382     if ($dotransfer) {
 383         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 384
 385         # don't need to update MARC anymore, we do it in batch now
 386         $messages->{'WasTransfered'} = 1;
 387
 388     }
 389     ModDateLastSeen( $itemnumber );
 390     return ( $dotransfer, $messages );
 391 }
 392
 393
 394 sub TooMany {
 395     my $borrower        = shift;
 396     my $item_object = shift;
 397     my $params = shift;
 398     my $onsite_checkout = $params->{onsite_checkout} || 0;
 399     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 400     my $cat_borrower    = $borrower->{'categorycode'};
 401     my $dbh             = C4::Context->dbh;
 402     # Get which branchcode we need
 403     my $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 404     my $type = $item_object->effective_itemtype;
 405
 406     my ($type_object, $parent_type, $parent_maxissueqty_rule);
 407     $type_object = Koha::ItemTypes->find( $type );
 408     $parent_type = $type_object->parent_type if $type_object;
 409     my $child_types = Koha::ItemTypes->search({ parent_type => $type });
 410     # Find any children if we are a parent_type;
 411
 412     # given branch, patron category, and item type, determine
 413     # applicable issuing rule
 414
 415     $parent_maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 416         {
 417             categorycode => $cat_borrower,
 418             itemtype     => $parent_type,
 419             branchcode   => $branch,
 420             rule_name    => 'maxissueqty',
 421         }
 422     ) if $parent_type;
 423     # If the parent rule is for default type we discount it
 424     $parent_maxissueqty_rule = undef if $parent_maxissueqty_rule && !defined $parent_maxissueqty_rule->itemtype;
 425
 426     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 427         {
 428             categorycode => $cat_borrower,
 429             itemtype     => $type,
 430             branchcode   => $branch,
 431             rule_name    => 'maxissueqty',
 432         }
 433     );
 434
 435     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 436         {
 437             categorycode => $cat_borrower,
 438             itemtype     => $type,
 439             branchcode   => $branch,
 440             rule_name    => 'maxonsiteissueqty',
 441         }
 442     );
 443
 444
 445     my $patron = Koha::Patrons->find($borrower->{borrowernumber});
 446     # if a rule is found and has a loan limit set, count
 447     # how many loans the patron already has that meet that
 448     # rule
 449     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne "") {
 450
 451         my $checkouts;
 452         if ( $maxissueqty_rule->branchcode ) {
 453             if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 454                 $checkouts = $patron->checkouts->search(
 455                     { 'me.branchcode' => $maxissueqty_rule->branchcode } );
 456             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 457                 $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 458             } else {
 459                 $checkouts = $patron->checkouts->search(
 460                     { 'item.homebranch' => $maxissueqty_rule->branchcode },
 461                     { prefetch          => 'item' } );
 462             }
 463         } else {
 464             $checkouts = $patron->checkouts; # if rule is not branch specific then count all loans by patron
 465         }
 466         my $sum_checkouts;
 467         my $rule_itemtype = $maxissueqty_rule->itemtype;
 468         while ( my $c = $checkouts->next ) {
 469             my $itemtype = $c->item->effective_itemtype;
 470             my @types;
 471             unless ( $rule_itemtype ) {
 472                 # matching rule has the default item type, so count only
 473                 # those existing loans that don't fall under a more
 474                 # specific rule
 475                 @types = Koha::CirculationRules->search(
 476                     {
 477                         branchcode => $maxissueqty_rule->branchcode,
 478                         categorycode => [ $maxissueqty_rule->categorycode, $cat_borrower ],
 479                         itemtype  => { '!=' => undef },
 480                         rule_name => 'maxissueqty'
 481                     }
 482                 )->get_column('itemtype');
 483
 484                 next if grep {$_ eq $itemtype} @types;
 485             } else {
 486                 my @types;
 487                 if ( $parent_maxissueqty_rule ) {
 488                 # if we have a parent item type then we count loans of the
 489                 # specific item type or its siblings or parent
 490                     my $children = Koha::ItemTypes->search({ parent_type => $parent_type });
 491                     @types = $children->get_column('itemtype');
 492                     push @types, $parent_type;
 493                 } elsif ( $child_types ) {
 494                 # If we are a parent type, we need to count all child types and our own type
 495                     @types = $child_types->get_column('itemtype');
 496                     push @types, $type; # And don't forget to count our own types
 497                 } else { push @types, $type; } # Otherwise only count the specific itemtype
 498
 499                 next unless grep {$_ eq $itemtype} @types;
 500             }
 501             $sum_checkouts->{total}++;
 502             $sum_checkouts->{onsite_checkouts}++ if $c->onsite_checkout;
 503             $sum_checkouts->{itemtype}->{$itemtype}++;
 504         }
 505
 506         my $checkout_count_type = $sum_checkouts->{itemtype}->{$type} || 0;
 507         my $checkout_count = $sum_checkouts->{total} || 0;
 508         my $onsite_checkout_count = $sum_checkouts->{onsite_checkouts} || 0;
 509
 510         my $checkout_rules = {
 511             checkout_count               => $checkout_count,
 512             onsite_checkout_count        => $onsite_checkout_count,
 513             onsite_checkout              => $onsite_checkout,
 514             max_checkouts_allowed        => $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef,
 515             max_onsite_checkouts_allowed => $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef,
 516             switch_onsite_checkout       => $switch_onsite_checkout,
 517         };
 518         # If parent rules exists
 519         if ( defined($parent_maxissueqty_rule) and defined($parent_maxissueqty_rule->rule_value) ){
 520             $checkout_rules->{max_checkouts_allowed} = $parent_maxissueqty_rule ? $parent_maxissueqty_rule->rule_value : undef;
 521             my $qty_over = _check_max_qty($checkout_rules);
 522             return $qty_over if defined $qty_over;
 523
 524             # If the parent rule is less than or equal to the child, we only need check the parent
 525             if( $maxissueqty_rule->rule_value < $parent_maxissueqty_rule->rule_value && defined($maxissueqty_rule->itemtype) ) {
 526                 $checkout_rules->{checkout_count} = $checkout_count_type;
 527                 $checkout_rules->{max_checkouts_allowed} = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 528                 my $qty_over = _check_max_qty($checkout_rules);
 529                 return $qty_over if defined $qty_over;
 530             }
 531         } else {
 532             my $qty_over = _check_max_qty($checkout_rules);
 533             return $qty_over if defined $qty_over;
 534         }
 535     }
 536
 537     # Now count total loans against the limit for the branch
 538     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 539     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 540         my $checkouts;
 541         if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 542             $checkouts = $patron->checkouts->search(
 543                 { 'me.branchcode' => $branch} );
 544         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 545             ; # if branch is the patron's home branch, then count all loans by patron
 546         } else {
 547             $checkouts = $patron->checkouts->search(
 548                 { 'item.homebranch' => $branch} );
 549         }
 550
 551         my $checkout_count = $checkouts->count;
 552         my $onsite_checkout_count = $checkouts->search({ onsite_checkout => 1 })->count;
 553         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 554         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty} || undef;
 555
 556         my $qty_over = _check_max_qty(
 557             {
 558                 checkout_count               => $checkout_count,
 559                 onsite_checkout_count        => $onsite_checkout_count,
 560                 onsite_checkout              => $onsite_checkout,
 561                 max_checkouts_allowed        => $max_checkouts_allowed,
 562                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 563                 switch_onsite_checkout       => $switch_onsite_checkout
 564             }
 565         );
 566         return $qty_over if defined $qty_over;
 567     }
 568
 569     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 570         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 571     }
 572
 573     # OK, the patron can issue !!!
 574     return;
 575 }
 576
 577 sub _check_max_qty {
 578     my $params                       = shift;
 579     my $checkout_count               = $params->{checkout_count};
 580     my $onsite_checkout_count        = $params->{onsite_checkout_count};
 581     my $onsite_checkout              = $params->{onsite_checkout};
 582     my $max_checkouts_allowed        = $params->{max_checkouts_allowed};
 583     my $max_onsite_checkouts_allowed = $params->{max_onsite_checkouts_allowed};
 584     my $switch_onsite_checkout       = $params->{switch_onsite_checkout};
 585
 586     if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 587         if ( $max_onsite_checkouts_allowed eq '' ) { return; }
 588         if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed ) {
 589             return {
 590                 reason      => 'TOO_MANY_ONSITE_CHECKOUTS',
 591                 count       => $onsite_checkout_count,
 592                 max_allowed => $max_onsite_checkouts_allowed,
 593             };
 594         }
 595     }
 596     if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 597         if ( $max_checkouts_allowed eq '' ) { return; }
 598         my $delta = $switch_onsite_checkout ? 1 : 0;
 599         if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 600             return {
 601                 reason      => 'TOO_MANY_CHECKOUTS',
 602                 count       => $checkout_count,
 603                 max_allowed => $max_checkouts_allowed,
 604             };
 605         }
 606     }
 607     elsif ( not $onsite_checkout ) {
 608         if ( $max_checkouts_allowed eq '' ) { return; }
 609         if (
 610             $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )
 611         {
 612             return {
 613                 reason      => 'TOO_MANY_CHECKOUTS',
 614                 count       => $checkout_count - $onsite_checkout_count,
 615                 max_allowed => $max_checkouts_allowed,
 616             };
 617         }
 618     }
 619
 620     return;
 621 }
 622
 623 =head2 CanBookBeIssued
 624
 625   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 626                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 627
 628 Check if a book can be issued.
 629
 630 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 631
 632 IMPORTANT: The assumption by users of this routine is that causes blocking
 633 the issue are keyed by uppercase labels and other returned
 634 data is keyed in lower case!
 635
 636 =over 4
 637
 638 =item C<$patron> is a Koha::Patron
 639
 640 =item C<$barcode> is the bar code of the book being issued.
 641
 642 =item C<$duedates> is a DateTime object.
 643
 644 =item C<$inprocess> boolean switch
 645
 646 =item C<$ignore_reserves> boolean switch
 647
 648 =item C<$params> Hashref of additional parameters
 649
 650 Available keys:
 651     override_high_holds - Ignore high holds
 652     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 653
 654 =back
 655
 656 Returns :
 657
 658 =over 4
 659
 660 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 661 Possible values are :
 662
 663 =back
 664
 665 =head3 INVALID_DATE
 666
 667 sticky due date is invalid
 668
 669 =head3 GNA
 670
 671 borrower gone with no address
 672
 673 =head3 CARD_LOST
 674
 675 borrower declared it's card lost
 676
 677 =head3 DEBARRED
 678
 679 borrower debarred
 680
 681 =head3 UNKNOWN_BARCODE
 682
 683 barcode unknown
 684
 685 =head3 NOT_FOR_LOAN
 686
 687 item is not for loan
 688
 689 =head3 WTHDRAWN
 690
 691 item withdrawn.
 692
 693 =head3 RESTRICTED
 694
 695 item is restricted (set by ??)
 696
 697 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 698 could be prevented, but ones that can be overriden by the operator.
 699
 700 Possible values are :
 701
 702 =head3 DEBT
 703
 704 borrower has debts.
 705
 706 =head3 RENEW_ISSUE
 707
 708 renewing, not issuing
 709
 710 =head3 ISSUED_TO_ANOTHER
 711
 712 issued to someone else.
 713
 714 =head3 RESERVED
 715
 716 reserved for someone else.
 717
 718 =head3 INVALID_DATE
 719
 720 sticky due date is invalid or due date in the past
 721
 722 =head3 TOO_MANY
 723
 724 if the borrower borrows to much things
 725
 726 =cut
 727
 728 sub CanBookBeIssued {
 729     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 730     my %needsconfirmation;    # filled with problems that needs confirmations
 731     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 732     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 733     my %messages;             # filled with information messages that should be displayed.
 734
 735     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 736     my $override_high_holds = $params->{override_high_holds} || 0;
 737
 738     my $item_object = Koha::Items->find({barcode => $barcode });
 739
 740     # MANDATORY CHECKS - unless item exists, nothing else matters
 741     unless ( $item_object ) {
 742         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 743     }
 744     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 745
 746     my $item_unblessed = $item_object->unblessed; # Transition...
 747     my $issue = $item_object->checkout;
 748     my $biblio = $item_object->biblio;
 749
 750     my $biblioitem = $biblio->biblioitem;
 751     my $effective_itemtype = $item_object->effective_itemtype;
 752     my $dbh             = C4::Context->dbh;
 753     my $patron_unblessed = $patron->unblessed;
 754
 755     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 756     #
 757     # DUE DATE is OK ? -- should already have checked.
 758     #
 759     if ($duedate && ref $duedate ne 'DateTime') {
 760         $duedate = dt_from_string($duedate);
 761     }
 762     my $now = dt_from_string();
 763     unless ( $duedate ) {
 764         my $issuedate = $now->clone();
 765
 766         $duedate = CalcDateDue( $issuedate, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 767
 768         # Offline circ calls AddIssue directly, doesn't run through here
 769         #  So issuingimpossible should be ok.
 770     }
 771
 772     my $fees = Koha::Charges::Fees->new(
 773         {
 774             patron    => $patron,
 775             library   => $circ_library,
 776             item      => $item_object,
 777             to_date   => $duedate,
 778         }
 779     );
 780
 781     if ($duedate) {
 782         my $today = $now->clone();
 783         $today->truncate( to => 'minute');
 784         if (DateTime->compare($duedate,$today) == -1 ) { # duedate cannot be before now
 785             $needsconfirmation{INVALID_DATE} = output_pref($duedate);
 786         }
 787     } else {
 788             $issuingimpossible{INVALID_DATE} = output_pref($duedate);
 789     }
 790
 791     #
 792     # BORROWER STATUS
 793     #
 794     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 795         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 796         &UpdateStats({
 797                      branch => C4::Context->userenv->{'branch'},
 798                      type => 'localuse',
 799                      itemnumber => $item_object->itemnumber,
 800                      itemtype => $effective_itemtype,
 801                      borrowernumber => $patron->borrowernumber,
 802                      ccode => $item_object->ccode}
 803                     );
 804         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 805         return( { STATS => 1 }, {});
 806     }
 807
 808     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 809         $issuingimpossible{GNA} = 1;
 810     }
 811
 812     if ( $patron->lost && $patron->lost == 1 ) {
 813         $issuingimpossible{CARD_LOST} = 1;
 814     }
 815     if ( $patron->is_debarred ) {
 816         $issuingimpossible{DEBARRED} = 1;
 817     }
 818
 819     if ( $patron->is_expired ) {
 820         $issuingimpossible{EXPIRED} = 1;
 821     }
 822
 823     #
 824     # BORROWER STATUS
 825     #
 826
 827     # DEBTS
 828     my $account = $patron->account;
 829     my $balance = $account->balance;
 830     my $non_issues_charges = $account->non_issues_charges;
 831     my $other_charges = $balance - $non_issues_charges;
 832
 833     my $amountlimit = C4::Context->preference("noissuescharge");
 834     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 835     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 836
 837     # Check the debt of this patrons guarantees
 838     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 839     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 840     if ( defined $no_issues_charge_guarantees ) {
 841         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships();
 842         my $guarantees_non_issues_charges;
 843         foreach my $g ( @guarantees ) {
 844             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 845         }
 846
 847         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 848             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 849         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 850             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 851         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 852             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 853         }
 854     }
 855
 856     if ( C4::Context->preference("IssuingInProcess") ) {
 857         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 858             $issuingimpossible{DEBT} = $non_issues_charges;
 859         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 860             $needsconfirmation{DEBT} = $non_issues_charges;
 861         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 862             $needsconfirmation{DEBT} = $non_issues_charges;
 863         }
 864     }
 865     else {
 866         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 867             $needsconfirmation{DEBT} = $non_issues_charges;
 868         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 869             $issuingimpossible{DEBT} = $non_issues_charges;
 870         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 871             $needsconfirmation{DEBT} = $non_issues_charges;
 872         }
 873     }
 874
 875     if ($balance > 0 && $other_charges > 0) {
 876         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 877     }
 878
 879     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 880     $patron_unblessed = $patron->unblessed;
 881
 882     if ( my $debarred_date = $patron->is_debarred ) {
 883          # patron has accrued fine days or has a restriction. $count is a date
 884         if ($debarred_date eq '9999-12-31') {
 885             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 886         }
 887         else {
 888             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 889         }
 890     } elsif ( my $num_overdues = $patron->has_overdues ) {
 891         ## patron has outstanding overdue loans
 892         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 893             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 894         }
 895         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 896             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 897         }
 898     }
 899
 900     # Additional Materials Check
 901     if ( C4::Context->preference("CircConfirmItemParts")
 902         && $item_object->materials )
 903     {
 904         $needsconfirmation{ADDITIONAL_MATERIALS} = $item_object->materials;
 905     }
 906
 907     #
 908     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 909     #
 910     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 911
 912         # Already issued to current borrower.
 913         # If it is an on-site checkout if it can be switched to a normal checkout
 914         # or ask whether the loan should be renewed
 915
 916         if ( $issue->onsite_checkout
 917                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 918             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 919         } else {
 920             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 921                 $patron->borrowernumber,
 922                 $item_object->itemnumber,
 923             );
 924             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 925                 if ( $renewerror eq 'onsite_checkout' ) {
 926                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 927                 }
 928                 else {
 929                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 930                 }
 931             }
 932             else {
 933                 $needsconfirmation{RENEW_ISSUE} = 1;
 934             }
 935         }
 936     }
 937     elsif ( $issue ) {
 938
 939         # issued to someone else
 940
 941         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 942
 943         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 944
 945         unless ( $can_be_returned ) {
 946             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 947             $issuingimpossible{branch_to_return} = $message;
 948         } else {
 949             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 950                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 951             } else {
 952             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 953             $needsconfirmation{issued_firstname} = $patron->firstname;
 954             $needsconfirmation{issued_surname} = $patron->surname;
 955             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 956             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 957             }
 958         }
 959     }
 960
 961     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
 962     #
 963     my $switch_onsite_checkout = (
 964           C4::Context->preference('SwitchOnSiteCheckouts')
 965       and $issue
 966       and $issue->onsite_checkout
 967       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
 968     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
 969     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
 970     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
 971         if ( $toomany->{max_allowed} == 0 ) {
 972             $needsconfirmation{PATRON_CANT} = 1;
 973         }
 974         if ( C4::Context->preference("AllowTooManyOverride") ) {
 975             $needsconfirmation{TOO_MANY} = $toomany->{reason};
 976             $needsconfirmation{current_loan_count} = $toomany->{count};
 977             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
 978         } else {
 979             $issuingimpossible{TOO_MANY} = $toomany->{reason};
 980             $issuingimpossible{current_loan_count} = $toomany->{count};
 981             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
 982         }
 983     }
 984
 985     #
 986     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
 987     #
 988     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 989     my $wants_check = $patron->wants_check_for_previous_checkout;
 990     $needsconfirmation{PREVISSUE} = 1
 991         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
 992
 993     #
 994     # ITEM CHECKING
 995     #
 996     if ( $item_object->notforloan )
 997     {
 998         if(!C4::Context->preference("AllowNotForLoanOverride")){
 999             $issuingimpossible{NOT_FOR_LOAN} = 1;
1000             $issuingimpossible{item_notforloan} = $item_object->notforloan;
1001         }else{
1002             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1003             $needsconfirmation{item_notforloan} = $item_object->notforloan;
1004         }
1005     }
1006     else {
1007         # we have to check itemtypes.notforloan also
1008         if (C4::Context->preference('item-level_itypes')){
1009             # this should probably be a subroutine
1010             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
1011             $sth->execute($effective_itemtype);
1012             my $notforloan=$sth->fetchrow_hashref();
1013             if ($notforloan->{'notforloan'}) {
1014                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1015                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1016                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1017                 } else {
1018                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1019                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1020                 }
1021             }
1022         }
1023         else {
1024             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
1025             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
1026                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1027                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1028                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1029                 } else {
1030                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1031                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1032                 }
1033             }
1034         }
1035     }
1036     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
1037     {
1038         $issuingimpossible{WTHDRAWN} = 1;
1039     }
1040     if (   $item_object->restricted
1041         && $item_object->restricted == 1 )
1042     {
1043         $issuingimpossible{RESTRICTED} = 1;
1044     }
1045     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
1046         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
1047         my $code = $av->count ? $av->next->lib : '';
1048         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
1049         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
1050     }
1051     if ( C4::Context->preference("IndependentBranches") ) {
1052         my $userenv = C4::Context->userenv;
1053         unless ( C4::Context->IsSuperLibrarian() ) {
1054             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
1055             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
1056                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
1057                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
1058             }
1059             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1060               if ( $patron->branchcode ne $userenv->{branch} );
1061         }
1062     }
1063
1064     #
1065     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1066     #
1067     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1068     if ($rentalConfirmation) {
1069         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1070
1071         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1072         if ($itemtype_object) {
1073             my $accumulate_charge = $fees->accumulate_rentalcharge();
1074             if ( $accumulate_charge > 0 ) {
1075                 $rentalCharge += $accumulate_charge;
1076             }
1077         }
1078
1079         if ( $rentalCharge > 0 ) {
1080             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1081         }
1082     }
1083
1084     unless ( $ignore_reserves ) {
1085         # See if the item is on reserve.
1086         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1087         if ($restype) {
1088             my $resbor = $res->{'borrowernumber'};
1089             if ( $resbor ne $patron->borrowernumber ) {
1090                 my $patron = Koha::Patrons->find( $resbor );
1091                 if ( $restype eq "Waiting" )
1092                 {
1093                     # The item is on reserve and waiting, but has been
1094                     # reserved by some other patron.
1095                     $needsconfirmation{RESERVE_WAITING} = 1;
1096                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1097                     $needsconfirmation{'ressurname'} = $patron->surname;
1098                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1099                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1100                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1101                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1102                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1103                 }
1104                 elsif ( $restype eq "Reserved" ) {
1105                     # The item is on reserve for someone else.
1106                     $needsconfirmation{RESERVED} = 1;
1107                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1108                     $needsconfirmation{'ressurname'} = $patron->surname;
1109                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1110                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1111                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1112                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1113                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1114                 }
1115             }
1116         }
1117     }
1118
1119     ## CHECK AGE RESTRICTION
1120     my $agerestriction  = $biblioitem->agerestriction;
1121     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1122     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1123         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1124             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1125         }
1126         else {
1127             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1128         }
1129     }
1130
1131     ## check for high holds decreasing loan period
1132     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1133         my $check = checkHighHolds( $item_unblessed, $patron_unblessed );
1134
1135         if ( $check->{exceeded} ) {
1136             if ($override_high_holds) {
1137                 $alerts{HIGHHOLDS} = {
1138                     num_holds  => $check->{outstanding},
1139                     duration   => $check->{duration},
1140                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1141                 };
1142             }
1143             else {
1144                 $needsconfirmation{HIGHHOLDS} = {
1145                     num_holds  => $check->{outstanding},
1146                     duration   => $check->{duration},
1147                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1148                 };
1149             }
1150         }
1151     }
1152
1153     if (
1154         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1155         # don't do the multiple loans per bib check if we've
1156         # already determined that we've got a loan on the same item
1157         !$issuingimpossible{NO_MORE_RENEWALS} &&
1158         !$needsconfirmation{RENEW_ISSUE}
1159     ) {
1160         # Check if borrower has already issued an item from the same biblio
1161         # Only if it's not a subscription
1162         my $biblionumber = $item_object->biblionumber;
1163         require C4::Serials;
1164         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1165         unless ($is_a_subscription) {
1166             # FIXME Should be $patron->checkouts($args);
1167             my $checkouts = Koha::Checkouts->search(
1168                 {
1169                     borrowernumber => $patron->borrowernumber,
1170                     biblionumber   => $biblionumber,
1171                 },
1172                 {
1173                     join => 'item',
1174                 }
1175             );
1176             # if we get here, we don't already have a loan on this item,
1177             # so if there are any loans on this bib, ask for confirmation
1178             if ( $checkouts->count ) {
1179                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1180             }
1181         }
1182     }
1183
1184     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1185 }
1186
1187 =head2 CanBookBeReturned
1188
1189   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1190
1191 Check whether the item can be returned to the provided branch
1192
1193 =over 4
1194
1195 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1196
1197 =item C<$branch> is the branchcode where the return is taking place
1198
1199 =back
1200
1201 Returns:
1202
1203 =over 4
1204
1205 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1206
1207 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1208
1209 =back
1210
1211 =cut
1212
1213 sub CanBookBeReturned {
1214   my ($item, $branch) = @_;
1215   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1216
1217   # assume return is allowed to start
1218   my $allowed = 1;
1219   my $message;
1220
1221   # identify all cases where return is forbidden
1222   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1223      $allowed = 0;
1224      $message = $item->{'homebranch'};
1225   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1226      $allowed = 0;
1227      $message = $item->{'holdingbranch'};
1228   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1229      $allowed = 0;
1230      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1231   }
1232
1233   return ($allowed, $message);
1234 }
1235
1236 =head2 CheckHighHolds
1237
1238     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1239     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1240     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1241
1242 =cut
1243
1244 sub checkHighHolds {
1245     my ( $item, $borrower ) = @_;
1246     my $branchcode = _GetCircControlBranch( $item, $borrower );
1247     my $item_object = Koha::Items->find( $item->{itemnumber} );
1248
1249     my $return_data = {
1250         exceeded    => 0,
1251         outstanding => 0,
1252         duration    => 0,
1253         due_date    => undef,
1254     };
1255
1256     my $holds = Koha::Holds->search( { biblionumber => $item->{'biblionumber'} } );
1257
1258     if ( $holds->count() ) {
1259         $return_data->{outstanding} = $holds->count();
1260
1261         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1262         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1263         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1264
1265         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1266
1267         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1268
1269             # static means just more than a given number of holds on the record
1270
1271             # If the number of holds is less than the threshold, we can stop here
1272             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1273                 return $return_data;
1274             }
1275         }
1276         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1277
1278             # dynamic means X more than the number of holdable items on the record
1279
1280             # let's get the items
1281             my @items = $holds->next()->biblio()->items()->as_list;
1282
1283             # Remove any items with status defined to be ignored even if the would not make item unholdable
1284             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1285                 @items = grep { !$_->$status } @items;
1286             }
1287
1288             # Remove any items that are not holdable for this patron
1289             @items = grep { CanItemBeReserved( $borrower->{borrowernumber}, $_->itemnumber, undef, { ignore_found_holds => 1 } )->{status} eq 'OK' } @items;
1290
1291             my $items_count = scalar @items;
1292
1293             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1294
1295             # If the number of holds is less than the count of items we have
1296             # plus the number of holds allowed above that count, we can stop here
1297             if ( $holds->count() <= $threshold ) {
1298                 return $return_data;
1299             }
1300         }
1301
1302         my $issuedate = dt_from_string();
1303
1304         my $itype = $item_object->effective_itemtype;
1305         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1306             {
1307                 categorycode => $borrower->{categorycode},
1308                 itemtype     => $itype,
1309                 branchcode   => $branchcode,
1310             }
1311         );
1312         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1313
1314         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1315
1316         my $decreaseLoanHighHoldsDuration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1317
1318         my $reduced_datedue = $calendar->addDate( $issuedate, $decreaseLoanHighHoldsDuration );
1319         $reduced_datedue->set_hour($orig_due->hour);
1320         $reduced_datedue->set_minute($orig_due->minute);
1321         $reduced_datedue->truncate( to => 'minute' );
1322
1323         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1324             $return_data->{exceeded} = 1;
1325             $return_data->{duration} = $decreaseLoanHighHoldsDuration;
1326             $return_data->{due_date} = $reduced_datedue;
1327         }
1328     }
1329
1330     return $return_data;
1331 }
1332
1333 =head2 AddIssue
1334
1335   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1336
1337 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1338
1339 =over 4
1340
1341 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1342
1343 =item C<$barcode> is the barcode of the item being issued.
1344
1345 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1346 Calculated if empty.
1347
1348 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1349
1350 =item C<$issuedate> is the date to issue the item in iso (YYYY-MM-DD) format (optional).
1351 Defaults to today.  Unlike C<$datedue>, NOT a DateTime object, unfortunately.
1352
1353 AddIssue does the following things :
1354
1355   - step 01: check that there is a borrowernumber & a barcode provided
1356   - check for RENEWAL (book issued & being issued to the same patron)
1357       - renewal YES = Calculate Charge & renew
1358       - renewal NO  =
1359           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1360           * RESERVE PLACED ?
1361               - fill reserve if reserve to this patron
1362               - cancel reserve or not, otherwise
1363           * TRANSFERT PENDING ?
1364               - complete the transfert
1365           * ISSUE THE BOOK
1366
1367 =back
1368
1369 =cut
1370
1371 sub AddIssue {
1372     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1373
1374     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1375     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1376     my $auto_renew = $params && $params->{auto_renew};
1377     my $dbh          = C4::Context->dbh;
1378     my $barcodecheck = CheckValidBarcode($barcode);
1379
1380     my $issue;
1381
1382     if ( $datedue && ref $datedue ne 'DateTime' ) {
1383         $datedue = dt_from_string($datedue);
1384     }
1385
1386     # $issuedate defaults to today.
1387     if ( !defined $issuedate ) {
1388         $issuedate = dt_from_string();
1389     }
1390     else {
1391         if ( ref $issuedate ne 'DateTime' ) {
1392             $issuedate = dt_from_string($issuedate);
1393
1394         }
1395     }
1396
1397     # Stop here if the patron or barcode doesn't exist
1398     if ( $borrower && $barcode && $barcodecheck ) {
1399         # find which item we issue
1400         my $item_object = Koha::Items->find({ barcode => $barcode })
1401           or return;    # if we don't get an Item, abort.
1402         my $item_unblessed = $item_object->unblessed;
1403
1404         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1405
1406         # get actual issuing if there is one
1407         my $actualissue = $item_object->checkout;
1408
1409         # check if we just renew the issue.
1410         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1411                 and not $switch_onsite_checkout ) {
1412             $datedue = AddRenewal(
1413                 $borrower->{'borrowernumber'},
1414                 $item_object->itemnumber,
1415                 $branchcode,
1416                 $datedue,
1417                 $issuedate,    # here interpreted as the renewal date
1418             );
1419         }
1420         else {
1421             unless ($datedue) {
1422                 my $itype = $item_object->effective_itemtype;
1423                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1424
1425             }
1426             $datedue->truncate( to => 'minute' );
1427
1428             my $patron = Koha::Patrons->find( $borrower );
1429             my $library = Koha::Libraries->find( $branchcode );
1430             my $fees = Koha::Charges::Fees->new(
1431                 {
1432                     patron    => $patron,
1433                     library   => $library,
1434                     item      => $item_object,
1435                     to_date   => $datedue,
1436                 }
1437             );
1438
1439             # it's NOT a renewal
1440             if ( $actualissue and not $switch_onsite_checkout ) {
1441                 # This book is currently on loan, but not to the person
1442                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1443                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1444                 return unless $allowed;
1445                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1446             }
1447
1448             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1449
1450             # Starting process for transfer job (checking transfert and validate it if we have one)
1451             if ( my $transfer = $item_object->get_transfer ) {
1452                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1453                 $transfer->set(
1454                     {
1455                         datearrived => dt_from_string,
1456                         tobranch    => C4::Context->userenv->{branch},
1457                         comments    => 'Forced branchtransfer'
1458                     }
1459                 )->store;
1460                 if ( $transfer->reason && $transfer->reason eq 'Reserve' ) {
1461                     my $hold = $item_object->holds->search( { found => 'T' } )->next;
1462                     if ( $hold ) { # Is this really needed?
1463                         $hold->set( { found => undef } )->store;
1464                         C4::Reserves::ModReserveMinusPriority($item_object->itemnumber, $hold->reserve_id);
1465                     }
1466                 }
1467             }
1468
1469             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1470             unless ($auto_renew) {
1471                 my $rule = Koha::CirculationRules->get_effective_rule(
1472                     {
1473                         categorycode => $borrower->{categorycode},
1474                         itemtype     => $item_object->effective_itemtype,
1475                         branchcode   => $branchcode,
1476                         rule_name    => 'auto_renew'
1477                     }
1478                 );
1479
1480                 $auto_renew = $rule->rule_value if $rule;
1481             }
1482
1483             # Record in the database the fact that the book was issued.
1484             unless ($datedue) {
1485                 my $itype = $item_object->effective_itemtype;
1486                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1487
1488             }
1489             $datedue->truncate( to => 'minute' );
1490
1491             my $issue_attributes = {
1492                 borrowernumber  => $borrower->{'borrowernumber'},
1493                 issuedate       => $issuedate->strftime('%Y-%m-%d %H:%M:%S'),
1494                 date_due        => $datedue->strftime('%Y-%m-%d %H:%M:%S'),
1495                 branchcode      => C4::Context->userenv->{'branch'},
1496                 onsite_checkout => $onsite_checkout,
1497                 auto_renew      => $auto_renew ? 1 : 0,
1498             };
1499
1500             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1501             if ($issue) {
1502                 $issue->set($issue_attributes)->store;
1503             }
1504             else {
1505                 $issue = Koha::Checkout->new(
1506                     {
1507                         itemnumber => $item_object->itemnumber,
1508                         %$issue_attributes,
1509                     }
1510                 )->store;
1511             }
1512             if ( $item_object->location && $item_object->location eq 'CART'
1513                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1514             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1515                 CartToShelf( $item_object->itemnumber );
1516             }
1517
1518             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1519                 UpdateTotalIssues( $item_object->biblionumber, 1 );
1520             }
1521
1522             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1523             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1524             $item_object->itemlost(0);
1525             $item_object->onloan($datedue->ymd());
1526             $item_object->datelastborrowed( dt_from_string()->ymd() );
1527             $item_object->store({log_action => 0});
1528             ModDateLastSeen( $item_object->itemnumber );
1529
1530             # If it costs to borrow this book, charge it to the patron's account.
1531             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1532             if ( $charge && $charge > 0 ) {
1533                 AddIssuingCharge( $issue, $charge, 'RENT' );
1534             }
1535
1536             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1537             if ( $itemtype_object ) {
1538                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1539                 if ( $accumulate_charge > 0 ) {
1540                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1541                     $charge += $accumulate_charge;
1542                     $item_unblessed->{charge} = $charge;
1543                 }
1544             }
1545
1546             # Record the fact that this book was issued.
1547             &UpdateStats(
1548                 {
1549                     branch => C4::Context->userenv->{'branch'},
1550                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1551                     amount         => $charge,
1552                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1553                     itemnumber     => $item_object->itemnumber,
1554                     itemtype       => $item_object->effective_itemtype,
1555                     location       => $item_object->location,
1556                     borrowernumber => $borrower->{'borrowernumber'},
1557                     ccode          => $item_object->ccode,
1558                 }
1559             );
1560
1561             # Send a checkout slip.
1562             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1563             my %conditions        = (
1564                 branchcode   => $branchcode,
1565                 categorycode => $borrower->{categorycode},
1566                 item_type    => $item_object->effective_itemtype,
1567                 notification => 'CHECKOUT',
1568             );
1569             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1570                 SendCirculationAlert(
1571                     {
1572                         type     => 'CHECKOUT',
1573                         item     => $item_object->unblessed,
1574                         borrower => $borrower,
1575                         branch   => $branchcode,
1576                     }
1577                 );
1578             }
1579             logaction(
1580                 "CIRCULATION", "ISSUE",
1581                 $borrower->{'borrowernumber'},
1582                 $item_object->itemnumber,
1583             ) if C4::Context->preference("IssueLog");
1584
1585             Koha::Plugins->call('after_circ_action', {
1586                 action  => 'checkout',
1587                 payload => {
1588                     type     => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1589                     checkout => $issue->get_from_storage
1590                 }
1591             });
1592         }
1593     }
1594     return $issue;
1595 }
1596
1597 =head2 GetLoanLength
1598
1599   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1600
1601 Get loan length for an itemtype, a borrower type and a branch
1602
1603 =cut
1604
1605 sub GetLoanLength {
1606     my ( $categorycode, $itemtype, $branchcode ) = @_;
1607
1608     # Initialize default values
1609     my $rules = {
1610         issuelength   => 0,
1611         renewalperiod => 0,
1612         lengthunit    => 'days',
1613     };
1614
1615     my $found = Koha::CirculationRules->get_effective_rules( {
1616         branchcode => $branchcode,
1617         categorycode => $categorycode,
1618         itemtype => $itemtype,
1619         rules => [
1620             'issuelength',
1621             'renewalperiod',
1622             'lengthunit'
1623         ],
1624     } );
1625
1626     # Search for rules!
1627     foreach my $rule_name (keys %$found) {
1628         $rules->{$rule_name} = $found->{$rule_name};
1629     }
1630
1631     return $rules;
1632 }
1633
1634
1635 =head2 GetHardDueDate
1636
1637   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1638
1639 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1640
1641 =cut
1642
1643 sub GetHardDueDate {
1644     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1645
1646     my $rules = Koha::CirculationRules->get_effective_rules(
1647         {
1648             categorycode => $borrowertype,
1649             itemtype     => $itemtype,
1650             branchcode   => $branchcode,
1651             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1652         }
1653     );
1654
1655     if ( defined( $rules->{hardduedate} ) ) {
1656         if ( $rules->{hardduedate} ) {
1657             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1658         }
1659         else {
1660             return ( undef, undef );
1661         }
1662     }
1663 }
1664
1665 =head2 GetBranchBorrowerCircRule
1666
1667   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1668
1669 Retrieves circulation rule attributes that apply to the given
1670 branch and patron category, regardless of item type.
1671 The return value is a hashref containing the following key:
1672
1673 patron_maxissueqty - maximum number of loans that a
1674 patron of the given category can have at the given
1675 branch.  If the value is undef, no limit.
1676
1677 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1678 patron of the given category can have at the given
1679 branch.  If the value is undef, no limit.
1680
1681 This will check for different branch/category combinations in the following order:
1682 branch and category
1683 branch only
1684 category only
1685 default branch and category
1686
1687 If no rule has been found in the database, it will default to
1688 the buillt in rule:
1689
1690 patron_maxissueqty - undef
1691 patron_maxonsiteissueqty - undef
1692
1693 C<$branchcode> and C<$categorycode> should contain the
1694 literal branch code and patron category code, respectively - no
1695 wildcards.
1696
1697 =cut
1698
1699 sub GetBranchBorrowerCircRule {
1700     my ( $branchcode, $categorycode ) = @_;
1701
1702     # Initialize default values
1703     my $rules = {
1704         patron_maxissueqty       => undef,
1705         patron_maxonsiteissueqty => undef,
1706     };
1707
1708     # Search for rules!
1709     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1710         my $rule = Koha::CirculationRules->get_effective_rule(
1711             {
1712                 categorycode => $categorycode,
1713                 itemtype     => undef,
1714                 branchcode   => $branchcode,
1715                 rule_name    => $rule_name,
1716             }
1717         );
1718
1719         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1720     }
1721
1722     return $rules;
1723 }
1724
1725 =head2 GetBranchItemRule
1726
1727   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1728
1729 Retrieves circulation rule attributes that apply to the given
1730 branch and item type, regardless of patron category.
1731
1732 The return value is a hashref containing the following keys:
1733
1734 holdallowed => Hold policy for this branch and itemtype. Possible values:
1735   0: No holds allowed.
1736   1: Holds allowed only by patrons that have the same homebranch as the item.
1737   2: Holds allowed from any patron.
1738
1739 returnbranch => branch to which to return item.  Possible values:
1740   noreturn: do not return, let item remain where checked in (floating collections)
1741   homebranch: return to item's home branch
1742   holdingbranch: return to issuer branch
1743
1744 This searches branchitemrules in the following order:
1745
1746   * Same branchcode and itemtype
1747   * Same branchcode, itemtype '*'
1748   * branchcode '*', same itemtype
1749   * branchcode and itemtype '*'
1750
1751 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1752
1753 =cut
1754
1755 sub GetBranchItemRule {
1756     my ( $branchcode, $itemtype ) = @_;
1757
1758     # Search for rules!
1759     my $holdallowed_rule = Koha::CirculationRules->get_effective_rule(
1760         {
1761             branchcode => $branchcode,
1762             itemtype => $itemtype,
1763             rule_name => 'holdallowed',
1764         }
1765     );
1766     my $hold_fulfillment_policy_rule = Koha::CirculationRules->get_effective_rule(
1767         {
1768             branchcode => $branchcode,
1769             itemtype => $itemtype,
1770             rule_name => 'hold_fulfillment_policy',
1771         }
1772     );
1773     my $returnbranch_rule = Koha::CirculationRules->get_effective_rule(
1774         {
1775             branchcode => $branchcode,
1776             itemtype => $itemtype,
1777             rule_name => 'returnbranch',
1778         }
1779     );
1780
1781     # built-in default circulation rule
1782     my $rules;
1783     $rules->{holdallowed} = defined $holdallowed_rule
1784         ? $holdallowed_rule->rule_value
1785         : 2;
1786     $rules->{hold_fulfillment_policy} = defined $hold_fulfillment_policy_rule
1787         ? $hold_fulfillment_policy_rule->rule_value
1788         : 'any';
1789     $rules->{returnbranch} = defined $returnbranch_rule
1790         ? $returnbranch_rule->rule_value
1791         : 'homebranch';
1792
1793     return $rules;
1794 }
1795
1796 =head2 AddReturn
1797
1798   ($doreturn, $messages, $iteminformation, $borrower) =
1799       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1800
1801 Returns a book.
1802
1803 =over 4
1804
1805 =item C<$barcode> is the bar code of the book being returned.
1806
1807 =item C<$branch> is the code of the branch where the book is being returned.
1808
1809 =item C<$exemptfine> indicates that overdue charges for the item will be
1810 removed. Optional.
1811
1812 =item C<$return_date> allows the default return date to be overridden
1813 by the given return date. Optional.
1814
1815 =back
1816
1817 C<&AddReturn> returns a list of four items:
1818
1819 C<$doreturn> is true iff the return succeeded.
1820
1821 C<$messages> is a reference-to-hash giving feedback on the operation.
1822 The keys of the hash are:
1823
1824 =over 4
1825
1826 =item C<BadBarcode>
1827
1828 No item with this barcode exists. The value is C<$barcode>.
1829
1830 =item C<NotIssued>
1831
1832 The book is not currently on loan. The value is C<$barcode>.
1833
1834 =item C<withdrawn>
1835
1836 This book has been withdrawn/cancelled. The value should be ignored.
1837
1838 =item C<Wrongbranch>
1839
1840 This book has was returned to the wrong branch.  The value is a hashref
1841 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
1842 contain the branchcode of the incorrect and correct return library, respectively.
1843
1844 =item C<ResFound>
1845
1846 The item was reserved. The value is a reference-to-hash whose keys are
1847 fields from the reserves table of the Koha database, and
1848 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
1849 either C<Waiting>, C<Reserved>, or 0.
1850
1851 =item C<WasReturned>
1852
1853 Value 1 if return is successful.
1854
1855 =item C<NeedsTransfer>
1856
1857 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
1858
1859 =back
1860
1861 C<$iteminformation> is a reference-to-hash, giving information about the
1862 returned item from the issues table.
1863
1864 C<$borrower> is a reference-to-hash, giving information about the
1865 patron who last borrowed the book.
1866
1867 =cut
1868
1869 sub AddReturn {
1870     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
1871
1872     if ($branch and not Koha::Libraries->find($branch)) {
1873         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
1874         undef $branch;
1875     }
1876     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
1877     my $return_date_specified = !!$return_date;
1878     $return_date //= dt_from_string();
1879     my $messages;
1880     my $patron;
1881     my $doreturn       = 1;
1882     my $validTransfer = 1;
1883     my $stat_type = 'return';
1884
1885     # get information on item
1886     my $item = Koha::Items->find({ barcode => $barcode });
1887     unless ($item) {
1888         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
1889     }
1890
1891     my $itemnumber = $item->itemnumber;
1892     my $itemtype = $item->effective_itemtype;
1893
1894     my $issue  = $item->checkout;
1895     if ( $issue ) {
1896         $patron = $issue->patron
1897             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
1898                 . Dumper($issue->unblessed) . "\n";
1899     } else {
1900         $messages->{'NotIssued'} = $barcode;
1901         $item->onloan(undef)->store if defined $item->onloan;
1902
1903         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
1904         $doreturn = 0;
1905         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
1906         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
1907         if (C4::Context->preference("RecordLocalUseOnReturn")) {
1908            $messages->{'LocalUse'} = 1;
1909            $stat_type = 'localuse';
1910         }
1911     }
1912
1913         # full item data, but no borrowernumber or checkout info (no issue)
1914     my $hbr = GetBranchItemRule($item->homebranch, $itemtype)->{'returnbranch'} || "homebranch";
1915         # get the proper branch to which to return the item
1916     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
1917         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
1918     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
1919
1920     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
1921     my $patron_unblessed = $patron ? $patron->unblessed : {};
1922
1923     my $update_loc_rules = get_yaml_pref_hash('UpdateItemLocationOnCheckin');
1924     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
1925     if ($update_loc_rules) {
1926         if (defined $update_loc_rules->{_ALL_}) {
1927             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
1928             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
1929             if ( $item->location ne $update_loc_rules->{_ALL_}) {
1930                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
1931                 $item->location($update_loc_rules->{_ALL_})->store;
1932             }
1933         }
1934         else {
1935             foreach my $key ( keys %$update_loc_rules ) {
1936                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
1937                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
1938                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
1939                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
1940                     $item->location($update_loc_rules->{$key})->store;
1941                     last;
1942                 }
1943             }
1944         }
1945     }
1946
1947     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
1948     if ($yaml) {
1949         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
1950         my $rules;
1951         eval { $rules = YAML::Load($yaml); };
1952         if ($@) {
1953             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
1954         }
1955         else {
1956             foreach my $key ( keys %$rules ) {
1957                 if ( $item->notforloan eq $key ) {
1958                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
1959                     $item->notforloan($rules->{$key})->store({ log_action => 0 });
1960                     last;
1961                 }
1962             }
1963         }
1964     }
1965
1966     # check if the return is allowed at this branch
1967     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
1968     unless ($returnallowed){
1969         $messages->{'Wrongbranch'} = {
1970             Wrongbranch => $branch,
1971             Rightbranch => $message
1972         };
1973         $doreturn = 0;
1974         return ( $doreturn, $messages, $issue, $patron_unblessed);
1975     }
1976
1977     if ( $item->withdrawn ) { # book has been cancelled
1978         $messages->{'withdrawn'} = 1;
1979         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
1980     }
1981
1982     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
1983         $doreturn = 0;
1984     }
1985
1986     # case of a return of document (deal with issues and holdingbranch)
1987     if ($doreturn) {
1988         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
1989         $patron or warn "AddReturn without current borrower";
1990
1991         if ($patron) {
1992             eval {
1993                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy );
1994             };
1995             unless ( $@ ) {
1996                 if (
1997                     (
1998                         C4::Context->preference('CalculateFinesOnReturn')
1999                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2000                     )
2001                     && !$item->itemlost
2002                   )
2003                 {
2004                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2005                 }
2006             } else {
2007                 carp "The checkin for the following issue failed, Please go to the about page, section 'data corrupted' to know how to fix this problem ($@)" . Dumper( $issue->unblessed );
2008
2009                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2010             }
2011
2012             # FIXME is the "= 1" right?  This could be the borrower hash.
2013             $messages->{'WasReturned'} = 1;
2014
2015         }
2016
2017         $item->onloan(undef)->store({ log_action => 0 });
2018     }
2019
2020     # the holdingbranch is updated if the document is returned to another location.
2021     # this is always done regardless of whether the item was on loan or not
2022     if ($item->holdingbranch ne $branch) {
2023         $item->holdingbranch($branch)->store;
2024     }
2025
2026     my $item_was_lost = $item->itemlost;
2027     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2028     my $updated_item = ModDateLastSeen( $item->itemnumber, $leave_item_lost ); # will unset itemlost if needed
2029
2030     # fix up the accounts.....
2031     if ( $item_was_lost ) {
2032         $messages->{'WasLost'} = 1;
2033         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2034             $messages->{'LostItemFeeRefunded'} = $updated_item->{_refunded};
2035         }
2036     }
2037
2038     # check if we have a transfer for this document
2039     my ($datesent,$frombranch,$tobranch) = GetTransfers( $item->itemnumber );
2040
2041     # if we have a transfer to do, we update the line of transfers with the datearrived
2042     my $is_in_rotating_collection = C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber );
2043     if ($datesent) {
2044         # At this point we will either fill the transfer or it is a wrong transfer
2045         # either way we should not now generate a new transfer
2046         $validTransfer = 0;
2047         if ( $tobranch eq $branch ) {
2048             my $sth = C4::Context->dbh->prepare(
2049                 "UPDATE branchtransfers SET datearrived = now() WHERE itemnumber= ? AND datearrived IS NULL"
2050             );
2051             $sth->execute( $item->itemnumber );
2052         } else {
2053             $messages->{'WrongTransfer'}     = $tobranch;
2054             $messages->{'WrongTransferItem'} = $item->itemnumber;
2055         }
2056     }
2057
2058     # fix up the overdues in accounts...
2059     if ($borrowernumber) {
2060         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2061         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2062
2063         if ( $issue and $issue->is_overdue($return_date) ) {
2064         # fix fine days
2065             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item->unblessed, dt_from_string($issue->date_due), $return_date );
2066             if ($reminder){
2067                 $messages->{'PrevDebarred'} = $debardate;
2068             } else {
2069                 $messages->{'Debarred'} = $debardate if $debardate;
2070             }
2071         # there's no overdue on the item but borrower had been previously debarred
2072         } elsif ( $issue->date_due and $patron->debarred ) {
2073              if ( $patron->debarred eq "9999-12-31") {
2074                 $messages->{'ForeverDebarred'} = $patron->debarred;
2075              } else {
2076                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2077                   $borrower_debar_dt->truncate(to => 'day');
2078                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2079                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2080                       $messages->{'PrevDebarred'} = $patron->debarred;
2081                   }
2082              }
2083         }
2084     }
2085
2086     # find reserves.....
2087     # launch the Checkreserves routine to find any holds
2088     my ($resfound, $resrec);
2089     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2090     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2091     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2092     if ( $resfound and $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2093         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2094         $resfound = 'Reserved';
2095         $resrec = $hold->unblessed;
2096     }
2097     if ($resfound) {
2098           $resrec->{'ResFound'} = $resfound;
2099         $messages->{'ResFound'} = $resrec;
2100     }
2101
2102     # Record the fact that this book was returned.
2103     UpdateStats({
2104         branch         => $branch,
2105         type           => $stat_type,
2106         itemnumber     => $itemnumber,
2107         itemtype       => $itemtype,
2108         location       => $item->location,
2109         borrowernumber => $borrowernumber,
2110         ccode          => $item->ccode,
2111     });
2112
2113     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2114     if ( $patron ) {
2115         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2116         my %conditions = (
2117             branchcode   => $branch,
2118             categorycode => $patron->categorycode,
2119             item_type    => $itemtype,
2120             notification => 'CHECKIN',
2121         );
2122         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2123             SendCirculationAlert({
2124                 type     => 'CHECKIN',
2125                 item     => $item->unblessed,
2126                 borrower => $patron->unblessed,
2127                 branch   => $branch,
2128             });
2129         }
2130
2131         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2132             if C4::Context->preference("ReturnLog");
2133         }
2134
2135     # Check if this item belongs to a biblio record that is attached to an
2136     # ILL request, if it is we need to update the ILL request's status
2137     if ( $doreturn and C4::Context->preference('CirculateILL')) {
2138         my $request = Koha::Illrequests->find(
2139             { biblio_id => $item->biblio->biblionumber }
2140         );
2141         $request->status('RET') if $request;
2142     }
2143
2144     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2145     if ($validTransfer && !$is_in_rotating_collection && ($doreturn or $messages->{'NotIssued'}) and !$resfound and ($branch ne $returnbranch) ){
2146         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2147         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2148             (C4::Context->preference("UseBranchTransferLimits") and
2149              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2150            )) {
2151             $debug and warn sprintf "about to call ModItemTransfer(%s, %s, %s, %s)", $item->itemnumber,$branch, $returnbranch, $transfer_trigger;
2152             $debug and warn "item: " . Dumper($item->unblessed);
2153             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger);
2154             $messages->{'WasTransfered'} = 1;
2155         } else {
2156             $messages->{'NeedsTransfer'} = $returnbranch;
2157             $messages->{'TransferTrigger'} = $transfer_trigger;
2158         }
2159     }
2160
2161     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2162         my $claims = Koha::Checkouts::ReturnClaims->search(
2163            {
2164                itemnumber => $item->id,
2165                resolution => undef,
2166            }
2167         );
2168
2169         if ( $claims->count ) {
2170             $messages->{ReturnClaims} = $claims;
2171         }
2172     }
2173
2174     if ( $doreturn and $issue ) {
2175         my $checkin = Koha::Old::Checkouts->find($issue->id);
2176
2177         Koha::Plugins->call('after_circ_action', {
2178             action  => 'checkin',
2179             payload => {
2180                 checkout=> $checkin
2181             }
2182         });
2183     }
2184
2185     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2186 }
2187
2188 =head2 MarkIssueReturned
2189
2190   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy);
2191
2192 Unconditionally marks an issue as being returned by
2193 moving the C<issues> row to C<old_issues> and
2194 setting C<returndate> to the current date.
2195
2196 if C<$returndate> is specified (in iso format), it is used as the date
2197 of the return.
2198
2199 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2200 the old_issue is immediately anonymised
2201
2202 Ideally, this function would be internal to C<C4::Circulation>,
2203 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2204 and offline_circ/process_koc.pl.
2205
2206 =cut
2207
2208 sub MarkIssueReturned {
2209     my ( $borrowernumber, $itemnumber, $returndate, $privacy ) = @_;
2210
2211     # Retrieve the issue
2212     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2213
2214     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2215
2216     my $issue_id = $issue->issue_id;
2217
2218     my $anonymouspatron;
2219     if ( $privacy && $privacy == 2 ) {
2220         # The default of 0 will not work due to foreign key constraints
2221         # The anonymisation will fail if AnonymousPatron is not a valid entry
2222         # We need to check if the anonymous patron exist, Koha will fail loudly if it does not
2223         # Note that a warning should appear on the about page (System information tab).
2224         $anonymouspatron = C4::Context->preference('AnonymousPatron');
2225         die "Fatal error: the patron ($borrowernumber) has requested their circulation history be anonymized on check-in, but the AnonymousPatron system preference is empty or not set correctly."
2226             unless Koha::Patrons->find( $anonymouspatron );
2227     }
2228
2229     my $schema = Koha::Database->schema;
2230
2231     # FIXME Improve the return value and handle it from callers
2232     $schema->txn_do(sub {
2233
2234         my $patron = Koha::Patrons->find( $borrowernumber );
2235
2236         # Update the returndate value
2237         if ( $returndate ) {
2238             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2239         }
2240         else {
2241             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2242         }
2243
2244         # Create the old_issues entry
2245         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2246
2247         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2248         if ( $privacy && $privacy == 2) {
2249             $old_checkout->borrowernumber($anonymouspatron)->store;
2250         }
2251
2252         # And finally delete the issue
2253         $issue->delete;
2254
2255         $issue->item->onloan(undef)->store({ log_action => 0 });
2256
2257         if ( C4::Context->preference('StoreLastBorrower') ) {
2258             my $item = Koha::Items->find( $itemnumber );
2259             $item->last_returned_by( $patron );
2260         }
2261
2262         # Remove any OVERDUES related debarment if the borrower has no overdues
2263         if ( C4::Context->preference('AutoRemoveOverduesRestrictions')
2264           && $patron->debarred
2265           && !$patron->has_overdues
2266           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2267         ) {
2268             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2269         }
2270
2271     });
2272
2273     return $issue_id;
2274 }
2275
2276 =head2 _debar_user_on_return
2277
2278     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2279
2280 C<$borrower> borrower hashref
2281
2282 C<$item> item hashref
2283
2284 C<$datedue> date due DateTime object
2285
2286 C<$returndate> DateTime object representing the return time
2287
2288 Internal function, called only by AddReturn that calculates and updates
2289  the user fine days, and debars them if necessary.
2290
2291 Should only be called for overdue returns
2292
2293 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2294 to ease testing.
2295
2296 =cut
2297
2298 sub _calculate_new_debar_dt {
2299     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2300
2301     my $branchcode = _GetCircControlBranch( $item, $borrower );
2302     my $circcontrol = C4::Context->preference('CircControl');
2303     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2304         {   categorycode => $borrower->{categorycode},
2305             itemtype     => $item->{itype},
2306             branchcode   => $branchcode,
2307             rules => [
2308                 'finedays',
2309                 'lengthunit',
2310                 'firstremind',
2311                 'maxsuspensiondays',
2312                 'suspension_chargeperiod',
2313             ]
2314         }
2315     );
2316     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2317     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2318     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2319
2320     return unless $finedays;
2321
2322     # finedays is in days, so hourly loans must multiply by 24
2323     # thus 1 hour late equals 1 day suspension * finedays rate
2324     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2325
2326     # grace period is measured in the same units as the loan
2327     my $grace =
2328       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} );
2329
2330     my $deltadays = DateTime::Duration->new(
2331         days => $chargeable_units
2332     );
2333
2334     if ( $deltadays->subtract($grace)->is_positive() ) {
2335         my $suspension_days = $deltadays * $finedays;
2336
2337         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2338             # No need to / 1 and do not consider / 0
2339             $suspension_days = DateTime::Duration->new(
2340                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2341             );
2342         }
2343
2344         # If the max suspension days is < than the suspension days
2345         # the suspension days is limited to this maximum period.
2346         my $max_sd = $issuing_rule->{maxsuspensiondays};
2347         if ( defined $max_sd && $max_sd ne '' ) {
2348             $max_sd = DateTime::Duration->new( days => $max_sd );
2349             $suspension_days = $max_sd
2350               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2351         }
2352
2353         my ( $has_been_extended );
2354         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2355             my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2356             if ( $debarment ) {
2357                 $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2358                 $has_been_extended = 1;
2359             }
2360         }
2361
2362         my $new_debar_dt;
2363         # Use the calendar or not to calculate the debarment date
2364         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2365             my $calendar = Koha::Calendar->new(
2366                 branchcode => $branchcode,
2367                 days_mode  => 'Calendar'
2368             );
2369             $new_debar_dt = $calendar->addDate( $return_date, $suspension_days );
2370         }
2371         else {
2372             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2373         }
2374         return $new_debar_dt;
2375     }
2376     return;
2377 }
2378
2379 sub _debar_user_on_return {
2380     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2381
2382     $return_date //= dt_from_string();
2383
2384     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2385
2386     return unless $new_debar_dt;
2387
2388     Koha::Patron::Debarments::AddUniqueDebarment({
2389         borrowernumber => $borrower->{borrowernumber},
2390         expiration     => $new_debar_dt->ymd(),
2391         type           => 'SUSPENSION',
2392     });
2393     # if borrower was already debarred but does not get an extra debarment
2394     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2395     my ($new_debarment_str, $is_a_reminder);
2396     if ( $borrower->{debarred} && $borrower->{debarred} eq $patron->is_debarred ) {
2397         $is_a_reminder = 1;
2398         $new_debarment_str = $borrower->{debarred};
2399     } else {
2400         $new_debarment_str = $new_debar_dt->ymd();
2401     }
2402     # FIXME Should return a DateTime object
2403     return $new_debarment_str, $is_a_reminder;
2404 }
2405
2406 =head2 _FixOverduesOnReturn
2407
2408    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2409
2410 C<$borrowernumber> borrowernumber
2411
2412 C<$itemnumber> itemnumber
2413
2414 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2415
2416 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2417
2418 Internal function
2419
2420 =cut
2421
2422 sub _FixOverduesOnReturn {
2423     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2424     unless( $borrowernumber ) {
2425         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2426         return;
2427     }
2428     unless( $item ) {
2429         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2430         return;
2431     }
2432     unless( $status ) {
2433         warn "_FixOverduesOnReturn() not supplied valid status";
2434         return;
2435     }
2436
2437     my $schema = Koha::Database->schema;
2438
2439     my $result = $schema->txn_do(
2440         sub {
2441             # check for overdue fine
2442             my $accountlines = Koha::Account::Lines->search(
2443                 {
2444                     borrowernumber  => $borrowernumber,
2445                     itemnumber      => $item,
2446                     debit_type_code => 'OVERDUE',
2447                     status          => 'UNRETURNED'
2448                 }
2449             );
2450             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2451
2452             my $accountline = $accountlines->next;
2453             my $payments = $accountline->credits;
2454
2455             my $amountoutstanding = $accountline->amountoutstanding;
2456             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2457                 $accountline->delete;
2458             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2459                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2460                 my $credit = $account->add_credit(
2461                     {
2462                         amount     => $amountoutstanding,
2463                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2464                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2465                         interface  => C4::Context->interface,
2466                         type       => 'FORGIVEN',
2467                         item_id    => $item
2468                     }
2469                 );
2470
2471                 $credit->apply({ debits => [ $accountline ], offset_type => 'Forgiven' });
2472
2473                 if (C4::Context->preference("FinesLog")) {
2474                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2475                 }
2476
2477                 $accountline->status('FORGIVEN');
2478                 $accountline->store();
2479             } else {
2480                 $accountline->status($status);
2481                 $accountline->store();
2482
2483             }
2484         }
2485     );
2486
2487     return $result;
2488 }
2489
2490 =head2 _GetCircControlBranch
2491
2492    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2493
2494 Internal function :
2495
2496 Return the library code to be used to determine which circulation
2497 policy applies to a transaction.  Looks up the CircControl and
2498 HomeOrHoldingBranch system preferences.
2499
2500 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2501
2502 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2503
2504 =cut
2505
2506 sub _GetCircControlBranch {
2507     my ($item, $borrower) = @_;
2508     my $circcontrol = C4::Context->preference('CircControl');
2509     my $branch;
2510
2511     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2512         $branch= C4::Context->userenv->{'branch'};
2513     } elsif ($circcontrol eq 'PatronLibrary') {
2514         $branch=$borrower->{branchcode};
2515     } else {
2516         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2517         $branch = $item->{$branchfield};
2518         # default to item home branch if holdingbranch is used
2519         # and is not defined
2520         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2521             $branch = $item->{homebranch};
2522         }
2523     }
2524     return $branch;
2525 }
2526
2527 =head2 GetOpenIssue
2528
2529   $issue = GetOpenIssue( $itemnumber );
2530
2531 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2532
2533 C<$itemnumber> is the item's itemnumber
2534
2535 Returns a hashref
2536
2537 =cut
2538
2539 sub GetOpenIssue {
2540   my ( $itemnumber ) = @_;
2541   return unless $itemnumber;
2542   my $dbh = C4::Context->dbh;
2543   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2544   $sth->execute( $itemnumber );
2545   return $sth->fetchrow_hashref();
2546
2547 }
2548
2549 =head2 GetBiblioIssues
2550
2551   $issues = GetBiblioIssues($biblionumber);
2552
2553 this function get all issues from a biblionumber.
2554
2555 Return:
2556 C<$issues> is a reference to array which each value is ref-to-hash. This ref-to-hash contains all column from
2557 tables issues and the firstname,surname & cardnumber from borrowers.
2558
2559 =cut
2560
2561 sub GetBiblioIssues {
2562     my $biblionumber = shift;
2563     return unless $biblionumber;
2564     my $dbh   = C4::Context->dbh;
2565     my $query = "
2566         SELECT issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2567         FROM issues
2568             LEFT JOIN borrowers ON borrowers.borrowernumber = issues.borrowernumber
2569             LEFT JOIN items ON issues.itemnumber = items.itemnumber
2570             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2571             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2572         WHERE biblio.biblionumber = ?
2573         UNION ALL
2574         SELECT old_issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2575         FROM old_issues
2576             LEFT JOIN borrowers ON borrowers.borrowernumber = old_issues.borrowernumber
2577             LEFT JOIN items ON old_issues.itemnumber = items.itemnumber
2578             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2579             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2580         WHERE biblio.biblionumber = ?
2581         ORDER BY timestamp
2582     ";
2583     my $sth = $dbh->prepare($query);
2584     $sth->execute($biblionumber, $biblionumber);
2585
2586     my @issues;
2587     while ( my $data = $sth->fetchrow_hashref ) {
2588         push @issues, $data;
2589     }
2590     return \@issues;
2591 }
2592
2593 =head2 GetUpcomingDueIssues
2594
2595   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2596
2597 =cut
2598
2599 sub GetUpcomingDueIssues {
2600     my $params = shift;
2601
2602     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2603     my $dbh = C4::Context->dbh;
2604
2605     my $statement = <<END_SQL;
2606 SELECT *
2607 FROM (
2608     SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2609     FROM issues
2610     LEFT JOIN items USING (itemnumber)
2611     LEFT OUTER JOIN branches USING (branchcode)
2612     WHERE returndate is NULL
2613 ) tmp
2614 WHERE days_until_due >= 0 AND days_until_due <= ?
2615 END_SQL
2616
2617     my @bind_parameters = ( $params->{'days_in_advance'} );
2618
2619     my $sth = $dbh->prepare( $statement );
2620     $sth->execute( @bind_parameters );
2621     my $upcoming_dues = $sth->fetchall_arrayref({});
2622
2623     return $upcoming_dues;
2624 }
2625
2626 =head2 CanBookBeRenewed
2627
2628   ($ok,$error) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2629
2630 Find out whether a borrowed item may be renewed.
2631
2632 C<$borrowernumber> is the borrower number of the patron who currently
2633 has the item on loan.
2634
2635 C<$itemnumber> is the number of the item to renew.
2636
2637 C<$override_limit>, if supplied with a true value, causes
2638 the limit on the number of times that the loan can be renewed
2639 (as controlled by the item type) to be ignored. Overriding also allows
2640 to renew sooner than "No renewal before" and to manually renew loans
2641 that are automatically renewed.
2642
2643 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2644 item must currently be on loan to the specified borrower; renewals
2645 must be allowed for the item's type; and the borrower must not have
2646 already renewed the loan. $error will contain the reason the renewal can not proceed
2647
2648 =cut
2649
2650 sub CanBookBeRenewed {
2651     my ( $borrowernumber, $itemnumber, $override_limit, $cron ) = @_;
2652
2653     my $dbh    = C4::Context->dbh;
2654     my $renews = 1;
2655     my $auto_renew = "no";
2656
2657     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2658     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2659     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2660     return ( 0, 'item_denied_renewal') if _item_denied_renewal({ item => $item });
2661
2662     my $patron = $issue->patron or return;
2663
2664     # override_limit will override anything else except on_reserve
2665     unless ( $override_limit ){
2666         my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2667         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2668             {
2669                 categorycode => $patron->categorycode,
2670                 itemtype     => $item->effective_itemtype,
2671                 branchcode   => $branchcode,
2672                 rules => [
2673                     'renewalsallowed',
2674                     'no_auto_renewal_after',
2675                     'no_auto_renewal_after_hard_limit',
2676                     'lengthunit',
2677                     'norenewalbefore',
2678                 ]
2679             }
2680         );
2681
2682         return ( 0, "too_many" )
2683           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals;
2684
2685         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2686         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2687         $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2688         my $restricted  = $patron->is_debarred;
2689         my $hasoverdues = $patron->has_overdues;
2690
2691         if ( $restricted and $restrictionblockrenewing ) {
2692             return ( 0, 'restriction');
2693         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2694             return ( 0, 'overdue');
2695         }
2696
2697         if ( $issue->auto_renew && $patron->autorenew_checkouts ) {
2698
2699             if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
2700                 return ( 0, 'auto_account_expired' );
2701             }
2702
2703             if ( defined $issuing_rule->{no_auto_renewal_after}
2704                     and $issuing_rule->{no_auto_renewal_after} ne "" ) {
2705                 # Get issue_date and add no_auto_renewal_after
2706                 # If this is greater than today, it's too late for renewal.
2707                 my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
2708                 $maximum_renewal_date->add(
2709                     $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
2710                 );
2711                 my $now = dt_from_string;
2712                 if ( $now >= $maximum_renewal_date ) {
2713                     return ( 0, "auto_too_late" );
2714                 }
2715             }
2716             if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
2717                           and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
2718                 # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
2719                 if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
2720                     return ( 0, "auto_too_late" );
2721                 }
2722             }
2723
2724             if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
2725                 my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
2726                 my $amountoutstanding =
2727                   C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
2728                   ? $patron->account->balance
2729                   : $patron->account->outstanding_debits->total_outstanding;
2730                 if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
2731                     return ( 0, "auto_too_much_oweing" );
2732                 }
2733             }
2734         }
2735
2736         if ( defined $issuing_rule->{norenewalbefore}
2737             and $issuing_rule->{norenewalbefore} ne "" )
2738         {
2739
2740             # Calculate soonest renewal by subtracting 'No renewal before' from due date
2741             my $soonestrenewal = dt_from_string( $issue->date_due, 'sql' )->subtract(
2742                 $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
2743
2744             # Depending on syspref reset the exact time, only check the date
2745             if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
2746                 and $issuing_rule->{lengthunit} eq 'days' )
2747             {
2748                 $soonestrenewal->truncate( to => 'day' );
2749             }
2750
2751             if ( $soonestrenewal > dt_from_string() )
2752             {
2753                 $auto_renew = ($issue->auto_renew && $patron->autorenew_checkouts) ? "auto_too_soon" : "too_soon";
2754             }
2755             elsif ( $issue->auto_renew && $patron->autorenew_checkouts ) {
2756                 $auto_renew = "ok";
2757             }
2758         }
2759
2760         # Fallback for automatic renewals:
2761         # If norenewalbefore is undef, don't renew before due date.
2762         if ( $issue->auto_renew && $auto_renew eq "no" && $patron->autorenew_checkouts ) {
2763             my $now = dt_from_string;
2764             if ( $now >= dt_from_string( $issue->date_due, 'sql' ) ){
2765                 $auto_renew = "ok";
2766             } else {
2767                 $auto_renew = "auto_too_soon";
2768             }
2769         }
2770     }
2771
2772     my ( $resfound, $resrec, undef ) = C4::Reserves::CheckReserves($itemnumber);
2773
2774     # If next hold is non priority, then check if any hold with priority (non_priority = 0) exists for the same biblionumber.
2775     if ( $resfound && $resrec->{non_priority} ) {
2776         $resfound = Koha::Holds->search(
2777             { biblionumber => $resrec->{biblionumber}, non_priority => 0 } )
2778           ->count > 0;
2779     }
2780
2781
2782
2783     # This item can fill one or more unfilled reserve, can those unfilled reserves
2784     # all be filled by other available items?
2785     if ( $resfound
2786         && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') )
2787     {
2788         my $schema = Koha::Database->new()->schema();
2789
2790         my $item_holds = $schema->resultset('Reserve')->search( { itemnumber => $itemnumber, found => undef } )->count();
2791         if ($item_holds) {
2792             # There is an item level hold on this item, no other item can fill the hold
2793             $resfound = 1;
2794         }
2795         else {
2796
2797             # Get all other items that could possibly fill reserves
2798             my @itemnumbers = $schema->resultset('Item')->search(
2799                 {
2800                     biblionumber => $resrec->{biblionumber},
2801                     onloan       => undef,
2802                     notforloan   => 0,
2803                     -not         => { itemnumber => $itemnumber }
2804                 },
2805                 { columns => 'itemnumber' }
2806             )->get_column('itemnumber')->all();
2807
2808             # Get all other reserves that could have been filled by this item
2809             my @borrowernumbers;
2810             while (1) {
2811                 my ( $reserve_found, $reserve, undef ) =
2812                   C4::Reserves::CheckReserves( $itemnumber, undef, undef, \@borrowernumbers );
2813
2814                 if ($reserve_found) {
2815                     push( @borrowernumbers, $reserve->{borrowernumber} );
2816                 }
2817                 else {
2818                     last;
2819                 }
2820             }
2821
2822             # If the count of the union of the lists of reservable items for each borrower
2823             # is equal or greater than the number of borrowers, we know that all reserves
2824             # can be filled with available items. We can get the union of the sets simply
2825             # by pushing all the elements onto an array and removing the duplicates.
2826             my @reservable;
2827             my %patrons;
2828             ITEM: foreach my $itemnumber (@itemnumbers) {
2829                 my $item = Koha::Items->find( $itemnumber );
2830                 next if IsItemOnHoldAndFound( $itemnumber );
2831                 for my $borrowernumber (@borrowernumbers) {
2832                     my $patron = $patrons{$borrowernumber} //= Koha::Patrons->find( $borrowernumber );
2833                     next unless IsAvailableForItemLevelRequest($item, $patron);
2834                     next unless CanItemBeReserved($borrowernumber,$itemnumber);
2835
2836                     push @reservable, $itemnumber;
2837                     if (@reservable >= @borrowernumbers) {
2838                         $resfound = 0;
2839                         last ITEM;
2840                     }
2841                     last;
2842                 }
2843             }
2844         }
2845     }
2846     if( $cron ) { #The cron wants to return 'too_soon' over 'on_reserve'
2847         return ( 0, $auto_renew  ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
2848         return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2849     } else { # For other purposes we want 'on_reserve' before 'too_soon'
2850         return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2851         return ( 0, $auto_renew  ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
2852     }
2853
2854     return ( 0, "auto_renew" ) if $auto_renew eq "ok" && !$override_limit; # 0 if auto-renewal should not succeed
2855
2856     return ( 1, undef );
2857 }
2858
2859 =head2 AddRenewal
2860
2861   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate]);
2862
2863 Renews a loan.
2864
2865 C<$borrowernumber> is the borrower number of the patron who currently
2866 has the item.
2867
2868 C<$itemnumber> is the number of the item to renew.
2869
2870 C<$branch> is the library where the renewal took place (if any).
2871            The library that controls the circ policies for the renewal is retrieved from the issues record.
2872
2873 C<$datedue> can be a DateTime object used to set the due date.
2874
2875 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
2876 this parameter is not supplied, lastreneweddate is set to the current date.
2877
2878 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
2879 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
2880 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
2881 syspref)
2882
2883 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
2884 from the book's item type.
2885
2886 =cut
2887
2888 sub AddRenewal {
2889     my $borrowernumber  = shift;
2890     my $itemnumber      = shift or return;
2891     my $branch          = shift;
2892     my $datedue         = shift;
2893     my $lastreneweddate = shift || dt_from_string();
2894     my $skipfinecalc    = shift;
2895
2896     my $item_object   = Koha::Items->find($itemnumber) or return;
2897     my $biblio = $item_object->biblio;
2898     my $issue  = $item_object->checkout;
2899     my $item_unblessed = $item_object->unblessed;
2900
2901     my $dbh = C4::Context->dbh;
2902
2903     return unless $issue;
2904
2905     $borrowernumber ||= $issue->borrowernumber;
2906
2907     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
2908         carp 'Invalid date passed to AddRenewal.';
2909         return;
2910     }
2911
2912     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
2913     my $patron_unblessed = $patron->unblessed;
2914
2915     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
2916
2917     my $schema = Koha::Database->schema;
2918     $schema->txn_do(sub{
2919
2920         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
2921             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
2922         }
2923         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
2924
2925         # If the due date wasn't specified, calculate it by adding the
2926         # book's loan length to today's date or the current due date
2927         # based on the value of the RenewalPeriodBase syspref.
2928         my $itemtype = $item_object->effective_itemtype;
2929         unless ($datedue) {
2930
2931             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
2932                                             dt_from_string( $issue->date_due, 'sql' ) :
2933                                             dt_from_string();
2934             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
2935         }
2936
2937         my $fees = Koha::Charges::Fees->new(
2938             {
2939                 patron    => $patron,
2940                 library   => $circ_library,
2941                 item      => $item_object,
2942                 from_date => dt_from_string( $issue->date_due, 'sql' ),
2943                 to_date   => dt_from_string($datedue),
2944             }
2945         );
2946
2947         # Update the issues record to have the new due date, and a new count
2948         # of how many times it has been renewed.
2949         my $renews = ( $issue->renewals || 0 ) + 1;
2950         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals = ?, lastreneweddate = ?
2951                                 WHERE borrowernumber=?
2952                                 AND itemnumber=?"
2953         );
2954
2955         $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $lastreneweddate, $borrowernumber, $itemnumber );
2956
2957         # Update the renewal count on the item, and tell zebra to reindex
2958         $renews = ( $item_object->renewals || 0 ) + 1;
2959         $item_object->renewals($renews);
2960         $item_object->onloan($datedue);
2961         $item_object->store({ log_action => 0 });
2962
2963         # Charge a new rental fee, if applicable
2964         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
2965         if ( $charge > 0 ) {
2966             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
2967         }
2968
2969         # Charge a new accumulate rental fee, if applicable
2970         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
2971         if ( $itemtype_object ) {
2972             my $accumulate_charge = $fees->accumulate_rentalcharge();
2973             if ( $accumulate_charge > 0 ) {
2974                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
2975             }
2976             $charge += $accumulate_charge;
2977         }
2978
2979         # Send a renewal slip according to checkout alert preferencei
2980         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
2981             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2982             my %conditions        = (
2983                 branchcode   => $branch,
2984                 categorycode => $patron->categorycode,
2985                 item_type    => $itemtype,
2986                 notification => 'CHECKOUT',
2987             );
2988             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
2989                 SendCirculationAlert(
2990                     {
2991                         type     => 'RENEWAL',
2992                         item     => $item_unblessed,
2993                         borrower => $patron->unblessed,
2994                         branch   => $branch,
2995                     }
2996                 );
2997             }
2998         }
2999
3000         # Remove any OVERDUES related debarment if the borrower has no overdues
3001         if ( $patron
3002           && $patron->is_debarred
3003           && ! $patron->has_overdues
3004           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
3005         ) {
3006             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3007         }
3008
3009         # Add the renewal to stats
3010         UpdateStats(
3011             {
3012                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3013                 type           => 'renew',
3014                 amount         => $charge,
3015                 itemnumber     => $itemnumber,
3016                 itemtype       => $itemtype,
3017                 location       => $item_object->location,
3018                 borrowernumber => $borrowernumber,
3019                 ccode          => $item_object->ccode,
3020             }
3021         );
3022
3023         #Log the renewal
3024         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3025
3026         Koha::Plugins->call('after_circ_action', {
3027             action  => 'renewal',
3028             payload => {
3029                 checkout  => $issue->get_from_storage
3030             }
3031         });
3032     });
3033
3034     return $datedue;
3035 }
3036
3037 sub GetRenewCount {
3038     # check renewal status
3039     my ( $bornum, $itemno ) = @_;
3040     my $dbh           = C4::Context->dbh;
3041     my $renewcount    = 0;
3042     my $renewsallowed = 0;
3043     my $renewsleft    = 0;
3044
3045     my $patron = Koha::Patrons->find( $bornum );
3046     my $item   = Koha::Items->find($itemno);
3047
3048     return (0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3049
3050     # Look in the issues table for this item, lent to this borrower,
3051     # and not yet returned.
3052
3053     # FIXME - I think this function could be redone to use only one SQL call.
3054     my $sth = $dbh->prepare(
3055         "select * from issues
3056                                 where (borrowernumber = ?)
3057                                 and (itemnumber = ?)"
3058     );
3059     $sth->execute( $bornum, $itemno );
3060     my $data = $sth->fetchrow_hashref;
3061     $renewcount = $data->{'renewals'} if $data->{'renewals'};
3062     # $item and $borrower should be calculated
3063     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3064
3065     my $rule = Koha::CirculationRules->get_effective_rule(
3066         {
3067             categorycode => $patron->categorycode,
3068             itemtype     => $item->effective_itemtype,
3069             branchcode   => $branchcode,
3070             rule_name    => 'renewalsallowed',
3071         }
3072     );
3073
3074     $renewsallowed = $rule ? $rule->rule_value : 0;
3075     $renewsleft    = $renewsallowed - $renewcount;
3076     if($renewsleft < 0){ $renewsleft = 0; }
3077     return ( $renewcount, $renewsallowed, $renewsleft );
3078 }
3079
3080 =head2 GetSoonestRenewDate
3081
3082   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
3083
3084 Find out the soonest possible renew date of a borrowed item.
3085
3086 C<$borrowernumber> is the borrower number of the patron who currently
3087 has the item on loan.
3088
3089 C<$itemnumber> is the number of the item to renew.
3090
3091 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3092 renew date, based on the value "No renewal before" of the applicable
3093 issuing rule. Returns the current date if the item can already be
3094 renewed, and returns undefined if the borrower, loan, or item
3095 cannot be found.
3096
3097 =cut
3098
3099 sub GetSoonestRenewDate {
3100     my ( $borrowernumber, $itemnumber ) = @_;
3101
3102     my $dbh = C4::Context->dbh;
3103
3104     my $item      = Koha::Items->find($itemnumber)      or return;
3105     my $itemissue = $item->checkout or return;
3106
3107     $borrowernumber ||= $itemissue->borrowernumber;
3108     my $patron = Koha::Patrons->find( $borrowernumber )
3109       or return;
3110
3111     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3112     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3113         {   categorycode => $patron->categorycode,
3114             itemtype     => $item->effective_itemtype,
3115             branchcode   => $branchcode,
3116             rules => [
3117                 'norenewalbefore',
3118                 'lengthunit',
3119             ]
3120         }
3121     );
3122
3123     my $now = dt_from_string;
3124     return $now unless $issuing_rule;
3125
3126     if ( defined $issuing_rule->{norenewalbefore}
3127         and $issuing_rule->{norenewalbefore} ne "" )
3128     {
3129         my $soonestrenewal =
3130           dt_from_string( $itemissue->date_due )->subtract(
3131             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3132
3133         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3134             and $issuing_rule->{lengthunit} eq 'days' )
3135         {
3136             $soonestrenewal->truncate( to => 'day' );
3137         }
3138         return $soonestrenewal if $now < $soonestrenewal;
3139     }
3140     return $now;
3141 }
3142
3143 =head2 GetLatestAutoRenewDate
3144
3145   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3146
3147 Find out the latest possible auto renew date of a borrowed item.
3148
3149 C<$borrowernumber> is the borrower number of the patron who currently
3150 has the item on loan.
3151
3152 C<$itemnumber> is the number of the item to renew.
3153
3154 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3155 auto renew date, based on the value "No auto renewal after" and the "No auto
3156 renewal after (hard limit) of the applicable issuing rule.
3157 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3158 or item cannot be found.
3159
3160 =cut
3161
3162 sub GetLatestAutoRenewDate {
3163     my ( $borrowernumber, $itemnumber ) = @_;
3164
3165     my $dbh = C4::Context->dbh;
3166
3167     my $item      = Koha::Items->find($itemnumber)  or return;
3168     my $itemissue = $item->checkout                 or return;
3169
3170     $borrowernumber ||= $itemissue->borrowernumber;
3171     my $patron = Koha::Patrons->find( $borrowernumber )
3172       or return;
3173
3174     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3175     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3176         {
3177             categorycode => $patron->categorycode,
3178             itemtype     => $item->effective_itemtype,
3179             branchcode   => $branchcode,
3180             rules => [
3181                 'no_auto_renewal_after',
3182                 'no_auto_renewal_after_hard_limit',
3183                 'lengthunit',
3184             ]
3185         }
3186     );
3187
3188     return unless $circulation_rules;
3189     return
3190       if ( not $circulation_rules->{no_auto_renewal_after}
3191             or $circulation_rules->{no_auto_renewal_after} eq '' )
3192       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3193              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3194
3195     my $maximum_renewal_date;
3196     if ( $circulation_rules->{no_auto_renewal_after} ) {
3197         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3198         $maximum_renewal_date->add(
3199             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3200         );
3201     }
3202
3203     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3204         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3205         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3206     }
3207     return $maximum_renewal_date;
3208 }
3209
3210
3211 =head2 GetIssuingCharges
3212
3213   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3214
3215 Calculate how much it would cost for a given patron to borrow a given
3216 item, including any applicable discounts.
3217
3218 C<$itemnumber> is the item number of item the patron wishes to borrow.
3219
3220 C<$borrowernumber> is the patron's borrower number.
3221
3222 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3223 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3224 if it's a video).
3225
3226 =cut
3227
3228 sub GetIssuingCharges {
3229
3230     # calculate charges due
3231     my ( $itemnumber, $borrowernumber ) = @_;
3232     my $charge = 0;
3233     my $dbh    = C4::Context->dbh;
3234     my $item_type;
3235
3236     # Get the book's item type and rental charge (via its biblioitem).
3237     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3238         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3239     $charge_query .= (C4::Context->preference('item-level_itypes'))
3240         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3241         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3242
3243     $charge_query .= ' WHERE items.itemnumber =?';
3244
3245     my $sth = $dbh->prepare($charge_query);
3246     $sth->execute($itemnumber);
3247     if ( my $item_data = $sth->fetchrow_hashref ) {
3248         $item_type = $item_data->{itemtype};
3249         $charge    = $item_data->{rentalcharge};
3250         my $branch = C4::Context::mybranch();
3251         my $patron = Koha::Patrons->find( $borrowernumber );
3252         my $discount = _get_discount_from_rule($patron->categorycode, $branch, $item_type);
3253         if ($discount) {
3254             # We may have multiple rules so get the most specific
3255             $charge = ( $charge * ( 100 - $discount ) ) / 100;
3256         }
3257         if ($charge) {
3258             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3259         }
3260     }
3261
3262     return ( $charge, $item_type );
3263 }
3264
3265 # Select most appropriate discount rule from those returned
3266 sub _get_discount_from_rule {
3267     my ($categorycode, $branchcode, $itemtype) = @_;
3268
3269     # Set search precedences
3270     my @params = (
3271         {
3272             branchcode   => $branchcode,
3273             itemtype     => $itemtype,
3274             categorycode => $categorycode,
3275         },
3276         {
3277             branchcode   => undef,
3278             categorycode => $categorycode,
3279             itemtype     => $itemtype,
3280         },
3281         {
3282             branchcode   => $branchcode,
3283             categorycode => $categorycode,
3284             itemtype     => undef,
3285         },
3286         {
3287             branchcode   => undef,
3288             categorycode => $categorycode,
3289             itemtype     => undef,
3290         },
3291     );
3292
3293     foreach my $params (@params) {
3294         my $rule = Koha::CirculationRules->search(
3295             {
3296                 rule_name => 'rentaldiscount',
3297                 %$params,
3298             }
3299         )->next();
3300
3301         return $rule->rule_value if $rule;
3302     }
3303
3304     # none of the above
3305     return 0;
3306 }
3307
3308 =head2 AddIssuingCharge
3309
3310   &AddIssuingCharge( $checkout, $charge, $type )
3311
3312 =cut
3313
3314 sub AddIssuingCharge {
3315     my ( $checkout, $charge, $type ) = @_;
3316
3317     # FIXME What if checkout does not exist?
3318
3319     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3320     my $accountline = $account->add_debit(
3321         {
3322             amount      => $charge,
3323             note        => undef,
3324             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3325             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3326             interface   => C4::Context->interface,
3327             type        => $type,
3328             item_id     => $checkout->itemnumber,
3329             issue_id    => $checkout->issue_id,
3330         }
3331     );
3332 }
3333
3334 =head2 GetTransfers
3335
3336   GetTransfers($itemnumber);
3337
3338 =cut
3339
3340 sub GetTransfers {
3341     my ($itemnumber) = @_;
3342
3343     my $dbh = C4::Context->dbh;
3344
3345     my $query = '
3346         SELECT datesent,
3347                frombranch,
3348                tobranch,
3349                branchtransfer_id
3350         FROM branchtransfers
3351         WHERE itemnumber = ?
3352           AND datearrived IS NULL
3353         ';
3354     my $sth = $dbh->prepare($query);
3355     $sth->execute($itemnumber);
3356     my @row = $sth->fetchrow_array();
3357     return @row;
3358 }
3359
3360 =head2 GetTransfersFromTo
3361
3362   @results = GetTransfersFromTo($frombranch,$tobranch);
3363
3364 Returns the list of pending transfers between $from and $to branch
3365
3366 =cut
3367
3368 sub GetTransfersFromTo {
3369     my ( $frombranch, $tobranch ) = @_;
3370     return unless ( $frombranch && $tobranch );
3371     my $dbh   = C4::Context->dbh;
3372     my $query = "
3373         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3374         FROM   branchtransfers
3375         WHERE  frombranch=?
3376           AND  tobranch=?
3377           AND datearrived IS NULL
3378     ";
3379     my $sth = $dbh->prepare($query);
3380     $sth->execute( $frombranch, $tobranch );
3381     my @gettransfers;
3382
3383     while ( my $data = $sth->fetchrow_hashref ) {
3384         push @gettransfers, $data;
3385     }
3386     return (@gettransfers);
3387 }
3388
3389 =head2 DeleteTransfer
3390
3391   &DeleteTransfer($itemnumber);
3392
3393 =cut
3394
3395 sub DeleteTransfer {
3396     my ($itemnumber) = @_;
3397     return unless $itemnumber;
3398     my $dbh          = C4::Context->dbh;
3399     my $sth          = $dbh->prepare(
3400         "DELETE FROM branchtransfers
3401          WHERE itemnumber=?
3402          AND datearrived IS NULL "
3403     );
3404     return $sth->execute($itemnumber);
3405 }
3406
3407 =head2 SendCirculationAlert
3408
3409 Send out a C<check-in> or C<checkout> alert using the messaging system.
3410
3411 B<Parameters>:
3412
3413 =over 4
3414
3415 =item type
3416
3417 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3418
3419 =item item
3420
3421 Hashref of information about the item being checked in or out.
3422
3423 =item borrower
3424
3425 Hashref of information about the borrower of the item.
3426
3427 =item branch
3428
3429 The branchcode from where the checkout or check-in took place.
3430
3431 =back
3432
3433 B<Example>:
3434
3435     SendCirculationAlert({
3436         type     => 'CHECKOUT',
3437         item     => $item,
3438         borrower => $borrower,
3439         branch   => $branch,
3440     });
3441
3442 =cut
3443
3444 sub SendCirculationAlert {
3445     my ($opts) = @_;
3446     my ($type, $item, $borrower, $branch) =
3447         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch});
3448     my %message_name = (
3449         CHECKIN  => 'Item_Check_in',
3450         CHECKOUT => 'Item_Checkout',
3451         RENEWAL  => 'Item_Checkout',
3452     );
3453     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3454         borrowernumber => $borrower->{borrowernumber},
3455         message_name   => $message_name{$type},
3456     });
3457     my $issues_table = ( $type eq 'CHECKOUT' || $type eq 'RENEWAL' ) ? 'issues' : 'old_issues';
3458
3459     my $schema = Koha::Database->new->schema;
3460     my @transports = keys %{ $borrower_preferences->{transports} };
3461
3462     # From the MySQL doc:
3463     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3464     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3465     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3466     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3467
3468     for my $mtt (@transports) {
3469         my $letter =  C4::Letters::GetPreparedLetter (
3470             module => 'circulation',
3471             letter_code => $type,
3472             branchcode => $branch,
3473             message_transport_type => $mtt,
3474             lang => $borrower->{lang},
3475             tables => {
3476                 $issues_table => $item->{itemnumber},
3477                 'items'       => $item->{itemnumber},
3478                 'biblio'      => $item->{biblionumber},
3479                 'biblioitems' => $item->{biblionumber},
3480                 'borrowers'   => $borrower,
3481                 'branches'    => $branch,
3482             }
3483         ) or next;
3484
3485         $schema->storage->txn_begin;
3486         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3487         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3488         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3489         unless ( $message ) {
3490             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3491             C4::Message->enqueue($letter, $borrower, $mtt);
3492         } else {
3493             $message->append($letter);
3494             $message->update;
3495         }
3496         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3497         $schema->storage->txn_commit;
3498     }
3499
3500     return;
3501 }
3502
3503 =head2 updateWrongTransfer
3504
3505   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3506
3507 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3508
3509 =cut
3510
3511 sub updateWrongTransfer {
3512         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3513         my $dbh = C4::Context->dbh;
3514 # first step validate the actual line of transfert .
3515         my $sth =
3516                 $dbh->prepare(
3517                         "update branchtransfers set datearrived = now(),tobranch=?,comments='wrongtransfer' where itemnumber= ? AND datearrived IS NULL"
3518                 );
3519                 $sth->execute($FromLibrary,$itemNumber);
3520
3521 # second step create a new line of branchtransfer to the right location .
3522         ModItemTransfer($itemNumber, $FromLibrary, $waitingAtLibrary);
3523
3524 #third step changing holdingbranch of item
3525     my $item = Koha::Items->find($itemNumber)->holdingbranch($FromLibrary)->store;
3526 }
3527
3528 =head2 CalcDateDue
3529
3530 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3531
3532 this function calculates the due date given the start date and configured circulation rules,
3533 checking against the holidays calendar as per the daysmode circulation rule.
3534 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3535 C<$itemtype>  = itemtype code of item in question
3536 C<$branch>  = location whose calendar to use
3537 C<$borrower> = Borrower object
3538 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3539
3540 =cut
3541
3542 sub CalcDateDue {
3543     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3544
3545     $isrenewal ||= 0;
3546
3547     # loanlength now a href
3548     my $loanlength =
3549             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3550
3551     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} )
3552             ? qq{renewalperiod}
3553             : qq{issuelength};
3554
3555     my $datedue;
3556     if ( $startdate ) {
3557         if (ref $startdate ne 'DateTime' ) {
3558             $datedue = dt_from_string($datedue);
3559         } else {
3560             $datedue = $startdate->clone;
3561         }
3562     } else {
3563         $datedue = dt_from_string()->truncate( to => 'minute' );
3564     }
3565
3566
3567     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3568         {
3569             categorycode => $borrower->{categorycode},
3570             itemtype     => $itemtype,
3571             branchcode   => $branch,
3572         }
3573     );
3574
3575     # calculate the datedue as normal
3576     if ( $daysmode eq 'Days' )
3577     {    # ignoring calendar
3578         if ( $loanlength->{lengthunit} eq 'hours' ) {
3579             $datedue->add( hours => $loanlength->{$length_key} );
3580         } else {    # days
3581             $datedue->add( days => $loanlength->{$length_key} );
3582             $datedue->set_hour(23);
3583             $datedue->set_minute(59);
3584         }
3585     } else {
3586         my $dur;
3587         if ($loanlength->{lengthunit} eq 'hours') {
3588             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3589         }
3590         else { # days
3591             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3592         }
3593         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3594         $datedue = $calendar->addDate( $datedue, $dur, $loanlength->{lengthunit} );
3595         if ($loanlength->{lengthunit} eq 'days') {
3596             $datedue->set_hour(23);
3597             $datedue->set_minute(59);
3598         }
3599     }
3600
3601     # if Hard Due Dates are used, retrieve them and apply as necessary
3602     my ( $hardduedate, $hardduedatecompare ) =
3603       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3604     if ($hardduedate) {    # hardduedates are currently dates
3605         $hardduedate->truncate( to => 'minute' );
3606         $hardduedate->set_hour(23);
3607         $hardduedate->set_minute(59);
3608         my $cmp = DateTime->compare( $hardduedate, $datedue );
3609
3610 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3611 # if the calculated date is before the 'after' Hard Due Date (floor), override
3612 # if the hard due date is set to 'exactly', overrride
3613         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3614             $datedue = $hardduedate->clone;
3615         }
3616
3617         # in all other cases, keep the date due as it is
3618
3619     }
3620
3621     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3622     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3623         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3624         if( $expiry_dt ) { #skip empty expiry date..
3625             $expiry_dt->set( hour => 23, minute => 59);
3626             my $d1= $datedue->clone->set_time_zone('floating');
3627             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3628                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3629             }
3630         }
3631         if ( $daysmode ne 'Days' ) {
3632           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3633           if ( $calendar->is_holiday($datedue) ) {
3634               # Don't return on a closed day
3635               $datedue = $calendar->prev_open_days( $datedue, 1 );
3636           }
3637         }
3638     }
3639
3640     return $datedue;
3641 }
3642
3643
3644 sub CheckValidBarcode{
3645 my ($barcode) = @_;
3646 my $dbh = C4::Context->dbh;
3647 my $query=qq|SELECT count(*)
3648              FROM items
3649              WHERE barcode=?
3650             |;
3651 my $sth = $dbh->prepare($query);
3652 $sth->execute($barcode);
3653 my $exist=$sth->fetchrow ;
3654 return $exist;
3655 }
3656
3657 =head2 IsBranchTransferAllowed
3658
3659   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3660
3661 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3662
3663 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3664 Koha::Item->can_be_transferred.
3665
3666 =cut
3667
3668 sub IsBranchTransferAllowed {
3669         my ( $toBranch, $fromBranch, $code ) = @_;
3670
3671         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3672
3673         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3674         my $dbh = C4::Context->dbh;
3675
3676         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3677         $sth->execute( $toBranch, $fromBranch, $code );
3678         my $limit = $sth->fetchrow_hashref();
3679
3680         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3681         if ( $limit->{'limitId'} ) {
3682                 return 0;
3683         } else {
3684                 return 1;
3685         }
3686 }
3687
3688 =head2 CreateBranchTransferLimit
3689
3690   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3691
3692 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3693
3694 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3695
3696 =cut
3697
3698 sub CreateBranchTransferLimit {
3699    my ( $toBranch, $fromBranch, $code ) = @_;
3700    return unless defined($toBranch) && defined($fromBranch);
3701    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3702
3703    my $dbh = C4::Context->dbh;
3704
3705    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3706    return $sth->execute( $code, $toBranch, $fromBranch );
3707 }
3708
3709 =head2 DeleteBranchTransferLimits
3710
3711     my $result = DeleteBranchTransferLimits($frombranch);
3712
3713 Deletes all the library transfer limits for one library.  Returns the
3714 number of limits deleted, 0e0 if no limits were deleted, or undef if
3715 no arguments are supplied.
3716
3717 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3718     fromBranch => $fromBranch
3719     })->delete.
3720
3721 =cut
3722
3723 sub DeleteBranchTransferLimits {
3724     my $branch = shift;
3725     return unless defined $branch;
3726     my $dbh    = C4::Context->dbh;
3727     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3728     return $sth->execute($branch);
3729 }
3730
3731 sub ReturnLostItem{
3732     my ( $borrowernumber, $itemnum ) = @_;
3733     MarkIssueReturned( $borrowernumber, $itemnum );
3734 }
3735
3736 =head2 LostItem
3737
3738   LostItem( $itemnumber, $mark_lost_from, $force_mark_returned, [$params] );
3739
3740 The final optional parameter, C<$params>, expected to contain
3741 'skip_record_index' key, which relayed down to Koha::Item/store,
3742 there it prevents calling of ModZebra index_records,
3743 which takes most of the time in batch adds/deletes: index_records better
3744 to be called later in C<additem.pl> after the whole loop.
3745
3746 $params:
3747     skip_record_index => 1|0
3748
3749 =cut
3750
3751 sub LostItem{
3752     my ($itemnumber, $mark_lost_from, $force_mark_returned, $params) = @_;
3753
3754     unless ( $mark_lost_from ) {
3755         # Temporary check to avoid regressions
3756         die q|LostItem called without $mark_lost_from, check the API.|;
3757     }
3758
3759     my $mark_returned;
3760     if ( $force_mark_returned ) {
3761         $mark_returned = 1;
3762     } else {
3763         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3764         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3765     }
3766
3767     my $dbh = C4::Context->dbh();
3768     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3769                            FROM issues
3770                            JOIN items USING (itemnumber)
3771                            JOIN biblio USING (biblionumber)
3772                            WHERE issues.itemnumber=?");
3773     $sth->execute($itemnumber);
3774     my $issues=$sth->fetchrow_hashref();
3775
3776     # If a borrower lost the item, add a replacement cost to the their record
3777     if ( my $borrowernumber = $issues->{borrowernumber} ){
3778         my $patron = Koha::Patrons->find( $borrowernumber );
3779
3780         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
3781         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3782
3783         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3784             C4::Accounts::chargelostitem(
3785                 $borrowernumber,
3786                 $itemnumber,
3787                 $issues->{'replacementprice'},
3788                 sprintf( "%s %s %s",
3789                     $issues->{'title'}          || q{},
3790                     $issues->{'barcode'}        || q{},
3791                     $issues->{'itemcallnumber'} || q{},
3792                 ),
3793             );
3794             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3795             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3796         }
3797
3798         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy) if $mark_returned;
3799     }
3800
3801     #When item is marked lost automatically cancel its outstanding transfers and set items holdingbranch to the transfer source branch (frombranch)
3802     if (my ( $datesent,$frombranch,$tobranch ) = GetTransfers($itemnumber)) {
3803         Koha::Items->find($itemnumber)->holdingbranch($frombranch)->store({ skip_record_index => $params->{skip_record_index} });
3804     }
3805     my $transferdeleted = DeleteTransfer($itemnumber);
3806 }
3807
3808 sub GetOfflineOperations {
3809     my $dbh = C4::Context->dbh;
3810     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3811     $sth->execute(C4::Context->userenv->{'branch'});
3812     my $results = $sth->fetchall_arrayref({});
3813     return $results;
3814 }
3815
3816 sub GetOfflineOperation {
3817     my $operationid = shift;
3818     return unless $operationid;
3819     my $dbh = C4::Context->dbh;
3820     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3821     $sth->execute( $operationid );
3822     return $sth->fetchrow_hashref;
3823 }
3824
3825 sub AddOfflineOperation {
3826     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3827     my $dbh = C4::Context->dbh;
3828     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3829     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3830     return "Added.";
3831 }
3832
3833 sub DeleteOfflineOperation {
3834     my $dbh = C4::Context->dbh;
3835     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
3836     $sth->execute( shift );
3837     return "Deleted.";
3838 }
3839
3840 sub ProcessOfflineOperation {
3841     my $operation = shift;
3842
3843     my $report;
3844     if ( $operation->{action} eq 'return' ) {
3845         $report = ProcessOfflineReturn( $operation );
3846     } elsif ( $operation->{action} eq 'issue' ) {
3847         $report = ProcessOfflineIssue( $operation );
3848     } elsif ( $operation->{action} eq 'payment' ) {
3849         $report = ProcessOfflinePayment( $operation );
3850     }
3851
3852     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
3853
3854     return $report;
3855 }
3856
3857 sub ProcessOfflineReturn {
3858     my $operation = shift;
3859
3860     my $item = Koha::Items->find({barcode => $operation->{barcode}});
3861
3862     if ( $item ) {
3863         my $itemnumber = $item->itemnumber;
3864         my $issue = GetOpenIssue( $itemnumber );
3865         if ( $issue ) {
3866             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
3867             ModDateLastSeen( $itemnumber, $leave_item_lost );
3868             MarkIssueReturned(
3869                 $issue->{borrowernumber},
3870                 $itemnumber,
3871                 $operation->{timestamp},
3872             );
3873             $item->renewals(0);
3874             $item->onloan(undef);
3875             $item->store({ log_action => 0 });
3876             return "Success.";
3877         } else {
3878             return "Item not issued.";
3879         }
3880     } else {
3881         return "Item not found.";
3882     }
3883 }
3884
3885 sub ProcessOfflineIssue {
3886     my $operation = shift;
3887
3888     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
3889
3890     if ( $patron ) {
3891         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
3892         unless ($item) {
3893             return "Barcode not found.";
3894         }
3895         my $itemnumber = $item->itemnumber;
3896         my $issue = GetOpenIssue( $itemnumber );
3897
3898         if ( $issue and ( $issue->{borrowernumber} ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
3899             MarkIssueReturned(
3900                 $issue->{borrowernumber},
3901                 $itemnumber,
3902                 $operation->{timestamp},
3903             );
3904         }
3905         AddIssue(
3906             $patron->unblessed,
3907             $operation->{'barcode'},
3908             undef,
3909             1,
3910             $operation->{timestamp},
3911             undef,
3912         );
3913         return "Success.";
3914     } else {
3915         return "Borrower not found.";
3916     }
3917 }
3918
3919 sub ProcessOfflinePayment {
3920     my $operation = shift;
3921
3922     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
3923
3924     $patron->account->pay(
3925         {
3926             amount     => $operation->{amount},
3927             library_id => $operation->{branchcode},
3928             interface  => 'koc'
3929         }
3930     );
3931
3932     return "Success.";
3933 }
3934
3935 =head2 TransferSlip
3936
3937   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
3938
3939   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
3940
3941 =cut
3942
3943 sub TransferSlip {
3944     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
3945
3946     my $item =
3947       $itemnumber
3948       ? Koha::Items->find($itemnumber)
3949       : Koha::Items->find( { barcode => $barcode } );
3950
3951     $item or return;
3952
3953     return C4::Letters::GetPreparedLetter (
3954         module => 'circulation',
3955         letter_code => 'TRANSFERSLIP',
3956         branchcode => $branch,
3957         tables => {
3958             'branches'    => $to_branch,
3959             'biblio'      => $item->biblionumber,
3960             'items'       => $item->unblessed,
3961         },
3962     );
3963 }
3964
3965 =head2 CheckIfIssuedToPatron
3966
3967   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
3968
3969   Return 1 if any record item is issued to patron, otherwise return 0
3970
3971 =cut
3972
3973 sub CheckIfIssuedToPatron {
3974     my ($borrowernumber, $biblionumber) = @_;
3975
3976     my $dbh = C4::Context->dbh;
3977     my $query = q|
3978         SELECT COUNT(*) FROM issues
3979         LEFT JOIN items ON items.itemnumber = issues.itemnumber
3980         WHERE items.biblionumber = ?
3981         AND issues.borrowernumber = ?
3982     |;
3983     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
3984     return 1 if $is_issued;
3985     return;
3986 }
3987
3988 =head2 IsItemIssued
3989
3990   IsItemIssued( $itemnumber )
3991
3992   Return 1 if the item is on loan, otherwise return 0
3993
3994 =cut
3995
3996 sub IsItemIssued {
3997     my $itemnumber = shift;
3998     my $dbh = C4::Context->dbh;
3999     my $sth = $dbh->prepare(q{
4000         SELECT COUNT(*)
4001         FROM issues
4002         WHERE itemnumber = ?
4003     });
4004     $sth->execute($itemnumber);
4005     return $sth->fetchrow;
4006 }
4007
4008 =head2 GetAgeRestriction
4009
4010   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4011   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4012
4013   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4014   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4015
4016 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4017 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4018 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4019          Negative days mean the borrower has gone past the age restriction age.
4020
4021 =cut
4022
4023 sub GetAgeRestriction {
4024     my ($record_restrictions, $borrower) = @_;
4025     my $markers = C4::Context->preference('AgeRestrictionMarker');
4026
4027     return unless $record_restrictions;
4028     # Split $record_restrictions to something like FSK 16 or PEGI 6
4029     my @values = split ' ', uc($record_restrictions);
4030     return unless @values;
4031
4032     # Search first occurrence of one of the markers
4033     my @markers = split /\|/, uc($markers);
4034     return unless @markers;
4035
4036     my $index            = 0;
4037     my $restriction_year = 0;
4038     for my $value (@values) {
4039         $index++;
4040         for my $marker (@markers) {
4041             $marker =~ s/^\s+//;    #remove leading spaces
4042             $marker =~ s/\s+$//;    #remove trailing spaces
4043             if ( $marker eq $value ) {
4044                 if ( $index <= $#values ) {
4045                     $restriction_year += $values[$index];
4046                 }
4047                 last;
4048             }
4049             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4050
4051                 # Perhaps it is something like "K16" (as in Finland)
4052                 $restriction_year += $1;
4053                 last;
4054             }
4055         }
4056         last if ( $restriction_year > 0 );
4057     }
4058
4059     #Check if the borrower is age restricted for this material and for how long.
4060     if ($restriction_year && $borrower) {
4061         if ( $borrower->{'dateofbirth'} ) {
4062             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4063             $alloweddate[0] += $restriction_year;
4064
4065             #Prevent runime eror on leap year (invalid date)
4066             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4067                 $alloweddate[2] = 28;
4068             }
4069
4070             #Get how many days the borrower has to reach the age restriction
4071             my @Today = split /-/, dt_from_string()->ymd();
4072             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4073             #Negative days means the borrower went past the age restriction age
4074             return ($restriction_year, $daysToAgeRestriction);
4075         }
4076     }
4077
4078     return ($restriction_year);
4079 }
4080
4081
4082 =head2 GetPendingOnSiteCheckouts
4083
4084 =cut
4085
4086 sub GetPendingOnSiteCheckouts {
4087     my $dbh = C4::Context->dbh;
4088     return $dbh->selectall_arrayref(q|
4089         SELECT
4090           items.barcode,
4091           items.biblionumber,
4092           items.itemnumber,
4093           items.itemnotes,
4094           items.itemcallnumber,
4095           items.location,
4096           issues.date_due,
4097           issues.branchcode,
4098           issues.date_due < NOW() AS is_overdue,
4099           biblio.author,
4100           biblio.title,
4101           borrowers.firstname,
4102           borrowers.surname,
4103           borrowers.cardnumber,
4104           borrowers.borrowernumber
4105         FROM items
4106         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4107         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4108         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4109         WHERE issues.onsite_checkout = 1
4110     |, { Slice => {} } );
4111 }
4112
4113 sub GetTopIssues {
4114     my ($params) = @_;
4115
4116     my ($count, $branch, $itemtype, $ccode, $newness)
4117         = @$params{qw(count branch itemtype ccode newness)};
4118
4119     my $dbh = C4::Context->dbh;
4120     my $query = q{
4121         SELECT * FROM (
4122         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4123           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4124           i.ccode, SUM(i.issues) AS count
4125         FROM biblio b
4126         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4127         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4128     };
4129
4130     my (@where_strs, @where_args);
4131
4132     if ($branch) {
4133         push @where_strs, 'i.homebranch = ?';
4134         push @where_args, $branch;
4135     }
4136     if ($itemtype) {
4137         if (C4::Context->preference('item-level_itypes')){
4138             push @where_strs, 'i.itype = ?';
4139             push @where_args, $itemtype;
4140         } else {
4141             push @where_strs, 'bi.itemtype = ?';
4142             push @where_args, $itemtype;
4143         }
4144     }
4145     if ($ccode) {
4146         push @where_strs, 'i.ccode = ?';
4147         push @where_args, $ccode;
4148     }
4149     if ($newness) {
4150         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4151         push @where_args, $newness;
4152     }
4153
4154     if (@where_strs) {
4155         $query .= 'WHERE ' . join(' AND ', @where_strs);
4156     }
4157
4158     $query .= q{
4159         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4160           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4161           i.ccode
4162         ORDER BY count DESC
4163     };
4164
4165     $query .= q{ ) xxx WHERE count > 0 };
4166     $count = int($count);
4167     if ($count > 0) {
4168         $query .= "LIMIT $count";
4169     }
4170
4171     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4172
4173     return @$rows;
4174 }
4175
4176 =head2 Internal methods
4177
4178 =cut
4179
4180 sub _CalculateAndUpdateFine {
4181     my ($params) = @_;
4182
4183     my $borrower    = $params->{borrower};
4184     my $item        = $params->{item};
4185     my $issue       = $params->{issue};
4186     my $return_date = $params->{return_date};
4187
4188     unless ($borrower) { carp "No borrower passed in!" && return; }
4189     unless ($item)     { carp "No item passed in!"     && return; }
4190     unless ($issue)    { carp "No issue passed in!"    && return; }
4191
4192     my $datedue = dt_from_string( $issue->date_due );
4193
4194     # we only need to calculate and change the fines if we want to do that on return
4195     # Should be on for hourly loans
4196     my $control = C4::Context->preference('CircControl');
4197     my $control_branchcode =
4198         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4199       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4200       :                                     $issue->branchcode;
4201
4202     my $date_returned = $return_date ? $return_date : dt_from_string();
4203
4204     my ( $amount, $unitcounttotal, $unitcount  ) =
4205       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4206
4207     if ( C4::Context->preference('finesMode') eq 'production' ) {
4208         if ( $amount > 0 ) {
4209             C4::Overdues::UpdateFine({
4210                 issue_id       => $issue->issue_id,
4211                 itemnumber     => $issue->itemnumber,
4212                 borrowernumber => $issue->borrowernumber,
4213                 amount         => $amount,
4214                 due            => output_pref($datedue),
4215             });
4216         }
4217         elsif ($return_date) {
4218
4219             # Backdated returns may have fines that shouldn't exist,
4220             # so in this case, we need to drop those fines to 0
4221
4222             C4::Overdues::UpdateFine({
4223                 issue_id       => $issue->issue_id,
4224                 itemnumber     => $issue->itemnumber,
4225                 borrowernumber => $issue->borrowernumber,
4226                 amount         => 0,
4227                 due            => output_pref($datedue),
4228             });
4229         }
4230     }
4231 }
4232
4233 sub _item_denied_renewal {
4234     my ($params) = @_;
4235
4236     my $item = $params->{item};
4237     return unless $item;
4238
4239     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
4240     return unless $denyingrules;
4241     foreach my $field (keys %$denyingrules) {
4242         my $val = $item->$field;
4243         if( !defined $val) {
4244             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
4245                 return 1;
4246             }
4247         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
4248            # If the results matches the values in the syspref
4249            # We return true if match found
4250             return 1;
4251         }
4252     }
4253     return 0;
4254 }
4255
4256 1;
4257
4258 __END__
4259
4260 =head1 AUTHOR
4261
4262 Koha Development Team <http://koha-community.org/>
4263
4264 =cut