acqui/neworderempty.pl

   1 #!/usr/bin/perl
   2
   3 #script to show display basket of orders
   4 #written by chris@katipo.co.nz 24/2/2000
   5
   6 # Copyright 2000-2002 Katipo Communications
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23
  24 =head1 NAME
  25
  26 neworderempty.pl
  27
  28 =head1 DESCRIPTION
  29
  30 this script allows to create a new record to order it. This record shouldn't exist
  31 on database.
  32
  33 =head1 CGI PARAMETERS
  34
  35 =over 4
  36
  37 =item booksellerid
  38 the bookseller the librarian has to buy a new book.
  39
  40 =item title
  41 the title of this new record.
  42
  43 =item author
  44 the author of this new record.
  45
  46 =item publication year
  47 the publication year of this new record.
  48
  49 =item ordernumber
  50 the number of this order.
  51
  52 =item biblio
  53
  54 =item basketno
  55 the basket number for this new order.
  56
  57 =item suggestionid
  58 if this order comes from a suggestion.
  59
  60 =item breedingid
  61 the item's id in the breeding reservoir
  62
  63 =back
  64
  65 =cut
  66
  67 use Modern::Perl;
  68 use CGI qw ( -utf8 );
  69 use C4::Context;
  70
  71 use C4::Auth;
  72 use C4::Budgets;
  73
  74 use C4::Acquisition;
  75 use C4::Contract;
  76 use C4::Suggestions;    # GetSuggestion
  77 use C4::Biblio;                 # GetBiblioData GetMarcPrice
  78 use C4::Items; #PrepareItemRecord
  79 use C4::Output;
  80 use C4::Koha;
  81 use C4::Members;
  82 use C4::Search qw/FindDuplicate/;
  83
  84 #needed for z3950 import:
  85 use C4::ImportBatch qw/GetImportRecordMarc SetImportRecordStatus/;
  86
  87 use Koha::Acquisition::Booksellers;
  88 use Koha::Acquisition::Currencies;
  89 use Koha::BiblioFrameworks;
  90 use Koha::DateUtils qw( dt_from_string );
  91 use Koha::MarcSubfieldStructures;
  92 use Koha::ItemTypes;
  93 use Koha::Patrons;
  94 use Koha::RecordProcessor;
  95 use Koha::Subscriptions;
  96
  97 our $input           = new CGI;
  98 my $booksellerid    = $input->param('booksellerid');    # FIXME: else ERROR!
  99 my $budget_id       = $input->param('budget_id') || 0;
 100 my $title           = $input->param('title');
 101 my $author          = $input->param('author');
 102 my $publicationyear = $input->param('publicationyear');
 103 my $ordernumber          = $input->param('ordernumber') || '';
 104 our $biblionumber    = $input->param('biblionumber');
 105 our $basketno        = $input->param('basketno');
 106 my $suggestionid    = $input->param('suggestionid');
 107 my $uncertainprice  = $input->param('uncertainprice');
 108 my $import_batch_id = $input->param('import_batch_id'); # if this is filled, we come from a staged file, and we will return here after saving the order !
 109 my $from_subscriptionid  = $input->param('from_subscriptionid');
 110 my $data;
 111 my $new = 'no';
 112
 113 our ( $template, $loggedinuser, $cookie, $userflags ) = get_template_and_user(
 114     {
 115         template_name   => "acqui/neworderempty.tt",
 116         query           => $input,
 117         type            => "intranet",
 118         authnotrequired => 0,
 119         flagsrequired   => { acquisition => 'order_manage' },
 120         debug           => 1,
 121     }
 122 );
 123
 124 our $marcflavour = C4::Context->preference('marcflavour');
 125
 126 if(!$basketno) {
 127     my $order = GetOrder($ordernumber);
 128     $basketno = $order->{'basketno'};
 129 }
 130
 131 our $basket = GetBasket($basketno);
 132 my $basketobj = Koha::Acquisition::Baskets->find( $basketno );
 133 $booksellerid = $basket->{booksellerid} unless $booksellerid;
 134 my $bookseller = Koha::Acquisition::Booksellers->find( $booksellerid );
 135
 136 output_and_exit( $input, $cookie, $template, 'unknown_basket') unless $basketobj;
 137 output_and_exit( $input, $cookie, $template, 'unknown_vendor') unless $bookseller;
 138
 139 my $contract = GetContract({
 140     contractnumber => $basket->{contractnumber}
 141 });
 142
 143 #simple parameters reading (all in one :-)
 144 our $params = $input->Vars;
 145 my $listprice=0; # the price, that can be in MARC record if we have one
 146 if ( $ordernumber eq '' and defined $params->{'breedingid'}){
 147 #we want to import from the breeding reservoir (from a z3950 search)
 148     my ($marcrecord, $encoding) = MARCfindbreeding($params->{'breedingid'});
 149     die("Could not find the selected record in the reservoir, bailing") unless $marcrecord;
 150
 151     # Remove all the items (952) from the imported record
 152     foreach my $item ($marcrecord->field('952')) {
 153         $marcrecord->delete_field($item);
 154     }
 155
 156     my $duplicatetitle;
 157 #look for duplicates
 158     ($biblionumber,$duplicatetitle) = FindDuplicate($marcrecord);
 159     if($biblionumber && !$input->param('use_external_source')) {
 160         #if duplicate record found and user did not decide yet, first warn user
 161         #and let them choose between using a new record or an existing record
 162         Load_Duplicate($duplicatetitle);
 163         exit;
 164     }
 165     #from this point: add a new record
 166         my $bibitemnum;
 167         $params->{'frameworkcode'} or $params->{'frameworkcode'} = "";
 168         ( $biblionumber, $bibitemnum ) = AddBiblio( $marcrecord, $params->{'frameworkcode'} );
 169         # get the price if there is one.
 170         $listprice = GetMarcPrice($marcrecord, $marcflavour);
 171         SetImportRecordStatus($params->{'breedingid'}, 'imported');
 172 }
 173
 174
 175
 176 my ( @order_user_ids, @order_users, @catalog_details );
 177 our $tagslib = GetMarcStructure(1, 'ACQ', { unsafe => 1 } );
 178 my ( $itemnumber_tag, $itemnumber_subtag ) = GetMarcFromKohaField( 'items.itemnumber' );
 179 if ( not $ordernumber ) {    # create order
 180     $new = 'yes';
 181
 182     if ( $biblionumber ) {
 183         $data = GetBiblioData($biblionumber);
 184     }
 185     # get suggestion fields if applicable. If it's a subscription renewal, then the biblio already exists
 186     # otherwise, retrieve suggestion information.
 187     elsif ($suggestionid) {
 188         $data = GetSuggestion($suggestionid);
 189         $budget_id ||= $data->{'budgetid'} // 0;
 190     }
 191
 192     if ( not $biblionumber and Koha::BiblioFrameworks->find('ACQ') ) {
 193         #my $acq_mss = Koha::MarcSubfieldStructures->search({ frameworkcode => 'ACQ', tagfield => { '!=' => $itemnumber_tag } });
 194         foreach my $tag ( sort keys %{$tagslib} ) {
 195             next if $tag eq '';
 196             next if $tag eq $itemnumber_tag;    # skip items fields
 197             foreach my $subfield ( sort keys %{ $tagslib->{$tag} } ) {
 198                 my $mss = $tagslib->{$tag}{$subfield};
 199                 next if IsMarcStructureInternal($mss);
 200                 next if $mss->{tab} == -1;
 201                 my $value = $mss->{defaultvalue};
 202
 203                 if ($suggestionid and $mss->{kohafield}) {
 204                     # Reading suggestion info if ordering from a suggestion
 205                     if ( $mss->{kohafield} eq 'biblio.title' ) {
 206                         $value = $data->{title};
 207                     }
 208                     elsif ( $mss->{kohafield} eq 'biblio.author' ) {
 209                         $value = $data->{author};
 210                     }
 211                     elsif ( $mss->{kohafield} eq 'biblioitems.publishercode' ) {
 212                         $value = $data->{publishercode};
 213                     }
 214                     elsif ( $mss->{kohafield} eq 'biblioitems.editionstatement' ) {
 215                         $value = $data->{editionstatement};
 216                     }
 217                     elsif ( $mss->{kohafield} eq 'biblioitems.publicationyear' ) {
 218                         $value = $data->{publicationyear};
 219                     }
 220                     elsif ( $mss->{kohafield} eq 'biblioitems.isbn' ) {
 221                         $value = $data->{isbn};
 222                     }
 223                     elsif ( $mss->{kohafield} eq 'biblio.seriestitle' ) {
 224                         $value = $data->{seriestitle};
 225                     }
 226                 }
 227
 228                 if ( $value eq '' ) {
 229
 230                     # get today date & replace <<YYYY>>, <<MM>>, <<DD>> if provided in the default value
 231                     my $today_dt = dt_from_string;
 232                     my $year     = $today_dt->strftime('%Y');
 233                     my $month    = $today_dt->strftime('%m');
 234                     my $day      = $today_dt->strftime('%d');
 235                     $value =~ s/<<YYYY>>/$year/g;
 236                     $value =~ s/<<MM>>/$month/g;
 237                     $value =~ s/<<DD>>/$day/g;
 238
 239                     # And <<USER>> with surname (?)
 240                     my $username =
 241                       (   C4::Context->userenv
 242                         ? C4::Context->userenv->{'surname'}
 243                         : "superlibrarian" );
 244                     $value =~ s/<<USER>>/$username/g;
 245                 }
 246                 push @catalog_details, {
 247                     tag      => $tag,
 248                     subfield => $subfield,
 249                     %$mss,    # Do we need plugins support (?)
 250                     value => $value,
 251                 };
 252             }
 253         }
 254     }
 255 }
 256 else {    #modify order
 257     $data   = GetOrder($ordernumber);
 258     $budget_id = $data->{'budget_id'};
 259
 260     $template->param(
 261         subscriptionid => $data->{subscriptionid},
 262     );
 263
 264     $basket   = GetBasket( $data->{'basketno'} );
 265     $basketno = $basket->{'basketno'};
 266
 267     @order_user_ids = GetOrderUsers($ordernumber);
 268     foreach my $order_user_id (@order_user_ids) {
 269         # FIXME Could be improved with search -in
 270         my $order_patron = Koha::Patrons->find( $order_user_id );
 271         push @order_users, $order_patron if $order_patron;
 272     }
 273 }
 274 $biblionumber = $data->{biblionumber};
 275
 276 # We can have:
 277 # - no ordernumber but a biblionumber: from a subscription, from an existing record
 278 # - no ordernumber, no biblionumber: from a suggestion, from a new order
 279 if ( not $ordernumber or $biblionumber ) {
 280     if ( C4::Context->preference('UseACQFrameworkForBiblioRecords') ) {
 281         my $record = $biblionumber ? GetMarcBiblio({ biblionumber => $biblionumber }) : undef;
 282         foreach my $tag ( sort keys %{$tagslib} ) {
 283             next if $tag eq '';
 284             next if $tag eq $itemnumber_tag; # skip items fields
 285             my @fields = $biblionumber ? $record->field($tag) : ();
 286             foreach my $subfield ( sort keys %{ $tagslib->{$tag} } ) {
 287                 my $mss = $tagslib->{$tag}{$subfield};
 288                 next if IsMarcStructureInternal($mss);
 289                 next if $mss->{tab} == -1;
 290                 # We only need to display the values
 291                 my $value = join '; ', map { $tag < 10 ? $_->data : $_->subfield( $subfield ) } @fields;
 292                 if ( $value ) {
 293                     push @catalog_details, {
 294                         tag => $tag,
 295                         subfield => $subfield,
 296                         %$mss,
 297                         value => $value,
 298                     };
 299                 }
 300             }
 301         }
 302     }
 303 }
 304
 305 $template->param( catalog_details => \@catalog_details, );
 306
 307 my $suggestion;
 308 $suggestion = GetSuggestionInfo($suggestionid) if $suggestionid;
 309
 310 my @currencies = Koha::Acquisition::Currencies->search;
 311 my $active_currency = Koha::Acquisition::Currencies->get_active;
 312
 313 # build bookfund list
 314 my $patron = Koha::Patrons->find( $loggedinuser )->unblessed;
 315
 316 my $budget =  GetBudget($budget_id);
 317 # build budget list
 318 my $budget_loop = [];
 319 my $budgets = GetBudgetHierarchy;
 320 foreach my $r (@{$budgets}) {
 321     next unless (CanUserUseBudget($patron, $r, $userflags));
 322     if (!defined $r->{budget_amount} || $r->{budget_amount} <0) {
 323         next;
 324     }
 325     push @{$budget_loop}, {
 326         b_id  => $r->{budget_id},
 327         b_txt => $r->{budget_name},
 328         b_sort1_authcat => $r->{'sort1_authcat'},
 329         b_sort2_authcat => $r->{'sort2_authcat'},
 330         b_active => $r->{budget_period_active},
 331         b_sel => ( $r->{budget_id} == $budget_id ) ? 1 : 0,
 332         b_level => $r->{budget_level},
 333     };
 334 }
 335
 336
 337 $template->param( sort1 => $data->{'sort1'} );
 338 $template->param( sort2 => $data->{'sort2'} );
 339
 340 if ($basketobj->effective_create_items eq 'ordering' && !$ordernumber) {
 341     # Check if ACQ framework exists
 342     my $marc = GetMarcStructure(1, 'ACQ', { unsafe => 1 } );
 343     unless($marc) {
 344         $template->param('NoACQframework' => 1);
 345     }
 346     $template->param(
 347         AcqCreateItemOrdering => 1,
 348         UniqueItemFields => C4::Context->preference('UniqueItemFields'),
 349     );
 350 }
 351
 352 # Get the item types list, but only if item_level_itype is YES. Otherwise, it will be in the item, no need to display it in the biblio
 353 my @itemtypes;
 354 @itemtypes = Koha::ItemTypes->search unless C4::Context->preference('item-level_itypes');
 355
 356 if ( defined $from_subscriptionid ) {
 357     my $lastOrderReceived = GetLastOrderReceivedFromSubscriptionid $from_subscriptionid;
 358     if ( defined $lastOrderReceived ) {
 359         $budget_id              = $lastOrderReceived->{budgetid};
 360         $data->{listprice}      = $lastOrderReceived->{listprice};
 361         $data->{uncertainprice} = $lastOrderReceived->{uncertainprice};
 362         $data->{tax_rate}       = $lastOrderReceived->{tax_rate_on_ordering};
 363         $data->{discount}       = $lastOrderReceived->{discount};
 364         $data->{rrp}            = $lastOrderReceived->{rrp};
 365         $data->{replacementprice} = $lastOrderReceived->{replacementprice};
 366         $data->{ecost}          = $lastOrderReceived->{ecost};
 367         $data->{quantity}       = $lastOrderReceived->{quantity};
 368         $data->{unitprice}       = $lastOrderReceived->{unitprice};
 369         $data->{order_internalnote} = $lastOrderReceived->{order_internalnote};
 370         $data->{order_vendornote}   = $lastOrderReceived->{order_vendornote};
 371         $data->{sort1}          = $lastOrderReceived->{sort1};
 372         $data->{sort2}          = $lastOrderReceived->{sort2};
 373
 374         $basket = GetBasket( $input->param('basketno') );
 375     }
 376
 377     my $subscription = Koha::Subscriptions->find($from_subscriptionid);
 378     $template->param(
 379         subscriptionid => $from_subscriptionid,
 380         subscription   => $subscription,
 381     );
 382 }
 383
 384 # Find the items.barcode subfield for barcode validations
 385 my (undef, $barcode_subfield) = GetMarcFromKohaField( 'items.barcode' );
 386
 387
 388 # get option values for gist syspref
 389 my @gst_values = map {
 390     option => $_ + 0.0
 391 }, split( '\|', C4::Context->preference("gist") );
 392
 393 my $quantity = $input->param('rr_quantity_to_order') ?
 394       $input->param('rr_quantity_to_order') :
 395       $data->{'quantity'};
 396 $quantity //= 0;
 397
 398 # fill template
 399 $template->param(
 400     existing         => $biblionumber,
 401     ordernumber           => $ordernumber,
 402     # basket informations
 403     basketno             => $basketno,
 404     basket               => $basket,
 405     basketname           => $basket->{'basketname'},
 406     basketnote           => $basket->{'note'},
 407     booksellerid         => $basket->{'booksellerid'},
 408     basketbooksellernote => $basket->{booksellernote},
 409     basketcontractno     => $basket->{contractnumber},
 410     basketcontractname   => $contract->{contractname},
 411     creationdate         => $basket->{creationdate},
 412     authorisedby         => $basket->{'authorisedby'},
 413     authorisedbyname     => $basket->{'authorisedbyname'},
 414     closedate            => $basket->{'closedate'},
 415     # order details
 416     suggestionid         => $suggestion->{suggestionid},
 417     surnamesuggestedby   => $suggestion->{surnamesuggestedby},
 418     firstnamesuggestedby => $suggestion->{firstnamesuggestedby},
 419     biblionumber         => $biblionumber,
 420     uncertainprice       => $data->{'uncertainprice'},
 421     discount_2dp         => sprintf( "%.2f",  $bookseller->discount ) ,   # for display
 422     discount             => $bookseller->discount,
 423     orderdiscount_2dp    => sprintf( "%.2f", $data->{'discount'} || 0 ),
 424     orderdiscount        => $data->{'discount'},
 425     order_internalnote   => $data->{'order_internalnote'},
 426     order_vendornote     => $data->{'order_vendornote'},
 427     listincgst       => $bookseller->listincgst,
 428     invoiceincgst    => $bookseller->invoiceincgst,
 429     name             => $bookseller->name,
 430     cur_active_sym   => $active_currency->symbol,
 431     cur_active       => $active_currency->currency,
 432     currencies       => \@currencies,
 433     currency         => $data->{currency},
 434     vendor_currency  => $bookseller->listprice,
 435     orderexists      => ( $new eq 'yes' ) ? 0 : 1,
 436     title            => $data->{'title'},
 437     author           => $data->{'author'},
 438     publicationyear  => $data->{'publicationyear'} ? $data->{'publicationyear'} : $data->{'copyrightdate'},
 439     editionstatement => $data->{'editionstatement'},
 440     budget_loop      => $budget_loop,
 441     isbn             => $data->{'isbn'},
 442     ean              => $data->{'ean'},
 443     seriestitle      => $data->{'seriestitle'},
 444     itemtypeloop     => \@itemtypes,
 445     quantity         => $quantity,
 446     quantityrec      => $quantity,
 447     rrp              => $data->{'rrp'},
 448     replacementprice => $data->{'replacementprice'},
 449     gst_values       => \@gst_values,
 450     tax_rate         => $data->{tax_rate_on_ordering} ? $data->{tax_rate_on_ordering}+0.0 : $bookseller->tax_rate ? $bookseller->tax_rate+0.0 : 0,
 451     listprice        => sprintf( "%.2f", $data->{listprice} || $data->{price} || $listprice),
 452     total            => sprintf( "%.2f", ($data->{ecost} || 0) * ($data->{'quantity'} || 0) ),
 453     ecost            => sprintf( "%.2f", $data->{ecost} || 0),
 454     unitprice        => sprintf( "%.2f", $data->{unitprice} || 0),
 455     publishercode    => $data->{'publishercode'},
 456     barcode_subfield => $barcode_subfield,
 457     import_batch_id  => $import_batch_id,
 458     acqcreate        => $basketobj->effective_create_items eq "ordering" ? 1 : "",
 459     users_ids        => join(':', @order_user_ids),
 460     users            => \@order_users,
 461     (uc(C4::Context->preference("marcflavour"))) => 1
 462 );
 463
 464 output_html_with_http_headers $input, $cookie, $template->output;
 465
 466
 467 =head2 MARCfindbreeding
 468
 469   $record = MARCfindbreeding($breedingid);
 470
 471 Look up the import record repository for the record with
 472 record with id $breedingid.  If found, returns the decoded
 473 MARC::Record; otherwise, -1 is returned (FIXME).
 474 Returns as second parameter the character encoding.
 475
 476 =cut
 477
 478 sub MARCfindbreeding {
 479     my ( $id ) = @_;
 480     my ($marc, $encoding) = GetImportRecordMarc($id);
 481     # remove the - in isbn, koha store isbn without any -
 482     if ($marc) {
 483         my $record = MARC::Record->new_from_usmarc($marc);
 484         my ($isbnfield,$isbnsubfield) = GetMarcFromKohaField( 'biblioitems.isbn' );
 485         if ( $record->field($isbnfield) ) {
 486             foreach my $field ( $record->field($isbnfield) ) {
 487                 foreach my $subfield ( $field->subfield($isbnsubfield) ) {
 488                     my $newisbn = $field->subfield($isbnsubfield);
 489                     $newisbn =~ s/-//g;
 490                     $field->update( $isbnsubfield => $newisbn );
 491                 }
 492             }
 493         }
 494         # fix the unimarc 100 coded field (with unicode information)
 495         if ($marcflavour eq 'UNIMARC' && $record->subfield(100,'a')) {
 496             my $f100a=$record->subfield(100,'a');
 497             my $f100 = $record->field(100);
 498             my $f100temp = $f100->as_string;
 499             $record->delete_field($f100);
 500             if ( length($f100temp) > 28 ) {
 501                 substr( $f100temp, 26, 2, "50" );
 502                 $f100->update( 'a' => $f100temp );
 503                 my $f100 = MARC::Field->new( '100', '', '', 'a' => $f100temp );
 504                 $record->insert_fields_ordered($f100);
 505             }
 506         }
 507
 508         if ( !defined(ref($record)) ) {
 509             return -1;
 510         }
 511         else {
 512             # normalize author : probably UNIMARC specific...
 513             if (    C4::Context->preference("z3950NormalizeAuthor")
 514                 and C4::Context->preference("z3950AuthorAuthFields") )
 515             {
 516                 my ( $tag, $subfield ) = GetMarcFromKohaField( "biblio.author" );
 517
 518                 my $auth_fields =
 519                 C4::Context->preference("z3950AuthorAuthFields");
 520                 my @auth_fields = split /,/, $auth_fields;
 521                 my $field;
 522
 523                 if ( $record->field($tag) ) {
 524                     foreach my $tmpfield ( $record->field($tag)->subfields ) {
 525
 526                         my $subfieldcode  = shift @$tmpfield;
 527                         my $subfieldvalue = shift @$tmpfield;
 528                         if ($field) {
 529                             $field->add_subfields(
 530                                 "$subfieldcode" => $subfieldvalue )
 531                             if ( $subfieldcode ne $subfield );
 532                         }
 533                         else {
 534                             $field =
 535                             MARC::Field->new( $tag, "", "",
 536                                 $subfieldcode => $subfieldvalue )
 537                             if ( $subfieldcode ne $subfield );
 538                         }
 539                     }
 540                 }
 541                 $record->delete_field( $record->field($tag) );
 542                 foreach my $fieldtag (@auth_fields) {
 543                     next unless ( $record->field($fieldtag) );
 544                     my $lastname  = $record->field($fieldtag)->subfield('a');
 545                     my $firstname = $record->field($fieldtag)->subfield('b');
 546                     my $title     = $record->field($fieldtag)->subfield('c');
 547                     my $number    = $record->field($fieldtag)->subfield('d');
 548                     if ($title) {
 549                         $field->add_subfields(
 550                                 "$subfield" => ucfirst($title) . " "
 551                             . ucfirst($firstname) . " "
 552                             . $number );
 553                     }
 554                     else {
 555                         $field->add_subfields(
 556                             "$subfield" => ucfirst($firstname) . ", "
 557                             . ucfirst($lastname) );
 558                     }
 559                 }
 560                 $record->insert_fields_ordered($field);
 561             }
 562             return $record, $encoding;
 563         }
 564     }
 565     return -1;
 566 }
 567
 568 sub Load_Duplicate {
 569   my ($duplicatetitle)= @_;
 570   ($template, $loggedinuser, $cookie) = get_template_and_user(
 571     {
 572         template_name   => "acqui/neworderempty_duplicate.tt",
 573         query           => $input,
 574         type            => "intranet",
 575         authnotrequired => 0,
 576         flagsrequired   => { acquisition => 'order_manage' },
 577 #        debug           => 1,
 578     }
 579   );
 580
 581   $template->param(
 582     biblionumber        => $biblionumber,
 583     basketno            => $basketno,
 584     booksellerid        => $basket->{'booksellerid'},
 585     breedingid          => $params->{'breedingid'},
 586     duplicatetitle      => $duplicatetitle,
 587     (uc(C4::Context->preference("marcflavour"))) => 1
 588   );
 589
 590   output_html_with_http_headers $input, $cookie, $template->output;
 591 }