tools/upload.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Copyright (C) 2015 Rijksmuseum
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use CGI qw/-utf8/;
  22 use JSON;
  23
  24 use C4::Auth;
  25 use C4::Output;
  26 use Koha::UploadedFiles;
  27
  28 use constant ERR_READING     => 'UPLERR_FILE_NOT_READ';
  29 use constant ALERT_DELETED   => 'UPL_FILE_DELETED'; # alert, no error
  30 use constant ERR_NOT_DELETED => 'UPLERR_FILE_NOT_DELETED';
  31
  32 my $input  = CGI::->new;
  33 my $op     = $input->param('op') // 'new';
  34 my $plugin = $input->param('plugin');
  35 my $index  = $input->param('index');         # MARC editor input field id
  36 my $term   = $input->param('term');
  37 my $id     = $input->param('id');
  38 my $msg    = $input->param('msg');
  39
  40 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  41     {   template_name   => "tools/upload.tt",
  42         query           => $input,
  43         type            => "intranet",
  44         flagsrequired   => { tools => 'upload_general_files' },
  45     }
  46 );
  47
  48 $template->param(
  49     index      => $index,
  50     owner      => $loggedinuser,
  51     plugin     => $plugin,
  52     uploadcategories => Koha::UploadedFiles->getCategories,
  53 );
  54
  55 if ( $op eq 'new' ) {
  56     $template->param(
  57         mode             => 'new',
  58     );
  59     output_html_with_http_headers $input, $cookie, $template->output;
  60
  61 } elsif ( $op eq 'search' ) {
  62     my $uploads;
  63     if( $id ) { # might be a comma separated list
  64         my @id = split /,/, $id;
  65         foreach my $recid (@id) {
  66             my $rec = Koha::UploadedFiles->find( $recid );
  67             push @$uploads, $rec->unblessed
  68                 if $rec && ( $rec->public || !$plugin );
  69                 # Do not show private uploads in the plugin mode (:editor)
  70         }
  71     } else {
  72         $uploads = Koha::UploadedFiles->search_term({
  73             term => $term,
  74             $plugin? (): ( include_private => 1 ),
  75         })->unblessed;
  76     }
  77
  78     $template->param(
  79         mode    => 'report',
  80         msg     => $msg,
  81         uploads => $uploads,
  82     );
  83     output_html_with_http_headers $input, $cookie, $template->output;
  84
  85 } elsif ( $op eq 'delete' ) {
  86     # delete only takes the id parameter
  87     my $rec = Koha::UploadedFiles->find($id);
  88     undef $rec if $rec && $plugin && !$rec->public;
  89     my $fn = $rec ? $rec->filename : '';
  90     my $delete = $rec ? $rec->delete : undef;
  91     #TODO Improve error handling
  92     my $msg = $delete
  93         ? JSON::to_json({ $fn => { code => ALERT_DELETED }})
  94         : $id
  95         ? JSON::to_json({ $fn || $id, { code => ERR_NOT_DELETED }})
  96         : '';
  97     $template->param(
  98         mode             => 'deleted',
  99         msg              => $msg,
 100     );
 101     output_html_with_http_headers $input, $cookie, $template->output;
 102
 103 } elsif ( $op eq 'download' ) {
 104     my $rec = Koha::UploadedFiles->find( $id );
 105     undef $rec if $rec && $plugin && !$rec->public;
 106     my $fh  = $rec? $rec->file_handle:  undef;
 107     if ( !$rec || !$fh ) {
 108         $template->param(
 109             mode             => 'new',
 110             msg              => JSON::to_json({ $id => { code => ERR_READING }}),
 111         );
 112         output_html_with_http_headers $input, $cookie, $template->output;
 113     } else {
 114         print Encode::encode_utf8( $input->header( $rec->httpheaders ) );
 115         while (<$fh>) {
 116             print $_;
 117         }
 118         $fh->close;
 119     }
 120 }